sysdeps/hppa/start.S

   1 /* ELF startup code for HPPA.
   2    Copyright (C) 2002-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library.  If not, see
  34    <http://www.gnu.org/licenses/>.  */
  35
  36         .import main, code
  37         .import $global$, data
  38         .import __libc_start_main, code
  39         .import __libc_csu_fini, code
  40         .import __libc_csu_init, code
  41
  42         /* Have the linker create plabel words so we get PLABEL32
  43            relocs and not 21/14.  The use of 21/14 relocs is only
  44            supported in the latest dynamic linker.  */
  45 #ifdef PIC
  46         .section        .data.rel.ro,"aw",@progbits
  47 #else
  48         .section        .rodata,"a",@progbits
  49 #endif
  50         .align 4
  51 .Lpmain:
  52         .word P%main
  53 .Lp__libc_start_main:
  54         .word P%__libc_start_main
  55 .Lp__libc_csu_fini:
  56         .word P%__libc_csu_fini
  57 .Lp__libc_csu_init:
  58         .word P%__libc_csu_init
  59
  60         .text
  61         .align 4
  62         .globl _start
  63         .export _start, ENTRY
  64         .type _start,@function
  65 _start:
  66         /* At entry to the function we have:
  67
  68                 r26 - Unused
  69                 r25 - argc
  70                 r24 - argv
  71                 r23 - False _dl_fini plabel address
  72
  73            This function is called from the lower half of RTLD_START.
  74
  75            The call to __libc_start_main expects:
  76
  77                 1. r26 - Application main
  78                 2. r25 - argc
  79                 3. r24 - argv
  80                 4. r23 - __libc_csu_init
  81                 5. sp-52 - __libc_csu_fini
  82                 6. sp-56 - rtld_fini
  83                 7. sp-60 - stackend  */
  84
  85         .proc
  86         .callinfo
  87         /* Clear previous-sp.  */
  88         stw     %r0, -4(%sp)
  89         /* Setup the stack and frame.  */
  90         stw     %rp, -20(%sp)
  91         ldo     64(%sp), %sp
  92         stw     %sp, -4(%sp)
  93         stw     %r19, -32(%sp)
  94
  95         /* argc and argv should be in 25 and 24 (2nd and 3rd argument) */
  96         /* void (*rtld_fini) (void) (6th argument) */
  97         stw     %r23, -56(%sp)
  98
  99         /* Need to setup 1, 4, 5, and 7th arguments */
 100
 101 #ifdef PIC
 102         /* Load $global$ address into %dp */
 103         bl      .+8, %dp
 104         addil   L'$global$-$PIC_pcrel$0+1, %dp
 105         ldo     R'$global$-$PIC_pcrel$0+5(%r1), %dp
 106
 107         /* load main (1st argument) */
 108         addil   LT'.Lpmain, %r19
 109         ldw     RT'.Lpmain(%r1), %r26
 110         ldw     0(%r26),%r26
 111         /* void (*init) (void) (4th argument) */
 112         addil   LT'.Lp__libc_csu_init, %r19
 113         ldw     RT'.Lp__libc_csu_init(%r1), %r23
 114         ldw     0(%r23), %r23
 115         /* void (*fini) (void) (5th argument) */
 116         addil   LT'.Lp__libc_csu_fini, %r19
 117         ldw     RT'.Lp__libc_csu_fini(%r1), %r22
 118         ldw     0(%r22), %r22
 119 #else
 120         /* Load $global$ address into %dp */
 121         ldil    L%$global$, %dp
 122         ldo     R%$global$(%dp), %dp
 123
 124         /* load main (1st argument) */
 125         ldil    LR'.Lpmain, %r26
 126         ldw     RR'.Lpmain(%r26), %r26
 127         /* void (*init) (void) (4th argument) */
 128         ldil    LR'.Lp__libc_csu_init, %r23
 129         ldw     RR'.Lp__libc_csu_init(%r23), %r23
 130         /* void (*fini) (void) (5th argument) */
 131         ldil    LR'.Lp__libc_csu_fini, %r22
 132         ldw     RR'.Lp__libc_csu_fini(%r22), %r22
 133 #endif
 134         /* Store 5th argument */
 135         stw     %r22, -52(%sp)
 136         /* void *stack_end (7th argument) */
 137         stw     %sp, -60(%sp)
 138         bl      __libc_start_main,%r2
 139         nop
 140         /* die horribly if it returned (it shouldn't) */
 141         iitlbp %r0,(%sr0,%r0)
 142         nop
 143
 144         .procend
 145
 146 /* Define a symbol for the first piece of initialized data.  */
 147         .data
 148         .globl __data_start
 149 __data_start:
 150         .long 0
 151         .weak data_start
 152         data_start = __data_start