scripts/versions.awk

   1 # Combine version map fragments into version scripts for our shared objects.
   2 # Copyright (C) 1998-2016 Free Software Foundation, Inc.
   3 # Written by Ulrich Drepper <drepper@cygnus.com>, 1998.
   4
   5 # This script expects the following variables to be defined:
   6 # defsfile              name of Versions.def file
   7 # buildroot             name of build directory with trailing slash
   8 # move_if_change        move-if-change command
   9
  10 # Read definitions for the versions.
  11 BEGIN {
  12   lossage = 0;
  13
  14   nlibs=0;
  15   while (getline < defsfile) {
  16     if (/^[a-zA-Z0-9_.]+ \{/) {
  17       libs[$1] = 1;
  18       curlib = $1;
  19       while (getline < defsfile && ! /^}/) {
  20         if ($2 == "=") {
  21           renamed[curlib "::" $1] = $3;
  22         }
  23         else
  24           versions[curlib "::" $1] = 1;
  25       }
  26     }
  27   }
  28   close(defsfile);
  29
  30   tmpfile = buildroot "Versions.tmp";
  31   # POSIX sort needed.
  32   sort = "sort -t. -k 1,1 -k 2n,2n -k 3 > " tmpfile;
  33 }
  34
  35 # Remove comment lines.
  36 /^ *#/ {
  37   next;
  38 }
  39
  40 # This matches the beginning of the version information for a new library.
  41 /^[a-zA-Z0-9_.]+/ {
  42   actlib = $1;
  43   if (!libs[$1]) {
  44     printf("no versions defined for %s\n", $1) > "/dev/stderr";
  45     ++lossage;
  46   }
  47   next;
  48 }
  49
  50 # This matches the beginning of a new version for the current library.
  51 /^  [A-Za-z_]/ {
  52   if (renamed[actlib "::" $1])
  53     actver = renamed[actlib "::" $1];
  54   else if (!versions[actlib "::" $1] && $1 != "GLIBC_PRIVATE") {
  55     printf("version %s not defined for %s\n", $1, actlib) > "/dev/stderr";
  56     ++lossage;
  57   }
  58   else
  59     actver = $1;
  60   next;
  61 }
  62
  63 # This matches lines with names to be added to the current version in the
  64 # current library.  This is the only place where we print something to
  65 # the intermediate file.
  66 /^   / {
  67   sortver=actver
  68   # Ensure GLIBC_ versions come always first
  69   sub(/^GLIBC_/," GLIBC_",sortver)
  70   printf("%s %s %s\n", actlib, sortver, $0) | sort;
  71 }
  72
  73
  74 function closeversion(name, oldname) {
  75   if (firstinfile) {
  76     printf("  local:\n    *;\n") > outfile;
  77     firstinfile = 0;
  78   }
  79   # This version inherits from the last one only if they
  80   # have the same nonnumeric prefix, i.e. GLIBC_x.y and GLIBC_x.z
  81   # or FOO_x and FOO_y but not GLIBC_x and FOO_y.
  82   pfx = oldname;
  83   sub(/[0-9.]+/,".+",pfx);
  84   if (oldname == "" || name !~ pfx) print "};" > outfile;
  85   else printf("} %s;\n", oldname) > outfile;
  86 }
  87
  88 function close_and_move(name, real_name) {
  89   close(name);
  90   system(move_if_change " " name " " real_name " >&2");
  91 }
  92
  93 # Now print the accumulated information.
  94 END {
  95   close(sort);
  96
  97   if (lossage) {
  98     system("rm -f " tmpfile);
  99     exit 1;
 100   }
 101
 102   oldlib = "";
 103   oldver = "";
 104   printf("version-maps =");
 105   while (getline < tmpfile) {
 106     if ($1 != oldlib) {
 107       if (oldlib != "") {
 108         closeversion(oldver, veryoldver);
 109         oldver = "";
 110         close_and_move(outfile, real_outfile);
 111       }
 112       oldlib = $1;
 113       real_outfile = buildroot oldlib ".map";
 114       outfile = real_outfile "T";
 115       firstinfile = 1;
 116       veryoldver = "";
 117       printf(" %s.map", oldlib);
 118     }
 119     if ($2 != oldver) {
 120       if (oldver != "") {
 121         closeversion(oldver, veryoldver);
 122         veryoldver = oldver;
 123       }
 124       printf("%s {\n  global:\n", $2) > outfile;
 125       oldver = $2;
 126     }
 127     printf("   ") > outfile;
 128     for (n = 3; n <= NF; ++n) {
 129       printf(" %s", $n) > outfile;
 130     }
 131     printf("\n") > outfile;
 132   }
 133   printf("\n");
 134   closeversion(oldver, veryoldver);
 135   close_and_move(outfile, real_outfile);
 136   #system("rm -f " tmpfile);
 137 }