sysdeps/arm/setjmp.S

   1 /* setjmp for ARM.
   2    Copyright (C) 1997, 1998, 2005, 2006, 2008 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #define _SETJMP_H
  21 #define _ASM
  22 #include <bits/setjmp.h>
  23 #include <rtld-global-offsets.h>
  24
  25 ENTRY (__sigsetjmp)
  26         mov     ip, r0
  27
  28         /* Save registers */
  29         stmia   ip!, {v1-v6, sl, fp, sp, lr}
  30
  31         /* Check if we have a VFP unit.  */
  32 #ifdef IS_IN_rtld
  33         ldr     a3, 1f
  34         ldr     a4, Lrtld_local_ro
  35 0:      add     a3, pc, a3
  36         add     a3, a3, a4
  37         ldr     a3, [a3, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  38 #else
  39 #ifdef PIC
  40         ldr     a3, 1f
  41         ldr     a4, Lrtld_global_ro
  42 0:      add     a3, pc, a3
  43         ldr     a3, [a3, a4]
  44         ldr     a3, [a3, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  45 #else
  46         ldr     a3, Lhwcap
  47         ldr     a3, [a3, #0]
  48 #endif
  49 #endif
  50
  51         tst     a3, #HWCAP_ARM_VFP
  52         beq     Lno_vfp
  53
  54         /* Store the VFP registers.
  55            Don't use VFP instructions directly because this code
  56            is used in non-VFP multilibs.  */
  57         /* Following instruction is vstmia ip!, {d8-d15}.  */
  58         stc     p11, cr8, [ip], #64
  59         /* Store the floating-point status register.  */
  60         /* Following instruction is vmrs a4, fpscr.  */
  61         mrc     p10, 7, a4, cr1, cr0, 0
  62         str     a4, [ip], #4
  63 Lno_vfp:
  64
  65         tst     a3, #HWCAP_ARM_IWMMXT
  66         beq     Lno_iwmmxt
  67
  68         /* Save the call-preserved iWMMXt registers.  */
  69         /* Following instructions are wstrd wr10, [ip], #8 (etc.)  */
  70         stcl    p1, cr10, [r12], #8
  71         stcl    p1, cr11, [r12], #8
  72         stcl    p1, cr12, [r12], #8
  73         stcl    p1, cr13, [r12], #8
  74         stcl    p1, cr14, [r12], #8
  75         stcl    p1, cr15, [r12], #8
  76 Lno_iwmmxt:
  77
  78         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  79         B       PLTJMP(C_SYMBOL_NAME(__sigjmp_save))
  80
  81 #ifdef IS_IN_rtld
  82 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
  83 Lrtld_local_ro:
  84         .long   C_SYMBOL_NAME(_rtld_local_ro)(GOTOFF)
  85 #else
  86 #ifdef PIC
  87 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
  88 Lrtld_global_ro:
  89         .long   C_SYMBOL_NAME(_rtld_global_ro)(GOT)
  90 #else
  91 Lhwcap:
  92         .long   C_SYMBOL_NAME(_dl_hwcap)
  93 #endif
  94 #endif
  95
  96 END (__sigsetjmp)
  97
  98 hidden_def (__sigsetjmp)