sysdeps/i386/start.S

   1 /* Startup code compliant to the ELF i386 ABI.
   2    Copyright (C) 1995-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    In addition to the permissions in the GNU Lesser General Public
  11    License, the Free Software Foundation gives you unlimited
  12    permission to link the compiled version of this file with other
  13    programs, and to distribute those programs without any restriction
  14    coming from the use of this file. (The GNU Lesser General Public
  15    License restrictions do apply in other respects; for example, they
  16    cover modification of the file, and distribution when not linked
  17    into another program.)
  18
  19    Note that people who make modified versions of this file are not
  20    obligated to grant this special exception for their modified
  21    versions; it is their choice whether to do so. The GNU Lesser
  22    General Public License gives permission to release a modified
  23    version without this exception; this exception also makes it
  24    possible to release a modified version which carries forward this
  25    exception.
  26
  27    The GNU C Library is distributed in the hope that it will be useful,
  28    but WITHOUT ANY WARRANTY; without even the implied warranty of
  29    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  30    Lesser General Public License for more details.
  31
  32    You should have received a copy of the GNU Lesser General Public
  33    License along with the GNU C Library; if not, see
  34    <http://www.gnu.org/licenses/>.  */
  35
  36 /* This is the canonical entry point, usually the first thing in the text
  37    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  38    point runs, most registers' values are unspecified, except for:
  39
  40    %edx         Contains a function pointer to be registered with `atexit'.
  41                 This is how the dynamic linker arranges to have DT_FINI
  42                 functions called for shared libraries that have been loaded
  43                 before this code runs.
  44
  45    %esp         The stack contains the arguments and environment:
  46                 0(%esp)                 argc
  47                 4(%esp)                 argv[0]
  48                 ...
  49                 (4*argc)(%esp)          NULL
  50                 (4*(argc+1))(%esp)      envp[0]
  51                 ...
  52                                         NULL
  53 */
  54
  55         .text
  56         .globl _start
  57         .type _start,@function
  58 _start:
  59         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  60            the outermost frame obviously.  */
  61         xorl %ebp, %ebp
  62
  63         /* Extract the arguments as encoded on the stack and set up
  64            the arguments for `main': argc, argv.  envp will be determined
  65            later in __libc_start_main.  */
  66         popl %esi               /* Pop the argument count.  */
  67         movl %esp, %ecx         /* argv starts just at the current stack top.*/
  68
  69         /* Before pushing the arguments align the stack to a 16-byte
  70         (SSE needs 16-byte alignment) boundary to avoid penalties from
  71         misaligned accesses.  Thanks to Edward Seidl <seidl@janed.com>
  72         for pointing this out.  */
  73         andl $0xfffffff0, %esp
  74         pushl %eax              /* Push garbage because we allocate
  75                                    28 more bytes.  */
  76
  77         /* Provide the highest stack address to the user code (for stacks
  78            which grow downwards).  */
  79         pushl %esp
  80
  81         pushl %edx              /* Push address of the shared library
  82                                    termination function.  */
  83
  84 #ifdef PIC
  85         /* Load PIC register.  */
  86         call 1f
  87         addl $_GLOBAL_OFFSET_TABLE_, %ebx
  88
  89         /* Push address of our own entry points to .fini and .init.  */
  90         leal __libc_csu_fini@GOTOFF(%ebx), %eax
  91         pushl %eax
  92         leal __libc_csu_init@GOTOFF(%ebx), %eax
  93         pushl %eax
  94
  95         pushl %ecx              /* Push second argument: argv.  */
  96         pushl %esi              /* Push first argument: argc.  */
  97
  98 # ifdef SHARED
  99         pushl main@GOT(%ebx)
 100 # else
 101         /* Avoid relocation in static PIE since _start is called before
 102            it is relocated.  Don't use "leal main@GOTOFF(%ebx), %eax"
 103            since main may be in a shared object.  Linker will convert
 104            "movl main@GOT(%ebx), %eax" to "leal main@GOTOFF(%ebx), %eax"
 105            if main is defined locally.  */
 106         movl main@GOT(%ebx), %eax
 107         pushl %eax
 108 # endif
 109
 110         /* Call the user's main function, and exit with its value.
 111            But let the libc call main.    */
 112         call __libc_start_main@PLT
 113 #else
 114         /* Push address of our own entry points to .fini and .init.  */
 115         pushl $__libc_csu_fini
 116         pushl $__libc_csu_init
 117
 118         pushl %ecx              /* Push second argument: argv.  */
 119         pushl %esi              /* Push first argument: argc.  */
 120
 121         pushl $main
 122
 123         /* Call the user's main function, and exit with its value.
 124            But let the libc call main.    */
 125         call __libc_start_main
 126 #endif
 127
 128         hlt                     /* Crash if somehow `exit' does return.  */
 129
 130 #ifdef PIC
 131 1:      movl    (%esp), %ebx
 132         ret
 133 #endif
 134
 135 /* To fulfill the System V/i386 ABI we need this symbol.  Yuck, it's so
 136    meaningless since we don't support machines < 80386.  */
 137         .section .rodata
 138         .globl _fp_hw
 139 _fp_hw: .long 3
 140         .size _fp_hw, 4
 141         .type _fp_hw,@object
 142
 143 /* Define a symbol for the first piece of initialized data.  */
 144         .data
 145         .globl __data_start
 146 __data_start:
 147         .long 0
 148         .weak data_start
 149         data_start = __data_start