sysdeps/sparc/sparc32/rshift.S

   1 ! sparc __mpn_rshift --
   2 !
   3 ! Copyright (C) 1995, 1996, 1997 Free Software Foundation, Inc.
   4 !
   5 ! This file is part of the GNU MP Library.
   6 !
   7 ! The GNU MP Library is free software; you can redistribute it and/or modify
   8 ! it under the terms of the GNU Lesser General Public License as published by
   9 ! the Free Software Foundation; either version 2.1 of the License, or (at your
  10 ! option) any later version.
  11 !
  12 ! The GNU MP Library is distributed in the hope that it will be useful, but
  13 ! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15 ! License for more details.
  16 !
  17 ! You should have received a copy of the GNU Lesser General Public License
  18 ! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 ! MA 02111-1307, USA.
  21
  22
  23 ! INPUT PARAMETERS
  24 ! RES_PTR       %o0
  25 ! SRC_PTR       %o1
  26 ! SIZE          %o2
  27 ! CNT           %o3
  28
  29 #include <sysdep.h>
  30
  31 ENTRY(__mpn_rshift)
  32         ld      [%o1],%g2       ! load first limb
  33         sub     %g0,%o3,%o5     ! negate shift count
  34         add     %o2,-1,%o2
  35         andcc   %o2,4-1,%g4     ! number of limbs in first loop
  36         sll     %g2,%o5,%g1     ! compute function result
  37         be      LOC(0)          ! if multiple of 4 limbs, skip first loop
  38         st      %g1,[%sp+80]
  39
  40         sub     %o2,%g4,%o2     ! adjust count for main loop
  41
  42 LOC(loop0):
  43         ld      [%o1+4],%g3
  44         add     %o0,4,%o0
  45         add     %o1,4,%o1
  46         addcc   %g4,-1,%g4
  47         srl     %g2,%o3,%o4
  48         sll     %g3,%o5,%g1
  49         mov     %g3,%g2
  50         or      %o4,%g1,%o4
  51         bne     LOC(loop0)
  52          st     %o4,[%o0-4]
  53
  54 LOC(0): tst     %o2
  55         be      LOC(end)
  56          nop
  57
  58 LOC(loop):
  59         ld      [%o1+4],%g3
  60         add     %o0,16,%o0
  61         addcc   %o2,-4,%o2
  62         srl     %g2,%o3,%o4
  63         sll     %g3,%o5,%g1
  64
  65         ld      [%o1+8],%g2
  66         srl     %g3,%o3,%g4
  67         or      %o4,%g1,%o4
  68         st      %o4,[%o0-16]
  69         sll     %g2,%o5,%g1
  70
  71         ld      [%o1+12],%g3
  72         srl     %g2,%o3,%o4
  73         or      %g4,%g1,%g4
  74         st      %g4,[%o0-12]
  75         sll     %g3,%o5,%g1
  76
  77         ld      [%o1+16],%g2
  78         srl     %g3,%o3,%g4
  79         or      %o4,%g1,%o4
  80         st      %o4,[%o0-8]
  81         sll     %g2,%o5,%g1
  82
  83         add     %o1,16,%o1
  84         or      %g4,%g1,%g4
  85         bne     LOC(loop)
  86          st     %g4,[%o0-4]
  87
  88 LOC(end):
  89         srl     %g2,%o3,%g2
  90         st      %g2,[%o0-0]
  91         retl
  92         ld      [%sp+80],%o0
  93
  94 END(__mpn_rshift)