sysdeps/i386/setjmp.S

   1 /* setjmp for i386.
   2    Copyright (C) 1995,1996,1997,2000,2001,2005 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #define _SETJMP_H
  23 #include <bits/setjmp.h>
  24 #include <asm-syntax.h>
  25 #include "bp-sym.h"
  26 #include "bp-asm.h"
  27
  28 #define PARMS   LINKAGE         /* no space for saved regs */
  29 #define JMPBUF  PARMS
  30 #define SIGMSK  JMPBUF+PTR_SIZE
  31
  32 ENTRY (BP_SYM (__sigsetjmp))
  33         ENTER
  34
  35         movl JMPBUF(%esp), %eax
  36         CHECK_BOUNDS_BOTH_WIDE (%eax, JMPBUF(%esp), $JB_SIZE)
  37
  38         /* Save registers.  */
  39         movl %ebx, (JB_BX*4)(%eax)
  40         movl %esi, (JB_SI*4)(%eax)
  41         movl %edi, (JB_DI*4)(%eax)
  42         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  43 #ifdef PTR_MANGLE
  44         PTR_MANGLE (%ecx)
  45 #endif
  46         movl %ecx, (JB_SP*4)(%eax)
  47         movl PCOFF(%esp), %ecx  /* Save PC we are returning to now.  */
  48 #ifdef PTR_MANGLE
  49         PTR_MANGLE (%ecx)
  50 #endif
  51         movl %ecx, (JB_PC*4)(%eax)
  52         LEAVE /* pop frame pointer to prepare for tail-call.  */
  53         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  54
  55 #if defined NOT_IN_libc && defined IS_IN_rtld
  56         /* In ld.so we never save the signal mask.  */
  57         xorl %eax, %eax
  58         ret
  59 #else
  60         /* Make a tail call to __sigjmp_save; it takes the same args.  */
  61         jmp __sigjmp_save
  62 #endif
  63 END (BP_SYM (__sigsetjmp))