| blob | d8cd5f167916aa1dc66be0302d6d4ac8cb78899d |
1 dnl Process this file with autoconf to produce a configure script.
2 AC_REVISION([$CVSid$])
3 AC_PREREQ(2.53)dnl dnl Minimum Autoconf version required.
4 AC_INIT([GNU C Library], [(see version.h)], [glibc])
5 AC_CONFIG_SRCDIR([include/features.h])
6 AC_CONFIG_HEADERS([config.h])
7 AC_CONFIG_AUX_DIR([scripts])
9 dnl This is here so we can set $subdirs directly based on configure fragments.
10 AC_CONFIG_SUBDIRS()
12 AC_CANONICAL_HOST
14 AC_PROG_CC
15 if test $host != $build; then
16 AC_CHECK_PROGS(BUILD_CC, gcc cc)
17 fi
18 AC_SUBST(cross_compiling)
19 AC_PROG_CPP
20 # We need the C++ compiler only for testing.
21 AC_PROG_CXX
23 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
24 AC_MSG_ERROR([you must configure in a separate build directory])
25 fi
27 # This will get text that should go into config.make.
28 config_vars=
30 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
31 AC_ARG_WITH([gd],
32 AC_HELP_STRING([--with-gd=DIR],
33 [find libgd include dir and library with prefix DIR]),
34 [dnl
35 case "$with_gd" in
36 yes|''|no) ;;
37 *) libgd_include="-I$withval/include"
38 libgd_ldflags="-L$withval/lib" ;;
39 esac
40 ])
41 AC_ARG_WITH([gd-include],
42 AC_HELP_STRING([--with-gd-include=DIR],
43 [find libgd include files in DIR]),
44 [dnl
45 case "$with_gd_include" in
46 ''|no) ;;
47 *) libgd_include="-I$withval" ;;
48 esac
49 ])
50 AC_ARG_WITH([gd-lib],
51 AC_HELP_STRING([--with-gd-lib=DIR],
52 [find libgd library files in DIR]),
53 [dnl
54 case "$with_gd_lib" in
55 ''|no) ;;
56 *) libgd_ldflags="-L$withval" ;;
57 esac
58 ])
60 if test -n "$libgd_include"; then
61 config_vars="$config_vars
62 CFLAGS-memusagestat.c = $libgd_include"
63 fi
64 if test -n "$libgd_ldflags"; then
65 config_vars="$config_vars
66 libgd-LDFLAGS = $libgd_ldflags"
67 fi
69 dnl Arguments to specify presence of other packages/features.
70 AC_ARG_WITH([fp],
71 AC_HELP_STRING([--with-fp],
72 [if using floating-point hardware @<:@default=yes@:>@]),
73 [with_fp=$withval],
74 [with_fp=yes])
75 AC_SUBST(with_fp)
76 AC_ARG_WITH([binutils],
77 AC_HELP_STRING([--with-binutils=PATH],
78 [specify location of binutils (as and ld)]),
79 [path_binutils=$withval],
80 [path_binutils=''])
81 AC_ARG_WITH([elf],
82 AC_HELP_STRING([--with-elf],
83 [if using the ELF object format]),
84 [elf=$withval],
85 [elf=no])
86 AC_ARG_WITH([selinux],
87 AC_HELP_STRING([--with-selinux],
88 [if building with SELinux support]),
89 [with_selinux=$withval],
90 [with_selinux=auto])
91 AC_ARG_WITH([xcoff],
92 AC_HELP_STRING([--with-xcoff],
93 [if using the XCOFF object format]),
94 [xcoff=$withval],
95 [xcoff=no])
96 AC_ARG_WITH([cvs],
97 AC_HELP_STRING([--without-cvs],
98 [if CVS should not be used]),
99 [with_cvs=$withval],
100 [with_cvs=yes])
101 if test "$with_cvs" = yes; then
102 if test -d $srcdir/CVS && grep :pserver: $srcdir/CVS/Root > /dev/null
103 then
104 with_cvs=no
105 fi
106 fi
107 AC_SUBST(with_cvs)
109 AC_ARG_WITH([headers],
110 AC_HELP_STRING([--with-headers=PATH],
111 [location of system headers to use
112 (for example /usr/src/linux/include)
113 @<:@default=compiler default@:>@]),
114 [sysheaders=$withval],
115 [sysheaders=''])
117 AC_ARG_ENABLE([sanity-checks],
118 AC_HELP_STRING([--disable-sanity-checks],
119 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
120 [enable_sanity=$enableval],
121 [enable_sanity=yes])
123 AC_SUBST(enable_check_abi)
124 AC_ARG_ENABLE([check-abi],
125 AC_HELP_STRING([--enable-check-abi],
126 [do "make check-abi" in "make check" (no/warn/yes)
127 @<:@default=no@:>@]),
128 [enable_check_abi=$enableval],
129 [enable_check_abi=no])
131 dnl Arguments to enable or disable building the static, shared, profiled,
132 dnl and -fomit-frame-pointer libraries.
133 dnl I've disabled this for now since we cannot build glibc without static
134 dnl libraries built in the moment.
135 dnl AC_ARG_ENABLE([static],
136 dnl AC_HELP_STRING([--enable-static],
137 dnl [build static library @<:@default=yes@:>@]),
138 dnl [static=$enableval],
139 dnl [static=yes])
140 static=yes
141 AC_ARG_ENABLE([shared],
142 AC_HELP_STRING([--enable-shared],
143 [build shared library @<:@default=yes if GNU ld & ELF@:>@]),
144 [shared=$enableval],
145 [shared=default])
146 AC_ARG_ENABLE([profile],
147 AC_HELP_STRING([--enable-profile],
148 [build profiled library @<:@default=no@:>@]),
149 [profile=$enableval],
150 [profile=no])
151 AC_ARG_ENABLE([omitfp],
152 AC_HELP_STRING([--enable-omitfp],
153 [build undebuggable optimized library @<:@default=no@:>@]),
154 [omitfp=$enableval],
155 [omitfp=no])
156 AC_ARG_ENABLE([bounded],
157 AC_HELP_STRING([--enable-bounded],
158 [build with runtime bounds checking @<:@default=no@:>@]),
159 [bounded=$enableval],
160 [bounded=no])
161 AC_ARG_ENABLE([versioning],
162 AC_HELP_STRING([--disable-versioning],
163 [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
164 [enable_versioning=$enableval],
165 [enable_versioning=yes])
167 AC_ARG_ENABLE([oldest-abi],
168 AC_HELP_STRING([--enable-oldest-abi=ABI],
169 [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
170 [oldest_abi=$enableval],
171 [oldest_abi=no])
172 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
173 oldest_abi=default
174 else
175 AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
176 fi
177 AC_SUBST(oldest_abi)
179 AC_ARG_ENABLE([stackguard-randomization],
180 AC_HELP_STRING([--enable-stackguard-randomization],
181 [initialize __stack_chk_guard canary with a random number at program start]),
182 [enable_stackguard_randomize=$enableval],
183 [enable_stackguard_randomize=no])
184 if test "$enable_stackguard_randomize" = yes; then
185 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
186 fi
188 dnl Generic infrastructure for drop-in additions to libc.
189 AC_ARG_ENABLE([add-ons],
190 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
191 [configure and build add-ons in DIR1,DIR2,...
192 search for add-ons if no parameter given]),
193 , [enable_add_ons=yes])
195 dnl Let the user avoid using TLS. Don't know why but...
196 AC_ARG_WITH([tls],
197 AC_HELP_STRING([--with-tls],
198 [enable support for TLS]),
199 [usetls=$withval],
200 [usetls=yes])
202 AC_ARG_WITH([__thread],
203 AC_HELP_STRING([--without-__thread],
204 [do not use TLS features even when supporting them]),
205 [use__thread=$withval],
206 [use__thread=yes])
208 AC_ARG_ENABLE([hidden-plt],
209 AC_HELP_STRING([--disable-hidden-plt],
210 [do not hide internal function calls to avoid PLT]),
211 [hidden=$enableval],
212 [hidden=yes])
213 if test "x$hidden" = xno; then
214 AC_DEFINE(NO_HIDDEN)
215 fi
217 AC_ARG_ENABLE([bind-now],
218 AC_HELP_STRING([--enable-bind-now],
219 [disable lazy relocations in DSOs]),
220 [bindnow=$enableval],
221 [bindnow=no])
222 AC_SUBST(bindnow)
224 dnl On some platforms we cannot use dynamic loading. We must provide
225 dnl static NSS modules.
226 AC_ARG_ENABLE([static-nss],
227 AC_HELP_STRING([--enable-static-nss],
228 [build static NSS modules @<:@default=no@:>@]),
229 [static_nss=$enableval],
230 [static_nss=no])
231 dnl Enable static NSS also if we build no shared objects.
232 if test x"$static_nss" = xyes || test x"$shared" = xno; then
233 static_nss=yes
234 AC_DEFINE(DO_STATIC_NSS)
235 fi
237 AC_ARG_ENABLE([force-install],
238 AC_HELP_STRING([--disable-force-install],
239 [don't force installation of files from this package, even if they are older than the installed files]),
240 [force_install=$enableval],
241 [force_install=yes])
242 AC_SUBST(force_install)
244 dnl On some platforms we allow dropping compatibility with all kernel
245 dnl versions.
246 AC_ARG_ENABLE([kernel],
247 AC_HELP_STRING([--enable-kernel=VERSION],
248 [compile for compatibility with kernel not older than VERSION]),
249 [minimum_kernel=$enableval],
250 [])
251 dnl Prevent unreasonable values.
252 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
253 # Better nothing than this.
254 minimum_kernel=""
255 else
256 if test "$minimum_kernel" = current; then
257 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
258 fi
259 fi
261 dnl For the development we sometimes want gcc to issue even more warnings.
262 dnl This is not the default since many of the extra warnings are not
263 dnl appropriate.
264 AC_ARG_ENABLE([all-warnings],
265 AC_HELP_STRING([--enable-all-warnings],
266 [enable all useful warnings gcc can issue]),
267 [all_warnings=$enableval],
268 [])
269 AC_SUBST(all_warnings)
271 AC_ARG_ENABLE([multi-arch],
272 AC_HELP_STRING([--enable-multi-arch],
273 [enable single DSO with optimizations for multiple architectures]),
274 [multi_arch=$enableval],
275 [multi_arch=default])
277 AC_ARG_ENABLE([experimental-malloc],
278 AC_HELP_STRING([--enable-experimental-malloc],
279 [enable experimental malloc features]),
280 [experimental_malloc=$enableval],
281 [])
282 AC_SUBST(experimental_malloc)
284 AC_ARG_ENABLE([nss-crypt],
285 AC_HELP_STRING([--enable-nss-crypt],
286 [enable libcrypt to use nss]),
287 [nss_crypt=$enableval],
288 [nss_crypt=no])
289 if test x$nss_crypt = xyes; then
290 nss_includes=-I$(nss-config --includedir 2>/dev/null)
291 if test $? -ne 0; then
292 AC_MSG_ERROR([cannot find include directory with nss-config])
293 fi
294 old_CFLAGS="$CFLAGS"
295 CFLAGS="$CFLAGS $nss_includes"
296 AC_COMPILE_IFELSE([typedef int PRBool;
297 #include <hasht.h>
298 #include <nsslowhash.h>
299 void f (void) { NSSLOW_Init (); }],
300 libc_cv_nss_crypt=yes,
301 AC_MSG_ERROR([
302 cannot find NSS headers with lowlevel hash function interfaces]))
303 old_LIBS="$LIBS"
304 LIBS="$LIBS -lfreebl3"
305 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
306 #include <hasht.h>
307 #include <nsslowhash.h>],
308 [NSSLOW_Init();])],
309 libc_cv_nss_crypt=yes,
310 AC_MSG_ERROR([
311 cannot link program using lowlevel NSS hash functions]))
312 CFLAGS="$old_CFLAGS"
313 LIBS="$old_LIBS"
314 else
315 libc_cv_nss_crypt=no
316 fi
317 AC_SUBST(libc_cv_nss_crypt)
319 # The way shlib-versions is used to generate soversions.mk uses a
320 # fairly simplistic model for name recognition that can't distinguish
321 # i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a $host_os
322 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
323 # tell. This doesn't get used much beyond that, so it's fairly safe.
324 case "$host_os" in
325 linux*)
326 ;;
327 gnu*)
328 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
329 ;;
330 esac
332 # We keep the original values in `$config_*' and never modify them, so we
333 # can write them unchanged into config.make. Everything else uses
334 # $machine, $vendor, and $os, and changes them whenever convenient.
335 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
337 # Don't allow vendor == "unknown"
338 test "$config_vendor" = unknown && config_vendor=
339 config_os="`echo $config_os | sed 's/^unknown-//'`"
341 # Some configurations imply other options.
342 case "$host_os" in
343 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
344 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
345 ;;
346 gnu* | linux* | freebsd* | netbsd* | sysv4* | solaris2* | irix6*)
347 # These systems (almost) always use the ELF format.
348 elf=yes
349 ;;
350 aix*)
351 # These systems are always xcoff
352 xcoff=yes
353 elf=no
354 ;;
355 esac
357 # The configure fragment of an add-on port can modify these to supplement
358 # or override the table in the case statement below. No fragment should
359 # ever change the config_* variables, however.
360 machine=$config_machine
361 vendor=$config_vendor
362 os=$config_os
363 base_os=''
365 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
366 # Unify this here.
367 if test "$machine" = rs6000; then
368 machine="powerpc"
369 fi
371 # Braindead PowerPC box with absolutely no FPU.
372 case "$machine-$host_os" in
373 powerpc*-*soft)
374 with_fp=no
375 ;;
376 esac
378 submachine=
379 AC_ARG_WITH([cpu],
380 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
381 [dnl
382 case "$withval" in
383 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
384 no) ;;
385 *) submachine="$withval" ;;
386 esac
387 ])
389 # An add-on can set this when it wants to disable the sanity check below.
390 libc_config_ok=no
392 dnl Having this here, though empty, makes sure that if add-ons' fragments
393 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
394 dnl our AC_OUTPUT will actually use it.
395 AC_CONFIG_SUBDIRS()
397 case "$enable_add_ons" in
398 ''|no) add_ons= ;;
399 yes|'*')
400 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
401 sed 's@/[[^/]]*$@@' | sort | uniq`
402 add_ons_automatic=yes
403 ;;
404 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
405 add_ons_automatic=no ;;
406 esac
408 configured_add_ons=
409 add_ons_sfx=
410 add_ons_pfx=
411 if test x"$add_ons" != x; then
412 for f in $add_ons; do
413 # Some sanity checks
414 case "$f" in
415 crypt)
416 AC_MSG_ERROR([
417 *** It seems that you're using an old \`crypt' add-on. crypt is now
418 *** part of glibc and using the old add-on will not work with this
419 *** release. Start again with fresh sources and without the old
420 *** \`crypt' add-on.])
421 ;;
422 localedata)
423 AC_MSG_ERROR([
424 *** It seems that you're using an old \`localedata' add-on. localedata
425 *** is now part of glibc and using the old add-on will not work with
426 *** this release. Start again with fresh sources and without the old
427 *** \`localedata' add-on.])
428 ;;
429 esac
430 done
432 # Now source each add-on's configure fragment.
433 # The fragments can use $srcdir/$libc_add_on to find themselves,
434 # and test $add_ons_automatic to see if they were explicitly requested.
435 # A fragment can clear (or even change) $libc_add_on to affect
436 # whether it goes into the list to be actually used in the build.
437 use_add_ons=
438 for libc_add_on in $add_ons; do
439 # Test whether such a directory really exists.
440 # It can be absolute, or relative to $srcdir, or relative to the build dir.
441 case "$libc_add_on" in
442 /*)
443 libc_add_on_srcdir=$libc_add_on
444 ;;
445 *)
446 test -d "$srcdir/$libc_add_on" || {
447 if test -d "$libc_add_on"; then
448 libc_add_on="`pwd`/$libc_add_on"
449 else
450 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
451 fi
452 }
453 libc_add_on_srcdir=$srcdir/$libc_add_on
454 ;;
455 esac
457 libc_add_on_frag=$libc_add_on_srcdir/configure
458 libc_add_on_canonical=
459 libc_add_on_config_subdirs=
460 if test -r "$libc_add_on_frag"; then
461 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
462 libc_add_on_canonical=unknown
463 libc_add_on_subdirs=
464 . "$libc_add_on_frag"
465 test -z "$libc_add_on" || {
466 configured_add_ons="$configured_add_ons $libc_add_on"
467 if test "x$libc_add_on_canonical" = xunknown; then
468 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
469 fi
470 for d in $libc_add_on_subdirs; do
471 case "$libc_add_on" in
472 /*) subdir_srcdir="$libc_add_on" ;;
473 *) subdir_srcdir="\$(..)$libc_add_on" ;;
474 esac
475 case "$d" in
476 .)
477 d="${libc_add_on_canonical:-$libc_add_on}"
478 ;;
479 /*)
480 subdir_srcdir="$d"
481 ;;
482 *)
483 subdir_srcdir="$subdir_srcdir/$d"
484 ;;
485 esac
486 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
487 add_on_subdirs="$add_on_subdirs $d"
488 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
489 $d-srcdir = $subdir_srcdir"
490 done
491 for d in $libc_add_on_config_subdirs; do
492 case "$d" in
493 /*) AC_MSG_ERROR(dnl
494 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
495 esac
496 if test ! -d "$libc_add_on_srcdir/$d"; then
497 AC_MSG_ERROR(fragment wants to configure missing directory $d)
498 fi
499 case "$libc_add_on" in
500 /*) AC_MSG_ERROR(dnl
501 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
502 esac
503 subdirs="$subdirs $libc_add_on/$d"
504 done
505 }
506 fi
507 if test -n "$libc_add_on"; then
508 if frags=`ls -d $libc_add_on_srcdir/sysdeps/*/preconfigure 2> /dev/null`
509 then
510 AC_MSG_CHECKING(add-on $libc_add_on for preconfigure fragments)
511 for frag in $frags; do
512 name=`echo "$frag" | sed 's@/[[^/]]*$@@;s@^.*/@@'`
513 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
514 . "$frag"
515 done
516 AC_MSG_RESULT()
517 fi
518 use_add_ons="$use_add_ons $libc_add_on"
519 add_ons_pfx="$add_ons_pfx $libc_add_on/"
520 test -z "$libc_add_on_canonical" ||
521 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
522 fi
523 done
524 # Use echo to strip excess whitespace.
525 add_ons="`echo $use_add_ons`"
526 fi
527 AC_SUBST(add_ons)
528 AC_SUBST(add_on_subdirs)
531 ###
532 ### I put this here to prevent those annoying emails from people who cannot
533 ### read and try to compile glibc on unsupported platforms. --drepper
534 ###
535 ### By using the undocumented --enable-hacker-mode option for configure
536 ### one can skip this test to make the configuration not fail for unsupported
537 ### platforms.
538 ###
539 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
540 case "$machine-$host_os" in
541 *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
542 ;;
543 *)
544 echo "*** The GNU C library is currently not available for this platform."
545 echo "*** So far nobody cared to port it and if there is no volunteer it"
546 echo "*** might never happen. So, if you have interest to see glibc on"
547 echo "*** this platform visit"
548 echo "*** http://www.gnu.org/software/libc/porting.html"
549 echo "*** and join the group of porters"
550 exit 1
551 ;;
552 esac
553 fi
555 dnl We need to use [ and ] for other purposes for a while now.
556 changequote(,)dnl
557 # Expand the configuration machine name into a subdirectory by architecture
558 # type and particular chip. If an add-on configure fragment already set
559 # base_machine, we don't change it.
560 test -n "$base_machine" || case "$machine" in
561 a29k | am29000) base_machine=a29k machine=a29k ;;
562 c3[012]) base_machine=cx0 machine=cx0/c30 ;;
563 c4[04]) base_machine=cx0 machine=cx0/c40 ;;
564 i[34567]86) base_machine=i386 machine=i386/$machine ;;
565 ia64) base_machine=ia64 machine=ia64 ;;
566 m88???) base_machine=m88k machine=m88k/$machine ;;
567 m88k) base_machine=m88k machine=m88k/m88100 ;;
568 powerpc) base_machine=powerpc machine=powerpc/powerpc32 ;;
569 powerpc64) base_machine=powerpc machine=powerpc/powerpc64 ;;
570 s390) base_machine=s390 machine=s390/s390-32 ;;
571 s390x) base_machine=s390 machine=s390/s390-64 ;;
572 sh3*) base_machine=sh machine=sh/sh3 ;;
573 sh4*) base_machine=sh machine=sh/sh4 ;;
574 sparc | sparcv[67])
575 base_machine=sparc machine=sparc/sparc32 ;;
576 sparcv8 | supersparc | hypersparc)
577 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
578 sparcv8plus | sparcv8plusa | sparcv9)
579 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
580 sparcv8plusb | sparcv9b)
581 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
582 sparcv9v)
583 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
584 sparcv9v2)
585 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
586 sparc64)
587 base_machine=sparc machine=sparc/sparc64 ;;
588 sparc64b)
589 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
590 sparc64v)
591 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
592 sparc64v2)
593 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
594 *) base_machine=$machine ;;
595 esac
596 changequote([,])dnl
597 AC_SUBST(base_machine)
599 if test "$base_machine" = "i386"; then
600 AC_DEFINE(USE_REGPARMS)
601 fi
603 # For the multi-arch option we need support in the assembler.
604 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
605 libc_cv_asm_gnu_indirect_function, [dnl
606 cat > conftest.s <<EOF
607 .type foo,%gnu_indirect_function
608 EOF
609 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
610 then
611 libc_cv_asm_gnu_indirect_function=yes
612 else
613 libc_cv_asm_gnu_indirect_function=no
614 fi
615 rm -f conftest*])
617 AC_MSG_CHECKING(whether .text pseudo-op must be used)
618 AC_CACHE_VAL(libc_cv_dot_text, [dnl
619 cat > conftest.s <<EOF
620 .text
621 EOF
622 libc_cv_dot_text=
623 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
624 libc_cv_dot_text=.text
625 fi
626 rm -f conftest*])
627 if test -z "$libc_cv_dot_text"; then
628 AC_MSG_RESULT(no)
629 else
630 AC_MSG_RESULT(yes)
631 fi
633 AC_CACHE_CHECK(for assembler global-symbol directive,
634 libc_cv_asm_global_directive, [dnl
635 libc_cv_asm_global_directive=UNKNOWN
636 for ac_globl in .globl .global .EXPORT; do
637 cat > conftest.s <<EOF
638 ${libc_cv_dot_text}
639 ${ac_globl} foo
640 foo:
641 EOF
642 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
643 libc_cv_asm_global_directive=${ac_globl}
644 fi
645 rm -f conftest*
646 test $libc_cv_asm_global_directive != UNKNOWN && break
647 done])
648 if test $libc_cv_asm_global_directive = UNKNOWN; then
649 AC_MSG_ERROR(cannot determine asm global directive)
650 else
651 AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
652 fi
654 AC_CACHE_CHECK(for assembler .type directive prefix,
655 libc_cv_asm_type_prefix, [dnl
656 libc_cv_asm_type_prefix=no
657 for ac_try_prefix in '@' '%' '#'; do
658 cat > conftest.s <<EOF
659 ${libc_cv_dot_text}
660 ${libc_cv_asm_global_directive} foo
661 .type foo, ${ac_try_prefix}object
662 .size foo, 1
663 foo:
664 .byte 1
665 EOF
666 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
667 libc_cv_asm_type_prefix=${ac_try_prefix}
668 fi
669 rm -f conftest*
670 test "x$libc_cv_asm_type_prefix" != xno && break
671 done])
672 if test "x$libc_cv_asm_type_prefix" != xno; then
673 AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
674 fi
676 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -a x"$libc_cv_asm_type_prefix" = xno; then
677 if test x"$multi_arch" = xyes; then
678 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
679 else
680 multi_arch=no
681 fi
682 fi
683 if test x"$multi_arch" != xno; then
684 multi_arch_d=/multiarch
685 fi
687 # Compute the list of sysdep directories for this configuration.
688 # This can take a while to compute.
689 sysdep_dir=$srcdir/sysdeps
690 AC_MSG_CHECKING(sysdep dirs)
691 dnl We need to use [ and ] for other purposes for a while now.
692 changequote(,)dnl
693 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
694 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
696 test "x$base_os" != x || case "$os" in
697 gnu*)
698 base_os=mach/hurd ;;
699 netbsd* | 386bsd* | freebsd* | bsdi*)
700 base_os=unix/bsd/bsd4.4 ;;
701 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
702 base_os=unix/bsd ;;
703 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
704 base_os=unix/sysv ;;
705 irix6*)
706 base_os=unix/sysv/irix6/$os ;;
707 solaris[2-9]*)
708 base_os=unix/sysv/sysv4 ;;
709 hpux*)
710 base_os=unix/sysv/hpux/$os ;;
711 aix4.3*)
712 base_os=unix/sysv/aix/aix4.3 ;;
713 none)
714 base_os=standalone ;;
715 esac
717 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
718 tail=$os
719 ostry=$os
720 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
721 ostry="$ostry /$o"
722 tail=$o
723 done
724 o=`echo $tail | sed 's/[0-9]*$//'`
725 if test $o != $tail; then
726 ostry="$ostry /$o"
727 fi
728 # For linux-gnu, try linux-gnu, then linux.
729 o=`echo $tail | sed 's/-.*$//'`
730 if test $o != $tail; then
731 ostry="$ostry /$o"
732 fi
734 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
735 base=
736 tail=$base_os
737 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
738 set $b
739 base="$base /$1"
740 tail="$2"
741 done
743 # For sparc/sparc32, try sparc/sparc32 and then sparc.
744 mach=
745 tail=$machine${submachine:+/$submachine}
746 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
747 set $m
748 # Prepend the machine's FPU directory unless --without-fp.
749 if test "$with_fp" = yes; then
750 mach="$mach /$1/fpu"
751 else
752 mach="$mach /$1/nofpu"
753 fi
754 mach="$mach /$1"
755 tail="$2"
756 done
758 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
759 changequote([,])dnl
761 # Find what sysdep directories exist.
762 sysnames_add_ons=
763 sysnames=
764 for b in $base ''; do
765 for m0 in $mach ''; do
766 for v in /$vendor ''; do
767 test "$v" = / && continue
768 for o in /$ostry ''; do
769 test "$o" = / && continue
770 for m in $multi_arch_d $mach ''; do
771 for d in $add_ons_pfx ''; do
772 for a in $add_ons_sfx ''; do
773 if test -n "$m0$m0sub$b$v$o$m$msub"; then
774 try_srcdir="${srcdir}/"
775 case "$d" in
776 /*) try_srcdir= ;;
777 esac
778 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
779 test -n "$enable_debug_configure" &&
780 echo "$0 [DEBUG]: try $try" >&2
781 if test -d "$try_srcdir$try"; then
782 sysnames="$sysnames $try"
783 { test -n "$o" || test -n "$b"; } && os_used=t
784 { test -n "$m" || test -n "$m0"; } && machine_used=t
785 case x${m0:-$m} in
786 x*/$submachine) submachine_used=t ;;
787 esac
788 if test -n "$d"; then
789 case "$sysnames_add_ons" in
790 *" $d "*) ;;
791 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
792 esac
793 fi
794 fi
795 fi
796 done
797 done
798 done
799 done
800 done
801 done
802 done
804 # If the assembler supports gnu_indirect_function symbol type and the
805 # architecture supports multi-arch, we enable multi-arch by default.
806 case $sysnames_add_ons$sysnames in
807 *"$multi_arch_d"*)
808 ;;
809 *)
810 multi_arch=no
811 ;;
812 esac
813 if test x"$multi_arch" != xno; then
814 AC_DEFINE(USE_MULTIARCH)
815 fi
816 AC_SUBST(multi_arch)
818 if test -z "$os_used" && test "$os" != none; then
819 AC_MSG_ERROR(Operating system $os is not supported.)
820 fi
821 if test -z "$machine_used" && test "$machine" != none; then
822 AC_MSG_ERROR(The $machine is not supported.)
823 fi
824 if test -z "$submachine_used" && test -n "$submachine"; then
825 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
826 fi
827 AC_SUBST(submachine)
829 # We have now validated the configuration.
832 # If using ELF, look for an `elf' subdirectory of each machine directory.
833 # We prepend these rather than inserting them whereever the machine appears
834 # because things specified by the machine's ELF ABI should override
835 # OS-specific things, and should always be the same for any OS on the
836 # machine (otherwise what's the point of an ABI?).
837 if test "$elf" = yes; then
838 elf_dirs=
839 for d in $add_ons_pfx ''; do
840 for m in $mach; do
841 if test -d $srcdir/${d}sysdeps$m/elf; then
842 elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
843 fi
844 done
845 done
846 sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
847 fi
850 # Expand the list of system names into a full list of directories
851 # from each element's parent name and Implies file (if present).
852 set $sysnames
853 names=
854 while test $# -gt 0; do
855 name=$1
856 shift
858 case " $names " in *" $name "*)
859 # Already in the list.
860 continue
861 esac
863 # Report each name as we discover it, so there is no long pause in output.
864 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
866 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
868 case $name in
869 /*) xsrcdir= ;;
870 *) xsrcdir=$srcdir/ ;;
871 esac
872 test -n "$enable_debug_configure" &&
873 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
875 if test -f $xsrcdir$name/Implies; then
876 # Collect more names from the `Implies' file (removing comments).
877 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
878 implied=
879 for x in $implied_candidate; do
880 found=no
881 if test -d $xsrcdir$name_base/$x; then
882 implied="$implied $name_base/$x";
883 found=yes
884 fi
885 for d in $add_ons_pfx ''; do
886 try="${d}sysdeps/$x"
887 case $d in
888 /*) try_srcdir= ;;
889 *) try_srcdir=$srcdir/ ;;
890 esac
891 test -n "$enable_debug_configure" &&
892 echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
893 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
894 then
895 implied="$implied $try"
896 found=yes
897 case "$sysnames_add_ons" in
898 *" $d "*) ;;
899 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
900 esac
901 fi
902 done
903 if test $found = no; then
904 AC_MSG_WARN($name/Implies specifies nonexistent $x)
905 fi
906 done
907 else
908 implied=
909 fi
911 # Add NAME to the list of names.
912 names="$names $name"
914 # Find the parent of NAME, using the empty string if it has none.
915 changequote(,)dnl
916 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
917 changequote([,])dnl
919 # Add the names implied by NAME, and NAME's parent (if it has one), to
920 # the list of names to be processed (the argument list). We prepend the
921 # implied names to the list and append the parent. We want implied
922 # directories to come before further directories inferred from the
923 # configuration components; this ensures that for sysv4, unix/common
924 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
925 # after sysv4).
926 sysnames="`echo $implied $* $parent`"
927 test -n "$sysnames" && set $sysnames
928 done
930 # Add the default directories.
931 default_sysnames=sysdeps/generic
932 if test "$elf" = yes; then
933 default_sysnames="sysdeps/generic/elf $default_sysnames"
934 fi
935 sysnames="$names $default_sysnames"
936 AC_SUBST(sysnames)
937 # The other names were emitted during the scan.
938 AC_MSG_RESULT($default_sysnames)
940 # Collect the list of add-ons that supply partial sysdeps trees.
941 sysdeps_add_ons=
942 for add_on in $add_ons; do
943 case "$add_on" in
944 /*) xsrcdir= ;;
945 *) xsrcdir="$srcdir/" ;;
946 esac
948 test -d "$xsrcdir$add_on/sysdeps" || {
949 case "$configured_add_ons " in
950 *" $add_on "*) ;;
951 *|'')
952 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
953 ;;
954 esac
955 continue
956 }
958 sysdeps_add_ons="$sysdeps_add_ons $add_on"
959 case "$sysnames_add_ons" in
960 *" $add_on/ "*) ;;
961 *|'')
962 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
963 continue ;;
964 esac
966 found=no
967 for d in $sysnames; do
968 case "$d" in
969 $add_on/sysdeps/*) ;;
970 *) continue ;;
971 esac
972 (cd "$xsrcdir$d" && for f in *[[!~]]; do
973 case "$f" in
974 sys|bits)
975 for ff in $f/*.h; do
976 test -d "$ff" || { test -e "$ff" && exit 88; }
977 done
978 ;;
979 *)
980 test -d "$f" || { test -e "$f" && exit 88; }
981 ;;
982 esac
983 done)
984 if test $? -eq 88; then
985 found=yes
986 break
987 fi
988 done
989 if test $found = no; then
990 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
991 fi
992 done
993 AC_SUBST(sysdeps_add_ons)
996 ### Locate tools.
998 AC_PROG_INSTALL
999 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
1000 # The makefiles need to use a different form to find it in $srcdir.
1001 INSTALL='\$(..)./scripts/install-sh -c'
1002 fi
1003 AC_PROG_LN_S
1005 LIBC_PROG_BINUTILS
1006 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
1008 # Accept binutils 2.13 or newer.
1009 AC_CHECK_PROG_VER(AS, $AS, --version,
1010 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
1011 [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
1012 AC_CHECK_PROG_VER(LD, $LD, --version,
1013 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
1014 [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
1016 # We need the physical current working directory. We cannot use the
1017 # "pwd -P" shell builtin since that's not portable. Instead we try to
1018 # find a pwd binary. Note that assigning to the PWD environment
1019 # variable might have some interesting side effects, so we don't do
1020 # that.
1021 AC_PATH_PROG(PWD_P, pwd, no)
1022 if test "$PWD_P" = no; then
1023 AC_MSG_ERROR(*** A pwd binary could not be found.)
1024 fi
1026 # These programs are version sensitive.
1027 AC_CHECK_TOOL_PREFIX
1028 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
1029 [version \([egcygnustpi-]*[0-9.]*\)], [3.4* | 4.[0-9]* ],
1030 critic_missing="$critic_missing gcc")
1031 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1032 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1033 [3.79* | 3.[89]*], critic_missing="$critic_missing make")
1035 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1036 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1037 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1038 MSGFMT=: aux_missing="$aux_missing msgfmt")
1039 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1040 [GNU texinfo.* \([0-9][0-9.]*\)],
1041 [4.*],
1042 MAKEINFO=: aux_missing="$aux_missing makeinfo")
1043 AC_CHECK_PROG_VER(SED, sed, --version,
1044 [GNU sed version \([0-9]*\.[0-9.]*\)],
1045 [3.0[2-9]*|3.[1-9]*|[4-9]*],
1046 SED=: aux_missing="$aux_missing sed")
1048 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1049 case "x$AUTOCONF" in
1050 xno|x|x:) AUTOCONF=no ;;
1051 *)
1052 AC_CACHE_CHECK(dnl
1053 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1054 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
1055 libc_cv_autoconf_works=yes
1056 else
1057 libc_cv_autoconf_works=no
1058 fi])
1059 test $libc_cv_autoconf_works = yes || AUTOCONF=no
1060 ;;
1061 esac
1062 if test "x$with_cvs" = xyes && test "x$AUTOCONF" = xno; then
1063 # If --without-cvs they probably won't change configure.in, so no complaints.
1064 aux_missing="$aux_missing autoconf"
1065 fi
1067 test -n "$critic_missing" && AC_MSG_ERROR([
1068 *** These critical programs are missing or too old:$critic_missing
1069 *** Check the INSTALL file for required versions.])
1071 test -n "$aux_missing" && AC_MSG_WARN([
1072 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1073 *** some features will be disabled.
1074 *** Check the INSTALL file for required versions.])
1076 # if using special system headers, find out the compiler's sekrit
1077 # header directory and add that to the list. NOTE: Only does the right
1078 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1079 if test -n "$sysheaders"; then
1080 SYSINCLUDES=-nostdinc
1081 for d in include include-fixed; do
1082 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1083 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1084 done
1085 SYSINCLUDES="$SYSINCLUDES \
1086 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1087 if test -n "$CXX"; then
1088 cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
1089 cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
1090 cxxheaders=`$CXX -print-file-name=../../../../include/c++/`"$cxxversion" &&
1091 CXX_SYSINCLUDES="-isystem $cxxheaders \
1092 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1093 fi
1094 fi
1095 AC_SUBST(SYSINCLUDES)
1096 AC_SUBST(CXX_SYSINCLUDES)
1098 # check if ranlib is necessary
1099 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
1100 cat > conftest.c <<EOF
1101 int a;
1102 char b;
1103 void c(void) {}
1104 EOF
1105 $CC $CFLAGS $CPPFLAGS -c conftest.c
1106 $AR cr conftest.a conftest.o
1107 cp conftest.a conftest2.a
1108 $RANLIB conftest.a
1109 if cmp -s conftest.a conftest2.a; then
1110 libc_cv_ranlib_necessary=no
1111 else
1112 libc_cv_ranlib_necessary=yes
1113 fi
1114 rm -rf conftest*])
1115 if test "$libc_cv_ranlib_necessary" = no; then
1116 RANLIB=:
1117 fi
1119 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1120 # since this would lead to problems installing/building glibc.
1121 # LD_LIBRARY_PATH contains the current directory if one of the following
1122 # is true:
1123 # - one of the terminals (":" and ";") is the first or last sign
1124 # - two terminals occur directly after each other
1125 # - the path contains an element with a dot in it
1126 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1127 changequote(,)dnl
1128 case ${LD_LIBRARY_PATH} in
1129 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1130 ld_library_path_setting="contains current directory"
1131 ;;
1132 *)
1133 ld_library_path_setting="ok"
1134 ;;
1135 esac
1136 changequote([,])dnl
1137 AC_MSG_RESULT($ld_library_path_setting)
1138 if test "$ld_library_path_setting" != "ok"; then
1139 AC_MSG_ERROR([
1140 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1141 *** building glibc. Please change the environment variable
1142 *** and run configure again.])
1143 fi
1145 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1146 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1147 libc_cv_gcc_static_libgcc=
1148 else
1149 libc_cv_gcc_static_libgcc=-static-libgcc
1150 fi])
1151 AC_SUBST(libc_cv_gcc_static_libgcc)
1153 AC_PATH_PROG(BASH_SHELL, bash, no)
1154 if test "$BASH_SHELL" != no &&
1155 $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1156 && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1157 libc_cv_have_bash2=yes
1158 else
1159 libc_cv_have_bash2=no
1160 fi
1161 AC_SUBST(libc_cv_have_bash2)
1163 dnl We need a ksh compatible shell for tzselect.
1164 if test "$BASH_SHELL" = no; then
1165 AC_PATH_PROG(KSH, ksh, no)
1166 if test "$KSH" = no; then
1167 libc_cv_have_ksh=no
1168 else
1169 libc_cv_have_ksh=yes
1170 fi
1171 else
1172 KSH="$BASH_SHELL"
1173 AC_SUBST(KSH)
1174 libc_cv_have_ksh=yes
1175 fi
1176 AC_SUBST(libc_cv_have_ksh)
1178 AC_PROG_AWK
1179 AC_PATH_PROG(PERL, perl, no)
1180 if test "$PERL" != no &&
1181 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1182 PERL=no
1183 fi
1184 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1185 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1186 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1188 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
1189 echo '#include <stddef.h>
1190 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
1191 if eval "$ac_cpp conftest.c 2>/dev/null" \
1192 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
1193 libc_cv_signed_size_t=no
1194 else
1195 libc_cv_signed_size_t=yes
1196 fi
1197 rm -f conftest*])
1198 if test $libc_cv_signed_size_t = yes; then
1199 dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
1200 cat >> confdefs.h <<\EOF
1201 #undef __SIZE_TYPE__
1202 #define __SIZE_TYPE__ unsigned
1203 EOF
1204 fi
1206 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1207 AC_TRY_COMPILE(dnl
1208 [#define __need_size_t
1209 #define __need_wchar_t
1210 #include <stddef.h>
1211 #define __need_NULL
1212 #include <stddef.h>], [size_t size; wchar_t wchar;
1213 #ifdef offsetof
1214 #error stddef.h ignored __need_*
1215 #endif
1216 if (&size == NULL || &wchar == NULL) abort ();],
1217 libc_cv_friendly_stddef=yes,
1218 libc_cv_friendly_stddef=no)])
1219 if test $libc_cv_friendly_stddef = yes; then
1220 config_vars="$config_vars
1221 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1222 fi
1224 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1225 libc_cv_need_minus_P, [dnl
1226 cat > conftest.S <<EOF
1227 #include "confdefs.h"
1228 /* Nothing whatsoever. */
1229 EOF
1230 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1231 libc_cv_need_minus_P=no
1232 else
1233 libc_cv_need_minus_P=yes
1234 fi
1235 rm -f conftest*])
1236 if test $libc_cv_need_minus_P = yes; then
1237 config_vars="$config_vars
1238 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1239 fi
1241 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1242 cat > conftest.s <<EOF
1243 ${libc_cv_dot_text}
1244 foo:
1245 .set glibc_conftest_frobozz,foo
1246 $libc_cv_asm_global_directive glibc_conftest_frobozz
1247 EOF
1248 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1249 # (but it doesn't work), so we must do a linking check to be sure.
1250 cat > conftest1.c <<\EOF
1251 extern int glibc_conftest_frobozz;
1252 void _start() { glibc_conftest_frobozz = 1; }
1253 EOF
1254 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1255 -nostartfiles -nostdlib \
1256 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1257 libc_cv_asm_set_directive=yes
1258 else
1259 libc_cv_asm_set_directive=no
1260 fi
1261 rm -f conftest*])
1262 if test $libc_cv_asm_set_directive = yes; then
1263 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1264 fi
1266 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1267 libc_cv_asm_unique_object, [dnl
1268 cat > conftest.s <<EOF
1269 ${libc_cv_dot_text}
1270 _sym:
1271 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1272 EOF
1273 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1274 libc_cv_asm_unique_object=yes
1275 else
1276 libc_cv_asm_unique_object=no
1277 fi
1278 rm -f conftest*])
1279 if test $libc_cv_asm_unique_object = yes; then
1280 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1281 fi
1283 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1284 [cat > conftest.s <<EOF
1285 ${libc_cv_dot_text}
1286 _sym:
1287 .symver _sym,sym@VERS
1288 EOF
1289 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1290 libc_cv_asm_symver_directive=yes
1291 else
1292 libc_cv_asm_symver_directive=no
1293 fi
1294 rm -f conftest*])
1295 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1296 if test $libc_cv_asm_symver_directive = yes; then
1297 cat > conftest.s <<EOF
1298 ${libc_cv_dot_text}
1299 _sym:
1300 .symver _sym,sym@VERS
1301 EOF
1302 cat > conftest.map <<EOF
1303 VERS_1 {
1304 global: sym;
1305 };
1307 VERS_2 {
1308 global: sym;
1309 } VERS_1;
1310 EOF
1311 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1312 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1313 -o conftest.so conftest.o
1314 -nostartfiles -nostdlib
1315 -Wl,--version-script,conftest.map
1316 1>&AS_MESSAGE_LOG_FD]);
1317 then
1318 libc_cv_ld_version_script_option=yes
1319 else
1320 libc_cv_ld_version_script_option=no
1321 fi
1322 else
1323 libc_cv_ld_version_script_option=no
1324 fi
1325 else
1326 libc_cv_ld_version_script_option=no
1327 fi
1328 rm -f conftest*])
1329 if test $shared != no &&
1330 test $libc_cv_asm_symver_directive = yes &&
1331 test $libc_cv_ld_version_script_option = yes &&
1332 test $enable_versioning = yes; then
1333 VERSIONING=yes
1334 AC_DEFINE(DO_VERSIONING)
1335 else
1336 VERSIONING=no
1337 fi
1338 AC_SUBST(VERSIONING)
1340 if test $elf = yes && test $shared != no && test $VERSIONING = no; then
1341 echo "\
1342 *** WARNING: You should not compile GNU libc without versioning. Not using
1343 *** versioning will introduce incompatibilities so that old binaries
1344 *** will not run anymore.
1345 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1346 fi
1347 if test $elf = yes; then
1348 AC_CACHE_CHECK(for .previous assembler directive,
1349 libc_cv_asm_previous_directive, [dnl
1350 cat > conftest.s <<EOF
1351 .section foo_section
1352 .previous
1353 EOF
1354 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1355 libc_cv_asm_previous_directive=yes
1356 else
1357 libc_cv_asm_previous_directive=no
1358 fi
1359 rm -f conftest*])
1360 if test $libc_cv_asm_previous_directive = yes; then
1361 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1362 else
1363 AC_CACHE_CHECK(for .popsection assembler directive,
1364 libc_cv_asm_popsection_directive, [dnl
1365 cat > conftest.s <<EOF
1366 .pushsection foo_section
1367 .popsection
1368 EOF
1369 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1370 libc_cv_asm_popsection_directive=yes
1371 else
1372 libc_cv_asm_popsection_directive=no
1373 fi
1374 rm -f conftest*])
1375 if test $libc_cv_asm_popsection_directive = yes; then
1376 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1377 fi
1378 fi
1379 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1380 libc_cv_asm_protected_directive, [dnl
1381 cat > conftest.s <<EOF
1382 .protected foo
1383 foo:
1384 .hidden bar
1385 bar:
1386 EOF
1387 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1388 libc_cv_asm_protected_directive=yes
1389 else
1390 AC_MSG_ERROR(assembler support for symbol visibility is required)
1391 fi
1392 rm -f conftest*])
1394 if test $libc_cv_asm_protected_directive = yes; then
1395 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1396 libc_cv_visibility_attribute,
1397 [cat > conftest.c <<EOF
1398 int foo __attribute__ ((visibility ("hidden"))) = 1;
1399 int bar __attribute__ ((visibility ("protected"))) = 1;
1400 EOF
1401 libc_cv_visibility_attribute=no
1402 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1403 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1404 if grep '\.protected.*bar' conftest.s >/dev/null; then
1405 libc_cv_visibility_attribute=yes
1406 fi
1407 fi
1408 fi
1409 rm -f conftest.[cs]
1410 ])
1411 if test $libc_cv_visibility_attribute != yes; then
1412 AC_MSG_ERROR(compiler support for visibility attribute is required)
1413 fi
1414 fi
1416 if test $libc_cv_visibility_attribute = yes; then
1417 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1418 libc_cv_broken_visibility_attribute,
1419 [cat > conftest.c <<EOF
1420 int foo (int x);
1421 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1422 int bar (int x) { return x; }
1423 EOF
1424 libc_cv_broken_visibility_attribute=yes
1425 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s1>&AS_MESSAGE_LOG_FD); then
1426 changequote(,)dnl
1427 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1428 changequote([,])dnl
1429 libc_cv_broken_visibility_attribute=no
1430 fi
1431 fi
1432 rm -f conftest.c conftest.s
1433 ])
1434 if test $libc_cv_broken_visibility_attribute = yes; then
1435 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1436 fi
1437 fi
1439 AC_CACHE_CHECK(for broken __attribute__((alias())),
1440 libc_cv_broken_alias_attribute,
1441 [cat > conftest.c <<EOF
1442 extern int foo (int x) __asm ("xyzzy");
1443 int bar (int x) { return x; }
1444 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1445 extern int dfoo;
1446 extern __typeof (dfoo) dfoo __asm ("abccb");
1447 int dfoo = 1;
1448 EOF
1449 libc_cv_broken_alias_attribute=yes
1450 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1451 if grep 'xyzzy' conftest.s >/dev/null &&
1452 grep 'abccb' conftest.s >/dev/null; then
1453 libc_cv_broken_alias_attribute=no
1454 fi
1455 fi
1456 rm -f conftest.c conftest.s
1457 ])
1458 if test $libc_cv_broken_alias_attribute = yes; then
1459 AC_MSG_ERROR(working alias attribute support required)
1460 fi
1462 if test $libc_cv_visibility_attribute = yes; then
1463 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1464 libc_cv_have_sdata_section,
1465 [echo "int i;" > conftest.c
1466 libc_cv_have_sdata_section=no
1467 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1468 | grep '\.sdata' >/dev/null; then
1469 libc_cv_have_sdata_section=yes
1470 fi
1471 rm -f conftest.c conftest.so
1472 ])
1473 if test $libc_cv_have_sdata_section = yes; then
1474 AC_DEFINE(HAVE_SDATA_SECTION)
1475 fi
1476 fi
1478 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1479 libc_cv_initfini_array, [dnl
1480 cat > conftest.c <<EOF
1481 int _start (void) { return 0; }
1482 int __start (void) { return 0; }
1483 int foo (void) { return 1; }
1484 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1485 EOF
1486 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -o conftest conftest.c
1487 -static -nostartfiles -nostdlib 1>&AS_MESSAGE_LOG_FD])
1488 then
1489 if readelf -S conftest | fgrep INIT_ARRAY > /dev/null; then
1490 libc_cv_initfini_array=yes
1491 else
1492 libc_cv_initfini_array=no
1493 fi
1494 else
1495 libc_cv_initfini_array=no
1496 fi
1497 rm -f conftest*])
1498 if test $libc_cv_initfini_array != yes; then
1499 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1500 fi
1502 AC_CACHE_CHECK(for libunwind-support in compiler,
1503 libc_cv_cc_with_libunwind, [
1504 cat > conftest.c <<EOF
1505 int main (void) { return 0; }
1506 EOF
1507 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1508 conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1509 libc_cv_cc_with_libunwind=yes
1510 else
1511 libc_cv_cc_with_libunwind=no
1512 fi
1513 rm -f conftest*])
1514 AC_SUBST(libc_cv_cc_with_libunwind)
1515 if test $libc_cv_cc_with_libunwind = yes; then
1516 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1517 fi
1519 AC_CACHE_CHECK(for -z nodelete option,
1520 libc_cv_z_nodelete, [dnl
1521 cat > conftest.c <<EOF
1522 int _start (void) { return 42; }
1523 EOF
1524 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1525 -fPIC -shared -o conftest.so conftest.c
1526 -nostartfiles -nostdlib
1527 -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1528 then
1529 libc_cv_z_nodelete=yes
1530 else
1531 AC_MSG_ERROR(linker with -z nodelete support required)
1532 fi
1533 rm -f conftest*])
1535 AC_CACHE_CHECK(for -z nodlopen option,
1536 libc_cv_z_nodlopen, [dnl
1537 cat > conftest.c <<EOF
1538 int _start (void) { return 42; }
1539 EOF
1540 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1541 -fPIC -shared -o conftest.so conftest.c
1542 -nostartfiles -nostdlib
1543 -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1544 then
1545 libc_cv_z_nodlopen=yes
1546 else
1547 AC_MSG_ERROR(linker with -z nodlopen support required)
1548 fi
1549 rm -f conftest*])
1551 AC_CACHE_CHECK(for -z initfirst option,
1552 libc_cv_z_initfirst, [dnl
1553 cat > conftest.c <<EOF
1554 int _start (void) { return 42; }
1555 EOF
1556 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1557 -fPIC -shared -o conftest.so conftest.c
1558 -nostartfiles -nostdlib
1559 -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1560 then
1561 libc_cv_z_initfirst=yes
1562 else
1563 AC_MSG_ERROR(linker with -z initfirst support required)
1564 fi
1565 rm -f conftest*])
1567 case "$base_machine" in
1568 changequote(,)dnl
1569 i[34567]86 | x86_64 | powerpc* | s390* | sparc* | alpha*)
1570 changequote([,])dnl
1571 AC_CACHE_CHECK(for -z relro option,
1572 libc_cv_z_relro, [dnl
1573 libc_cv_z_relro=no
1574 if AC_TRY_COMMAND([${CC-cc} -v --help 2>&1|grep "z relro" 1>&AS_MESSAGE_LOG_FD])
1575 then
1576 if AC_TRY_COMMAND([${CC-cc} -Wl,--verbose 2>&1|grep DATA_SEGMENT_RELRO_END 1>&AS_MESSAGE_LOG_FD])
1577 then
1578 libc_cv_z_relro=yes
1579 fi
1580 fi])
1581 if test "$libc_cv_z_relro" = no; then
1582 AC_MSG_ERROR(linker with -z relro support required)
1583 fi
1584 ;;
1585 *) ;;
1586 esac
1588 AC_CACHE_CHECK(for -Bgroup option,
1589 libc_cv_Bgroup, [dnl
1590 cat > conftest.c <<EOF
1591 int _start (void) { return 42; }
1592 EOF
1593 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1594 -fPIC -shared -o conftest.so conftest.c
1595 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1596 then
1597 libc_cv_Bgroup=yes
1598 else
1599 libc_cv_Bgroup=no
1600 fi
1601 rm -f conftest*])
1602 AC_SUBST(libc_cv_Bgroup)
1604 AC_CACHE_CHECK(for libgcc_s suffix,
1605 libc_cv_libgcc_s_suffix, [dnl
1606 cat > conftest.c <<EOF
1607 int main (void) { return 0; }
1608 EOF
1609 changequote(,)dnl
1610 libc_cv_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1611 -fPIC -shared -shared-libgcc -o conftest.so \
1612 conftest.c -v 2>&1 >/dev/null \
1613 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1614 changequote([,])dnl
1615 rm -f conftest*])
1616 AC_SUBST(libc_cv_libgcc_s_suffix)
1618 AC_CACHE_CHECK(for --as-needed option,
1619 libc_cv_as_needed, [dnl
1620 cat > conftest.c <<EOF
1621 int main (void) { return 0; }
1622 EOF
1623 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1624 -fPIC -shared -o conftest.so conftest.c
1625 -lgcc_s$libc_cv_libgcc_s_suffix -Wl,--as-needed
1626 -nostdlib 1>&AS_MESSAGE_LOG_FD])
1627 then
1628 libc_cv_as_needed=yes
1629 else
1630 libc_cv_as_needed=no
1631 fi
1632 rm -f conftest*])
1633 AC_SUBST(libc_cv_as_needed)
1635 ASFLAGS_config=
1636 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1637 libc_cv_as_noexecstack, [dnl
1638 cat > conftest.c <<EOF
1639 void foo (void) { }
1640 EOF
1641 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1642 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1643 && grep -q .note.GNU-stack conftest.s \
1644 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1645 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1646 then
1647 libc_cv_as_noexecstack=yes
1648 else
1649 libc_cv_as_noexecstack=no
1650 fi
1651 rm -f conftest*])
1652 if test $libc_cv_as_noexecstack = yes; then
1653 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1654 fi
1655 AC_SUBST(ASFLAGS_config)
1657 AC_CACHE_CHECK(for -z combreloc,
1658 libc_cv_z_combreloc, [dnl
1659 cat > conftest.c <<EOF
1660 extern int bar (int);
1661 extern int mumble;
1662 int foo (void) { return bar (mumble); }
1663 EOF
1664 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1665 -fPIC -shared -o conftest.so conftest.c
1666 -nostdlib -nostartfiles
1667 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1668 then
1669 dnl The following test is a bit weak. We must use a tool which can test
1670 dnl cross-platform since the gcc used can be a cross compiler. Without
1671 dnl introducing new options this is not easily doable. Instead use a tool
1672 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1673 dnl look for a section named .rel.dyn.
1674 if readelf -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1675 libc_cv_z_combreloc=yes
1676 else
1677 libc_cv_z_combreloc=no
1678 fi
1679 else
1680 libc_cv_z_combreloc=no
1681 fi
1682 rm -f conftest*])
1683 if test "$libc_cv_z_combreloc" = yes; then
1684 AC_DEFINE(HAVE_Z_COMBRELOC)
1685 fi
1686 AC_SUBST(libc_cv_z_combreloc)
1688 AC_CACHE_CHECK(for -z execstack,
1689 libc_cv_z_execstack, [dnl
1690 cat > conftest.c <<EOF
1691 int _start (void) { return 42; }
1692 EOF
1693 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1694 -fPIC -shared -o conftest.so conftest.c
1695 -Wl,-z,execstack -nostdlib
1696 1>&AS_MESSAGE_LOG_FD])
1697 then
1698 libc_cv_z_execstack=yes
1699 else
1700 libc_cv_z_execstack=no
1701 fi
1702 rm -f conftest*])
1703 AC_SUBST(libc_cv_z_execstack)
1705 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1706 cat > conftest.c <<EOF
1707 int foo;
1708 main () { return 0;}
1709 EOF
1710 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1711 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1712 then
1713 libc_cv_fpie=yes
1714 else
1715 libc_cv_fpie=no
1716 fi
1717 rm -f conftest*])
1719 AC_SUBST(libc_cv_fpie)
1721 AC_CACHE_CHECK(for --hash-style option,
1722 libc_cv_hashstyle, [dnl
1723 cat > conftest.c <<EOF
1724 int _start (void) { return 42; }
1725 EOF
1726 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1727 -fPIC -shared -o conftest.so conftest.c
1728 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1729 then
1730 libc_cv_hashstyle=yes
1731 else
1732 libc_cv_hashstyle=no
1733 fi
1734 rm -f conftest*])
1735 AC_SUBST(libc_cv_hashstyle)
1736 fi
1738 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1739 cat > conftest.c <<EOF
1740 int foo;
1741 EOF
1742 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1743 conftest.c 1>&AS_MESSAGE_LOG_FD])
1744 then
1745 libc_cv_fno_toplevel_reorder=yes
1746 else
1747 libc_cv_fno_toplevel_reorder=no
1748 fi
1749 rm -f conftest*])
1750 if test $libc_cv_fno_toplevel_reorder = yes; then
1751 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1752 else
1753 fno_unit_at_a_time=-fno-unit-at-a-time
1754 fi
1755 AC_SUBST(fno_unit_at_a_time)
1757 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1758 cat > conftest.c <<EOF
1759 int foo;
1760 main () { return 0;}
1761 EOF
1762 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -Werror -fstack-protector
1763 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1764 then
1765 libc_cv_ssp=yes
1766 else
1767 libc_cv_ssp=no
1768 fi
1769 rm -f conftest*])
1770 AC_SUBST(libc_cv_ssp)
1772 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1773 cat > conftest.c <<EOF
1774 int foo;
1775 #ifdef __GNUC_GNU_INLINE__
1776 main () { return 0;}
1777 #else
1778 #error
1779 #endif
1780 EOF
1781 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1782 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1783 then
1784 libc_cv_gnu89_inline=yes
1785 else
1786 libc_cv_gnu89_inline=no
1787 fi
1788 rm -f conftest*])
1789 if test $libc_cv_gnu89_inline = yes; then
1790 gnu89_inline=-fgnu89-inline
1791 else
1792 gnu89_inline=
1793 fi
1794 AC_SUBST(gnu89_inline)
1796 if test $elf != yes; then
1797 AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
1798 [AC_TRY_COMPILE(, [asm (".section .init");
1799 asm (".section .fini");
1800 asm ("${libc_cv_dot_text}");],
1801 libc_cv_have_initfini=yes,
1802 libc_cv_have_initfini=no)])
1803 AC_SUBST(libc_cv_have_initfini)dnl
1804 if test $libc_cv_have_initfini = yes; then
1805 AC_DEFINE(HAVE_INITFINI)
1806 fi
1807 fi
1809 if test $elf = yes; then
1810 AC_CACHE_CHECK(whether cc puts quotes around section names,
1811 libc_cv_have_section_quotes,
1812 [cat > conftest.c <<EOF
1813 static const int foo
1814 __attribute__ ((section ("bar"))) = 1;
1815 EOF
1816 if ${CC-cc} -S conftest.c -o conftest.s; then
1817 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1818 libc_cv_have_section_quotes=yes
1819 else
1820 libc_cv_have_section_quotes=no
1821 fi
1822 else
1823 libc_cv_have_section_quotes=unknown
1824 fi
1825 rm -f conftest.[cs]
1826 ])
1827 if test $libc_cv_have_section_quotes = yes; then
1828 AC_DEFINE(HAVE_SECTION_QUOTES)
1829 fi
1830 fi
1832 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
1833 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
1834 [cat > conftest.$ac_ext <<EOF
1835 dnl This sometimes fails to find confdefs.h, for some reason.
1836 dnl [#]line $LINENO "[$]0"
1837 [#]line $LINENO "configure"
1838 #include "confdefs.h"
1839 void underscore_test(void) {
1840 return; }
1841 EOF
1842 if AC_TRY_EVAL(ac_compile); then
1843 if grep _underscore_test conftest* >/dev/null; then
1844 ifelse([$1], , :, [rm -f conftest*
1845 $1])
1846 else
1847 ifelse([$2], , , [rm -f conftest*
1848 $2])
1849 fi
1850 else
1851 echo "configure: failed program was:" >&AS_MESSAGE_LOG_FD
1852 cat conftest.$ac_ext >&AS_MESSAGE_LOG_FD
1853 ifelse([$2], , , [rm -f conftest*
1854 $2])
1855 fi
1856 rm -f conftest*])
1858 if test $elf = yes; then
1859 libc_cv_asm_underscores=no
1860 else
1861 if test $ac_cv_prog_cc_works = yes; then
1862 AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1863 [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
1864 libc_cv_asm_underscores=yes,
1865 libc_cv_asm_underscores=no)])
1866 else
1867 AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
1868 [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
1869 libc_cv_asm_underscores=no)])
1870 fi
1871 fi
1872 if test $libc_cv_asm_underscores = no; then
1873 AC_DEFINE(NO_UNDERSCORES)
1874 fi
1876 if test $elf = yes; then
1877 libc_cv_weak_symbols=yes
1878 fi
1880 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1881 [dnl
1882 cat > conftest.s <<EOF
1883 ${libc_cv_dot_text}
1884 ${libc_cv_asm_global_directive} foo
1885 foo:
1886 .weak foo
1887 .weak bar; bar = foo
1888 EOF
1889 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1890 libc_cv_asm_weak_directive=yes
1891 else
1892 libc_cv_asm_weak_directive=no
1893 fi
1894 rm -f conftest*])
1896 if test $libc_cv_asm_weak_directive = no; then
1897 AC_CACHE_CHECK(for assembler .weakext directive,
1898 libc_cv_asm_weakext_directive,
1899 [dnl
1900 cat > conftest.s <<EOF
1901 ${libc_cv_dot_text}
1902 ${libc_cv_asm_global_directive} foo
1903 foo:
1904 .weakext bar foo
1905 .weakext baz
1906 ${libc_cv_asm_global_directive} baz
1907 baz:
1908 EOF
1909 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1910 libc_cv_asm_weakext_directive=yes
1911 else
1912 libc_cv_asm_weakext_directive=no
1913 fi
1914 rm -f conftest*])
1916 fi # no .weak
1918 if test $libc_cv_asm_weak_directive = yes; then
1919 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1920 elif test $libc_cv_asm_weakext_directive = yes; then
1921 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1922 fi
1924 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1925 case $machine in
1926 sparc/sparc64*) cfi_offset=2047;;
1927 *) cfi_offset=0;;
1928 esac
1929 cat > conftest.s <<EOF
1930 .text
1931 .type func,%function
1932 func:
1933 .cfi_startproc
1934 .cfi_remember_state
1935 .cfi_rel_offset 1, $cfi_offset
1936 .cfi_endproc
1937 EOF
1938 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1939 libc_cv_asm_cfi_directives=yes
1940 else
1941 libc_cv_asm_cfi_directives=no
1942 fi
1943 rm -f conftest*])
1944 if test $libc_cv_asm_cfi_directives = yes; then
1945 AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1946 fi
1948 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1949 cat > conftest.c <<\EOF
1950 _start () {}
1951 int __eh_pc;
1952 __throw () {}
1953 EOF
1954 dnl No \ in command here because it ends up inside ''.
1955 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1956 -nostdlib -nostartfiles -Wl,--no-whole-archive
1957 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1958 libc_cv_ld_no_whole_archive=yes
1959 else
1960 libc_cv_ld_no_whole_archive=no
1961 fi
1962 rm -f conftest*])
1963 if test $libc_cv_ld_no_whole_archive = yes; then
1964 no_whole_archive=-Wl,--no-whole-archive
1965 fi
1966 AC_SUBST(no_whole_archive)dnl
1968 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1969 cat > conftest.c <<\EOF
1970 _start () {}
1971 int __eh_pc;
1972 __throw () {}
1973 EOF
1974 dnl No \ in command here because it ends up inside ''.
1975 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1976 -nostdlib -nostartfiles -fexceptions
1977 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1978 libc_cv_gcc_exceptions=yes
1979 else
1980 libc_cv_gcc_exceptions=no
1981 fi
1982 rm -f conftest*])
1983 if test $libc_cv_gcc_exceptions = yes; then
1984 exceptions=-fexceptions
1985 fi
1986 AC_SUBST(exceptions)dnl
1988 if test "$host_cpu" = powerpc ; then
1989 # Check for a bug present in at least versions 2.8.x of GCC
1990 # and versions 1.0.x of EGCS.
1991 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1992 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1993 libc_cv_c_asmcr0_bug='no',
1994 libc_cv_c_asmcr0_bug='yes')])
1995 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1996 AC_DEFINE(BROKEN_PPC_ASM_CR0)
1997 fi
1998 fi
2000 dnl Check whether compiler understands __builtin_expect.
2001 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
2002 [cat > conftest.c <<EOF
2003 #line $LINENO "configure"
2004 int foo (int a)
2005 {
2006 a = __builtin_expect (a, 10);
2007 return a == 10 ? 0 : 1;
2008 }
2009 EOF
2010 dnl No \ in command here because it ends up inside ''.
2011 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostdlib -nostartfiles
2012 -o conftest conftest.c -lgcc >&AS_MESSAGE_LOG_FD]); then
2013 libc_cv_gcc_builtin_expect=yes
2014 else
2015 libc_cv_gcc_builtin_expect=no
2016 fi
2017 rm -f conftest*])
2018 if test "$libc_cv_gcc_builtin_expect" = yes; then
2019 AC_DEFINE(HAVE_BUILTIN_EXPECT)
2020 fi
2022 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
2023 cat > conftest.c <<\EOF
2024 void zero (void *x)
2025 {
2026 __builtin_memset (x, 0, 1000);
2027 }
2028 EOF
2029 dnl
2030 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
2031 then
2032 libc_cv_gcc_builtin_memset=no
2033 else
2034 libc_cv_gcc_builtin_memset=yes
2035 fi
2036 rm -f conftest* ])
2037 if test "$libc_cv_gcc_builtin_memset" = yes ; then
2038 AC_DEFINE(HAVE_BUILTIN_MEMSET)
2039 fi
2041 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
2042 cat > conftest.c <<\EOF
2043 extern char *strstr (const char *, const char *) __asm ("my_strstr");
2044 char *foo (const char *a, const char *b)
2045 {
2046 return __builtin_strstr (a, b);
2047 }
2048 EOF
2049 dnl
2050 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
2051 then
2052 libc_cv_gcc_builtin_redirection=yes
2053 else
2054 libc_cv_gcc_builtin_redirection=no
2055 fi
2056 rm -f conftest* ])
2057 if test "$libc_cv_gcc_builtin_redirection" = yes ; then
2058 AC_DEFINE(HAVE_BUILTIN_REDIRECTION)
2059 fi
2061 dnl Check whether the compiler supports the __thread keyword.
2062 if test "x$use__thread" != xno; then
2063 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
2064 [cat > conftest.c <<\EOF
2065 __thread int a = 42;
2066 EOF
2067 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
2068 libc_cv_gcc___thread=yes
2069 else
2070 libc_cv_gcc___thread=no
2071 fi
2072 rm -f conftest*])
2073 if test "$libc_cv_gcc___thread" = yes; then
2074 AC_DEFINE(HAVE___THREAD)
2075 fi
2076 else
2077 libc_cv_gcc___thread=no
2078 fi
2080 if test "$libc_cv_gcc___thread" = yes; then
2081 dnl Check whether the compiler supports the tls_model attribute.
2082 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
2083 cat > conftest.c <<\EOF
2084 extern __thread int a __attribute__((tls_model ("initial-exec")));
2085 EOF
2086 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
2087 libc_cv_gcc_tls_model_attr=yes
2088 else
2089 libc_cv_gcc_tls_model_attr=no
2090 fi
2091 rm -f conftest*])
2092 if test "$libc_cv_gcc_tls_model_attr" = yes; then
2093 AC_DEFINE(HAVE_TLS_MODEL_ATTRIBUTE)
2094 fi
2095 fi
2097 if test -n "$submachine"; then
2098 AC_CACHE_CHECK([for compiler option for CPU variant],
2099 libc_cv_cc_submachine, [dnl
2100 libc_cv_cc_submachine=no
2101 for opt in "-march=$submachine" "-mcpu=$submachine"; do
2102 if AC_TRY_COMMAND([${CC-cc} $opt -xc /dev/null -S -o /dev/null]); then
2103 libc_cv_cc_submachine="$opt"
2104 break
2105 fi
2106 done])
2107 if test "x$libc_cv_cc_submachine" = xno; then
2108 AC_MSG_ERROR([${CC-cc} does not support $submachine])
2109 fi
2110 fi
2111 AC_SUBST(libc_cv_cc_submachine)
2113 dnl Check whether we have the gd library available.
2114 AC_MSG_CHECKING(for libgd)
2115 if test "$with_gd" != "no"; then
2116 old_CFLAGS="$CFLAGS"
2117 CFLAGS="$CFLAGS $libgd_include"
2118 old_LDFLAGS="$LDFLAGS"
2119 LDFLAGS="$LDFLAGS $libgd_ldflags"
2120 old_LIBS="$LIBS"
2121 LIBS="$LIBS -lgd -lpng -lz -lm"
2122 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
2123 CFLAGS="$old_CFLAGS"
2124 LDFLAGS="$old_LDFLAGS"
2125 LIBS="$old_LIBS"
2126 else
2127 LIBGD=no
2128 fi
2129 AC_MSG_RESULT($LIBGD)
2130 AC_SUBST(LIBGD)
2132 # SELinux detection
2133 if test x$with_selinux = xno ; then
2134 have_selinux=no;
2135 else
2136 # See if we have the SELinux library
2137 AC_CHECK_LIB(selinux, is_selinux_enabled,
2138 have_selinux=yes, have_selinux=no)
2139 # See if we have the SELinux header with the NSCD permissions in it.
2140 if test x$have_selinux = xyes ; then
2141 AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2142 AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2143 [#ifdef NSCD__SHMEMHOST
2144 return 0;
2145 #else
2146 #error NSCD__SHMEMHOST not defined
2147 #endif],
2148 have_selinux=yes, have_selinux=no)
2149 AC_MSG_RESULT($have_selinux)
2150 fi
2152 if test x$with_selinux = xyes ; then
2153 if test x$have_selinux = xno ; then
2154 AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2155 fi
2156 fi
2157 fi
2158 # Check if we're building with SELinux support.
2159 if test "x$have_selinux" = xyes; then
2160 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2162 # See if we have the libaudit library
2163 AC_CHECK_LIB(audit, audit_log_user_avc_message,
2164 have_libaudit=yes, have_libaudit=no)
2165 if test "x$have_libaudit" = xyes; then
2166 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2167 fi
2168 AC_SUBST(have_libaudit)
2170 # See if we have the libcap library
2171 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2172 if test "x$have_libcap" = xyes; then
2173 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2174 fi
2175 AC_SUBST(have_libcap)
2176 fi
2177 AC_SUBST(have_selinux)
2179 dnl check for the size of 'long double'.
2180 AC_CHECK_SIZEOF(long double, 0)
2181 sizeof_long_double=$ac_cv_sizeof_long_double
2182 AC_SUBST(sizeof_long_double)
2184 ### End of automated tests.
2185 ### Now run sysdeps configure fragments.
2187 # They also can set these variables.
2188 use_ldconfig=no
2189 ldd_rewrite_script=no
2190 libc_cv_sysconfdir=$sysconfdir
2191 libc_cv_gcc_unwind_find_fde=no
2192 libc_cv_idn=no
2194 # Iterate over all the sysdep directories we will use, running their
2195 # configure fragments.
2196 for dir in $sysnames; do
2197 case $dir in
2198 /*) dest=$dir ;;
2199 *) dest=$srcdir/$dir ;;
2200 esac
2201 if test -r $dest/configure; then
2202 AC_MSG_RESULT(running configure fragment for $dir)
2203 . $dest/configure
2204 fi
2205 done
2207 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2208 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2209 fi
2210 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2212 dnl This is tested by existing code and it's simpler to avoid changing it.
2213 AC_DEFINE(USE_IN_LIBIO)
2215 # Test for old glibc 2.0.x headers so that they can be removed properly
2216 # Search only in includedir.
2217 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2218 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2219 then
2220 old_glibc_headers=yes
2221 else
2222 old_glibc_headers=no
2223 fi
2224 AC_MSG_RESULT($old_glibc_headers)
2225 if test ${old_glibc_headers} = yes; then
2226 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2227 AC_MSG_WARN(*** be removed.)
2228 fi
2229 AC_SUBST(old_glibc_headers)
2231 AC_SUBST(libc_cv_slibdir)
2232 AC_SUBST(libc_cv_localedir)
2233 AC_SUBST(libc_cv_sysconfdir)
2234 AC_SUBST(libc_cv_rootsbindir)
2235 AC_SUBST(libc_cv_forced_unwind)
2237 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2238 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2239 AC_SUBST(libc_cv_cc_sse4)
2240 AC_SUBST(libc_cv_cc_avx)
2241 AC_SUBST(libc_cv_as_i686)
2243 AC_SUBST(use_ldconfig)
2244 AC_SUBST(ldd_rewrite_script)
2246 AC_SUBST(elf) AC_SUBST(xcoff)
2247 if test $elf = yes; then
2248 AC_DEFINE(HAVE_ELF)
2249 fi
2250 if test $xcoff = yes; then
2251 AC_DEFINE(HAVE_XCOFF)
2252 fi
2254 AC_SUBST(static)
2255 AC_SUBST(shared)
2256 if test $shared = default; then
2257 shared=$elf
2258 fi
2260 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2261 [libc_cv_pic_default=yes
2262 cat > conftest.c <<EOF
2263 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2264 # error PIC is default.
2265 #endif
2266 EOF
2267 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2268 libc_cv_pic_default=no
2269 fi
2270 rm -f conftest.*])
2271 AC_SUBST(libc_cv_pic_default)
2273 AC_SUBST(profile)
2274 AC_SUBST(omitfp)
2275 AC_SUBST(bounded)
2276 AC_SUBST(static_nss)
2277 AC_SUBST(nopic_initfini)
2279 AC_SUBST(DEFINES)
2281 dnl See sysdeps/mach/configure.in for this variable.
2282 AC_SUBST(mach_interface_list)
2284 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2285 config_makefile=
2286 else
2287 config_makefile=Makefile
2288 fi
2290 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2291 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2292 AC_SUBST(VERSION)
2293 AC_SUBST(RELEASE)
2295 AC_CONFIG_FILES([config.make ${config_makefile}])
2296 AC_CONFIG_COMMANDS([default],[[
2297 case $CONFIG_FILES in *config.make*)
2298 echo "$config_vars" >> config.make;;
2299 esac
2300 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2301 AC_OUTPUT