sysdeps/powerpc/powerpc32/fpu/s_lround.S

   1 /* lround function.  PowerPC32 version.
   2    Copyright (C) 2004, 2006 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 1 Franklin Street, Fifth Floor, Boston MA
  18    02110-1301 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata.cst8,"aM",@progbits,8
  23         .align  2
  24 .LC0:   /* 0.0 */
  25         .long 0x00000000
  26 .LC1:   /* 0.5 */
  27         .long 0x3f000000
  28
  29         .section        ".text"
  30
  31 /* long [r3] lround (float x [fp1])
  32    IEEE 1003.1 lround function.  IEEE specifies "round to the nearest
  33    integer value, rounding halfway cases away from zero, regardless of
  34    the current rounding mode."  However PowerPC Architecture defines
  35    "round to Nearest" as "Choose the best approximation. In case of a
  36    tie, choose the one that is even (least significant bit o).".
  37    So we can't use the PowerPC "round to Nearest" mode. Instead we set
  38    "round toward Zero" mode and round by adding +-0.5 before rounding
  39    to the integer value.  */
  40
  41 ENTRY (__lround)
  42         stwu    r1,-16(r1)
  43         cfi_adjust_cfa_offset (16)
  44 #ifdef SHARED
  45         mflr    r11
  46         cfi_register(lr,r11)
  47 # ifdef HAVE_ASM_PPC_REL16
  48         bcl     20,31,1f
  49 1:      mflr    r9
  50         addis   r9,r9,.LC0-1b@ha
  51         addi    r9,r9,.LC0-1b@l
  52 # else
  53         bl      _GLOBAL_OFFSET_TABLE_@local-4
  54         mflr    r10
  55         lwz     r9,.LC0@got(10)
  56 # endif
  57         mtlr    r11
  58         cfi_same_value (lr)
  59         lfs     fp12,0(r9)
  60 #else
  61         lis     r9,.LC0@ha
  62         lfs     fp12,.LC0@l(r9)
  63 #endif
  64 #ifdef SHARED
  65         lfs     fp10,.LC1-.LC0(r9)
  66 #else
  67         lis     r9,.LC1@ha
  68         lfs     fp10,.LC1@l(r9)
  69 #endif
  70         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  71         ble-    cr6,.L4
  72         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  73 .L9:
  74         fctiwz  fp2,fp1         /* Convert To Integer DW lround toward 0.  */
  75         stfd    fp2,8(r1)
  76         nop     /* Ensure the following load is in a different dispatch  */
  77         nop     /* group to avoid pipe stall on POWER4&5.  */
  78         nop
  79         lwz     r3,12(r1)
  80         addi    r1,r1,16
  81         blr
  82 .L4:
  83         fsub    fp1,fp1,fp10    /* x-= 0.5;  */
  84         b       .L9
  85         END (__lround)
  86
  87 weak_alias (__lround, lround)
  88
  89 strong_alias (__lround, __lroundf)
  90 weak_alias (__lround, lroundf)
  91
  92 #ifdef NO_LONG_DOUBLE
  93 weak_alias (__lround, lroundl)
  94 strong_alias (__lround, __lroundl)
  95 #endif