sysdeps/unix/sysv/linux/powerpc/powerpc32/socket.S

   1 /* Copyright (C) 1995, 1996, 1997, 1999 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, write to the Free
  16    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  17    02111-1307 USA.  */
  18
  19 #include <sysdep.h>
  20 #include <socketcall.h>
  21
  22 #define P(a, b) P2(a, b)
  23 #define P2(a, b) a##b
  24
  25 /* The socket-oriented system calls are handled unusally in Linux.
  26    They are all gated through the single `socketcall' system call number.
  27    `socketcall' takes two arguments: the first is the subcode, specifying
  28    which socket function is being called; and the second is a pointer to
  29    the arguments to the specific function.
  30
  31    The .S files for the other calls just #define socket and #include this.
  32    They also #define a 'number-of-arguments' word in NARGS, which
  33    defaults to 3.  */
  34
  35 #ifndef NARGS
  36 #ifdef socket
  37 #error NARGS not defined
  38 #endif
  39 #define NARGS 3
  40 #endif
  41
  42 #define stackblock 20
  43
  44 #ifndef __socket
  45 #define __socket P(__,socket)
  46 #endif
  47
  48         .text
  49 ENTRY(__socket)
  50         stwu r1,-48(r1)
  51 #if NARGS >= 1
  52         stw  r3,stackblock(r1)
  53 #endif
  54 #if NARGS >= 2
  55         stw  r4,4+stackblock(r1)
  56 #endif
  57 #if NARGS >= 3
  58         stw  r5,8+stackblock(r1)
  59 #endif
  60 #if NARGS >= 4
  61         stw  r6,12+stackblock(r1)
  62 #endif
  63 #if NARGS >= 5
  64         stw  r7,16+stackblock(r1)
  65 #endif
  66 #if NARGS >= 6
  67         stw  r8,20+stackblock(r1)
  68 #endif
  69 #if NARGS >= 7
  70         stw  r9,24+stackblock(r1)
  71 #endif
  72 #if NARGS >= 8
  73         stw  r10,28+stackblock(r1)
  74 #endif
  75 #if NARGS >= 9
  76 #error too many arguments!
  77 #endif
  78         li      r3,P(SOCKOP_,socket)
  79         addi    r4,r1,stackblock
  80         DO_CALL(SYS_ify(socketcall))
  81         addi    r1,r1,48
  82         PSEUDO_RET
  83 PSEUDO_END (__socket)
  84
  85 weak_alias (__socket, socket)