sysdeps/arm/strlen.S

   1 /* Copyright (C) 1998-2017 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Code contributed by Matthew Wilcox <willy@odie.barnet.ac.uk>
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 /* Thumb requires excessive IT insns here.  */
  20 #define NO_THUMB
  21 #include <sysdep.h>
  22
  23 /* size_t strlen(const char *S)
  24  * entry: r0 -> string
  25  * exit: r0 = len
  26  */
  27
  28         .syntax unified
  29         .text
  30
  31 ENTRY(strlen)
  32         bic     r1, r0, $3              @ addr of word containing first byte
  33         ldr     r2, [r1], $4            @ get the first word
  34         ands    r3, r0, $3              @ how many bytes are duff?
  35         rsb     r0, r3, $0              @ get - that number into counter.
  36         beq     Laligned                @ skip into main check routine if no
  37                                         @ more
  38 #ifdef __ARMEB__
  39         orr     r2, r2, $0xff000000     @ set this byte to non-zero
  40         subs    r3, r3, $1              @ any more to do?
  41         orrgt   r2, r2, $0x00ff0000     @ if so, set this byte
  42         subs    r3, r3, $1              @ more?
  43         orrgt   r2, r2, $0x0000ff00     @ then set.
  44 #else
  45         orr     r2, r2, $0x000000ff     @ set this byte to non-zero
  46         subs    r3, r3, $1              @ any more to do?
  47         orrgt   r2, r2, $0x0000ff00     @ if so, set this byte
  48         subs    r3, r3, $1              @ more?
  49         orrgt   r2, r2, $0x00ff0000     @ then set.
  50 #endif
  51 Laligned:                               @ here, we have a word in r2.  Does it
  52         tst     r2, $0x000000ff         @ contain any zeroes?
  53         tstne   r2, $0x0000ff00         @
  54         tstne   r2, $0x00ff0000         @
  55         tstne   r2, $0xff000000         @
  56         addne   r0, r0, $4              @ if not, the string is 4 bytes longer
  57         ldrne   r2, [r1], $4            @ and we continue to the next word
  58         bne     Laligned                @
  59 Llastword:                              @ drop through to here once we find a
  60 #ifdef __ARMEB__
  61         tst     r2, $0xff000000         @ word that has a zero byte in it
  62         addne   r0, r0, $1              @
  63         tstne   r2, $0x00ff0000         @ and add up to 3 bytes on to it
  64         addne   r0, r0, $1              @
  65         tstne   r2, $0x0000ff00         @ (if first three all non-zero, 4th
  66         addne   r0, r0, $1              @  must be zero)
  67 #else
  68         tst     r2, $0x000000ff         @ word that has a zero byte in it
  69         addne   r0, r0, $1              @
  70         tstne   r2, $0x0000ff00         @ and add up to 3 bytes on to it
  71         addne   r0, r0, $1              @
  72         tstne   r2, $0x00ff0000         @ (if first three all non-zero, 4th
  73         addne   r0, r0, $1              @  must be zero)
  74 #endif
  75         DO_RET(lr)
  76 END(strlen)
  77 libc_hidden_builtin_def (strlen)