sysdeps/i386/fpu/e_expl.S

   1 /*
   2  * Written by J.T. Conklin <jtc@netbsd.org>.
   3  * Public domain.
   4  *
   5  * Adapted for `long double' by Ulrich Drepper <drepper@cygnus.com>.
   6  */
   7
   8 /*
   9  * The 8087 method for the exponential function is to calculate
  10  *   exp(x) = 2^(x log2(e))
  11  * after separating integer and fractional parts
  12  *   x log2(e) = i + f, |f| <= .5
  13  * 2^i is immediate but f needs to be precise for long double accuracy.
  14  * Suppress range reduction error in computing f by the following.
  15  * Separate x into integer and fractional parts
  16  *   x = xi + xf, |xf| <= .5
  17  * Separate log2(e) into the sum of an exact number c0 and small part c1.
  18  *   c0 + c1 = log2(e) to extra precision
  19  * Then
  20  *   f = (c0 xi - i) + c0 xf + c1 x
  21  * where c0 xi is exact and so also is (c0 xi - i).
  22  * -- moshier@na-net.ornl.gov
  23  */
  24
  25 #include <libm-alias-ldouble.h>
  26 #include <machine/asm.h>
  27 #include <i386-math-asm.h>
  28 #include <libm-alias-finite.h>
  29
  30 #ifdef USE_AS_EXP10L
  31 # define IEEE754_EXPL __ieee754_exp10l
  32 # define FLDLOG fldl2t
  33 #elif defined USE_AS_EXPM1L
  34 # define IEEE754_EXPL __expm1l
  35 # define FLDLOG fldl2e
  36 #else
  37 # define IEEE754_EXPL __ieee754_expl
  38 # define FLDLOG fldl2e
  39 #endif
  40
  41         .section .rodata.cst16,"aM",@progbits,16
  42
  43         .p2align 4
  44 #ifdef USE_AS_EXP10L
  45         .type c0,@object
  46 c0:     .byte 0, 0, 0, 0, 0, 0, 0x9a, 0xd4, 0x00, 0x40
  47         .byte 0, 0, 0, 0, 0, 0
  48         ASM_SIZE_DIRECTIVE(c0)
  49         .type c1,@object
  50 c1:     .byte 0x58, 0x92, 0xfc, 0x15, 0x37, 0x9a, 0x97, 0xf0, 0xef, 0x3f
  51         .byte 0, 0, 0, 0, 0, 0
  52         ASM_SIZE_DIRECTIVE(c1)
  53 #else
  54         .type c0,@object
  55 c0:     .byte 0, 0, 0, 0, 0, 0, 0xaa, 0xb8, 0xff, 0x3f
  56         .byte 0, 0, 0, 0, 0, 0
  57         ASM_SIZE_DIRECTIVE(c0)
  58         .type c1,@object
  59 c1:     .byte 0x20, 0xfa, 0xee, 0xc2, 0x5f, 0x70, 0xa5, 0xec, 0xed, 0x3f
  60         .byte 0, 0, 0, 0, 0, 0
  61         ASM_SIZE_DIRECTIVE(c1)
  62 #endif
  63 #ifndef USE_AS_EXPM1L
  64         .type csat,@object
  65 csat:   .byte 0, 0, 0, 0, 0, 0, 0, 0x80, 0x0e, 0x40
  66         .byte 0, 0, 0, 0, 0, 0
  67         ASM_SIZE_DIRECTIVE(csat)
  68 DEFINE_LDBL_MIN
  69 #endif
  70
  71 #ifdef PIC
  72 # define MO(op) op##@GOTOFF(%ecx)
  73 #else
  74 # define MO(op) op
  75 #endif
  76
  77         .text
  78 ENTRY(IEEE754_EXPL)
  79 #ifdef USE_AS_EXPM1L
  80         movzwl  4+8(%esp), %eax
  81         xorb    $0x80, %ah      // invert sign bit (now 1 is "positive")
  82         cmpl    $0xc006, %eax   // is num positive and exp >= 6 (number is >= 128.0)?
  83         jae     HIDDEN_JUMPTARGET (__expl) // (if num is denormal, it is at least >= 64.0)
  84 #endif
  85         fldt    4(%esp)
  86 /* I added the following ugly construct because expl(+-Inf) resulted
  87    in NaN.  The ugliness results from the bright minds at Intel.
  88    For the i686 the code can be written better.
  89    -- drepper@cygnus.com.  */
  90         fxam                    /* Is NaN or +-Inf?  */
  91 #ifdef PIC
  92         LOAD_PIC_REG (cx)
  93 #endif
  94 #ifdef USE_AS_EXPM1L
  95         xorb    $0x80, %ah
  96         cmpl    $0xc006, %eax
  97         fstsw   %ax
  98         movb    $0x45, %dh
  99         jb      4f
 100
 101         /* Below -64.0 (may be -NaN or -Inf). */
 102         andb    %ah, %dh
 103         cmpb    $0x01, %dh
 104         je      6f              /* Is +-NaN, jump.  */
 105         jmp     1f              /* -large, possibly -Inf.  */
 106
 107 4:      /* In range -64.0 to 64.0 (may be +-0 but not NaN or +-Inf).  */
 108         /* Test for +-0 as argument.  */
 109         andb    %ah, %dh
 110         cmpb    $0x40, %dh
 111         je      2f
 112
 113         /* Test for arguments that are small but not subnormal.  */
 114         movzwl  4+8(%esp), %eax
 115         andl    $0x7fff, %eax
 116         cmpl    $0x3fbf, %eax
 117         jge     3f
 118         /* Argument's exponent below -64; avoid spurious underflow if
 119            normal.  */
 120         cmpl    $0x0001, %eax
 121         jge     2f
 122         /* Force underflow and return the argument, to avoid wrong signs
 123            of zero results from the code below in some rounding modes.  */
 124         fld     %st
 125         fmul    %st
 126         fstp    %st
 127         jmp     2f
 128 #else
 129         movzwl  4+8(%esp), %eax
 130         andl    $0x7fff, %eax
 131         cmpl    $0x400d, %eax
 132         jg      5f
 133         cmpl    $0x3fbc, %eax
 134         jge     3f
 135         /* Argument's exponent below -67, result rounds to 1.  */
 136         fld1
 137         faddp
 138         jmp     2f
 139 5:      /* Overflow, underflow or infinity or NaN as argument.  */
 140         fstsw   %ax
 141         movb    $0x45, %dh
 142         andb    %ah, %dh
 143         cmpb    $0x05, %dh
 144         je      1f              /* Is +-Inf, jump.    */
 145         cmpb    $0x01, %dh
 146         je      6f              /* Is +-NaN, jump.    */
 147         /* Overflow or underflow; saturate.  */
 148         fstp    %st
 149         fldt    MO(csat)
 150         andb    $2, %ah
 151         jz      3f
 152         fchs
 153 #endif
 154 3:      FLDLOG                  /* 1  log2(base)      */
 155         fmul    %st(1), %st     /* 1  x log2(base)    */
 156         /* Set round-to-nearest temporarily.  */
 157         subl    $8, %esp
 158         cfi_adjust_cfa_offset (8)
 159         fstcw   4(%esp)
 160         movl    $0xf3ff, %edx
 161         andl    4(%esp), %edx
 162         movl    %edx, (%esp)
 163         fldcw   (%esp)
 164         frndint                 /* 1  i               */
 165         fld     %st(1)          /* 2  x               */
 166         frndint                 /* 2  xi              */
 167         fldcw   4(%esp)
 168         addl    $8, %esp
 169         cfi_adjust_cfa_offset (-8)
 170         fld     %st(1)          /* 3  i               */
 171         fldt    MO(c0)          /* 4  c0              */
 172         fld     %st(2)          /* 5  xi              */
 173         fmul    %st(1), %st     /* 5  c0 xi           */
 174         fsubp   %st, %st(2)     /* 4  f = c0 xi  - i  */
 175         fld     %st(4)          /* 5  x               */
 176         fsub    %st(3), %st     /* 5  xf = x - xi     */
 177         fmulp   %st, %st(1)     /* 4  c0 xf           */
 178         faddp   %st, %st(1)     /* 3  f = f + c0 xf   */
 179         fldt    MO(c1)          /* 4                  */
 180         fmul    %st(4), %st     /* 4  c1 * x          */
 181         faddp   %st, %st(1)     /* 3  f = f + c1 * x  */
 182         f2xm1                   /* 3 2^(fract(x * log2(base))) - 1 */
 183 #ifdef USE_AS_EXPM1L
 184         fstp    %st(1)          /* 2                  */
 185         fscale                  /* 2 scale factor is st(1); base^x - 2^i */
 186         fxch                    /* 2 i                */
 187         fld1                    /* 3 1.0              */
 188         fscale                  /* 3 2^i              */
 189         fld1                    /* 4 1.0              */
 190         fsubrp  %st, %st(1)     /* 3 2^i - 1.0        */
 191         fstp    %st(1)          /* 2                  */
 192         faddp   %st, %st(1)     /* 1 base^x - 1.0     */
 193 #else
 194         fld1                    /* 4 1.0              */
 195         faddp                   /* 3 2^(fract(x * log2(base))) */
 196         fstp    %st(1)          /* 2  */
 197         fscale                  /* 2 scale factor is st(1); base^x */
 198         fstp    %st(1)          /* 1  */
 199         LDBL_CHECK_FORCE_UFLOW_NONNEG
 200 #endif
 201         fstp    %st(1)          /* 0  */
 202         jmp     2f
 203 1:
 204 #ifdef USE_AS_EXPM1L
 205         /* For expm1l, only negative sign gets here.  */
 206         fstp    %st
 207         fld1
 208         fchs
 209 #else
 210         testl   $0x200, %eax    /* Test sign.  */
 211         jz      2f              /* If positive, jump.  */
 212         fstp    %st
 213         fldz                    /* Set result to 0.  */
 214 #endif
 215 2:      ret
 216 6:      /* NaN argument.  */
 217         fadd    %st
 218         ret
 219 END(IEEE754_EXPL)
 220
 221 #ifdef USE_AS_EXPM1L
 222 libm_hidden_def (__expm1l)
 223 libm_alias_ldouble (__expm1, expm1)
 224 #elif defined USE_AS_EXP10L
 225 libm_alias_finite (__ieee754_exp10l, __exp10l)
 226 #else
 227 libm_alias_finite (__ieee754_expl, __expl)
 228 #endif