sysdeps/powerpc/powerpc32/fpu/s_rint.S

   1 /* Round to int floating-point values.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 /* This has been coded in assembler because GCC makes such a mess of it
  21    when it's coded in C.  */
  22
  23 #include <sysdep.h>
  24
  25         .section        .rodata.cst4,"aM",@progbits,4
  26         .align  2
  27 .LC0:   /* 2**52 */
  28         .long 0x59800000
  29
  30         .section        ".text"
  31 ENTRY (__rint)
  32 #ifdef SHARED
  33         mflr    r11
  34         cfi_register(lr,r11)
  35 # ifdef HAVE_ASM_PPC_REL16
  36         bcl     20,31,1f
  37 1:      mflr    r9
  38         addis   r9,r9,.LC0-1b@ha
  39         lfs     fp13,.LC0-1b@l(r9)
  40 # else
  41         bl      _GLOBAL_OFFSET_TABLE_@local-4
  42         mflr    r10
  43         lwz     r9,.LC0@got(10)
  44         lfs     fp13,0(r9)
  45 # endif
  46         mtlr    r11
  47         cfi_same_value (lr)
  48 #else
  49         lis     r9,.LC0@ha
  50         lfs     fp13,.LC0@l(r9)
  51 #endif
  52         fabs    fp0,fp1
  53         fsub    fp12,fp13,fp13  /* generate 0.0  */
  54         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  55         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  56         bnllr-  cr7
  57         bng-    cr6,.L4
  58         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  59         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  60         fabs    fp1,fp1         /* if (x == 0.0)  */
  61         blr                     /* x = 0.0; */
  62 .L4:
  63         bnllr-  cr6             /* if (x < 0.0)  */
  64         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  65         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  66         fnabs   fp1,fp1         /* if (x == 0.0)  */
  67         blr                     /* x = -0.0; */
  68         END (__rint)
  69
  70 weak_alias (__rint, rint)
  71
  72 #ifdef NO_LONG_DOUBLE
  73 weak_alias (__rint, rintl)
  74 strong_alias (__rint, __rintl)
  75 #endif