sysdeps/arm/configure.ac

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2 # Local configure fragment for sysdeps/arm.
   3
   4 dnl It is always possible to access static and hidden symbols in an
   5 dnl position independent way.
   6 dnl NOTE: This feature was added by the GCC TLS patches.  We should test for
   7 dnl it.  Until we do, don't define it.
   8 #AC_DEFINE(PI_STATIC_AND_HIDDEN)
   9
  10 AC_CACHE_CHECK([whether the CFI directive .cfi_sections is supported],
  11   [libc_cv_asm_cfi_directive_sections],
  12   [cat > conftest.s <<EOF
  13         .text
  14         .cfi_sections .debug_frame, .eh_frame
  15         .cfi_startproc
  16         .cfi_endproc
  17 EOF
  18   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
  19     libc_cv_asm_cfi_directive_sections=yes
  20   else
  21     libc_cv_asm_cfi_directive_sections=no
  22   fi
  23   rm -f conftest*])
  24 if test $libc_cv_asm_cfi_directive_sections != yes; then
  25   AC_MSG_ERROR([need .cfi_sections in this configuration])
  26 fi
  27
  28 # We check to see if the compiler and flags are
  29 # selecting the hard-float ABI and if they are then
  30 # we set libc_cv_arm_pcs_vfp to yes which causes
  31 # HAVE_ARM_PCS_VFP to be defined in config.h and
  32 # in include/libc-symbols.h and thus available to
  33 # shlib-versions to select the appropriate name for
  34 # the dynamic linker via %ifdef.
  35 AC_CACHE_CHECK([whether the compiler is using the ARM hard-float ABI],
  36   [libc_cv_arm_pcs_vfp],
  37   [AC_EGREP_CPP(yes,[#ifdef __ARM_PCS_VFP
  38                       yes
  39                      #endif
  40   ], libc_cv_arm_pcs_vfp=yes, libc_cv_arm_pcs_vfp=no)])
  41 if test $libc_cv_arm_pcs_vfp = yes; then
  42   AC_DEFINE(HAVE_ARM_PCS_VFP)
  43   LIBC_CONFIG_VAR([default-abi], [hard])
  44 else
  45   LIBC_CONFIG_VAR([default-abi], [soft])
  46 fi