ports/sysdeps/arm/__longjmp.S

   1 /* longjmp for ARM.
   2    Copyright (C) 1997-2013 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* ??? Needs more rearrangement for the LDM to handle thumb mode.  */
  20 #define NO_THUMB
  21 #include <sysdep.h>
  22 #define _SETJMP_H
  23 #define _ASM
  24 #include <bits/setjmp.h>
  25 #include <rtld-global-offsets.h>
  26 #include <arm-features.h>
  27
  28 /* __longjmp(jmpbuf, val) */
  29
  30 ENTRY (__longjmp)
  31         mov     ip, r0
  32         movs    r0, r1          /* get the return value in place */
  33         moveq   r0, #1          /* can't let setjmp() return zero! */
  34
  35 #ifdef CHECK_SP
  36         ldr     r4, [ip, #32]   /* jmpbuf's sp */
  37         cfi_undefined (r4)
  38         CHECK_SP (r4)
  39 #endif
  40         ldmia   ip!, {v1-v6, sl, fp, sp, lr}
  41         cfi_restore (v1)
  42         cfi_restore (v2)
  43         cfi_restore (v3)
  44         cfi_restore (v4)
  45         cfi_restore (v5)
  46         cfi_restore (v6)
  47         cfi_restore (sl)
  48         cfi_restore (fp)
  49         cfi_restore (sp)
  50         cfi_restore (lr)
  51
  52 #if !defined ARM_ASSUME_NO_IWMMXT || defined __SOFTFP__
  53 # define NEED_HWCAP 1
  54 #endif
  55
  56 #ifdef NEED_HWCAP
  57 # ifdef IS_IN_rtld
  58         ldr     a2, 1f
  59         ldr     a3, .Lrtld_local_ro
  60 0:      add     a2, pc, a2
  61         add     a2, a2, a3
  62         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  63 # else
  64 #  ifdef PIC
  65         ldr     a2, 1f
  66         ldr     a3, .Lrtld_global_ro
  67 0:      add     a2, pc, a2
  68         ldr     a2, [a2, a3]
  69         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  70 #  else
  71         ldr     a2, .Lhwcap
  72         ldr     a2, [a2, #0]
  73 #  endif
  74 # endif
  75 #endif
  76
  77 #ifdef __SOFTFP__
  78         tst     a2, #HWCAP_ARM_VFP
  79         beq     .Lno_vfp
  80 #endif
  81
  82         /* Restore the VFP registers.  */
  83         /* Following instruction is vldmia ip!, {d8-d15}.  */
  84         ldc     p11, cr8, [r12], #64
  85         /* Restore the floating-point status register.  */
  86         ldr     a3, [ip], #4
  87         /* Following instruction is fmxr fpscr, a3.  */
  88         mcr     p10, 7, a3, cr1, cr0, 0
  89 .Lno_vfp:
  90
  91 #ifndef ARM_ASSUME_NO_IWMMXT
  92         tst     a2, #HWCAP_ARM_IWMMXT
  93         beq     .Lno_iwmmxt
  94
  95         /* Restore the call-preserved iWMMXt registers.  */
  96         /* Following instructions are wldrd wr10, [ip], #8 (etc.)  */
  97         ldcl    p1, cr10, [r12], #8
  98         ldcl    p1, cr11, [r12], #8
  99         ldcl    p1, cr12, [r12], #8
 100         ldcl    p1, cr13, [r12], #8
 101         ldcl    p1, cr14, [r12], #8
 102         ldcl    p1, cr15, [r12], #8
 103 .Lno_iwmmxt:
 104 #endif
 105
 106         DO_RET(lr)
 107
 108 #ifdef NEED_HWCAP
 109 # ifdef IS_IN_rtld
 110 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - PC_OFS
 111 .Lrtld_local_ro:
 112         .long   C_SYMBOL_NAME(_rtld_local_ro)(GOTOFF)
 113 # else
 114 #  ifdef PIC
 115 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - PC_OFS
 116 .Lrtld_global_ro:
 117         .long   C_SYMBOL_NAME(_rtld_global_ro)(GOT)
 118 #  else
 119 .Lhwcap:
 120         .long   C_SYMBOL_NAME(_dl_hwcap)
 121 #  endif
 122 # endif
 123 #endif
 124
 125 END (__longjmp)