sysdeps/powerpc/powerpc32/fpu/s_round.S

   1 /* round function.  PowerPC32 version.
   2    Copyright (C) 2004 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21
  22         .section        .rodata
  23         .align 3
  24         .type   TWO52.0,@object
  25         .size   TWO52.0,8
  26 TWO52.0:
  27         .long 0x43300000
  28         .long 0
  29         .type   POINTFIVE.0,@object
  30         .size   POINTFIVE.0,8
  31 POINTFIVE.0:
  32         .long 0x3fe00000
  33         .long 0
  34         .type   NEGZERO.0,@object
  35         .size   NEGZERO.0,8
  36 NEGZERO.0:
  37         .long 0x80000000
  38         .long 0
  39
  40         .section        .rodata.cst8,"aM",@progbits,8
  41         .align 3
  42 .LC0:   /* 2**52 */
  43         .long 0x43300000
  44         .long 0
  45 .LC1:   /* 0.5 */
  46         .long 0x3fe00000
  47         .long 0
  48 .LC2:   /* -0.0 */
  49         .long 0x80000000
  50         .long 0
  51
  52 /* double [fp1] round (double x [fp1])
  53    IEEE 1003.1 round function.  IEEE specifies "round to the nearest
  54    integer value, rounding halfway cases away from zero, regardless of
  55    the current rounding mode."  However PowerPC Architecture defines
  56    "Round to Nearest" as "Choose the best approximation. In case of a
  57    tie, choose the one that is even (least significant bit o).".
  58    So we can't use the PowerPC "Round to Nearest" mode. Instead we set
  59    "Round toward Zero" mode and round by adding +-0.5 before rounding
  60    to the integer value.  */
  61
  62 ENTRY (__round)
  63         mffs    fp11            /* Save current FPU rounding mode.  */
  64 #ifdef SHARED
  65         mflr    r11
  66         bl      _GLOBAL_OFFSET_TABLE_@local-4
  67         mflr    r10
  68         lwz     r9,.LC0@got(10)
  69         mtlr    r11
  70         lfd     fp13,0(r9)
  71 #else
  72         lis     r9,.LC0@ha
  73         lfd     fp13,.LC0@l(r9)
  74 #endif
  75         fabs    fp0,fp1
  76         fsub    fp12,fp13,fp13  /* generate 0.0  */
  77         fcmpu   cr7,fp0,fp13    /* if (fabs(x) > TWO52)  */
  78         fcmpu   cr6,fp1,fp12    /* if (x > 0.0)  */
  79         bnllr-  cr7
  80         mtfsfi  7,1             /* Set rounding mode toward 0.  */
  81 #ifdef SHARED
  82         lwz     r9,.LC1@got(10)
  83         lfd     fp10,0(r9)
  84 #else
  85         lis     r9,.LC1@ha
  86         lfd     fp10,.LC1@l(r9)
  87 #endif
  88         ble-    cr6,.L4
  89         fadd    fp1,fp1,fp10    /* x+= 0.5;  */
  90         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
  91         fsub    fp1,fp1,fp13    /* x-= TWO52;  */
  92 .L9:
  93         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
  94         blr
  95 .L4:
  96         fsub    fp9,fp1,fp10    /* x+= 0.5;  */
  97         bge-    cr6,.L9         /* if (x < 0.0)  */
  98         fsub    fp1,fp9,fp13    /* x-= TWO52;  */
  99         fadd    fp1,fp1,fp13    /* x+= TWO52;  */
 100         fcmpu   cr5,fp1,fp12    /* if (x > 0.0)  */
 101         mtfsf   0x01,fp11       /* restore previous rounding mode.  */
 102         bnelr+  cr5
 103 #ifdef SHARED
 104         lwz     r9,.LC2@got(10)
 105         lfd     fp1,0(r9)
 106 #else
 107         lis     r9,.LC2@ha
 108         lfd     fp1,.LC2@l(r9)
 109 #endif
 110         blr
 111         END (__round)
 112
 113 weak_alias (__round, round)
 114
 115 #ifdef NO_LONG_DOUBLE
 116 weak_alias (__round, roundl)
 117 strong_alias (__round, __roundl)
 118 #endif