sysdeps/x86/configure.ac

   1 GLIBC_PROVIDES dnl See aclocal.m4 in the top level source directory.
   2 # Local configure fragment for sysdeps/x86.
   3
   4 if test x"$enable_cet" = xyes; then
   5   # Check if CET can be enabled.
   6   AC_CACHE_CHECK(whether CET can be enabled,
   7                  libc_cv_x86_cet_available, [dnl
   8 cat > conftest.c <<EOF
   9 #if !defined __CET__ || __CET__ != 3
  10 # error CET isn't available.
  11 #endif
  12 EOF
  13                  if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS -fcf-protection -include cet.h conftest.c 1>&AS_MESSAGE_LOG_FD); then
  14                    libc_cv_x86_cet_available=yes
  15                  else
  16                    libc_cv_x86_cet_available=no
  17                  fi
  18                  rm -rf conftest*])
  19   if test $libc_cv_x86_cet_available = yes; then
  20     enable_cet=yes
  21   else
  22     if test x"$enable_cet" = xdefault; then
  23       enable_cet=no
  24     else
  25       AC_MSG_ERROR([$CC doesn't support CET])
  26     fi
  27   fi
  28 fi
  29 if test $enable_cet = yes; then
  30   # Check if assembler supports CET.
  31   AC_CACHE_CHECK(whether $AS supports CET,
  32                  libc_cv_x86_cet_as, [dnl
  33 cat > conftest.s <<EOF
  34         incsspd %ecx
  35 EOF
  36                  if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s -o conftest.o 1>&AS_MESSAGE_LOG_FD); then
  37                    libc_cv_x86_cet_as=yes
  38                  else
  39                    libc_cv_x86_cet_as=no
  40                  fi
  41                  rm -rf conftest*])
  42   if test $libc_cv_x86_cet_as = no; then
  43     AC_MSG_ERROR([$AS doesn't support CET])
  44   fi
  45 fi
  46 LIBC_CONFIG_VAR([enable-cet], [$enable_cet])