configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.11)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37 [  --with-fp              if using floating-point hardware [default=yes]],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 AC_ARG_ENABLE(sanity-checks, dnl
  63 [  --disable-sanity-checks really do not use threads (should not be used
  64                           except in special situations) [default=yes]],
  65               enable_sanity=$enableval, enable_sanity=yes)
  66
  67 dnl Arguments to enable or disable building the shared, profiled, and
  68 dnl -fomit-frame-pointer libraries.
  69 AC_ARG_ENABLE(shared, dnl
  70 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  71               shared=$enableval, shared=default)
  72 AC_ARG_ENABLE(profile, dnl
  73 [  --enable-profile        build profiled library [default=yes]],
  74               profile=$enableval, profile=yes)
  75 AC_ARG_ENABLE(omitfp, dnl
  76 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  77               omitfp=$enableval, omitfp=no)
  78
  79 dnl Some gcc versions have problems with omit-frame-pointer.  Warn about this.
  80 if test $omitfp = yes; then
  81   echo "*** Not all versions of GCC compile code correctly when the"
  82   echo "*** -fomit-frame-pointer option is used.  You are on your own"
  83   echo "*** if you use it."
  84 fi
  85
  86 dnl Generic infrastructure for drop-in additions to libc.
  87 AC_ARG_ENABLE(add-ons, dnl
  88 [  --enable-add-ons[=DIR1,DIR2]... configure and build add-ons in DIR1,DIR2,...
  89                                   search for add-ons if no parameter given],
  90  [case "$enableval" in
  91     yes) if test "$srcdir" = "."; then
  92            add_ons=`echo */configure | sed -e 's!/configure!!g'`
  93          else
  94            add_ons=`echo $srcdir/*/configure | \
  95                     sed  -e 's!/configure!!g' -e "s!$srcdir/!!g"`
  96          fi;;
  97     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
  98    esac],
  99   [add_ons=])
 100 AC_CONFIG_SUBDIRS($add_ons)
 101 add_ons_pfx=
 102 if test x"$add_ons" != x; then
 103   for f in $add_ons; do
 104     # Test whether such a subdir really exists.
 105     if test -d $srcdir/$f; then
 106       add_ons_pfx="$add_ons_pfx $f/"
 107     else
 108       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 109     fi
 110   done
 111 fi
 112
 113 AC_CANONICAL_HOST
 114
 115 # The way shlib-versions is used to generate soversions.mk uses a
 116 # fairly simplistic model for name recognition that can't distinguish
 117 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 118 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 119 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 120 case "$host_os" in
 121 linux*)
 122   ;;
 123 gnu*)
 124   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 125   ;;
 126 esac
 127 ###
 128 ### I put this here to prevent those annoying emails from people who cannot
 129 ### read and try to compile glibc on unsupported platforms.  --drepper
 130 ###
 131 ### By using the undocumented --enable-hacker-mode option for configure
 132 ### one can skip this test to make the configuration not fail for unsupported
 133 ### platforms.
 134 ###
 135 if test -z "$enable_hacker_mode"; then
 136   case "$host_os" in
 137   linux* | gnu*)
 138     ;;
 139   *)
 140     echo "*** The GNU C library is currently not available for this platform."
 141     echo "*** So far nobody cared to port it and if there is no volunteer it"
 142     echo "*** might never happen.  So, if you have interest to see glibc on"
 143     echo "*** this platform visit"
 144     echo "***  http://www.gnu.org/software/libc/porting.html"
 145     echo "*** and join the group of porters"
 146     exit 1
 147     ;;
 148   esac
 149 fi
 150
 151
 152 # We keep the original values in `$config_*' and never modify them, so we
 153 # can write them unchanged into config.make.  Everything else uses
 154 # $machine, $vendor, and $os, and changes them whenever convenient.
 155 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 156
 157 # Some configurations imply other options.
 158 case "$host_os" in
 159 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 160   # These systems always use GNU tools.
 161   gnu_ld=yes gnu_as=yes ;;
 162 esac
 163 case "$host_os" in
 164 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 165 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 166   ;;
 167 gnu* | linux* | sysv4* | solaris2*)
 168   # These systems (almost) always use the ELF format.
 169   elf=yes
 170   ;;
 171 esac
 172
 173 machine=$config_machine
 174 vendor=$config_vendor
 175 os=$config_os
 176
 177 dnl We need to use [ and ] for other purposes for a while now.
 178 changequote(,)dnl
 179 # Expand the configuration machine name into a subdirectory by architecture
 180 # type and particular chip.
 181 case "$machine" in
 182 a29k | am29000) base_machine=a29k machine=a29k ;;
 183 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 184 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 185 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 186 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 187 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 188 m88???)         base_machine=m88k machine=m88k/$machine ;;
 189 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 190 mips*)          base_machine=mips machine=mips/$machine ;;
 191 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 192 sparc | sparcv[67])
 193                 base_machine=sparc machine=sparc/sparc32 ;;
 194 sparcv8 | supersparc | hypersparc)
 195                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 196 sparc64)        base_machine=sparc machine=sparc/sparc64 ;;
 197 esac
 198 changequote([,])dnl
 199 AC_SUBST(base_machine)
 200
 201 # Compute the list of sysdep directories for this configuration.
 202 # This can take a while to compute.
 203 sysdep_dir=$srcdir/sysdeps
 204 AC_MSG_CHECKING(sysdep dirs)
 205 dnl We need to use [ and ] for other purposes for a while now.
 206 changequote(,)dnl
 207 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 208 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 209
 210 case "$os" in
 211 gnu*)
 212   base_os=mach/hurd ;;
 213 netbsd* | 386bsd* | freebsd* | bsdi*)
 214   base_os=unix/bsd/bsd4.4 ;;
 215 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 216   base_os=unix/bsd ;;
 217 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 218   base_os=unix/sysv ;;
 219 solaris[2-9]*)
 220   base_os=unix/sysv/sysv4 ;;
 221 none)
 222   base_os=standalone ;;
 223 *)
 224   base_os='' ;;
 225 esac
 226
 227 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 228 tail=$os
 229 ostry=$os
 230 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 231   ostry="$ostry /$o"
 232   tail=$o
 233 done
 234 o=`echo $tail | sed 's/[0-9]*$//'`
 235 if test $o != $tail; then
 236   ostry="$ostry /$o"
 237 fi
 238 # For linux-gnu, try linux-gnu, then linux.
 239 o=`echo $tail | sed 's/-.*$//'`
 240 if test $o != $tail; then
 241   ostry="$ostry /$o"
 242 fi
 243
 244 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 245 base=
 246 tail=$base_os
 247 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 248   set $b
 249   base="$base /$1"
 250   tail="$2"
 251 done
 252
 253 # For sparc/sparcv9, try sparc/sparcv9 and then sparc.
 254 mach=
 255 tail=$machine
 256 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 257   set $m
 258   # Prepend the machine's FPU directory unless --without-fp.
 259   if test "$with_fp" = yes; then
 260     mach="$mach /$1/fpu"
 261   fi
 262   mach="$mach /$1"
 263   tail="$2"
 264 done
 265
 266 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 267 changequote([,])dnl
 268
 269 # Find what sysdep directories exist.
 270 sysnames=
 271 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 272 for d in $add_ons_pfx ''; do
 273   for b in $base ''; do
 274     for m0 in $mach ''; do
 275       for v in /$vendor ''; do
 276         for o in /$ostry ''; do
 277           for m in $mach ''; do
 278             if test "$m0$b$v$o$m"; then
 279               try="${d}sysdeps$m0$b$v$o$m"
 280               test -n "$enable_debug_configure" &&
 281               echo "$0 [DEBUG]: try $try" >&2
 282               case $try in
 283                 /*) dest=$try ;;
 284                 *)  dest=$srcdir/$try ;;
 285               esac
 286               if test -d $dest; then
 287                 sysnames="$sysnames $try"
 288                 { test -n "$o" || test -n "$b"; } && os_used=t
 289                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 290               fi
 291             fi
 292           done
 293         done
 294       done
 295     done
 296   done
 297 done
 298 IFS="$ac_save_ifs"
 299
 300 if test -z "$os_used" && test "$os" != none; then
 301   AC_MSG_ERROR(Operating system $os is not supported.)
 302 fi
 303 if test -z "$machine_used" && test "$machine" != none; then
 304   AC_MSG_ERROR(The $machine is not supported.)
 305 fi
 306
 307 # We have now validated the configuration.
 308
 309
 310 # If using ELF, look for an `elf' subdirectory of each machine directory.
 311 # We prepend these rather than inserting them whereever the machine appears
 312 # because things specified by the machine's ELF ABI should override
 313 # OS-specific things, and should always be the same for any OS on the
 314 # machine (otherwise what's the point of an ABI?).
 315 if test "$elf" = yes; then
 316   elf_dirs=
 317   for d in $add_ons_pfx ''; do
 318     case $d in
 319       /*) xsrcdir= ;;
 320       *)  xsrcdir=$srcdir/ ;;
 321     esac
 322     for m in $mach; do
 323       if test -d $xsrcdir${d}sysdeps$m/elf; then
 324         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 325       fi
 326     done
 327   done
 328   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 329 fi
 330
 331
 332 # Expand the list of system names into a full list of directories
 333 # from each element's parent name and Implies file (if present).
 334 set $sysnames
 335 names=
 336 while test $# -gt 0; do
 337   name=$1
 338   shift
 339
 340   case " $names " in *" $name "*)
 341     # Already in the list.
 342     continue
 343   esac
 344
 345   # Report each name as we discover it, so there is no long pause in output.
 346   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 347
 348   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 349
 350   case $name in
 351     /*) xsrcdir= ;;
 352     *)  xsrcdir=$srcdir/ ;;
 353   esac
 354   test -n "$enable_debug_configure" &&
 355   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 356
 357   if test -f $xsrcdir$name/Implies; then
 358     # Collect more names from the `Implies' file (removing comments).
 359     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 360     implied=
 361     for x in $implied_candidate; do
 362       if test -d $xsrcdir$name_base/$x; then
 363         implied="$implied $name_base/$x";
 364       else
 365         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 366       fi
 367     done
 368   else
 369     implied=
 370   fi
 371
 372   # Add NAME to the list of names.
 373   names="$names $name"
 374
 375   # Find the parent of NAME, using the empty string if it has none.
 376 changequote(,)dnl
 377   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 378 changequote([,])dnl
 379
 380   # Add the names implied by NAME, and NAME's parent (if it has one), to
 381   # the list of names to be processed (the argument list).  We prepend the
 382   # implied names to the list and append the parent.  We want implied
 383   # directories to come before further directories inferred from the
 384   # configuration components; this ensures that for sysv4, unix/common
 385   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 386   # after sysv4).
 387   sysnames="`echo $implied $* $parent`"
 388   test -n "$sysnames" && set $sysnames
 389 done
 390
 391 # Add the default directories.
 392 sysnames="$names sysdeps/generic sysdeps/stub"
 393 AC_SUBST(sysnames)
 394 # The other names were emitted during the scan.
 395 AC_MSG_RESULT(sysdeps/generic sysdeps/stub)
 396
 397
 398 ### Locate tools.
 399
 400 AC_PROG_INSTALL
 401 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 402   # The makefiles need to use a different form to find it in $srcdir.
 403   INSTALL='\$(..)./install-sh -c'
 404 fi
 405 AC_PROG_LN_S
 406 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 407
 408 AC_PROG_CC_LOCAL
 409 AC_CANONICAL_BUILD
 410 if test $host != $build; then
 411   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 412 fi
 413 AC_SUBST(cross_compiling)
 414 AC_PROG_CPP
 415 AC_CHECK_TOOL(AR, ar)
 416 AC_CHECK_TOOL(RANLIB, ranlib, :)
 417
 418 AC_PATH_PROG(BASH, bash, no)
 419 if test "$BASH" != no &&
 420    $BASH -c 'test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 421   libc_cv_have_bash2=yes
 422 else
 423   libc_cv_have_bash2=no
 424 fi
 425 AC_SUBST(libc_cv_have_bash2)
 426
 427 dnl We need a ksh compatible shell for tzselect.
 428 if test "$BASH" = no; then
 429   AC_PATH_PROG(KSH, ksh, no)
 430   if test "$KSH" = no; then
 431     libc_cv_have_ksh=no
 432   else
 433     libc_cv_have_ksh=yes
 434   fi
 435 else
 436   KSH="$BASH"
 437   AC_SUBST(KSH)
 438   libc_cv_have_ksh=yes
 439 fi
 440 AC_SUBST(libc_cv_have_ksh)
 441
 442 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 443 echo '#include <stddef.h>
 444 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 445 if eval "$ac_cpp conftest.c 2>/dev/null" \
 446 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 447   libc_cv_signed_size_t=no
 448 else
 449   libc_cv_signed_size_t=yes
 450 fi
 451 rm -f conftest*])
 452 if test $libc_cv_signed_size_t = yes; then
 453   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 454   cat >> confdefs.h <<\EOF
 455 #undef __SIZE_TYPE__
 456 #define __SIZE_TYPE__ unsigned
 457 EOF
 458 fi
 459
 460 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 461 AC_TRY_COMPILE(dnl
 462 [#define __need_size_t
 463 #define __need_wchar_t
 464 #include <stddef.h>
 465 #define __need_NULL
 466 #include <stddef.h>], [size_t size; wchar_t wchar;
 467 #ifdef offsetof
 468 #error stddef.h ignored __need_*
 469 #endif
 470 if (&size == NULL || &wchar == NULL) abort ();],
 471                libc_cv_friendly_stddef=yes,
 472                libc_cv_friendly_stddef=no)])
 473 if test $libc_cv_friendly_stddef = yes; then
 474   config_vars="$config_vars
 475 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 476 fi
 477
 478 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 479                libc_cv_need_minus_P, [dnl
 480 cat > conftest.S <<EOF
 481 #include "confdefs.h"
 482 /* Nothing whatsoever.  */
 483 EOF
 484 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 485   libc_cv_need_minus_P=no
 486 else
 487   libc_cv_need_minus_P=yes
 488 fi
 489 rm -f conftest*])
 490 if test $libc_cv_need_minus_P = yes; then
 491   config_vars="$config_vars
 492 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 493 fi
 494
 495 # gcc 2.7.x has a bug where if -pipe is set, the assembler will always
 496 # be told to read stdin.  This causes the compiler to hang when fed an
 497 # .s file.
 498 if test $ac_cv_prog_gcc = yes; then
 499  case `${CC-cc} -v 2>&1` in
 500   *2.7*)
 501   # We must check this even if -pipe is not given here, because the user
 502   # might do `make CFLAGS=-pipe'.
 503   AC_CACHE_CHECK(for gcc 2.7.x -pipe bug, libc_cv_gcc_pipe_bug, [dnl
 504    cp /dev/null conftest.s
 505    cat >conftest1.s <<EOF
 506 .nosuchdirective
 507 EOF
 508    if ${CC-cc} -pipe -c conftest.s <conftest1.s 2>/dev/null; then
 509     libc_cv_gcc_pipe_bug=no
 510    else
 511     libc_cv_gcc_pipe_bug=yes
 512    fi
 513    rm -f conftest*])
 514   if test $libc_cv_gcc_pipe_bug = yes; then
 515    makeCC="${CC-cc} -B\$(common-objpfx)"
 516    makeCFLAGS=$CFLAGS
 517    CFLAGS=`echo $CFLAGS |sed 's/-pipe//'`
 518   fi;;
 519  *) libc_cv_gcc_pipe_bug=no;;
 520  esac
 521 else
 522  libc_cv_gcc_pipe_bug=no
 523 fi
 524
 525
 526 AC_CACHE_CHECK(for assembler global-symbol directive,
 527                libc_cv_asm_global_directive, [dnl
 528 libc_cv_asm_global_directive=UNKNOWN
 529 for ac_globl in .globl .global; do
 530   cat > conftest.s <<EOF
 531 .text
 532 ${ac_globl} foo
 533 foo:
 534 EOF
 535   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 536     libc_cv_asm_global_directive=${ac_globl}
 537   fi
 538   rm -f conftest*
 539   test $libc_cv_asm_global_directive != UNKNOWN && break
 540 done])
 541 if test $libc_cv_asm_global_directive = UNKNOWN; then
 542   AC_MSG_ERROR(cannot determine asm global directive)
 543 else
 544   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 545 fi
 546
 547 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 548 cat > conftest.s <<EOF
 549 .text
 550 foo: .long 0
 551 .set glibc_conftest_frobozz,foo
 552 $libc_cv_asm_global_directive glibc_conftest_frobozz
 553 EOF
 554 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 555 # (but it doesn't work), so we must do a linking check to be sure.
 556 cat > conftest1.c <<\EOF
 557 extern int glibc_conftest_frobozz;
 558 main () { printf ("%d\n", glibc_conftest_frobozz); }
 559 EOF
 560 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 561             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 562   libc_cv_asm_set_directive=yes
 563 else
 564   libc_cv_asm_set_directive=no
 565 fi
 566 rm -f conftest*])
 567 if test $libc_cv_asm_set_directive = yes; then
 568   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 569 fi
 570
 571 if test $elf = yes; then
 572   AC_CACHE_CHECK(for .previous assembler directive,
 573                  libc_cv_asm_previous_directive, [dnl
 574   cat > conftest.s <<EOF
 575 .section foo_section
 576 .previous
 577 EOF
 578   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 579     libc_cv_asm_previous_directive=yes
 580   else
 581     libc_cv_asm_previous_directive=no
 582   fi
 583   rm -f conftest*])
 584   if test $libc_cv_asm_previous_directive = yes; then
 585     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 586   else
 587     AC_CACHE_CHECK(for .popsection assembler directive,
 588                    libc_cv_asm_popsection_directive, [dnl
 589     cat > conftest.s <<EOF
 590 .pushsection foo_section
 591 .popsection
 592 EOF
 593     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 594       libc_cv_asm_popsection_directive=yes
 595     else
 596       libc_cv_asm_popsection_directive=no
 597     fi
 598     rm -f conftest*])
 599     if test $libc_cv_asm_popsection_directive = yes; then
 600       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 601     fi
 602   fi
 603 fi
 604
 605 if test $elf != yes; then
 606   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 607                  [AC_TRY_COMPILE(, [asm (".section .init");
 608                                     asm (".section .fini");
 609                                     asm (".text");],
 610                                  libc_cv_have_initfini=yes,
 611                                  libc_cv_have_initfini=no)])
 612   AC_SUBST(libc_cv_have_initfini)dnl
 613   if test $libc_cv_have_initfini = yes; then
 614     AC_DEFINE(HAVE_INITFINI)
 615   fi
 616 fi
 617
 618 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 619 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 620 [cat > conftest.$ac_ext <<EOF
 621 dnl This sometimes fails to find confdefs.h, for some reason.
 622 dnl [#]line __oline__ "[$]0"
 623 [#]line __oline__ "configure"
 624 #include "confdefs.h"
 625 void underscore_test(void) {
 626 return; }
 627 EOF
 628 if AC_TRY_EVAL(ac_compile); then
 629   if grep _underscore_test conftest* >/dev/null; then
 630     ifelse([$1], , :, [rm -f conftest*
 631     $1])
 632   else
 633     ifelse([$2], , , [rm -f conftest*
 634     $2])
 635   fi
 636 else
 637   echo "configure: failed program was:" >&AC_FD_CC
 638   cat conftest.$ac_ext >&AC_FD_CC
 639   ifelse([$2], , , [rm -f conftest*
 640   $2])
 641 fi
 642 rm -f conftest*])
 643
 644 if test $elf = yes; then
 645   libc_cv_asm_underscores=no
 646 else
 647   if test $ac_cv_prog_cc_works = yes; then
 648     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 649                   [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 650                                libc_cv_asm_underscores=yes,
 651                                libc_cv_asm_underscores=no)])
 652   else
 653     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 654                   [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 655                                            libc_cv_asm_underscores=no)])
 656   fi
 657 fi
 658 if test $libc_cv_asm_underscores = no; then
 659   AC_DEFINE(NO_UNDERSCORES)
 660 fi
 661
 662 if test $elf = yes; then
 663   libc_cv_weak_symbols=yes
 664   libc_cv_asm_weak_directive=yes
 665   libc_cv_asm_weakext_directive=no
 666 else
 667   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 668                  [dnl
 669 cat > conftest.s <<EOF
 670 .text
 671 ${libc_cv_asm_global_directive} foo
 672 foo:
 673 .weak foo
 674 .weak bar; bar = foo
 675 EOF
 676   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 677     libc_cv_asm_weak_directive=yes
 678   else
 679     libc_cv_asm_weak_directive=no
 680   fi
 681   rm -f conftest*])
 682
 683 if test $libc_cv_asm_weak_directive = no; then
 684   AC_CACHE_CHECK(for assembler .weakext directive,
 685                  libc_cv_asm_weakext_directive,
 686                  [dnl
 687 cat > conftest.s <<EOF
 688 .text
 689 ${libc_cv_asm_global_directive} foo
 690 foo:
 691 .weakext foo
 692 .weakext foo, bar
 693 EOF
 694   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 695     libc_cv_asm_weakext_directive=yes
 696   else
 697     libc_cv_asm_weakext_directive=no
 698   fi
 699   rm -f conftest*])
 700
 701   fi # no .weak
 702 fi # not ELF
 703
 704 if test $libc_cv_asm_weak_directive = yes; then
 705   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 706 elif test $libc_cv_asm_weakext_directive = yes; then
 707   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 708 fi
 709
 710 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 711 cat > conftest.c <<\EOF
 712 _start () {}
 713 int __eh_pc;
 714 __throw () {}
 715 EOF
 716 dnl No \ in command here because it ends up inside ''.
 717 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 718                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 719                             -o conftest conftest.c 1>&AC_FD_CC]); then
 720   libc_cv_ld_no_whole_archive=yes
 721 else
 722   libc_cv_ld_no_whole_archive=no
 723 fi
 724 rm -f conftest*])
 725 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 726
 727 AC_CACHE_CHECK(for gcc -fno-exceptions, libc_cv_gcc_no_exceptions, [dnl
 728 cat > conftest.c <<\EOF
 729 _start () {}
 730 int __eh_pc;
 731 __throw () {}
 732 EOF
 733 dnl No \ in command here because it ends up inside ''.
 734 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 735                             -nostdlib -nostartfiles -fno-exceptions
 736                             -o conftest conftest.c 1>&AC_FD_CC]); then
 737   libc_cv_gcc_no_exceptions=yes
 738 else
 739   libc_cv_gcc_no_exceptions=no
 740 fi
 741 rm -f conftest*])
 742 AC_SUBST(libc_cv_gcc_no_exceptions)dnl
 743
 744 if test "$base_machine" = alpha ; then
 745 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 746 cat > conftest.c <<\EOF
 747 foo () { }
 748 EOF
 749 dnl
 750 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 751 then
 752   libc_cv_gcc_alpha_ng_prefix=yes
 753 else
 754   libc_cv_gcc_alpha_ng_prefix=no
 755 fi
 756 rm -f conftest* ])
 757 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 758   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 759 else
 760   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 761 fi
 762 fi
 763
 764 ### End of automated tests.
 765 ### Now run sysdeps configure fragments.
 766
 767 # sysdeps configure fragments may set these with files to be linked below.
 768 libc_link_dests=
 769 libc_link_sources=
 770
 771 # Iterate over all the sysdep directories we will use, running their
 772 # configure fragments, and looking for a uname implementation.
 773 uname=
 774 for dir in $sysnames; do
 775   case $dir in
 776     /*) dest=$dir ;;
 777     *)  dest=$srcdir/$dir ;;
 778   esac
 779   if test -r $dest/configure; then
 780     AC_MSG_RESULT(running configure fragment for $dest)
 781     . $dest/configure
 782   fi
 783 [
 784   if test -z "$uname"; then
 785     if test -r $sysdep_dir/$dir/uname.c ||
 786        test -r $sysdep_dir/$dir/uname.S ||
 787        { test -r $sysdep_dir/$dir/syscalls.list &&
 788          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 789       uname=$dir
 790     fi
 791   fi
 792 ]dnl
 793 done
 794
 795 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 796
 797 # If we will use the generic uname implementation, we must figure out what
 798 # it will say by examining the system, and write the results in config-name.h.
 799 if test "$uname" = generic; then
 800
 801 changequote(,)dnl
 802   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 803 changequote([,])dnl
 804   if test $uname_sysname != $config_os; then
 805     config_release=`echo $config_os | sed s/$uname_sysname//`
 806   fi
 807 dnl
 808 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 809     if test -r /vmunix; then
 810       kernel_id=`strings /vmunix | grep UNIX`
 811     elif test -r /dynix; then
 812       kernel_id=`strings /dynix | grep DYNIX`
 813     else
 814       kernel_id=
 815     fi
 816 ])dnl
 817
 818   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 819 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 820 changequote(,)dnl
 821   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 822 changequote([,])dnl
 823   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 824          != x$config_release; then
 825     # The configuration release is a substring of the kernel release.
 826     libc_cv_uname_release=$kernel_release
 827   elif test x$config_release != x; then
 828     libc_cv_uname_release=$config_release
 829   elif test x$kernel_release != x; then
 830     libc_cv_uname_release=$kernel_release
 831   else
 832     libc_cv_uname_release=unknown
 833   fi])
 834   uname_release="$libc_cv_uname_release"
 835
 836   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 837 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 838 changequote(,)dnl
 839   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 840 changequote([,])dnl
 841   if test -n "$kernel_version"; then
 842     libc_cv_uname_version="$kernel_version"
 843   else
 844     libc_cv_uname_version=unknown
 845   fi])
 846   uname_version="$libc_cv_uname_version"
 847
 848 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 849   config_uname=config-name.h:config-name.in
 850 else
 851   # For non-generic uname, we don't need to create config-name.h at all.
 852   config_uname=
 853 fi
 854
 855 AC_MSG_CHECKING(stdio selection)
 856 AC_SUBST(stdio)
 857 case $stdio in
 858 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 859 default) stdio=stdio ;;
 860 esac
 861 AC_MSG_RESULT($stdio)
 862
 863 AC_SUBST(libc_cv_slibdir)
 864 AC_SUBST(libc_cv_sysconfdir)
 865 AC_SUBST(libc_cv_rootsbindir)
 866
 867 AC_SUBST(has_ldconfig)
 868
 869 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 870 if test $gnu_ld = yes; then
 871   AC_DEFINE(HAVE_GNU_LD)
 872 fi
 873 if test $gnu_as = yes; then
 874   AC_DEFINE(HAVE_GNU_AS)
 875 fi
 876 if test $elf = yes; then
 877   AC_DEFINE(HAVE_ELF)
 878 fi
 879
 880 AC_SUBST(shared)
 881 if test $shared = default; then
 882   if test $gnu_ld = yes; then
 883     shared=$elf
 884   else
 885     # For now we do not assume shared libs are available.  In future more
 886     # tests might become available.
 887     shared=no
 888   fi
 889 fi
 890 AC_SUBST(profile)
 891 AC_SUBST(omitfp)
 892
 893 AC_SUBST(DEFINES)
 894
 895 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 896   config_makefile=
 897 else
 898   config_makefile=Makefile
 899 fi
 900
 901 VERSION=`sed -e 's/^#define VERSION "\([^"]*\)"/\1/p' -e d < $srcdir/version.h`
 902 AC_SUBST(VERSION)
 903
 904 if test $libc_cv_gcc_pipe_bug = yes; then
 905  realCC=$CC
 906  CC=$makeCC
 907  CFLAGS=$makeCFLAGS
 908 fi
 909 AC_OUTPUT_COMMANDS([
 910 if test "$realCC"; then
 911  sed -e 's/%{pipe:-}/%|/g' `$realCC -print-file-name=specs` >specsT
 912  mv specsT specs
 913 fi], [realCC=$realCC])
 914
 915 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, ,
 916           [echo '$config_vars' >> config.make])