configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/],
   4   [glibc], [https://www.gnu.org/software/glibc/])
   5 AC_CONFIG_SRCDIR([include/features.h])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_AUX_DIR([scripts])
   8
   9 ACX_PKGVERSION([GNU libc])
  10 ACX_BUGURL([https://www.gnu.org/software/libc/bugs.html])
  11 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  12                    [Package description])
  13 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  14                    [Bug reporting address])
  15
  16 # Glibc should not depend on any header files
  17 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  18   [m4_divert_text([DEFAULTS],
  19     [ac_includes_default='/* none */'])])
  20
  21 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  22 # here to work around the Autoconf issue discussed in
  23 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  24 AC_DEFUN([AC_PROG_CPP],
  25 [AC_REQUIRE([AC_PROG_CC])dnl
  26 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  27 _AC_ARG_VAR_CPPFLAGS()dnl
  28 # On Suns, sometimes $CPP names a directory.
  29 if test -n "$CPP" && test -d "$CPP"; then
  30   CPP=
  31 fi
  32 if test -z "$CPP"; then
  33   CPP="$CC -E"
  34 fi
  35 AC_SUBST(CPP)dnl
  36 ])# AC_PROG_CPP
  37
  38 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  39 # issue discussed in
  40 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  41 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  42
  43 dnl This is here so we can set $subdirs directly based on configure fragments.
  44 AC_CONFIG_SUBDIRS()
  45
  46 AC_CANONICAL_HOST
  47
  48 AC_PROG_CC
  49 if test $host != $build; then
  50   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  51 fi
  52 AC_SUBST(cross_compiling)
  53 AC_PROG_CPP
  54 AC_CHECK_TOOL(READELF, readelf, false)
  55
  56 # We need the C++ compiler only for testing.
  57 AC_PROG_CXX
  58 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  59 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  60 AC_LANG_PUSH([C++])
  61 # Default, dynamic case.
  62 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  63                [libc_cv_cxx_link_ok=yes],
  64                [libc_cv_cxx_link_ok=no])
  65 # Static case.
  66 old_LDFLAGS="$LDFLAGS"
  67 LDFLAGS="$LDFLAGS -static"
  68 AC_LINK_IFELSE([AC_LANG_SOURCE([
  69 #include <iostream>
  70
  71 int
  72 main()
  73 {
  74   std::cout << "Hello, world!";
  75   return 0;
  76 }
  77 ])],
  78                [],
  79                [libc_cv_cxx_link_ok=no])
  80 LDFLAGS="$old_LDFLAGS"
  81 AC_LANG_POP([C++])])
  82 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  83
  84 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  85   AC_MSG_ERROR([you must configure in a separate build directory])
  86 fi
  87
  88 # This will get text that should go into config.make.
  89 config_vars=
  90
  91 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  92 AC_ARG_WITH([gd],
  93             AC_HELP_STRING([--with-gd=DIR],
  94                            [find libgd include dir and library with prefix DIR]),
  95             [dnl
  96 case "$with_gd" in
  97 yes|''|no) ;;
  98 *) libgd_include="-I$withval/include"
  99    libgd_ldflags="-L$withval/lib" ;;
 100 esac
 101 ])
 102 AC_ARG_WITH([gd-include],
 103             AC_HELP_STRING([--with-gd-include=DIR],
 104                            [find libgd include files in DIR]),
 105             [dnl
 106 case "$with_gd_include" in
 107 ''|no) ;;
 108 *) libgd_include="-I$withval" ;;
 109 esac
 110 ])
 111 AC_ARG_WITH([gd-lib],
 112             AC_HELP_STRING([--with-gd-lib=DIR],
 113                            [find libgd library files in DIR]),
 114             [dnl
 115 case "$with_gd_lib" in
 116 ''|no) ;;
 117 *) libgd_ldflags="-L$withval" ;;
 118 esac
 119 ])
 120
 121 if test -n "$libgd_include"; then
 122   config_vars="$config_vars
 123 CFLAGS-memusagestat.c = $libgd_include"
 124 fi
 125 if test -n "$libgd_ldflags"; then
 126   config_vars="$config_vars
 127 libgd-LDFLAGS = $libgd_ldflags"
 128 fi
 129
 130 dnl Arguments to specify presence of other packages/features.
 131 AC_ARG_WITH([binutils],
 132             AC_HELP_STRING([--with-binutils=PATH],
 133                            [specify location of binutils (as and ld)]),
 134             [path_binutils=$withval],
 135             [path_binutils=''])
 136 AC_ARG_WITH([selinux],
 137             AC_HELP_STRING([--with-selinux],
 138                            [if building with SELinux support]),
 139             [with_selinux=$withval],
 140             [with_selinux=auto])
 141
 142 AC_ARG_WITH([headers],
 143             AC_HELP_STRING([--with-headers=PATH],
 144                            [location of system headers to use
 145                             (for example /usr/src/linux/include)
 146                             @<:@default=compiler default@:>@]),
 147             [sysheaders=$withval],
 148             [sysheaders=''])
 149 AC_SUBST(sysheaders)
 150
 151 AC_SUBST(use_default_link)
 152 AC_ARG_WITH([default-link],
 153             AC_HELP_STRING([--with-default-link],
 154                            [do not use explicit linker scripts]),
 155             [use_default_link=$withval],
 156             [use_default_link=default])
 157
 158 dnl Additional build flags injection.
 159 AC_ARG_WITH([nonshared-cflags],
 160             AC_HELP_STRING([--with-nonshared-cflags=CFLAGS],
 161                            [build nonshared libraries with additional CFLAGS]),
 162             [extra_nonshared_cflags=$withval],
 163             [extra_nonshared_cflags=])
 164 AC_SUBST(extra_nonshared_cflags)
 165
 166 AC_ARG_ENABLE([sanity-checks],
 167               AC_HELP_STRING([--disable-sanity-checks],
 168                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 169               [enable_sanity=$enableval],
 170               [enable_sanity=yes])
 171
 172 AC_ARG_ENABLE([shared],
 173               AC_HELP_STRING([--enable-shared],
 174                              [build shared library @<:@default=yes if GNU ld@:>@]),
 175               [shared=$enableval],
 176               [shared=yes])
 177 AC_ARG_ENABLE([profile],
 178               AC_HELP_STRING([--enable-profile],
 179                              [build profiled library @<:@default=no@:>@]),
 180               [profile=$enableval],
 181               [profile=no])
 182 AC_ARG_ENABLE([static-pie],
 183               AC_HELP_STRING([--enable-static-pie],
 184                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 185               [static_pie=$enableval],
 186               [static_pie=no])
 187 AC_ARG_ENABLE([timezone-tools],
 188               AC_HELP_STRING([--disable-timezone-tools],
 189                              [do not install timezone tools @<:@default=install@:>@]),
 190               [enable_timezone_tools=$enableval],
 191               [enable_timezone_tools=yes])
 192 AC_SUBST(enable_timezone_tools)
 193
 194 AC_ARG_ENABLE([hardcoded-path-in-tests],
 195               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 196                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 197               [hardcoded_path_in_tests=$enableval],
 198               [hardcoded_path_in_tests=no])
 199 AC_SUBST(hardcoded_path_in_tests)
 200
 201 AC_ARG_ENABLE([stackguard-randomization],
 202               AC_HELP_STRING([--enable-stackguard-randomization],
 203                              [initialize __stack_chk_guard canary with a random number at program start]),
 204               [enable_stackguard_randomize=$enableval],
 205               [enable_stackguard_randomize=no])
 206 if test "$enable_stackguard_randomize" = yes; then
 207   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 208 fi
 209
 210 AC_ARG_ENABLE([hidden-plt],
 211               AC_HELP_STRING([--disable-hidden-plt],
 212                              [do not hide internal function calls to avoid PLT]),
 213               [hidden=$enableval],
 214               [hidden=yes])
 215 if test "x$hidden" = xno; then
 216   AC_DEFINE(NO_HIDDEN)
 217 fi
 218
 219 AC_ARG_ENABLE([bind-now],
 220               AC_HELP_STRING([--enable-bind-now],
 221                              [disable lazy relocations in DSOs]),
 222               [bindnow=$enableval],
 223               [bindnow=no])
 224 AC_SUBST(bindnow)
 225 if test "x$bindnow" = xyes; then
 226   AC_DEFINE(BIND_NOW)
 227 fi
 228
 229 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 230 dnl -fstack-protector-strong.
 231 AC_ARG_ENABLE([stack-protector],
 232               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 233                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 234               [enable_stack_protector=$enableval],
 235               [enable_stack_protector=no])
 236 case "$enable_stack_protector" in
 237 all|yes|no|strong) ;;
 238 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 239 esac
 240
 241 dnl On some platforms we cannot use dynamic loading.  We must provide
 242 dnl static NSS modules.
 243 AC_ARG_ENABLE([static-nss],
 244               AC_HELP_STRING([--enable-static-nss],
 245                              [build static NSS modules @<:@default=no@:>@]),
 246               [static_nss=$enableval],
 247               [static_nss=no])
 248 dnl Enable static NSS also if we build no shared objects.
 249 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 250   static_nss=yes
 251   AC_DEFINE(DO_STATIC_NSS)
 252 fi
 253
 254 AC_ARG_ENABLE([force-install],
 255               AC_HELP_STRING([--disable-force-install],
 256                              [don't force installation of files from this package, even if they are older than the installed files]),
 257               [force_install=$enableval],
 258               [force_install=yes])
 259 AC_SUBST(force_install)
 260
 261 AC_ARG_ENABLE([maintainer-mode],
 262               AC_HELP_STRING([--enable-maintainer-mode],
 263                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 264               [maintainer=$enableval],
 265               [maintainer=no])
 266
 267 dnl On some platforms we allow dropping compatibility with all kernel
 268 dnl versions.
 269 AC_ARG_ENABLE([kernel],
 270               AC_HELP_STRING([--enable-kernel=VERSION],
 271                              [compile for compatibility with kernel not older than VERSION]),
 272               [minimum_kernel=$enableval],
 273               [])
 274 dnl Prevent unreasonable values.
 275 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 276   # Better nothing than this.
 277   minimum_kernel=""
 278 else
 279   if test "$minimum_kernel" = current; then
 280     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 281   fi
 282 fi
 283
 284 dnl For the development we sometimes want gcc to issue even more warnings.
 285 dnl This is not the default since many of the extra warnings are not
 286 dnl appropriate.
 287 AC_ARG_ENABLE([all-warnings],
 288               AC_HELP_STRING([--enable-all-warnings],
 289                              [enable all useful warnings gcc can issue]),
 290               [all_warnings=$enableval],
 291               [])
 292 AC_SUBST(all_warnings)
 293
 294 AC_ARG_ENABLE([werror],
 295               AC_HELP_STRING([--disable-werror],
 296                              [do not build with -Werror]),
 297               [enable_werror=$enableval],
 298               [enable_werror=yes])
 299 AC_SUBST(enable_werror)
 300
 301 AC_ARG_ENABLE([multi-arch],
 302               AC_HELP_STRING([--enable-multi-arch],
 303                              [enable single DSO with optimizations for multiple architectures]),
 304               [multi_arch=$enableval],
 305               [multi_arch=default])
 306
 307 AC_ARG_ENABLE([experimental-malloc],
 308               AC_HELP_STRING([--disable-experimental-malloc],
 309                              [disable experimental malloc features]),
 310               [experimental_malloc=$enableval],
 311               [experimental_malloc=yes])
 312 AC_SUBST(experimental_malloc)
 313
 314 AC_ARG_ENABLE([crypt],
 315               AC_HELP_STRING([--disable-crypt],
 316                              [do not build nor install the passphrase hashing library, libcrypt]),
 317               [build_crypt=$enableval],
 318               [build_crypt=yes])
 319 AC_SUBST(build_crypt)
 320
 321 AC_ARG_ENABLE([nss-crypt],
 322               AC_HELP_STRING([--enable-nss-crypt],
 323                              [enable libcrypt to use nss]),
 324               [nss_crypt=$enableval],
 325               [nss_crypt=no])
 326 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 327   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 328   nss_crypt=no
 329 fi
 330 if test x$nss_crypt = xyes; then
 331   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 332   if test $? -ne 0; then
 333     AC_MSG_ERROR([cannot find include directory with nss-config])
 334   fi
 335   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 336   if test $? -ne 0; then
 337     AC_MSG_ERROR([cannot find include directory with nspr-config])
 338   fi
 339   old_CFLAGS="$CFLAGS"
 340   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 341   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 342 #include <hasht.h>
 343 #include <nsslowhash.h>
 344 void f (void) { NSSLOW_Init (); }])],
 345              libc_cv_nss_crypt=yes,
 346              AC_MSG_ERROR([
 347 cannot find NSS headers with lowlevel hash function interfaces]))
 348   old_LIBS="$LIBS"
 349   old_LDFLAGS="$LDFLAGS"
 350   LIBS="$LIBS -lfreebl3"
 351   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 352 #include <hasht.h>
 353 #include <nsslowhash.h>],
 354                                   [NSSLOW_Init();])],
 355                  libc_cv_nss_crypt=yes,
 356                  AC_MSG_ERROR([
 357 cannot link program using lowlevel NSS hash functions]))
 358   # Check to see if there is a static NSS cryptographic library.
 359   # If there isn't then we can't link anything with libcrypt.a,
 360   # and that might mean disabling some static tests.
 361   LDFLAGS="$LDFLAGS -static"
 362   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 363 #include <hasht.h>
 364 #include <nsslowhash.h>],
 365                                   [NSSLOW_Init();])],
 366                  libc_cv_static_nss_crypt=yes,
 367                  libc_cv_static_nss_crypt=no)
 368   LDFLAGS="$old_LDFLAGS"
 369   CFLAGS="$old_CFLAGS"
 370   LIBS="$old_LIBS"
 371 else
 372   libc_cv_nss_crypt=no
 373   libc_cv_static_nss_crypt=no
 374 fi
 375 AC_SUBST(libc_cv_nss_crypt)
 376 AC_SUBST(libc_cv_static_nss_crypt)
 377
 378
 379 AC_ARG_ENABLE([obsolete-rpc],
 380               AC_HELP_STRING([--enable-obsolete-rpc],
 381                              [build and install the obsolete RPC code for link-time usage]),
 382               [link_obsolete_rpc=$enableval],
 383               [link_obsolete_rpc=no])
 384 AC_SUBST(link_obsolete_rpc)
 385
 386 if test "$link_obsolete_rpc" = yes; then
 387   AC_DEFINE(LINK_OBSOLETE_RPC)
 388 fi
 389
 390 AC_ARG_ENABLE([obsolete-nsl],
 391               AC_HELP_STRING([--enable-obsolete-nsl],
 392                              [build and install the obsolete libnsl library and depending NSS modules]),
 393               [build_obsolete_nsl=$enableval],
 394               [build_obsolete_nsl=no])
 395 AC_SUBST(build_obsolete_nsl)
 396
 397 if test "$build_obsolete_nsl" = yes; then
 398   AC_DEFINE(LINK_OBSOLETE_NSL)
 399 fi
 400
 401 AC_ARG_ENABLE([systemtap],
 402               [AS_HELP_STRING([--enable-systemtap],
 403                [enable systemtap static probe points @<:@default=no@:>@])],
 404               [systemtap=$enableval],
 405               [systemtap=no])
 406 if test "x$systemtap" != xno; then
 407   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 408   old_CFLAGS="$CFLAGS"
 409   CFLAGS="-std=gnu11 $CFLAGS"
 410   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 411 void foo (int i, void *p)
 412 {
 413   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 414        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 415 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 416   CFLAGS="$old_CFLAGS"])
 417   if test $libc_cv_sdt = yes; then
 418     AC_DEFINE([USE_STAP_PROBE])
 419   elif test "x$systemtap" != xauto; then
 420     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 421   fi
 422 fi
 423
 424 AC_ARG_ENABLE([build-nscd],
 425               [AS_HELP_STRING([--disable-build-nscd],
 426                [disable building and installing the nscd daemon])],
 427               [build_nscd=$enableval],
 428               [build_nscd=default])
 429 AC_SUBST(build_nscd)
 430
 431 # Note the use of $use_nscd is near the bottom of the file.
 432 AC_ARG_ENABLE([nscd],
 433               [AS_HELP_STRING([--disable-nscd],
 434                [library functions will not contact the nscd daemon])],
 435               [use_nscd=$enableval],
 436               [use_nscd=yes])
 437
 438 AC_ARG_ENABLE([pt_chown],
 439               [AS_HELP_STRING([--enable-pt_chown],
 440                [Enable building and installing pt_chown])],
 441               [build_pt_chown=$enableval],
 442               [build_pt_chown=no])
 443 AC_SUBST(build_pt_chown)
 444 if test "$build_pt_chown" = yes; then
 445   AC_DEFINE(HAVE_PT_CHOWN)
 446 fi
 447
 448 AC_ARG_ENABLE([tunables],
 449               [AS_HELP_STRING([--enable-tunables],
 450                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 451               [have_tunables=$enableval],
 452               [have_tunables=yes])
 453 AC_SUBST(have_tunables)
 454 if test "$have_tunables" = yes; then
 455   AC_DEFINE(HAVE_TUNABLES)
 456 fi
 457
 458 # The abi-tags file uses a fairly simplistic model for name recognition that
 459 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 460 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 461 # This doesn't get used much beyond that, so it's fairly safe.
 462 case "$host_os" in
 463 linux*)
 464   ;;
 465 gnu*)
 466   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 467   ;;
 468 esac
 469
 470 AC_ARG_ENABLE([mathvec],
 471               [AS_HELP_STRING([--enable-mathvec],
 472               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 473               [build_mathvec=$enableval],
 474               [build_mathvec=notset])
 475
 476 AC_TRY_COMPILE([], [
 477 #ifndef __CET__
 478 # error no CET compiler support
 479 #endif],
 480                [libc_cv_compiler_default_cet=yes],
 481                [libc_cv_compiler_default_cet=no])
 482
 483 AC_ARG_ENABLE([cet],
 484               AC_HELP_STRING([--enable-cet],
 485                              [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
 486               [enable_cet=$enableval],
 487               [enable_cet=$libc_cv_compiler_default_cet])
 488
 489 # We keep the original values in `$config_*' and never modify them, so we
 490 # can write them unchanged into config.make.  Everything else uses
 491 # $machine, $vendor, and $os, and changes them whenever convenient.
 492 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 493
 494 # Don't allow vendor == "unknown"
 495 test "$config_vendor" = unknown && config_vendor=
 496 config_os="`echo $config_os | sed 's/^unknown-//'`"
 497
 498 # Some configurations imply other options.
 499 elf=yes
 500
 501 # The configure fragment of a port can modify these to supplement
 502 # or override the table in the case statement below.  No fragment should
 503 # ever change the config_* variables, however.
 504 machine=$config_machine
 505 vendor=$config_vendor
 506 os=$config_os
 507 base_os=''
 508
 509 submachine=
 510 AC_ARG_WITH([cpu],
 511             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 512             [dnl
 513   case "$withval" in
 514   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 515   no) ;;
 516   *) submachine="$withval" ;;
 517   esac
 518 ])
 519
 520 # An preconfigure script can set this when it wants to disable the sanity
 521 # check below.
 522 libc_config_ok=no
 523
 524 # A preconfigure script for a system that may or may not use fpu
 525 # sysdeps directories sets this to a preprocessor conditional for
 526 # whether to use such directories.
 527 with_fp_cond=1
 528
 529 dnl Let sysdeps/*/preconfigure act here.
 530 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 531
 532
 533 ###
 534 ### By using the undocumented --enable-hacker-mode option for configure
 535 ### one can skip this test to make the configuration not fail for unsupported
 536 ### platforms.
 537 ###
 538 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 539   case "$machine-$host_os" in
 540   *-linux* | *-gnu*)
 541     ;;
 542   *)
 543     AC_MSG_ERROR([
 544 *** The GNU C library is currently unavailable for this platform.
 545 *** If you are interested in seeing glibc on this platform visit
 546 *** the "How to submit a new port" in the wiki:
 547 ***   https://sourceware.org/glibc/wiki/#Development
 548 *** and join the community!])
 549     ;;
 550   esac
 551 fi
 552
 553 # Set base_machine if not set by a preconfigure fragment.
 554 test -n "$base_machine" || base_machine=$machine
 555 AC_SUBST(base_machine)
 556
 557 # Determine whether to use fpu or nofpu sysdeps directories.
 558 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 559                libc_cv_with_fp, [dnl
 560 cat > conftest.c <<EOF
 561 #if $with_fp_cond
 562 int dummy;
 563 #else
 564 # error "no hardware floating point"
 565 #endif
 566 EOF
 567 libc_cv_with_fp=no
 568 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 569    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 570   libc_cv_with_fp=yes
 571 fi
 572 rm -f conftest*])
 573 AC_SUBST(libc_cv_with_fp)
 574
 575 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 576 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 577                    [libc_cv_ssp=yes],
 578                    [libc_cv_ssp=no])
 579 ])
 580
 581 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 582 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 583                    [libc_cv_ssp_strong=yes],
 584                    [libc_cv_ssp_strong=no])
 585 ])
 586
 587 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 588 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 589                    [libc_cv_ssp_all=yes],
 590                    [libc_cv_ssp_all=no])
 591 ])
 592
 593 stack_protector=
 594 no_stack_protector=
 595 if test "$libc_cv_ssp" = yes; then
 596   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 597   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 598 fi
 599
 600 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 601   stack_protector="-fstack-protector"
 602   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 603 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 604   stack_protector="-fstack-protector-all"
 605   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 606 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 607   stack_protector="-fstack-protector-strong"
 608   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 609 else
 610   stack_protector="-fno-stack-protector"
 611   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 612 fi
 613 AC_SUBST(libc_cv_ssp)
 614 AC_SUBST(stack_protector)
 615 AC_SUBST(no_stack_protector)
 616
 617 if test -n "$stack_protector"; then
 618   dnl Don't run configure tests with stack-protection on, to avoid problems with
 619   dnl bootstrapping.
 620   no_ssp=-fno-stack-protector
 621 else
 622   no_ssp=
 623
 624   if test "$enable_stack_protector" != no; then
 625     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 626   fi
 627 fi
 628
 629 # For the multi-arch option we need support in the assembler & linker.
 630 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 631                libc_cv_ld_gnu_indirect_function, [dnl
 632 cat > conftest.S <<EOF
 633 .type foo,%gnu_indirect_function
 634 foo:
 635 .globl _start
 636 _start:
 637 .globl __start
 638 __start:
 639 .data
 640 #ifdef _LP64
 641 .quad foo
 642 #else
 643 .long foo
 644 #endif
 645 EOF
 646 libc_cv_ld_gnu_indirect_function=no
 647 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 648             -nostartfiles -nostdlib $no_ssp \
 649             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 650   # Do a link to see if the backend supports IFUNC relocs.
 651   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 652   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 653     libc_cv_ld_gnu_indirect_function=yes
 654   }
 655 fi
 656 rm -f conftest*])
 657
 658 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 659 AC_CACHE_CHECK([for gcc attribute ifunc support],
 660                libc_cv_gcc_indirect_function, [dnl
 661 cat > conftest.c <<EOF
 662 extern int func (int);
 663 int used_func (int a)
 664 {
 665   return a;
 666 }
 667 static void *resolver ()
 668 {
 669   return &used_func;
 670 }
 671 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 672 EOF
 673 libc_cv_gcc_indirect_function=no
 674 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 675    2>&AS_MESSAGE_LOG_FD ; then
 676   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 677     libc_cv_gcc_indirect_function=yes
 678   fi
 679 fi
 680 rm -f conftest*])
 681
 682 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
 683 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
 684 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
 685                libc_cv_textrel_ifunc, [dnl
 686 cat > conftest.S <<EOF
 687 .type foo,%gnu_indirect_function
 688 foo:
 689 .globl _start
 690 _start:
 691 .globl __start
 692 __start:
 693 .data
 694 #ifdef _LP64
 695 .quad foo
 696 #else
 697 .long foo
 698 #endif
 699 .text
 700 .globl address
 701 address:
 702 #ifdef _LP64
 703 .quad address
 704 #else
 705 .long address
 706 #endif
 707 EOF
 708 libc_cv_textrel_ifunc=no
 709 if test $libc_cv_ld_gnu_indirect_function = yes; then
 710    if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
 711      libc_cv_textrel_ifunc=yes
 712    fi
 713 fi
 714 rm -f conftest*])
 715 AC_SUBST(libc_cv_textrel_ifunc)
 716
 717 # Check if gcc warns about alias for function with incompatible types.
 718 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 719                libc_cv_gcc_incompatible_alias, [dnl
 720 cat > conftest.c <<EOF
 721 int __redirect_foo (const void *s, int c);
 722
 723 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 724 __typeof (__redirect_foo) *foo_impl (void)
 725 {
 726   return 0;
 727 }
 728
 729 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 730 EOF
 731 libc_cv_gcc_incompatible_alias=yes
 732 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 733   libc_cv_gcc_incompatible_alias=no
 734 fi
 735 rm -f conftest*])
 736
 737 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 738   if test x"$multi_arch" = xyes; then
 739     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 740   else
 741     multi_arch=no
 742   fi
 743 fi
 744 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 745   # GCC 8+ emits a warning for alias with incompatible types and it might
 746   # fail to build ifunc resolvers aliases to either weak or internal
 747   # symbols.  Disables multiarch build in this case.
 748   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 749     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 750     if test x"$multi_arch" = xyes; then
 751       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 752     fi
 753     AC_MSG_WARN([Multi-arch is disabled.])
 754     multi_arch=no
 755   elif test x"$multi_arch" = xyes; then
 756     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 757 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 758   fi
 759 fi
 760 multi_arch_d=
 761 if test x"$multi_arch" != xno; then
 762   multi_arch_d=/multiarch
 763 fi
 764
 765 # Compute the list of sysdep directories for this configuration.
 766 # This can take a while to compute.
 767 sysdep_dir=$srcdir/sysdeps
 768 AC_MSG_CHECKING(sysdep dirs)
 769 dnl We need to use [ and ] for other purposes for a while now.
 770 changequote(,)dnl
 771 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 772 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 773
 774 test "x$base_os" != x || case "$os" in
 775 gnu*)
 776   base_os=mach/hurd ;;
 777 linux*)
 778   base_os=unix/sysv ;;
 779 esac
 780
 781 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 782 tail=$os
 783 ostry=$os
 784 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 785   ostry="$ostry /$o"
 786   tail=$o
 787 done
 788 o=`echo $tail | sed 's/[0-9]*$//'`
 789 if test $o != $tail; then
 790   ostry="$ostry /$o"
 791 fi
 792 # For linux-gnu, try linux-gnu, then linux.
 793 o=`echo $tail | sed 's/-.*$//'`
 794 if test $o != $tail; then
 795   ostry="$ostry /$o"
 796 fi
 797
 798 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 799 base=
 800 tail=$base_os
 801 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 802   set $b
 803   base="$base /$1"
 804   tail="$2"
 805 done
 806
 807 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 808 mach=
 809 tail=$machine${submachine:+/$submachine}
 810 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 811   set $m
 812   # Prepend the machine's FPU directory unless --without-fp.
 813   if test "$libc_cv_with_fp" = yes; then
 814     maybe_fpu=/fpu
 815   else
 816     maybe_fpu=/nofpu
 817   fi
 818   # For each machine term, try it with and then without /multiarch.
 819   for try_fpu in $maybe_fpu ''; do
 820     for try_multi in $multi_arch_d ''; do
 821       mach="$mach /$1$try_fpu$try_multi"
 822     done
 823   done
 824   tail="$2"
 825 done
 826
 827 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 828 changequote([,])dnl
 829
 830 # Find what sysdep directories exist.
 831 sysnames=
 832 for b in $base ''; do
 833   for m0 in $mach ''; do
 834     for v in /$vendor ''; do
 835       test "$v" = / && continue
 836       for o in /$ostry ''; do
 837         test "$o" = / && continue
 838         for m in $mach ''; do
 839           try_suffix="$m0$b$v$o$m"
 840           if test -n "$try_suffix"; then
 841             try_srcdir="${srcdir}/"
 842             try="sysdeps$try_suffix"
 843             test -n "$enable_debug_configure" &&
 844             echo "$0 [DEBUG]: try $try" >&2
 845             if test -d "$try_srcdir$try"; then
 846               sysnames="$sysnames $try"
 847               { test -n "$o" || test -n "$b"; } && os_used=t
 848               { test -n "$m" || test -n "$m0"; } && machine_used=t
 849               case x${m0:-$m} in
 850               x*/$submachine) submachine_used=t ;;
 851               esac
 852             fi
 853           fi
 854         done
 855       done
 856     done
 857   done
 858 done
 859
 860 # If the assembler supports gnu_indirect_function symbol type and the
 861 # architecture supports multi-arch, we enable multi-arch by default.
 862 case $sysnames in
 863 *"$multi_arch_d"*)
 864   ;;
 865 *)
 866   test x"$multi_arch" = xdefault && multi_arch=no
 867   ;;
 868 esac
 869 if test x"$multi_arch" != xno; then
 870   AC_DEFINE(USE_MULTIARCH)
 871 fi
 872 AC_SUBST(multi_arch)
 873
 874 if test -z "$os_used" && test "$os" != none; then
 875   AC_MSG_ERROR(Operating system $os is not supported.)
 876 fi
 877 if test -z "$machine_used" && test "$machine" != none; then
 878   AC_MSG_ERROR(The $machine is not supported.)
 879 fi
 880 if test -z "$submachine_used" && test -n "$submachine"; then
 881   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 882 fi
 883 AC_SUBST(submachine)
 884
 885 # We have now validated the configuration.
 886
 887 # Expand the list of system names into a full list of directories
 888 # from each element's parent name and Implies file (if present).
 889 set $sysnames
 890 names=
 891 while test $# -gt 0; do
 892   name=$1
 893   shift
 894
 895   case " $names " in *" $name "*)
 896     # Already in the list.
 897     continue
 898   esac
 899
 900   # Report each name as we discover it, so there is no long pause in output.
 901   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 902
 903   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 904
 905   case $name in
 906     /*) xsrcdir= ;;
 907     *)  xsrcdir=$srcdir/ ;;
 908   esac
 909   test -n "$enable_debug_configure" &&
 910   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 911
 912   for implies_file in Implies Implies-before Implies-after; do
 913     implies_type=`echo $implies_file | sed s/-/_/`
 914     eval ${implies_type}=
 915     if test -f $xsrcdir$name/$implies_file; then
 916       # Collect more names from the `Implies' file (removing comments).
 917       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 918       for x in $implied_candidate; do
 919         found=no
 920         if test -d $xsrcdir$name_base/$x; then
 921           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 922           found=yes
 923         fi
 924         try="sysdeps/$x"
 925         try_srcdir=$srcdir/
 926         test -n "$enable_debug_configure" &&
 927          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 928         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 929         then
 930           eval "${implies_type}=\"\$${implies_type} \$try\""
 931           found=yes
 932         fi
 933         if test $found = no; then
 934           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 935         fi
 936       done
 937     fi
 938   done
 939
 940   # Add NAME to the list of names.
 941   names="$names $name"
 942
 943   # Find the parent of NAME, using the empty string if it has none.
 944 changequote(,)dnl
 945   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 946 changequote([,])dnl
 947
 948   test -n "$enable_debug_configure" &&
 949     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 950 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 951
 952   # Add the names implied by NAME, and NAME's parent (if it has one), to
 953   # the list of names to be processed (the argument list).  We prepend the
 954   # implied names to the list and append the parent.  We want implied
 955   # directories to come before further directories inferred from the
 956   # configuration components; this ensures that for sysv4, unix/common
 957   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 958   # after sysv4).
 959   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 960   test -n "$sysnames" && set $sysnames
 961 done
 962
 963 # Add the default directories.
 964 default_sysnames="sysdeps/generic"
 965 sysnames="$names $default_sysnames"
 966 AC_SUBST(sysnames)
 967 # The other names were emitted during the scan.
 968 AC_MSG_RESULT($default_sysnames)
 969
 970
 971 ### Locate tools.
 972
 973 AC_PROG_INSTALL
 974 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 975   # The makefiles need to use a different form to find it in $srcdir.
 976   INSTALL='\$(..)./scripts/install-sh -c'
 977 fi
 978 AC_PROG_LN_S
 979
 980 LIBC_PROG_BINUTILS
 981
 982 # Accept binutils 2.25 or newer.
 983 AC_CHECK_PROG_VER(AS, $AS, --version,
 984                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 985                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 986                   AS=: critic_missing="$critic_missing as")
 987
 988 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 989   # Accept gold 1.14 or higher
 990   AC_CHECK_PROG_VER(LD, $LD, --version,
 991                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 992                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 993                     LD=: critic_missing="$critic_missing GNU gold")
 994 else
 995   AC_CHECK_PROG_VER(LD, $LD, --version,
 996                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 997                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 998                     LD=: critic_missing="$critic_missing GNU ld")
 999 fi
1000
1001 # These programs are version sensitive.
1002 AC_CHECK_TOOL_PREFIX
1003 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
1004   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
1005   [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
1006
1007 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1008   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1009   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1010   MSGFMT=: aux_missing="$aux_missing msgfmt")
1011 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1012   [GNU texinfo.* \([0-9][0-9.]*\)],
1013   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1014   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1015 AC_CHECK_PROG_VER(SED, sed, --version,
1016   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1017   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1018   SED=: aux_missing="$aux_missing sed")
1019 AC_CHECK_PROG_VER(AWK, gawk, --version,
1020   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1021   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1022 AC_CHECK_PROG_VER(BISON, bison, --version,
1023   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1024   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1025
1026 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1027 AC_TRY_COMPILE([], [
1028 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1029 #error insufficient compiler
1030 #endif],
1031                [libc_cv_compiler_ok=yes],
1032                [libc_cv_compiler_ok=no])])
1033 AS_IF([test $libc_cv_compiler_ok != yes],
1034       [critic_missing="$critic_missing compiler"])
1035
1036 AC_CHECK_TOOL(NM, nm, false)
1037
1038 if test "x$maintainer" = "xyes"; then
1039   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1040   case "x$AUTOCONF" in
1041   xno|x|x:) AUTOCONF=no ;;
1042   *)
1043     AC_CACHE_CHECK(dnl
1044   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1045     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1046       libc_cv_autoconf_works=yes
1047     else
1048       libc_cv_autoconf_works=no
1049     fi])
1050     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1051     ;;
1052   esac
1053   if test "x$AUTOCONF" = xno; then
1054     aux_missing="$aux_missing autoconf"
1055   fi
1056 else
1057   AUTOCONF=no
1058 fi
1059
1060 # Check for python3 if available, or else python.
1061 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1062   [Python \([0-9][0-9.]*\)],
1063   [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1064   critic_missing="$critic_missing python")
1065 PYTHON="$PYTHON_PROG -B"
1066 AC_SUBST(PYTHON)
1067
1068 test -n "$critic_missing" && AC_MSG_ERROR([
1069 *** These critical programs are missing or too old:$critic_missing
1070 *** Check the INSTALL file for required versions.])
1071
1072 test -n "$aux_missing" && AC_MSG_WARN([
1073 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1074 *** some features or tests will be disabled.
1075 *** Check the INSTALL file for required versions.])
1076
1077 # if using special system headers, find out the compiler's sekrit
1078 # header directory and add that to the list.  NOTE: Only does the right
1079 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1080 if test -n "$sysheaders"; then
1081   SYSINCLUDES=-nostdinc
1082   for d in include include-fixed; do
1083     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1084     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1085   done
1086   SYSINCLUDES="$SYSINCLUDES \
1087 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1088   if test -n "$CXX"; then
1089     CXX_SYSINCLUDES=
1090     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1091     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1092       test "x$cxxheaders" != x &&
1093       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1094     done
1095   fi
1096 fi
1097 AC_SUBST(SYSINCLUDES)
1098 AC_SUBST(CXX_SYSINCLUDES)
1099
1100 # Obtain some C++ header file paths.  This is used to make a local
1101 # copy of those headers in Makerules.
1102 if test -n "$CXX"; then
1103   find_cxx_header () {
1104     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1105          | sed -n "\,$1:,{s/:\$//;p}"
1106   }
1107   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1108   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1109   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1110 fi
1111 AC_SUBST(CXX_CSTDLIB_HEADER)
1112 AC_SUBST(CXX_CMATH_HEADER)
1113 AC_SUBST(CXX_BITS_STD_ABS_H)
1114
1115 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1116 # since this would lead to problems installing/building glibc.
1117 # LD_LIBRARY_PATH contains the current directory if one of the following
1118 # is true:
1119 # - one of the terminals (":" and ";") is the first or last sign
1120 # - two terminals occur directly after each other
1121 # - the path contains an element with a dot in it
1122 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1123 changequote(,)dnl
1124 case ${LD_LIBRARY_PATH} in
1125   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1126     ld_library_path_setting="contains current directory"
1127     ;;
1128   *)
1129     ld_library_path_setting="ok"
1130     ;;
1131 esac
1132 changequote([,])dnl
1133 AC_MSG_RESULT($ld_library_path_setting)
1134 if test "$ld_library_path_setting" != "ok"; then
1135 AC_MSG_ERROR([
1136 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1137 *** building glibc. Please change the environment variable
1138 *** and run configure again.])
1139 fi
1140
1141 AC_PATH_PROG(BASH_SHELL, bash, no)
1142
1143 AC_PATH_PROG(PERL, perl, no)
1144 if test "$PERL" != no &&
1145    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1146   PERL=no
1147 fi
1148 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1149              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1150
1151 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1152 cat > conftest.s <<EOF
1153 .text
1154 foo:
1155 .set glibc_conftest_frobozz,foo
1156 .globl glibc_conftest_frobozz
1157 EOF
1158 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1159 # (but it doesn't work), so we must do a linking check to be sure.
1160 cat > conftest1.c <<\EOF
1161 extern int glibc_conftest_frobozz;
1162 void _start() { glibc_conftest_frobozz = 1; }
1163 EOF
1164 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1165             -nostartfiles -nostdlib $no_ssp \
1166             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1167   libc_cv_asm_set_directive=yes
1168 else
1169   libc_cv_asm_set_directive=no
1170 fi
1171 rm -f conftest*])
1172 if test $libc_cv_asm_set_directive = yes; then
1173   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1174 fi
1175
1176 AC_CACHE_CHECK(linker support for protected data symbol,
1177                libc_cv_protected_data,
1178                [cat > conftest.c <<EOF
1179                 int bar __attribute__ ((visibility ("protected"))) = 1;
1180 EOF
1181                 libc_cv_protected_data=no
1182                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1183                   cat > conftest.c <<EOF
1184                   extern int bar;
1185                   int main (void) { return bar; }
1186 EOF
1187                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1188                     libc_cv_protected_data=yes
1189                   fi
1190                 fi
1191                 rm -f conftest.*
1192                ])
1193 AC_SUBST(libc_cv_protected_data)
1194
1195 AC_CACHE_CHECK(linker support for INSERT in linker script,
1196                libc_cv_insert,
1197                [cat > conftest.c <<EOF
1198                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1199                 int test (void) { return bar; }
1200 EOF
1201                 cat > conftest.t <<EOF
1202                 SECTIONS
1203                 {
1204                   .bar : { *(.bar) }
1205                 }
1206                 INSERT AFTER .rela.dyn;
1207 EOF
1208                 libc_cv_insert=no
1209                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1210                   libc_cv_insert=yes
1211                 fi
1212                 rm -f conftest.*
1213                ])
1214 AC_SUBST(libc_cv_insert)
1215
1216 AC_CACHE_CHECK(for broken __attribute__((alias())),
1217                libc_cv_broken_alias_attribute,
1218                [cat > conftest.c <<EOF
1219                extern int foo (int x) __asm ("xyzzy");
1220                int bar (int x) { return x; }
1221                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1222                extern int dfoo;
1223                extern __typeof (dfoo) dfoo __asm ("abccb");
1224                int dfoo = 1;
1225 EOF
1226                libc_cv_broken_alias_attribute=yes
1227                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1228                  if grep 'xyzzy' conftest.s >/dev/null &&
1229                     grep 'abccb' conftest.s >/dev/null; then
1230                    libc_cv_broken_alias_attribute=no
1231                  fi
1232                fi
1233                rm -f conftest.c conftest.s
1234                ])
1235 if test $libc_cv_broken_alias_attribute = yes; then
1236   AC_MSG_ERROR(working alias attribute support required)
1237 fi
1238
1239 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1240                libc_cv_have_sdata_section,
1241                [echo "int i;" > conftest.c
1242                 libc_cv_have_sdata_section=no
1243                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1244                    | grep '\.sdata' >/dev/null; then
1245                   libc_cv_have_sdata_section=yes
1246                 fi
1247                 rm -f conftest.c conftest.so
1248                ])
1249 if test $libc_cv_have_sdata_section = yes; then
1250   AC_DEFINE(HAVE_SDATA_SECTION)
1251 fi
1252
1253 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1254                libc_cv_ctors_header, [dnl
1255   libc_cv_ctors_header=yes
1256   LIBC_TRY_LINK_STATIC([
1257 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1258 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1259 ],
1260               [dnl
1261       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1262         { gsub(/\@<:@ */, "@<:@") }
1263         $2 == ".ctors" || $2 == ".dtors" {
1264           size = strtonum("0x" $6)
1265           align = strtonum("0x" $NF)
1266           seen@<:@$2@:>@ = 1
1267           stub@<:@$2@:>@ = size == align * 2
1268         }
1269         END {
1270           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1271           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1272           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1273         }
1274       '], [libc_cv_ctors_header=no])
1275     ], [dnl
1276       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1277     ])
1278 ])
1279 if test $libc_cv_ctors_header = no; then
1280   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1281 fi
1282
1283 AC_CACHE_CHECK(for libunwind-support in compiler,
1284                libc_cv_cc_with_libunwind, [
1285   cat > conftest.c <<EOF
1286 int main (void) { return 0; }
1287 EOF
1288   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1289      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1290     libc_cv_cc_with_libunwind=yes
1291   else
1292     libc_cv_cc_with_libunwind=no
1293   fi
1294   rm -f conftest*])
1295 AC_SUBST(libc_cv_cc_with_libunwind)
1296 if test $libc_cv_cc_with_libunwind = yes; then
1297   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1298 fi
1299
1300 ASFLAGS_config=
1301 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1302                libc_cv_as_noexecstack, [dnl
1303 cat > conftest.c <<EOF
1304 void foo (void) { }
1305 EOF
1306 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1307                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1308    && grep .note.GNU-stack conftest.s >/dev/null \
1309    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1310                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1311 then
1312   libc_cv_as_noexecstack=yes
1313 else
1314   libc_cv_as_noexecstack=no
1315 fi
1316 rm -f conftest*])
1317 if test $libc_cv_as_noexecstack = yes; then
1318   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1319 fi
1320 AC_SUBST(ASFLAGS_config)
1321
1322 AC_CACHE_CHECK(for -z combreloc,
1323                libc_cv_z_combreloc, [dnl
1324 cat > conftest.c <<EOF
1325 extern int bar (int);
1326 extern int mumble;
1327 int foo (void) { return bar (mumble); }
1328 EOF
1329 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1330                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1331                         -nostdlib -nostartfiles
1332                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1333 then
1334 dnl The following test is a bit weak.  We must use a tool which can test
1335 dnl cross-platform since the gcc used can be a cross compiler.  Without
1336 dnl introducing new options this is not easily doable.  Instead use a tool
1337 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1338 dnl look for a section named .rel.dyn or .rela.dyn.
1339   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1340     libc_cv_z_combreloc=yes
1341   else
1342     libc_cv_z_combreloc=no
1343   fi
1344 else
1345   libc_cv_z_combreloc=no
1346 fi
1347 rm -f conftest*])
1348 if test "$libc_cv_z_combreloc" = yes; then
1349   AC_DEFINE(HAVE_Z_COMBRELOC)
1350 fi
1351 AC_SUBST(libc_cv_z_combreloc)
1352
1353 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1354                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1355 AC_SUBST(libc_cv_z_execstack)
1356
1357 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1358                     [-Wl,--no-dynamic-linker],
1359                     [libc_cv_no_dynamic_linker=yes],
1360                     [libc_cv_no_dynamic_linker=no])
1361 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1362
1363 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1364 LIBC_TRY_CC_OPTION([-static-pie],
1365                    [libc_cv_static_pie=yes],
1366                    [libc_cv_static_pie=no])
1367 ])
1368 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1369
1370 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1371 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1372 ])
1373
1374 AC_SUBST(libc_cv_fpie)
1375
1376 AC_CACHE_CHECK(for --hash-style option,
1377                libc_cv_hashstyle, [dnl
1378 cat > conftest.c <<EOF
1379 int _start (void) { return 42; }
1380 EOF
1381 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1382                             -fPIC -shared -o conftest.so conftest.c
1383                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1384 then
1385   libc_cv_hashstyle=yes
1386 else
1387   libc_cv_hashstyle=no
1388 fi
1389 rm -f conftest*])
1390 AC_SUBST(libc_cv_hashstyle)
1391
1392 # The linker's default -shared behavior is good enough if it
1393 # does these things that our custom linker scripts ensure that
1394 # all allocated NOTE sections come first.
1395 if test "$use_default_link" = default; then
1396   AC_CACHE_CHECK([for sufficient default -shared layout],
1397                   libc_cv_use_default_link, [dnl
1398   libc_cv_use_default_link=no
1399   cat > conftest.s <<\EOF
1400           .section .note.a,"a",%note
1401           .balign 4
1402           .long 4,4,9
1403           .string "GNU"
1404           .string "foo"
1405           .section .note.b,"a",%note
1406           .balign 4
1407           .long 4,4,9
1408           .string "GNU"
1409           .string "bar"
1410 EOF
1411   if AC_TRY_COMMAND([dnl
1412   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1413        ac_try=`$READELF -S conftest.so | sed -n \
1414          ['${x;p;}
1415           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1416           t a
1417           b
1418           : a
1419           H']`
1420   then
1421     libc_seen_a=no libc_seen_b=no
1422     set -- $ac_try
1423     while test $# -ge 2 -a "$1" = NOTE; do
1424       case "$2" in
1425       .note.a) libc_seen_a=yes ;;
1426       .note.b) libc_seen_b=yes ;;
1427       esac
1428       shift 2
1429     done
1430     case "$libc_seen_a$libc_seen_b" in
1431     yesyes)
1432       libc_cv_use_default_link=yes
1433       ;;
1434     *)
1435       echo >&AS_MESSAGE_LOG_FD "\
1436 $libc_seen_a$libc_seen_b from:
1437 $ac_try"
1438       ;;
1439     esac
1440   fi
1441   rm -f conftest*])
1442   use_default_link=$libc_cv_use_default_link
1443 fi
1444
1445 AC_CACHE_CHECK(for GLOB_DAT reloc,
1446                libc_cv_has_glob_dat, [dnl
1447 cat > conftest.c <<EOF
1448 extern int mumble;
1449 int foo (void) { return mumble; }
1450 EOF
1451 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1452                         -fPIC -shared -o conftest.so conftest.c
1453                         -nostdlib -nostartfiles $no_ssp
1454                         1>&AS_MESSAGE_LOG_FD])
1455 then
1456 dnl look for GLOB_DAT relocation.
1457   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1458     libc_cv_has_glob_dat=yes
1459   else
1460     libc_cv_has_glob_dat=no
1461   fi
1462 else
1463   libc_cv_has_glob_dat=no
1464 fi
1465 rm -f conftest*])
1466 AC_SUBST(libc_cv_has_glob_dat)
1467
1468 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1469 if libc_cv_output_format=`
1470 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1471 then
1472   :
1473 else
1474   libc_cv_output_format=
1475 fi
1476 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1477 AC_SUBST(libc_cv_output_format)
1478
1479 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1480 cat > conftest.c <<EOF
1481 int foo;
1482 EOF
1483 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1484                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1485 then
1486   libc_cv_fno_toplevel_reorder=yes
1487 else
1488   libc_cv_fno_toplevel_reorder=no
1489 fi
1490 rm -f conftest*])
1491 if test $libc_cv_fno_toplevel_reorder = yes; then
1492   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1493 else
1494   fno_unit_at_a_time=-fno-unit-at-a-time
1495 fi
1496 AC_SUBST(fno_unit_at_a_time)
1497
1498 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1499 [dnl
1500 cat > conftest.c <<EOF
1501 __thread int i;
1502 void foo (void)
1503 {
1504   i = 10;
1505 }
1506 EOF
1507 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1508                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1509 then
1510   libc_cv_mtls_dialect_gnu2=yes
1511 else
1512   libc_cv_mtls_dialect_gnu2=no
1513 fi
1514 rm -f conftest*])
1515 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1516 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1517
1518 AC_CACHE_CHECK(whether cc puts quotes around section names,
1519                libc_cv_have_section_quotes,
1520                [cat > conftest.c <<EOF
1521                 static const int foo
1522                 __attribute__ ((section ("bar"))) = 1;
1523 EOF
1524                 if ${CC-cc} -S conftest.c -o conftest.s; then
1525                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1526                     libc_cv_have_section_quotes=yes
1527                   else
1528                     libc_cv_have_section_quotes=no
1529                   fi
1530                 else
1531                   libc_cv_have_section_quotes=unknown
1532                 fi
1533                 rm -f conftest.{c,s}
1534                 ])
1535 if test $libc_cv_have_section_quotes = yes; then
1536   AC_DEFINE(HAVE_SECTION_QUOTES)
1537 fi
1538
1539 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1540 cat > conftest.c <<\EOF
1541 void zero (void *x)
1542 {
1543   __builtin_memset (x, 0, 1000);
1544 }
1545 EOF
1546 dnl
1547 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1548 then
1549   libc_cv_gcc_builtin_memset=no
1550 else
1551   libc_cv_gcc_builtin_memset=yes
1552 fi
1553 rm -f conftest* ])
1554 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1555   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1556 fi
1557
1558 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1559 cat > conftest.c <<\EOF
1560 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1561 char *foo (const char *a, const char *b)
1562 {
1563   return __builtin_strstr (a, b);
1564 }
1565 EOF
1566 dnl
1567 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1568 then
1569   libc_cv_gcc_builtin_redirection=yes
1570 else
1571   libc_cv_gcc_builtin_redirection=no
1572 fi
1573 rm -f conftest* ])
1574 if test "$libc_cv_gcc_builtin_redirection" = no; then
1575   AC_MSG_ERROR([support for the symbol redirection needed])
1576 fi
1577
1578 dnl Determine how to disable generation of FMA instructions.
1579 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1580                libc_cv_cc_nofma, [dnl
1581 libc_cv_cc_nofma=
1582 for opt in -ffp-contract=off -mno-fused-madd; do
1583   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1584 done])
1585 AC_SUBST(libc_cv_cc_nofma)
1586
1587 if test -n "$submachine"; then
1588   AC_CACHE_CHECK([for compiler option for CPU variant],
1589                  libc_cv_cc_submachine, [dnl
1590   libc_cv_cc_submachine=no
1591   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1592     LIBC_TRY_CC_OPTION([$opt], [
1593       libc_cv_cc_submachine="$opt"
1594       break], [])
1595   done])
1596   if test "x$libc_cv_cc_submachine" = xno; then
1597     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1598   fi
1599 fi
1600 AC_SUBST(libc_cv_cc_submachine)
1601
1602 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1603 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1604 cat > conftest.c <<EOF
1605 void
1606 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1607 foo (void) {}
1608 EOF
1609 libc_cv_cc_loop_to_function=no
1610 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1611 then
1612   libc_cv_cc_loop_to_function=yes
1613 fi
1614 rm -f conftest*])
1615 if test $libc_cv_cc_loop_to_function = yes; then
1616   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1617 fi
1618 AC_SUBST(libc_cv_cc_loop_to_function)
1619
1620 dnl Check whether we have the gd library available.
1621 AC_MSG_CHECKING(for libgd)
1622 if test "$with_gd" != "no"; then
1623   old_CFLAGS="$CFLAGS"
1624   CFLAGS="$CFLAGS $libgd_include"
1625   old_LDFLAGS="$LDFLAGS"
1626   LDFLAGS="$LDFLAGS $libgd_ldflags"
1627   old_LIBS="$LIBS"
1628   LIBS="$LIBS -lgd -lpng -lz -lm"
1629   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1630   CFLAGS="$old_CFLAGS"
1631   LDFLAGS="$old_LDFLAGS"
1632   LIBS="$old_LIBS"
1633 else
1634   LIBGD=no
1635 fi
1636 AC_MSG_RESULT($LIBGD)
1637 AC_SUBST(LIBGD)
1638
1639 # SELinux detection
1640 if test x$with_selinux = xno ; then
1641   have_selinux=no;
1642 else
1643   # See if we have the SELinux library
1644   AC_CHECK_LIB(selinux, is_selinux_enabled,
1645                have_selinux=yes, have_selinux=no)
1646   if test x$with_selinux = xyes ; then
1647     if test x$have_selinux = xno ; then
1648       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1649     fi
1650   fi
1651 fi
1652 # Check if we're building with SELinux support.
1653 if test "x$have_selinux" = xyes; then
1654   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1655
1656   # See if we have the libaudit library
1657   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1658                have_libaudit=yes, have_libaudit=no)
1659   if test "x$have_libaudit" = xyes; then
1660     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1661   fi
1662   AC_SUBST(have_libaudit)
1663
1664   # See if we have the libcap library
1665   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1666   if test "x$have_libcap" = xyes; then
1667     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1668   fi
1669   AC_SUBST(have_libcap)
1670 fi
1671 AC_SUBST(have_selinux)
1672
1673 CPPUNDEFS=
1674 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1675 dnl Since we are building the implementations of the fortified functions here,
1676 dnl having the macro defined interacts very badly.
1677 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1678 [AC_TRY_COMPILE([], [
1679 #ifdef _FORTIFY_SOURCE
1680 # error bogon
1681 #endif],
1682                 [libc_cv_predef_fortify_source=no],
1683                 [libc_cv_predef_fortify_source=yes])])
1684 if test $libc_cv_predef_fortify_source = yes; then
1685   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1686 fi
1687 AC_SUBST(CPPUNDEFS)
1688
1689 # Some linkers on some architectures support __ehdr_start but with
1690 # bugs.  Make sure usage of it does not create relocations in the
1691 # output (as the linker should resolve them all for us).
1692 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1693                libc_cv_ehdr_start, [
1694 old_CFLAGS="$CFLAGS"
1695 old_LDFLAGS="$LDFLAGS"
1696 old_LIBS="$LIBS"
1697 CFLAGS="$CFLAGS -fPIC"
1698 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1699 LIBS=
1700 AC_LINK_IFELSE([AC_LANG_SOURCE([
1701 typedef struct {
1702   char foo;
1703   long val;
1704 } Ehdr;
1705 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1706 long ehdr (void) { return __ehdr_start.val; }
1707 ])],
1708                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1709                   libc_cv_ehdr_start=broken
1710                 else
1711                   libc_cv_ehdr_start=yes
1712                 fi], [libc_cv_ehdr_start=no])
1713 CFLAGS="$old_CFLAGS"
1714 LDFLAGS="$old_LDFLAGS"
1715 LIBS="$old_LIBS"
1716 ])
1717 if test "$libc_cv_ehdr_start" = yes; then
1718   AC_DEFINE([HAVE_EHDR_START])
1719 elif test "$libc_cv_ehdr_start" = broken; then
1720   AC_MSG_WARN([linker is broken -- you should upgrade])
1721 fi
1722
1723 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1724                libc_cv_builtin_trap, [dnl
1725 libc_cv_builtin_trap=no
1726 AC_TRY_COMPILE([], [__builtin_trap ()], [
1727 libc_undefs=`$NM -u conftest.o |
1728   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1729     2>&AS_MESSAGE_LOG_FD` || {
1730   AC_MSG_ERROR([confusing output from $NM -u])
1731 }
1732 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1733 if test -z "$libc_undefs"; then
1734   libc_cv_builtin_trap=yes
1735 fi])])
1736 if test $libc_cv_builtin_trap = yes; then
1737   AC_DEFINE([HAVE_BUILTIN_TRAP])
1738 fi
1739
1740 dnl C++ feature tests.
1741 AC_LANG_PUSH([C++])
1742
1743 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1744                libc_cv_cxx_thread_local, [
1745 old_CXXFLAGS="$CXXFLAGS"
1746 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1747 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1748 #include <thread>
1749
1750 // Compiler support.
1751 struct S
1752 {
1753   S ();
1754   ~S ();
1755 };
1756 thread_local S s;
1757 S * get () { return &s; }
1758
1759 // libstdc++ support.
1760 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1761 #error __cxa_thread_atexit_impl not supported
1762 #endif
1763 ])],
1764                [libc_cv_cxx_thread_local=yes],
1765                [libc_cv_cxx_thread_local=no])
1766 CXXFLAGS="$old_CXXFLAGS"
1767 ])
1768 AC_SUBST(libc_cv_cxx_thread_local)
1769
1770 AC_LANG_POP([C++])
1771 dnl End of C++ feature tests.
1772
1773 ### End of automated tests.
1774 ### Now run sysdeps configure fragments.
1775
1776 # They also can set these variables.
1777 use_ldconfig=no
1778 ldd_rewrite_script=no
1779 libc_cv_sysconfdir=$sysconfdir
1780 libc_cv_localstatedir=$localstatedir
1781 libc_cv_gcc_unwind_find_fde=no
1782 libc_cv_idn=no
1783
1784 # Iterate over all the sysdep directories we will use, running their
1785 # configure fragments.
1786 for dir in $sysnames; do
1787   case $dir in
1788     /*) dest=$dir ;;
1789     *)  dest=$srcdir/$dir ;;
1790   esac
1791   if test -r $dest/configure; then
1792     AC_MSG_RESULT(running configure fragment for $dir)
1793     . $dest/configure
1794   fi
1795 done
1796
1797 if test x"$build_mathvec" = xnotset; then
1798   build_mathvec=no
1799 fi
1800 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1801
1802 AC_SUBST(libc_extra_cflags)
1803 AC_SUBST(libc_extra_cppflags)
1804
1805 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1806   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1807 fi
1808 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1809
1810 # A sysdeps configure fragment can reset this if IFUNC is not actually
1811 # usable even though the assembler knows how to generate the symbol type.
1812 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1813   AC_DEFINE(HAVE_IFUNC)
1814 fi
1815 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1816
1817 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1818   AC_DEFINE(HAVE_GCC_IFUNC)
1819 fi
1820
1821 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1822 # configure fragment can override the value to prevent this AC_DEFINE.
1823 AC_SUBST(use_nscd)
1824 if test "x$use_nscd" != xno; then
1825   AC_DEFINE([USE_NSCD])
1826 fi
1827 if test "x$build_nscd" = xdefault; then
1828   build_nscd=$use_nscd
1829 fi
1830
1831 AC_SUBST(libc_cv_slibdir)
1832 AC_SUBST(libc_cv_rtlddir)
1833 AC_SUBST(libc_cv_complocaledir)
1834 AC_SUBST(libc_cv_sysconfdir)
1835 AC_SUBST(libc_cv_localstatedir)
1836 AC_SUBST(libc_cv_rootsbindir)
1837
1838 if test x$use_ldconfig = xyes; then
1839   AC_DEFINE(USE_LDCONFIG)
1840 fi
1841 AC_SUBST(use_ldconfig)
1842 AC_SUBST(ldd_rewrite_script)
1843
1844 AC_SUBST(static)
1845 AC_SUBST(shared)
1846
1847 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1848 [libc_cv_pic_default=yes
1849 cat > conftest.c <<EOF
1850 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1851 # error PIC is default.
1852 #endif
1853 EOF
1854 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1855   libc_cv_pic_default=no
1856 fi
1857 rm -f conftest.*])
1858 AC_SUBST(libc_cv_pic_default)
1859
1860 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1861 [libc_cv_cc_pie_default=yes
1862 cat > conftest.c <<EOF
1863 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1864 # error PIE is default.
1865 #endif
1866 EOF
1867 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1868   libc_cv_cc_pie_default=no
1869 fi
1870 rm -f conftest.*])
1871 libc_cv_pie_default=$libc_cv_cc_pie_default
1872 AC_SUBST(libc_cv_cc_pie_default)
1873 AC_SUBST(libc_cv_pie_default)
1874
1875 # Set the `multidir' variable by grabbing the variable from the compiler.
1876 # We do it once and save the result in a generated makefile.
1877 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1878 AC_SUBST(libc_cv_multidir)
1879
1880 if test "$static_pie" = yes; then
1881   # The linker must support --no-dynamic-linker.
1882   if test "$libc_cv_no_dynamic_linker" != yes; then
1883     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1884   fi
1885   # Default to PIE.
1886   libc_cv_pie_default=yes
1887   AC_DEFINE(ENABLE_STATIC_PIE)
1888 fi
1889 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1890
1891 AC_SUBST(profile)
1892 AC_SUBST(static_nss)
1893
1894 AC_SUBST(DEFINES)
1895
1896 dnl See sysdeps/mach/configure.ac for this variable.
1897 AC_SUBST(mach_interface_list)
1898
1899 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1900 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1901 AC_SUBST(VERSION)
1902 AC_SUBST(RELEASE)
1903
1904 AC_CONFIG_FILES([config.make Makefile])
1905 AC_CONFIG_COMMANDS([default],[[
1906 case $CONFIG_FILES in *config.make*)
1907 echo "$config_vars" >> config.make;;
1908 esac
1909 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1910 AC_OUTPUT