sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995, 1996, 1997, 2000, 2001 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #define _SETJMP_H
  23 #include <bits/setjmp.h>
  24 #include <asm-syntax.h>
  25 #include "bp-sym.h"
  26 #include "bp-asm.h"
  27
  28 #define PARMS   LINKAGE         /* no space for saved regs */
  29 #define JMPBUF  PARMS
  30 #define SIGMSK  JMPBUF+PTR_SIZE
  31
  32 ENTRY (BP_SYM (__sigsetjmp))
  33         ENTER
  34
  35         movl JMPBUF(%esp), %eax
  36         CHECK_BOUNDS_BOTH_WIDE (%eax, JMPBUF(%esp), $JB_SIZE)
  37
  38         /* Save registers.  */
  39         movl %ebx, (JB_BX*4)(%eax)
  40         movl %esi, (JB_SI*4)(%eax)
  41         movl %edi, (JB_DI*4)(%eax)
  42         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  43         movl %ecx, (JB_SP*4)(%eax)
  44         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
  45         movl %ecx, (JB_PC*4)(%eax)
  46         LEAVE /* pop frame pointer to prepare for tail-call.  */
  47         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  48
  49         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  50         jmp BP_SYM (__sigjmp_save)
  51 END (BP_SYM (__sigsetjmp))