sysdeps/arm/__longjmp.S

   1 /* longjmp for ARM.
   2    Copyright (C) 1997-2015 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #include <stap-probe.h>
  21 #include <bits/setjmp.h>
  22 #include <rtld-global-offsets.h>
  23 #include <arm-features.h>
  24
  25 /* __longjmp(jmpbuf, val) */
  26
  27 ENTRY (__longjmp)
  28         mov     ip, r0
  29
  30 #ifdef CHECK_SP
  31         sfi_breg ip, \
  32         ldr     r4, [\B]        /* jmpbuf's sp */
  33         cfi_undefined (r4)
  34 #ifdef PTR_DEMANGLE
  35         PTR_DEMANGLE (r4, r4, a3, a4)
  36 #endif
  37         CHECK_SP (r4)
  38 #endif
  39
  40 #ifdef PTR_DEMANGLE
  41         sfi_breg ip, \
  42         ldr     a4, [\B], #4
  43         PTR_DEMANGLE (a4, a4, a3, r4)
  44         cfi_undefined (r4)
  45         sfi_breg ip, \
  46         ldr     r4, [\B], #4
  47         PTR_DEMANGLE2 (r4, r4, a3)
  48 #else
  49         sfi_breg ip, \
  50         ldr     a4, [\B], #4
  51         sfi_breg ip, \
  52         ldr     r4, [\B], #4
  53         cfi_undefined (r4)
  54 #endif
  55         /* longjmp probe expects longjmp first argument (4@r0), second
  56            argument (-4@r1), and target address (4@r4), respectively.  */
  57         LIBC_PROBE (longjmp, 3, 4@r0, -4@r1, 4@r4)
  58         sfi_sp \
  59         mov     sp, a4
  60         mov     lr, r4
  61         sfi_breg ip, \
  62         ldmia   \B!, JMP_BUF_REGLIST
  63         cfi_restore (v1)
  64         cfi_restore (v2)
  65         cfi_restore (v3)
  66         cfi_restore (v4)
  67         cfi_restore (v5)
  68         cfi_restore (v6)
  69         cfi_restore (sl)
  70         cfi_restore (fp)
  71         cfi_restore (sp)
  72         cfi_restore (lr)
  73
  74 #if !defined ARM_ASSUME_NO_IWMMXT || defined __SOFTFP__
  75 # define NEED_HWCAP 1
  76 #endif
  77
  78 #ifdef NEED_HWCAP
  79 # if IS_IN (rtld)
  80         LDST_PCREL (ldr, a4, a3, \
  81                     C_SYMBOL_NAME(_rtld_local_ro) \
  82                     + RTLD_GLOBAL_RO_DL_HWCAP_OFFSET)
  83 # else
  84 #  ifdef PIC
  85         LDR_GLOBAL (a4, a3, C_SYMBOL_NAME(_rtld_global_ro), \
  86                     RTLD_GLOBAL_RO_DL_HWCAP_OFFSET)
  87 #  else
  88         LDR_GLOBAL (a4, a3, C_SYMBOL_NAME(_dl_hwcap), 0)
  89 #  endif
  90 # endif
  91 #endif
  92
  93 #ifdef __SOFTFP__
  94         tst     a4, #HWCAP_ARM_VFP
  95         beq     .Lno_vfp
  96 #endif
  97
  98         /* Restore the VFP registers.  */
  99         /* Following instruction is vldmia ip!, {d8-d15}.  */
 100         sfi_breg r12, \
 101         ldc     p11, cr8, [\B], #64
 102 .Lno_vfp:
 103
 104 #ifndef ARM_ASSUME_NO_IWMMXT
 105         tst     a4, #HWCAP_ARM_IWMMXT
 106         beq     .Lno_iwmmxt
 107
 108         /* Restore the call-preserved iWMMXt registers.  */
 109         /* Following instructions are wldrd wr10, [ip], #8 (etc.)  */
 110         sfi_breg r12, \
 111         ldcl    p1, cr10, [\B], #8
 112         sfi_breg r12, \
 113         ldcl    p1, cr11, [\B], #8
 114         sfi_breg r12, \
 115         ldcl    p1, cr12, [\B], #8
 116         sfi_breg r12, \
 117         ldcl    p1, cr13, [\B], #8
 118         sfi_breg r12, \
 119         ldcl    p1, cr14, [\B], #8
 120         sfi_breg r12, \
 121         ldcl    p1, cr15, [\B], #8
 122 .Lno_iwmmxt:
 123 #endif
 124
 125         /* longjmp_target probe expects longjmp first argument (4@r0), second
 126            argument (-4@r1), and target address (4@r14), respectively.  */
 127         LIBC_PROBE (longjmp_target, 3, 4@r0, -4@r1, 4@r14)
 128
 129         movs    r0, r1          /* get the return value in place */
 130         it      eq
 131         moveq   r0, #1          /* can't let setjmp() return zero! */
 132
 133         DO_RET(lr)
 134
 135 END (__longjmp)