configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.2)dnl               dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21
  22 dnl Arguments to specify presence of other packages/features.
  23 AC_ARG_WITH(fp, dnl
  24   --with-fp               if using floating-point hardware,
  25             with_fp=$withval, with_fp=yes)
  26 AC_ARG_WITH(gnu-binutils, dnl
  27   --with-gnu-binutils     if using GNU binutils (as and ld),
  28             gnu_binutils=$withval, gnu_binutils=no)
  29 AC_ARG_WITH(gnu-ld, dnl
  30   --with-gnu-ld           if using GNU ld (in the binutils package),
  31             gnu_ld=$withval, gnu_ld=no)
  32 AC_ARG_WITH(gnu-as, dnl
  33   --with-gnu-as           if using GNU as (in the binutils package),
  34             gnu_as=$withval, gnu_as=no)
  35 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  36 AC_ARG_WITH(elf, dnl
  37   --with-elf              if using the ELF object format,
  38             elf=$withval, elf=no)
  39 AC_ARG_WITH(weak-symbols, dnl
  40   --with-weak-symbols     if weak symbols are available in as and ld,
  41             weak=$withval, weak=no)
  42
  43 dnl Arguments to enable or disable building the shared, profiled, and
  44 dnl -fomit-frame-pointer libraries.
  45 AC_ARG_ENABLE(shared, dnl
  46 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  47             shared=$enableval, shared=default)
  48 AC_ARG_ENABLE(profile, dnl
  49 [  --enable-profile        build profiled library [default=yes]],
  50             profile=$enableval, profile=yes)
  51 AC_ARG_ENABLE(omitfp, dnl
  52 [  --enable-omitfp       build undebuggable optimized library [default=no]],
  53             omitfp=$enableval, omitfp=no)
  54
  55 AC_CANONICAL_HOST
  56 # We keep the original values in `$config_*' and never modify them, so we
  57 # can write them unchanged into config.make.  Everything else uses
  58 # $machine, $vendor, and $os, and changes them whenever convenient.
  59 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  60
  61 # Some configurations imply other options.
  62 case "$host_os" in
  63 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  64   # These systems always use GNU tools.
  65   gnu_ld=yes gnu_as=yes
  66 esac
  67 case "$host_os" in
  68 gnu* | linux* | sysv4* | solaris2*)
  69   # These systems always use the ELF format.
  70   elf=yes
  71 esac
  72
  73 # Compute the list of sysdep directories for this configuration.
  74 sysdep_dir=$srcdir/sysdeps
  75 AC_MSG_CHECKING(sysdep dirs)
  76 AC_CACHE_VAL(libc_cv_sysdirs, [dnl
  77 machine=$config_machine
  78 vendor=$config_vendor
  79 os=$config_os
  80
  81 dnl We need to use [ and ] for other purposes for a while now.
  82 changequote(,)dnl
  83 # Expand the configuration machine name into a subdirectory by architecture
  84 # type and particular chip.
  85 case "$machine" in
  86 i[345]86)
  87   machine=i386/$machine ;;
  88 sparc[6789])
  89   machine=sparc/$machine ;;
  90 m68k)
  91   machine=m68k/m68020 ;;
  92 m680?0)
  93   machine=m68k/$machine ;;
  94 m88k)
  95   machine=m88k/m88100 ;;
  96 m88???)
  97   machine=m88k/$machine ;;
  98 mips64*)
  99   machine=mips/mips64/$machine ;;
 100 mips*)
 101   machine=mips/$machine ;;
 102 esac
 103
 104 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 105 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 106
 107 case "$os" in
 108 gnu*)
 109   base_os=mach/hurd ;;
 110 netbsd* | 386bsd* | freebsd* | bsdi*)
 111   base_os=unix/bsd/bsd4.4 ;;
 112 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 113   base_os=unix/bsd ;;
 114 sysv* | isc* | esix* | sco* | minix* | irix4*)
 115   base_os=unix/sysv ;;
 116 linux* | solaris[2-9]*)
 117   base_os=unix/sysv/sysv4 ;;
 118 none)
 119   base_os=standalone ;;
 120 *)
 121   base_os='' ;;
 122 esac
 123
 124 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 125 tail=$os
 126 ostry=$os
 127 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 128   ostry="$ostry /$o"
 129   tail=$o
 130 done
 131 o=`echo $tail | sed 's/[0-9]*$//'`
 132 if test $o != $tail; then
 133   ostry="$ostry /$o"
 134 fi
 135
 136 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 137 base=
 138 tail=$base_os
 139 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 140   set $b
 141   base="$base /$1"
 142   tail="$2"
 143 done
 144
 145 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 146 mach=
 147 tail=$machine
 148 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 149   set $m
 150   # Prepend the machine's FPU directory unless --without-fp.
 151   if test "$with_fp" = yes; then
 152     mach="$mach /$1/fpu"
 153   fi
 154   mach="$mach /$1"
 155   tail="$2"
 156 done
 157
 158 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 159 changequote([,])dnl
 160
 161 # Find what sysdep directories exist.
 162 sysnames=
 163 for b in $base ''; do
 164   for m0 in $mach ''; do
 165     for v in /$vendor ''; do
 166       for o in /$ostry ''; do
 167         for m in $mach ''; do
 168           try="$m0$b$v$o$m"
 169           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 170           if test -d $sysdep_dir$try; then
 171             sysnames="$sysnames $try"
 172             { test -n "$o" || test -n "$b"; } && os_used=t
 173             { test -n "$m" || test -n "$m0"; } && machine_used=t
 174           fi
 175         done
 176       done
 177     done
 178   done
 179 done
 180
 181 if test -z "$os_used" && test "$os" != none; then
 182   AC_MSG_ERROR(Operating system $os is not supported.)
 183 fi
 184 if test -z "$machine_used" && test "$machine" != none; then
 185   AC_MSG_ERROR(The $machine is not supported.)
 186 fi
 187
 188 # We have now validated the configuration.
 189
 190
 191 # If using ELF, look for an `elf' subdirectory of each machine directory.
 192 # We prepend these rather than inserting them whereever the machine appears
 193 # because things specified by the machine's ELF ABI should override
 194 # OS-specific things, and should always be the same for any OS on the
 195 # machine (otherwise what's the point of an ABI?).
 196 if test "$elf" = yes; then
 197   elf_dirs=
 198   for m in $mach; do
 199     if test -d $sysdep_dir$m/elf; then
 200       elf_dirs="$elf_dirs $m/elf"
 201     fi
 202   done
 203   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 204 fi
 205
 206
 207 # Remove the leading slashes.
 208 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 209
 210
 211 # Expand the list of system names into a full list of directories
 212 # from each element's parent name and Implies file (if present).
 213 set $sysnames
 214 while test $# -gt 0; do
 215   name=$1
 216   shift
 217
 218   if test -f $sysdep_dir/$name/Implies; then
 219     # Collect more names from the `Implies' file (removing comments).
 220     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 221     for x in $implied; do
 222       test -d $sysdep_dir/$x || echo "Warning: $name implies nonexistent $x">&2
 223     done
 224   else
 225     implied=
 226   fi
 227
 228   # Add NAME to the list of names.
 229   names="$names $name"
 230
 231   # Find the parent of NAME, using the empty string if it has none.
 232 changequote(,)dnl
 233   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 234 changequote([,])dnl
 235
 236   # Add the names implied by NAME, and NAME's parent (if it has one), to
 237   # the list of names to be processed (the argument list).  We prepend the
 238   # implied names to the list and append the parent.  We want implied
 239   # directories to come before further directories inferred from the
 240   # configuration components; this ensures that for sysv4, unix/common
 241   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 242   # after sysv4).
 243   sysnames="`echo $implied $* $parent`"
 244   test -n "$sysnames" && set $sysnames
 245 done
 246
 247 # Add the default directories.
 248 names="$names generic stub"
 249
 250 # Now uniquize the list.
 251 seen=
 252 sysnames=
 253 for name in $names; do
 254   if echo "$seen" | fgrep -x $name >/dev/null; then
 255     # Already in the list.
 256     true;
 257   else
 258     # A new one.
 259     if test -z "$seen"; then
 260       seen="$name" sysnames="$name"
 261     else
 262       seen="$seen
 263 $name"
 264       sysnames="$sysnames $name"
 265     fi
 266   fi
 267 done
 268 libc_cv_sysdirs="$sysnames"])
 269 AC_SUBST(sysnames) sysnames="$libc_cv_sysdirs"
 270 AC_MSG_RESULT(${sysnames})
 271
 272 AC_PROG_INSTALL
 273 if test "$INSTALL" = "${srcdir}/install-sh"; then
 274   # The makefiles need to use a different form to find it in $srcdir.
 275   INSTALL='$(..)./install-sh'
 276 fi
 277
 278 AC_CHECK_TOOL(CC, gcc)
 279 AC_CHECK_TOOL(AR, ar)
 280 AC_CHECK_TOOL(RANLIB, ranlib, :)
 281 AC_PROG_CPP
 282
 283 AC_MSG_CHECKING(signed size_t type)
 284 AC_CACHE_VAL(libc_cv_signed_size_t, [dnl
 285 echo '#include <stddef.h>
 286 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 287 if eval "$ac_cpp conftest.c 2>/dev/null" \
 288 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 289   libc_cv_signed_size_t=no
 290 else
 291   libc_cv_signed_size_t=yes
 292 fi
 293 rm -f conftest*])
 294 AC_MSG_RESULT($libc_cv_signed_size_t)
 295 if test $libc_cv_signed_size_t = yes; then
 296   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 297   cat >> confdefs.h <<\EOF
 298 #undef __SIZE_TYPE__
 299 #define __SIZE_TYPE__ unsigned
 300 EOF
 301 fi
 302
 303 AC_MSG_CHECKING(libc-friendly stddef.h)
 304 AC_CACHE_VAL(libc_cv_friendly_stddef, [dnl
 305 AC_TRY_COMPILE(dnl
 306 [#define __need_size_t
 307 #define __need_wchar_t
 308 #include <stddef.h>
 309 #define __need_NULL
 310 #include <stddef.h>], [size_t size; wchar_t wchar;
 311 #ifdef offsetof
 312 #error stddef.h ignored __need_*
 313 #endif
 314 if (&size == NULL || &wchar == NULL) abort ();],
 315                libc_cv_friendly_stddef=yes,
 316                libc_cv_friendly_stddef=no)])
 317 AC_MSG_RESULT($libc_cv_friendly_stddef)
 318 if test $libc_cv_friendly_stddef = yes; then
 319   config_vars="$config_vars
 320 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 321 fi
 322
 323 AC_MSG_CHECKING(whether we need to use -P to assemble .S files)
 324 AC_CACHE_VAL(libc_cv_need_minus_P, [dnl
 325 cat > conftest.S <<EOF
 326 #include "confdefs.h"
 327 /* Nothing whatsoever.  */
 328 EOF
 329 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 330   libc_cv_need_minus_P=no
 331 else
 332   libc_cv_need_minus_P=yes
 333 fi
 334 rm -f conftest*])
 335 AC_MSG_RESULT($libc_cv_need_minus_P)
 336 if test $libc_cv_need_minus_P = yes; then
 337   config_vars="$config_vars
 338 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 339 fi
 340
 341 AC_MSG_CHECKING(for assembler global-symbol directive)
 342 AC_CACHE_VAL(libc_cv_asm_global_directive, [dnl
 343 libc_cv_asm_global_directive=UNKNOWN
 344 for ac_globl in .globl .global; do
 345   cat > conftest.s <<EOF
 346 .text
 347 ${ac_globl} foo
 348 foo: .long 0
 349 EOF
 350   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 351     libc_cv_asm_global_directive=${ac_globl}
 352   fi
 353   rm -f conftest*
 354   test $libc_cv_asm_global_directive != UNKNOWN && break
 355 done])
 356 AC_MSG_RESULT($libc_cv_asm_global_directive)
 357 if test $libc_cv_asm_global_directive = UNKNOWN; then
 358   AC_MSG_ERROR(cannot determine asm global directive)
 359 else
 360   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 361 fi
 362
 363 AC_MSG_CHECKING(for .set assembler directive)
 364 AC_CACHE_VAL(libc_cv_asm_set_directive, [dnl
 365 cat > conftest.s <<EOF
 366 .text
 367 foo: .long 0
 368 .set glibc_conftest_frobozz,foo
 369 $libc_cv_asm_global_directive glibc_conftest_frobozz
 370 EOF
 371 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 372 # (but it doesn't work), so we must do a linking check to be sure.
 373 cat > conftest1.c <<\EOF
 374 extern int glibc_conftest_frobozz;
 375 main () { printf ("%d\n", glibc_conftest_frobozz); }
 376 EOF
 377 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 378             conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 379   libc_cv_asm_set_directive=yes
 380 else
 381   libc_cv_asm_set_directive=no
 382 fi
 383 rm -f conftest*])
 384 AC_MSG_RESULT($libc_cv_asm_set_directive)
 385 if test $libc_cv_asm_set_directive = yes; then
 386   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 387 fi
 388
 389
 390 # sysdeps configure fragments may set these with files to be linked below.
 391 libc_link_dests=
 392 libc_link_sources=
 393
 394 # Iterate over all the sysdep directories we will use, running their
 395 # configure fragments, and looking for a uname implementation.
 396 uname=
 397 for dir in $sysnames; do
 398   if test -r $sysdep_dir/$dir/configure; then
 399     AC_MSG_RESULT(running configure fragment for $dir)
 400     . $sysdep_dir/$dir/configure
 401   fi
 402   if test -z "$uname"; then
 403     { test -r $sysdep_dir/$dir/uname.c || test -r $sysdep_dir/$dir/uname.S; } \
 404     && uname=$dir
 405   fi
 406 done
 407
 408 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 409
 410 # If we will use the generic uname implementation, we must figure out what
 411 # it will say by examining the system, and write the results in config-name.h.
 412 if test "$uname" = generic; then
 413
 414 changequote(,)dnl
 415   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 416 changequote([,])dnl
 417   if test $uname_sysname != $config_os; then
 418     config_release=`echo $config_os | sed s/$uname_sysname//`
 419   fi
 420 dnl
 421 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 422     if test -r /vmunix; then
 423       kernel_id=`strings /vmunix | grep UNIX`
 424     elif test -r /dynix; then
 425       kernel_id=`strings /dynix | grep DYNIX`
 426     else
 427       kernel_id=
 428     fi
 429 ])dnl
 430
 431   AC_MSG_CHECKING(OS release for uname)
 432   AC_CACHE_VAL(libc_cv_uname_release, [dnl
 433 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 434 changequote(,)dnl
 435   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 436 changequote([,])dnl
 437   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 438          != x$config_release; then
 439     # The configuration release is a substring of the kernel release.
 440     libc_cv_uname_release=$kernel_release
 441   elif test x$config_release != x; then
 442     libc_cv_uname_release=$config_release
 443   elif test x$kernel_release != x; then
 444     libc_cv_uname_release=$kernel_release
 445   else
 446     libc_cv_uname_release=unknown
 447   fi])
 448   AC_MSG_RESULT($libc_cv_uname_release)
 449   uname_release="$libc_cv_uname_release"
 450
 451   AC_MSG_CHECKING(OS version for uname)
 452   AC_CACHE_VAL(libc_cv_uname_version, [dnl
 453 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 454 changequote(,)dnl
 455   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 456 changequote([,])dnl
 457   if test -n "$kernel_version"; then
 458     libc_cv_uname_version="$kernel_version"
 459   else
 460     libc_cv_uname_version=unknown
 461   fi])
 462   AC_MSG_RESULT($libc_cv_uname_version)
 463   uname_version="$libc_cv_uname_version"
 464
 465 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 466   config_uname=config-name.h:config-name.in
 467 else
 468   # For non-generic uname, we don't need to create config-name.h at all.
 469   config_uname=
 470 fi
 471
 472 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf) AC_SUBST(weak)
 473 if test $gnu_ld = yes; then
 474   AC_DEFINE(HAVE_GNU_LD)
 475 fi
 476 if test $gnu_as = yes; then
 477   AC_DEFINE(HAVE_GNU_AS)
 478 fi
 479 if test $elf = yes; then
 480   AC_DEFINE(HAVE_ELF)
 481 fi
 482 if test $weak = yes; then
 483   AC_DEFINE(HAVE_WEAK_SYMBOLS)
 484 fi
 485
 486 AC_SUBST(shared)
 487 if test $shared = default; then
 488   if test $gnu_ld = yes; then
 489     shared=$elf
 490   fi
 491 fi
 492 AC_SUBST(profile)
 493 AC_SUBST(omitfp)
 494
 495
 496 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 497   config_makefile=
 498 else
 499   config_makefile=Makefile
 500 fi
 501
 502 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 503           [echo '$config_vars' >> config.make])