sysdeps/arm/__longjmp.S

   1 /* longjmp for ARM.
   2    Copyright (C) 1997, 1998, 2005, 2006, 2009, 2010
   3      Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library.  If not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #define _SETJMP_H
  22 #define _ASM
  23 #include <bits/setjmp.h>
  24 #include <rtld-global-offsets.h>
  25
  26 /* __longjmp(jmpbuf, val) */
  27
  28 ENTRY (__longjmp)
  29         mov     ip, r0
  30         movs    r0, r1          /* get the return value in place */
  31         moveq   r0, #1          /* can't let setjmp() return zero! */
  32
  33 #ifdef CHECK_SP
  34         ldr     r4, [ip, #32]   /* jmpbuf's sp */
  35         cfi_undefined (r4)
  36         CHECK_SP (r4)
  37 #endif
  38         LOADREGS(ia, ip!, {v1-v6, sl, fp, sp, lr})
  39         cfi_restore (v1)
  40         cfi_restore (v2)
  41         cfi_restore (v3)
  42         cfi_restore (v4)
  43         cfi_restore (v5)
  44         cfi_restore (v6)
  45         cfi_restore (sl)
  46         cfi_restore (fp)
  47         cfi_restore (sp)
  48         cfi_restore (lr)
  49
  50 #ifdef IS_IN_rtld
  51         ldr     a2, 1f
  52         ldr     a3, Lrtld_local_ro
  53 0:      add     a2, pc, a2
  54         add     a2, a2, a3
  55         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  56 #else
  57 #ifdef PIC
  58         ldr     a2, 1f
  59         ldr     a3, Lrtld_global_ro
  60 0:      add     a2, pc, a2
  61         ldr     a2, [a2, a3]
  62         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  63 #else
  64         ldr     a2, Lhwcap
  65         ldr     a2, [a2, #0]
  66 #endif
  67 #endif
  68
  69         tst     a2, #HWCAP_ARM_VFP
  70         beq     Lno_vfp
  71
  72         /* Restore the VFP registers.  */
  73         /* Following instruction is vldmia ip!, {d8-d15}.  */
  74         ldc     p11, cr8, [r12], #64
  75         /* Restore the floating-point status register.  */
  76         ldr     a3, [ip], #4
  77         /* Following instruction is fmxr fpscr, a3.  */
  78         mcr     p10, 7, a3, cr1, cr0, 0
  79 Lno_vfp:
  80
  81         tst     a2, #HWCAP_ARM_IWMMXT
  82         beq     Lno_iwmmxt
  83
  84         /* Restore the call-preserved iWMMXt registers.  */
  85         /* Following instructions are wldrd wr10, [ip], #8 (etc.)  */
  86         ldcl    p1, cr10, [r12], #8
  87         ldcl    p1, cr11, [r12], #8
  88         ldcl    p1, cr12, [r12], #8
  89         ldcl    p1, cr13, [r12], #8
  90         ldcl    p1, cr14, [r12], #8
  91         ldcl    p1, cr15, [r12], #8
  92 Lno_iwmmxt:
  93
  94         DO_RET(lr)
  95
  96 #ifdef IS_IN_rtld
  97 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
  98 Lrtld_local_ro:
  99         .long   C_SYMBOL_NAME(_rtld_local_ro)(GOTOFF)
 100 #else
 101 #ifdef PIC
 102 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
 103 Lrtld_global_ro:
 104         .long   C_SYMBOL_NAME(_rtld_global_ro)(GOT)
 105 #else
 106 Lhwcap:
 107         .long   C_SYMBOL_NAME(_dl_hwcap)
 108 #endif
 109 #endif
 110
 111 END (__longjmp)