| blob | 67218c737ff4c256c0f93dfaa9832ca62c36f114 |
1 .file "exp10f.s"
4 // Copyright (c) 2000 - 2005, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
39 //
40 // History
41 //==============================================================
42 // 08/25/00 Initial version
43 // 05/20/02 Cleaned up namespace and sf0 syntax
44 // 09/06/02 Improved performance and accuracy; no inexact flags on exact cases
45 // 01/29/03 Added missing } to bundle templates
46 // 12/16/04 Call error handling on underflow.
47 // 03/31/05 Reformatted delimiters between data tables
48 //
49 // API
50 //==============================================================
51 // float exp10f(float)
52 //
53 // Overview of operation
54 //==============================================================
55 // Background
56 //
57 // Implementation
58 //
59 // Let x= (K + fh + fl + r)/log2(10), where
60 // K is an integer, fh= 0.b1 b2 b3 b4 b5,
61 // fl= 2^{-5}* 0.b6 b7 b8 b8 b10 (fh, fl >= 0),
62 // and |r|<2^{-11}
63 // Th is a table that stores 2^fh (32 entries) rounded to
64 // double extended precision (only mantissa is stored)
65 // Tl is a table that stores 2^fl (32 entries) rounded to
66 // double extended precision (only mantissa is stored)
67 //
68 // 10^x is approximated as
69 // 2^K * Th [ f ] * Tl [ f ] * (1+c1*r+c2*r^2)
71 // Note there are only 10 non-zero values that produce an exact result:
72 // 1.0, 2.0, ... 10.0.
73 // We test for these cases and use s1 to avoid setting the inexact flag.
75 // Special values
76 //==============================================================
77 // exp10(0)= 1
78 // exp10(+inf)= inf
79 // exp10(-inf)= 0
80 //
82 // Registers used
83 //==============================================================
84 // r2-r3, r14-r40
85 // f6-f15, f32-f52
86 // p6-p12
87 //
89 #include <shlib-compat.h>
92 GR_TBL_START = r2
93 GR_LOG_TBL = r3
95 GR_OF_LIMIT = r14
96 GR_UF_LIMIT = r15
97 GR_EXP_CORR = r16
98 GR_F_low = r17
99 GR_F_high = r18
100 GR_K = r19
101 GR_Flow_ADDR = r20
103 GR_BIAS = r21
104 GR_Fh = r22
105 GR_Fh_ADDR = r23
106 GR_EXPMAX = r24
108 GR_ROUNDVAL = r26
109 GR_SNORM_LIMIT = r26
110 GR_MASK = r27
111 GR_KF0 = r28
112 GR_MASK_low = r29
113 GR_COEFF_START = r30
114 GR_exact_limit = r31
116 GR_SAVE_B0 = r33
117 GR_SAVE_PFS = r34
118 GR_SAVE_GP = r35
119 GR_SAVE_SP = r36
121 GR_Parameter_X = r37
122 GR_Parameter_Y = r38
123 GR_Parameter_RESULT = r39
124 GR_Parameter_TAG = r40
127 FR_X = f10
128 FR_Y = f1
129 FR_RESULT = f8
132 FR_COEFF1 = f6
133 FR_COEFF2 = f7
134 FR_R = f9
135 FR_LOG2_10 = f10
137 FR_2P53 = f11
138 FR_KF0 = f12
139 FR_COEFF3 = f13
140 FR_COEFF4 = f14
141 FR_UF_LIMIT = f15
143 FR_OF_LIMIT = f32
144 FR_DX_L210 = f33
145 FR_ROUNDVAL = f34
146 FR_KF = f35
148 FR_2_TO_K = f36
149 FR_T_low = f37
150 FR_T_high = f38
152 FR_P12 = f41
153 FR_T_low_K = f42
154 FR_T = f44
155 FR_P = f45
157 FR_E = f49
158 FR_exact_limit = f50
160 FR_int_x = f51
161 FR_SNORM_LIMIT = f52
164 // Data tables
165 //==============================================================
167 RODATA
169 .align 16
171 LOCAL_OBJECT_START(poly_coeffs)
173 data8 0xd49a784bcd1b8afe, 0x00003fcb // log2(10)*2^(10-63)
174 data8 0xb17217f7d1cf79ab, 0x00004033 // C_1 * 2^53
175 data8 0xf5fdeffc162c7541, 0x00004066 // C_2 * 2^106
176 LOCAL_OBJECT_END(poly_coeffs)
179 LOCAL_OBJECT_START(T_table)
181 // 2^{0.00000 b6 b7 b8 b9 b10}
182 data8 0x8000000000000000, 0x8016302f17467628
183 data8 0x802c6436d0e04f50, 0x80429c17d77c18ed
184 data8 0x8058d7d2d5e5f6b0, 0x806f17687707a7af
185 data8 0x80855ad965e88b83, 0x809ba2264dada76a
186 data8 0x80b1ed4fd999ab6c, 0x80c83c56b50cf77f
187 data8 0x80de8f3b8b85a0af, 0x80f4e5ff089f763e
188 data8 0x810b40a1d81406d4, 0x81219f24a5baa59d
189 data8 0x813801881d886f7b, 0x814e67cceb90502c
190 data8 0x8164d1f3bc030773, 0x817b3ffd3b2f2e47
191 data8 0x8191b1ea15813bfd, 0x81a827baf7838b78
192 data8 0x81bea1708dde6055, 0x81d51f0b8557ec1c
193 data8 0x81eba08c8ad4536f, 0x820225f44b55b33b
194 data8 0x8218af4373fc25eb, 0x822f3c7ab205c89a
195 data8 0x8245cd9ab2cec048, 0x825c62a423d13f0c
196 data8 0x8272fb97b2a5894c, 0x828998760d01faf3
197 data8 0x82a0393fe0bb0ca8, 0x82b6ddf5dbc35906
198 //
199 // 2^{0.b1 b2 b3 b4 b5}
200 data8 0x8000000000000000, 0x82cd8698ac2ba1d7
201 data8 0x85aac367cc487b14, 0x88980e8092da8527
202 data8 0x8b95c1e3ea8bd6e6, 0x8ea4398b45cd53c0
203 data8 0x91c3d373ab11c336, 0x94f4efa8fef70961
204 data8 0x9837f0518db8a96f, 0x9b8d39b9d54e5538
205 data8 0x9ef5326091a111ad, 0xa27043030c496818
206 data8 0xa5fed6a9b15138ea, 0xa9a15ab4ea7c0ef8
207 data8 0xad583eea42a14ac6, 0xb123f581d2ac258f
208 data8 0xb504f333f9de6484, 0xb8fbaf4762fb9ee9
209 data8 0xbd08a39f580c36be, 0xc12c4cca66709456
210 data8 0xc5672a115506dadd, 0xc9b9bd866e2f27a2
211 data8 0xce248c151f8480e3, 0xd2a81d91f12ae45a
212 data8 0xd744fccad69d6af4, 0xdbfbb797daf23755
213 data8 0xe0ccdeec2a94e111, 0xe5b906e77c8348a8
214 data8 0xeac0c6e7dd24392e, 0xefe4b99bdcdaf5cb
215 data8 0xf5257d152486cc2c, 0xfa83b2db722a033a
216 LOCAL_OBJECT_END(T_table)
220 .section .text
221 GLOBAL_IEEE754_ENTRY(exp10f)
224 {.mfi
225 alloc r32= ar.pfs, 1, 4, 4, 0
226 // will continue only for non-zero normal/denormal numbers
227 fclass.nm.unc p12, p7= f8, 0x1b
228 nop.i 0
229 }
230 {.mlx
231 // GR_TBL_START= pointer to log2(10), C_1...C_4 followed by T_table
232 addl GR_TBL_START= @ltoff(poly_coeffs), gp
233 movl GR_ROUNDVAL= 0x3fc00000 // 1.5 (SP)
234 }
235 ;;
237 {.mfi
238 ld8 GR_COEFF_START= [ GR_TBL_START ] // Load pointer to coeff table
239 fcmp.lt.s1 p6, p8= f8, f0 // X<0 ?
240 nop.i 0
241 }
242 ;;
244 {.mlx
245 nop.m 0
246 movl GR_UF_LIMIT= 0xc2349e35 // (-2^7-22) / log2(10)
247 }
248 {.mlx
249 setf.s FR_ROUNDVAL= GR_ROUNDVAL
250 movl GR_OF_LIMIT= 0x421a209a // Overflow threshold
251 }
252 ;;
254 {.mlx
255 ldfe FR_LOG2_10= [ GR_COEFF_START ], 16 // load log2(10)*2^(10-63)
256 movl GR_SNORM_LIMIT= 0xc217b818 // Smallest normal threshold
257 }
258 {.mib
259 nop.m 0
260 nop.i 0
261 (p12) br.cond.spnt SPECIAL_exp10 // Branch if nan, inf, zero
262 }
263 ;;
265 {.mfi
266 setf.s FR_OF_LIMIT= GR_OF_LIMIT // Set overflow limit
267 fma.s0 f8= f8, f1, f0 // normalize x
268 nop.i 0
269 }
270 ;;
272 {.mfi
273 setf.s FR_SNORM_LIMIT= GR_SNORM_LIMIT // Set smallest normal limit
274 (p8) fcvt.fx.s1 FR_int_x = f8 // Convert x to integer
275 nop.i 0
276 }
277 {.mfi
278 setf.s FR_UF_LIMIT= GR_UF_LIMIT // Set underflow limit
279 fma.s1 FR_KF0= f8, FR_LOG2_10, FR_ROUNDVAL // y= (x*log2(10)*2^10 +
280 // 1.5*2^63) * 2^(-63)
281 mov GR_EXP_CORR= 0xffff-126
282 }
283 ;;
285 {.mfi
286 ldfe FR_COEFF1= [ GR_COEFF_START ], 16 // load C_1
287 fms.s1 FR_KF= FR_KF0, f1, FR_ROUNDVAL // (K+f)*2^(10-63)
288 mov GR_MASK= 1023
289 }
290 ;;
292 {.mfi
293 ldfe FR_COEFF2= [ GR_COEFF_START ], 16 // load C_2
294 nop.f 0
295 mov GR_MASK_low= 31
296 }
297 ;;
299 {.mlx
300 getf.sig GR_KF0= FR_KF0 // (K+f)*2^10= round_to_int(y)
301 (p8) movl GR_exact_limit= 0x41200000 // Largest x for exact result,
302 // +10.0
303 }
304 ;;
306 {.mfi
307 add GR_LOG_TBL= 256, GR_COEFF_START // Pointer to high T_table
308 fcmp.gt.s1 p12, p7= f8, FR_OF_LIMIT // x>overflow threshold ?
309 nop.i 0
310 }
311 ;;
313 {.mfi
314 (p8) setf.s FR_exact_limit = GR_exact_limit // Largest x for exact result
315 (p8) fcvt.xf FR_int_x = FR_int_x // Integral part of x
316 shr GR_K= GR_KF0, 10 // K
317 }
318 {.mfi
319 and GR_F_high= GR_MASK, GR_KF0 // f_high*32
320 fms.s1 FR_R= f8, FR_LOG2_10, FR_KF // r*2^(-53)= [ x*log2(10)-
321 // (K+f) ] *2^{10-63}
322 and GR_F_low= GR_KF0, GR_MASK_low // f_low
323 }
324 ;;
326 {.mmi
327 shladd GR_Flow_ADDR= GR_F_low, 3, GR_COEFF_START // address of 2^{f_low}
328 add GR_BIAS= GR_K, GR_EXP_CORR // K= bias-2*63
329 shr GR_Fh= GR_F_high, 5 // f_high
330 }
331 ;;
333 {.mfi
334 setf.exp FR_2_TO_K= GR_BIAS // 2^{K-126}
335 (p7) fcmp.lt.s1 p12, p7= f8, FR_UF_LIMIT // x<underflow threshold ?
336 shladd GR_Fh_ADDR= GR_Fh, 3, GR_LOG_TBL // address of 2^{f_high}
337 }
338 {.mfi
339 ldf8 FR_T_low= [ GR_Flow_ADDR ] // load T_low= 2^{f_low}
340 nop.f 0
341 nop.i 0
342 }
343 ;;
345 {.mfb
346 ldf8 FR_T_high= [ GR_Fh_ADDR ] // load T_high= 2^{f_high}
347 fcmp.ge.s1 p11, p0= f8, FR_SNORM_LIMIT // Test x for normal range
348 (p12) br.cond.spnt OUT_RANGE_exp10
349 }
350 ;;
352 {.mfi
353 nop.m 0
354 fma.s1 FR_P12= FR_COEFF2, FR_R, FR_COEFF1 // P12= C_1+C_2*r
355 cmp.eq p7,p9= r0,r0 // Assume inexact result
356 }
357 ;;
359 {.mfi
360 nop.m 0
361 (p8) fcmp.eq.s1 p9,p7= FR_int_x, f8 // Test x positive integer
362 nop.i 0
363 }
364 {.mfi
365 nop.m 0
366 fma.s1 FR_T_low_K= FR_T_low, FR_2_TO_K, f0 // T= 2^{K-126}*T_low
367 nop.i 0
368 }
369 ;;
371 {.mfi
372 nop.m 0
373 fma.s1 FR_P= FR_P12, FR_R, f0 // P= P12*r
374 nop.i 0
375 }
376 ;;
378 // If x a positive integer, will it produce an exact result?
379 // p7 result will be inexact
380 // p9 result will be exact
381 {.mfi
382 nop.m 0
383 (p9) fcmp.le.s1 p9,p7= f8, FR_exact_limit // Test x gives exact result
384 nop.i 0
385 }
386 {.mfi
387 nop.m 0
388 fma.s1 FR_T= FR_T_low_K, FR_T_high, f0 // T= T*T_high
389 nop.i 0
390 }
391 ;;
393 .pred.rel "mutex",p7,p9
394 {.mfi
395 nop.m 0
396 (p7) fma.s.s0 f8= FR_P, FR_T, FR_T // result= T+T*P, inexact set
397 nop.i 0
398 }
399 {.mfb
400 nop.m 0
401 (p9) fma.s.s1 f8= FR_P, FR_T, FR_T // result= T+T*P, exact use s1
402 (p11) br.ret.sptk b0 // return, if result normal
403 }
404 ;;
406 // Here if result in denormal range (and not zero)
407 {.mib
408 nop.m 0
409 mov GR_Parameter_TAG= 266
410 br.cond.sptk __libm_error_region // Branch to error handling
411 }
412 ;;
414 SPECIAL_exp10:
415 {.mfi
416 nop.m 0
417 fclass.m p6, p0= f8, 0x22 // x= -Infinity ?
418 nop.i 0
419 }
420 ;;
422 {.mfi
423 nop.m 0
424 fclass.m p7, p0= f8, 0x21 // x= +Infinity ?
425 nop.i 0
426 }
427 ;;
429 {.mfi
430 nop.m 0
431 fclass.m p8, p0= f8, 0x7 // x= +/-Zero ?
432 nop.i 0
433 }
434 {.mfb
435 nop.m 0
436 (p6) mov f8= f0 // exp10(-Infinity)= 0
437 (p6) br.ret.spnt b0
438 }
439 ;;
441 {.mfb
442 nop.m 0
443 nop.f 0
444 (p7) br.ret.spnt b0 // exp10(+Infinity)= +Infinity
445 }
446 ;;
448 {.mfb
449 nop.m 0
450 (p8) mov f8= f1 // exp10(+/-0)= 1
451 (p8) br.ret.spnt b0
452 }
453 ;;
455 {.mfb
456 nop.m 0
457 fma.s.s0 f8= f8, f1, f0 // Remaining cases: NaNs
458 br.ret.sptk b0
459 }
460 ;;
463 OUT_RANGE_exp10:
465 // underflow: p6= 1
466 // overflow: p8= 1
468 .pred.rel "mutex",p6,p8
469 {.mmi
470 (p8) mov GR_EXPMAX= 0x1fffe
471 (p6) mov GR_EXPMAX= 1
472 nop.i 0
473 }
474 ;;
476 {.mii
477 setf.exp FR_R= GR_EXPMAX
478 (p8) mov GR_Parameter_TAG= 167
479 (p6) mov GR_Parameter_TAG= 266
480 }
481 ;;
483 {.mfb
484 nop.m 0
485 fma.s.s0 f8= FR_R, FR_R, f0 // Create overflow/underflow
486 br.cond.sptk __libm_error_region // Branch to error handling
487 }
488 ;;
490 GLOBAL_IEEE754_END(exp10f)
491 libm_alias_float_other (__exp10, exp10)
492 #if SHLIB_COMPAT (libm, GLIBC_2_1, GLIBC_2_27)
493 compat_symbol (libm, exp10f, pow10f, GLIBC_2_2)
494 #endif
497 LOCAL_LIBM_ENTRY(__libm_error_region)
499 .prologue
500 {.mfi
501 add GR_Parameter_Y= -32, sp // Parameter 2 value
502 nop.f 0
503 .save ar.pfs, GR_SAVE_PFS
504 mov GR_SAVE_PFS= ar.pfs // Save ar.pfs
505 }
507 {.mfi
508 .fframe 64
509 add sp= -64, sp // Create new stack
510 nop.f 0
511 mov GR_SAVE_GP= gp // Save gp
512 }
513 ;;
515 {.mmi
516 stfs [ GR_Parameter_Y ]= FR_Y, 16 // STORE Parameter 2 on stack
517 add GR_Parameter_X= 16, sp // Parameter 1 address
518 .save b0, GR_SAVE_B0
519 mov GR_SAVE_B0= b0 // Save b0
520 }
521 ;;
523 .body
524 {.mib
525 stfs [ GR_Parameter_X ]= FR_X // STORE Parameter 1 on stack
526 add GR_Parameter_RESULT= 0, GR_Parameter_Y // Parameter 3 address
527 nop.b 0
528 }
529 {.mib
530 stfs [ GR_Parameter_Y ]= FR_RESULT // STORE Parameter 3 on stack
531 add GR_Parameter_Y= -16, GR_Parameter_Y
532 br.call.sptk b0= __libm_error_support# // Call error handling function
533 }
534 ;;
536 {.mmi
537 add GR_Parameter_RESULT= 48, sp
538 nop.m 0
539 nop.i 0
540 }
541 ;;
543 {.mmi
544 ldfs f8= [ GR_Parameter_RESULT ] // Get return result off stack
545 .restore sp
546 add sp= 64, sp // Restore stack pointer
547 mov b0= GR_SAVE_B0 // Restore return address
548 }
549 ;;
551 {.mib
552 mov gp= GR_SAVE_GP // Restore gp
553 mov ar.pfs= GR_SAVE_PFS // Restore ar.pfs
554 br.ret.sptk b0 // Return
555 }
556 ;;
559 LOCAL_LIBM_END(__libm_error_region)
561 .type __libm_error_support#, @function
562 .global __libm_error_support#