configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 ACX_PKGVERSION([GNU libc])
   9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
  10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  11                    [Package description])
  12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  13                    [Bug reporting address])
  14
  15 # Glibc should not depend on any header files
  16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  17   [m4_divert_text([DEFAULTS],
  18     [ac_includes_default='/* none */'])])
  19
  20 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  21 # here to work around the Autoconf issue discussed in
  22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  23 AC_DEFUN([AC_PROG_CPP],
  24 [AC_REQUIRE([AC_PROG_CC])dnl
  25 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  26 _AC_ARG_VAR_CPPFLAGS()dnl
  27 # On Suns, sometimes $CPP names a directory.
  28 if test -n "$CPP" && test -d "$CPP"; then
  29   CPP=
  30 fi
  31 if test -z "$CPP"; then
  32   CPP="$CC -E"
  33 fi
  34 AC_SUBST(CPP)dnl
  35 ])# AC_PROG_CPP
  36
  37 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  38 # issue discussed in
  39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  41
  42 dnl This is here so we can set $subdirs directly based on configure fragments.
  43 AC_CONFIG_SUBDIRS()
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_PROG_CC
  48 if test $host != $build; then
  49   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  50 fi
  51 AC_SUBST(cross_compiling)
  52 AC_PROG_CPP
  53 AC_CHECK_TOOL(READELF, readelf, false)
  54
  55 # We need the C++ compiler only for testing.
  56 AC_PROG_CXX
  57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  59 AC_LANG_PUSH([C++])
  60 # Default, dynamic case.
  61 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  62                [libc_cv_cxx_link_ok=yes],
  63                [libc_cv_cxx_link_ok=no])
  64 # Static case.
  65 old_LDFLAGS="$LDFLAGS"
  66 LDFLAGS="$LDFLAGS -static"
  67 AC_LINK_IFELSE([AC_LANG_SOURCE([
  68 #include <iostream>
  69
  70 int
  71 main()
  72 {
  73   std::cout << "Hello, world!";
  74   return 0;
  75 }
  76 ])],
  77                [],
  78                [libc_cv_cxx_link_ok=no])
  79 LDFLAGS="$old_LDFLAGS"
  80 AC_LANG_POP([C++])])
  81 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  82
  83 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  84   AC_MSG_ERROR([you must configure in a separate build directory])
  85 fi
  86
  87 # This will get text that should go into config.make.
  88 config_vars=
  89
  90 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  91 AC_ARG_WITH([gd],
  92             AC_HELP_STRING([--with-gd=DIR],
  93                            [find libgd include dir and library with prefix DIR]),
  94             [dnl
  95 case "$with_gd" in
  96 yes|''|no) ;;
  97 *) libgd_include="-I$withval/include"
  98    libgd_ldflags="-L$withval/lib" ;;
  99 esac
 100 ])
 101 AC_ARG_WITH([gd-include],
 102             AC_HELP_STRING([--with-gd-include=DIR],
 103                            [find libgd include files in DIR]),
 104             [dnl
 105 case "$with_gd_include" in
 106 ''|no) ;;
 107 *) libgd_include="-I$withval" ;;
 108 esac
 109 ])
 110 AC_ARG_WITH([gd-lib],
 111             AC_HELP_STRING([--with-gd-lib=DIR],
 112                            [find libgd library files in DIR]),
 113             [dnl
 114 case "$with_gd_lib" in
 115 ''|no) ;;
 116 *) libgd_ldflags="-L$withval" ;;
 117 esac
 118 ])
 119
 120 if test -n "$libgd_include"; then
 121   config_vars="$config_vars
 122 CFLAGS-memusagestat.c = $libgd_include"
 123 fi
 124 if test -n "$libgd_ldflags"; then
 125   config_vars="$config_vars
 126 libgd-LDFLAGS = $libgd_ldflags"
 127 fi
 128
 129 dnl Arguments to specify presence of other packages/features.
 130 AC_ARG_WITH([fp],
 131             AC_HELP_STRING([--with-fp],
 132                            [if using floating-point hardware @<:@default=yes@:>@]),
 133             [with_fp=$withval],
 134             [with_fp=yes])
 135 AC_SUBST(with_fp)
 136 AC_ARG_WITH([binutils],
 137             AC_HELP_STRING([--with-binutils=PATH],
 138                            [specify location of binutils (as and ld)]),
 139             [path_binutils=$withval],
 140             [path_binutils=''])
 141 AC_ARG_WITH([selinux],
 142             AC_HELP_STRING([--with-selinux],
 143                            [if building with SELinux support]),
 144             [with_selinux=$withval],
 145             [with_selinux=auto])
 146
 147 AC_ARG_WITH([headers],
 148             AC_HELP_STRING([--with-headers=PATH],
 149                            [location of system headers to use
 150                             (for example /usr/src/linux/include)
 151                             @<:@default=compiler default@:>@]),
 152             [sysheaders=$withval],
 153             [sysheaders=''])
 154 AC_SUBST(sysheaders)
 155
 156 AC_SUBST(use_default_link)
 157 AC_ARG_WITH([default-link],
 158             AC_HELP_STRING([--with-default-link],
 159                            [do not use explicit linker scripts]),
 160             [use_default_link=$withval],
 161             [use_default_link=default])
 162
 163 AC_ARG_ENABLE([sanity-checks],
 164               AC_HELP_STRING([--disable-sanity-checks],
 165                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 166               [enable_sanity=$enableval],
 167               [enable_sanity=yes])
 168
 169 AC_ARG_ENABLE([shared],
 170               AC_HELP_STRING([--enable-shared],
 171                              [build shared library @<:@default=yes if GNU ld@:>@]),
 172               [shared=$enableval],
 173               [shared=yes])
 174 AC_ARG_ENABLE([profile],
 175               AC_HELP_STRING([--enable-profile],
 176                              [build profiled library @<:@default=no@:>@]),
 177               [profile=$enableval],
 178               [profile=no])
 179 AC_ARG_ENABLE([timezone-tools],
 180               AC_HELP_STRING([--disable-timezone-tools],
 181                              [do not install timezone tools @<:@default=install@:>@]),
 182               [enable_timezone_tools=$enableval],
 183               [enable_timezone_tools=yes])
 184 AC_SUBST(enable_timezone_tools)
 185
 186 AC_ARG_ENABLE([hardcoded-path-in-tests],
 187               AC_HELP_STRING([--enable-hardcoded-path-in-tests],
 188                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 189               [hardcoded_path_in_tests=$enableval],
 190               [hardcoded_path_in_tests=no])
 191 AC_SUBST(hardcoded_path_in_tests)
 192
 193 AC_ARG_ENABLE([stackguard-randomization],
 194               AC_HELP_STRING([--enable-stackguard-randomization],
 195                              [initialize __stack_chk_guard canary with a random number at program start]),
 196               [enable_stackguard_randomize=$enableval],
 197               [enable_stackguard_randomize=no])
 198 if test "$enable_stackguard_randomize" = yes; then
 199   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 200 fi
 201
 202 AC_ARG_ENABLE([lock-elision],
 203               AC_HELP_STRING([--enable-lock-elision[=yes/no]],
 204                              [Enable lock elision for pthread mutexes by default]),
 205               [enable_lock_elision=$enableval],
 206               [enable_lock_elision=no])
 207 AC_SUBST(enable_lock_elision)
 208 if test "$enable_lock_elision" = yes ; then
 209   AC_DEFINE(ENABLE_LOCK_ELISION)
 210 fi
 211
 212 AC_ARG_ENABLE([hidden-plt],
 213               AC_HELP_STRING([--disable-hidden-plt],
 214                              [do not hide internal function calls to avoid PLT]),
 215               [hidden=$enableval],
 216               [hidden=yes])
 217 if test "x$hidden" = xno; then
 218   AC_DEFINE(NO_HIDDEN)
 219 fi
 220
 221 AC_ARG_ENABLE([bind-now],
 222               AC_HELP_STRING([--enable-bind-now],
 223                              [disable lazy relocations in DSOs]),
 224               [bindnow=$enableval],
 225               [bindnow=no])
 226 AC_SUBST(bindnow)
 227 if test "x$bindnow" = xyes; then
 228   AC_DEFINE(BIND_NOW)
 229 fi
 230
 231 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 232 dnl -fstack-protector-strong.
 233 AC_ARG_ENABLE([stack-protector],
 234               AC_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 235                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 236               [enable_stack_protector=$enableval],
 237               [enable_stack_protector=no])
 238 case "$enable_stack_protector" in
 239 all|yes|no|strong) ;;
 240 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 241 esac
 242
 243 dnl On some platforms we cannot use dynamic loading.  We must provide
 244 dnl static NSS modules.
 245 AC_ARG_ENABLE([static-nss],
 246               AC_HELP_STRING([--enable-static-nss],
 247                              [build static NSS modules @<:@default=no@:>@]),
 248               [static_nss=$enableval],
 249               [static_nss=no])
 250 dnl Enable static NSS also if we build no shared objects.
 251 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 252   static_nss=yes
 253   AC_DEFINE(DO_STATIC_NSS)
 254 fi
 255
 256 AC_ARG_ENABLE([force-install],
 257               AC_HELP_STRING([--disable-force-install],
 258                              [don't force installation of files from this package, even if they are older than the installed files]),
 259               [force_install=$enableval],
 260               [force_install=yes])
 261 AC_SUBST(force_install)
 262
 263 AC_ARG_ENABLE([maintainer-mode],
 264               AC_HELP_STRING([--enable-maintainer-mode],
 265                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 266               [maintainer=$enableval],
 267               [maintainer=no])
 268
 269 dnl On some platforms we allow dropping compatibility with all kernel
 270 dnl versions.
 271 AC_ARG_ENABLE([kernel],
 272               AC_HELP_STRING([--enable-kernel=VERSION],
 273                              [compile for compatibility with kernel not older than VERSION]),
 274               [minimum_kernel=$enableval],
 275               [])
 276 dnl Prevent unreasonable values.
 277 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 278   # Better nothing than this.
 279   minimum_kernel=""
 280 else
 281   if test "$minimum_kernel" = current; then
 282     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 283   fi
 284 fi
 285
 286 dnl For the development we sometimes want gcc to issue even more warnings.
 287 dnl This is not the default since many of the extra warnings are not
 288 dnl appropriate.
 289 AC_ARG_ENABLE([all-warnings],
 290               AC_HELP_STRING([--enable-all-warnings],
 291                              [enable all useful warnings gcc can issue]),
 292               [all_warnings=$enableval],
 293               [])
 294 AC_SUBST(all_warnings)
 295
 296 AC_ARG_ENABLE([werror],
 297               AC_HELP_STRING([--disable-werror],
 298                              [do not build with -Werror]),
 299               [enable_werror=$enableval],
 300               [enable_werror=yes])
 301 AC_SUBST(enable_werror)
 302
 303 AC_ARG_ENABLE([multi-arch],
 304               AC_HELP_STRING([--enable-multi-arch],
 305                              [enable single DSO with optimizations for multiple architectures]),
 306               [multi_arch=$enableval],
 307               [multi_arch=default])
 308
 309 AC_ARG_ENABLE([experimental-malloc],
 310               AC_HELP_STRING([--disable-experimental-malloc],
 311                              [disable experimental malloc features]),
 312               [experimental_malloc=$enableval],
 313               [experimental_malloc=yes])
 314 AC_SUBST(experimental_malloc)
 315
 316 AC_ARG_ENABLE([nss-crypt],
 317               AC_HELP_STRING([--enable-nss-crypt],
 318                              [enable libcrypt to use nss]),
 319               [nss_crypt=$enableval],
 320               [nss_crypt=no])
 321 if test x$nss_crypt = xyes; then
 322   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 323   if test $? -ne 0; then
 324     AC_MSG_ERROR([cannot find include directory with nss-config])
 325   fi
 326   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 327   if test $? -ne 0; then
 328     AC_MSG_ERROR([cannot find include directory with nspr-config])
 329   fi
 330   old_CFLAGS="$CFLAGS"
 331   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 332   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 333 #include <hasht.h>
 334 #include <nsslowhash.h>
 335 void f (void) { NSSLOW_Init (); }])],
 336              libc_cv_nss_crypt=yes,
 337              AC_MSG_ERROR([
 338 cannot find NSS headers with lowlevel hash function interfaces]))
 339   old_LIBS="$LIBS"
 340   old_LDFLAGS="$LDFLAGS"
 341   LIBS="$LIBS -lfreebl3"
 342   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 343 #include <hasht.h>
 344 #include <nsslowhash.h>],
 345                                   [NSSLOW_Init();])],
 346                  libc_cv_nss_crypt=yes,
 347                  AC_MSG_ERROR([
 348 cannot link program using lowlevel NSS hash functions]))
 349   # Check to see if there is a static NSS cryptographic library.
 350   # If there isn't then we can't link anything with libcrypt.a,
 351   # and that might mean disabling some static tests.
 352   LDFLAGS="$LDFLAGS -static"
 353   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 354 #include <hasht.h>
 355 #include <nsslowhash.h>],
 356                                   [NSSLOW_Init();])],
 357                  libc_cv_static_nss_crypt=yes,
 358                  libc_cv_static_nss_crypt=no)
 359   LDFLAGS="$old_LDFLAGS"
 360   CFLAGS="$old_CFLAGS"
 361   LIBS="$old_LIBS"
 362 else
 363   libc_cv_nss_crypt=no
 364   libc_cv_static_nss_crypt=no
 365 fi
 366 AC_SUBST(libc_cv_nss_crypt)
 367 AC_SUBST(libc_cv_static_nss_crypt)
 368
 369
 370 AC_ARG_ENABLE([obsolete-rpc],
 371               AC_HELP_STRING([--enable-obsolete-rpc],
 372                              [build and install the obsolete RPC code for link-time usage]),
 373               [link_obsolete_rpc=$enableval],
 374               [link_obsolete_rpc=no])
 375 AC_SUBST(link_obsolete_rpc)
 376
 377 if test "$link_obsolete_rpc" = yes; then
 378   AC_DEFINE(LINK_OBSOLETE_RPC)
 379 fi
 380
 381 AC_ARG_ENABLE([obsolete-nsl],
 382               AC_HELP_STRING([--enable-obsolete-nsl],
 383                              [build and install the obsolete libnsl library and depending NSS modules]),
 384               [build_obsolete_nsl=$enableval],
 385               [build_obsolete_nsl=no])
 386 AC_SUBST(build_obsolete_nsl)
 387
 388 if test "$build_obsolete_nsl" = yes; then
 389   AC_DEFINE(LINK_OBSOLETE_NSL)
 390 fi
 391
 392 AC_ARG_ENABLE([systemtap],
 393               [AS_HELP_STRING([--enable-systemtap],
 394                [enable systemtap static probe points @<:@default=no@:>@])],
 395               [systemtap=$enableval],
 396               [systemtap=no])
 397 if test "x$systemtap" != xno; then
 398   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 399   old_CFLAGS="$CFLAGS"
 400   CFLAGS="-std=gnu11 $CFLAGS"
 401   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 402 void foo (int i, void *p)
 403 {
 404   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 405        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 406 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 407   CFLAGS="$old_CFLAGS"])
 408   if test $libc_cv_sdt = yes; then
 409     AC_DEFINE([USE_STAP_PROBE])
 410   elif test "x$systemtap" != xauto; then
 411     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 412   fi
 413 fi
 414
 415 AC_ARG_ENABLE([build-nscd],
 416               [AS_HELP_STRING([--disable-build-nscd],
 417                [disable building and installing the nscd daemon])],
 418               [build_nscd=$enableval],
 419               [build_nscd=default])
 420 AC_SUBST(build_nscd)
 421
 422 # Note the use of $use_nscd is near the bottom of the file.
 423 AC_ARG_ENABLE([nscd],
 424               [AS_HELP_STRING([--disable-nscd],
 425                [library functions will not contact the nscd daemon])],
 426               [use_nscd=$enableval],
 427               [use_nscd=yes])
 428
 429 AC_ARG_ENABLE([pt_chown],
 430               [AS_HELP_STRING([--enable-pt_chown],
 431                [Enable building and installing pt_chown])],
 432               [build_pt_chown=$enableval],
 433               [build_pt_chown=no])
 434 AC_SUBST(build_pt_chown)
 435 if test "$build_pt_chown" = yes; then
 436   AC_DEFINE(HAVE_PT_CHOWN)
 437 fi
 438
 439 AC_ARG_ENABLE([tunables],
 440               [AS_HELP_STRING([--enable-tunables],
 441                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 442               [have_tunables=$enableval],
 443               [have_tunables=yes])
 444 AC_SUBST(have_tunables)
 445 if test "$have_tunables" = yes; then
 446   AC_DEFINE(HAVE_TUNABLES)
 447 fi
 448
 449 # The abi-tags file uses a fairly simplistic model for name recognition that
 450 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 451 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 452 # This doesn't get used much beyond that, so it's fairly safe.
 453 case "$host_os" in
 454 linux*)
 455   ;;
 456 gnu*)
 457   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 458   ;;
 459 esac
 460
 461 AC_ARG_ENABLE([mathvec],
 462               [AS_HELP_STRING([--enable-mathvec],
 463               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 464               [build_mathvec=$enableval],
 465               [build_mathvec=notset])
 466
 467 # We keep the original values in `$config_*' and never modify them, so we
 468 # can write them unchanged into config.make.  Everything else uses
 469 # $machine, $vendor, and $os, and changes them whenever convenient.
 470 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 471
 472 # Don't allow vendor == "unknown"
 473 test "$config_vendor" = unknown && config_vendor=
 474 config_os="`echo $config_os | sed 's/^unknown-//'`"
 475
 476 # Some configurations imply other options.
 477 elf=yes
 478
 479 # The configure fragment of a port can modify these to supplement
 480 # or override the table in the case statement below.  No fragment should
 481 # ever change the config_* variables, however.
 482 machine=$config_machine
 483 vendor=$config_vendor
 484 os=$config_os
 485 base_os=''
 486
 487 submachine=
 488 AC_ARG_WITH([cpu],
 489             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 490             [dnl
 491   case "$withval" in
 492   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 493   no) ;;
 494   *) submachine="$withval" ;;
 495   esac
 496 ])
 497
 498 # An preconfigure script can set this when it wants to disable the sanity
 499 # check below.
 500 libc_config_ok=no
 501
 502 dnl Let sysdeps/*/preconfigure act here.
 503 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 504
 505
 506 ###
 507 ### By using the undocumented --enable-hacker-mode option for configure
 508 ### one can skip this test to make the configuration not fail for unsupported
 509 ### platforms.
 510 ###
 511 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 512   case "$machine-$host_os" in
 513   *-linux* | *-gnu*)
 514     ;;
 515   *)
 516     AC_MSG_ERROR([
 517 *** The GNU C library is currently unavailable for this platform.
 518 *** If you are interested in seeing glibc on this platform visit
 519 *** the "How to submit a new port" in the wiki:
 520 ***   https://sourceware.org/glibc/wiki/#Development
 521 *** and join the community!])
 522     ;;
 523   esac
 524 fi
 525
 526 # Set base_machine if not set by a preconfigure fragment.
 527 test -n "$base_machine" || base_machine=$machine
 528 AC_SUBST(base_machine)
 529
 530 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 531 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 532                    [libc_cv_ssp=yes],
 533                    [libc_cv_ssp=no])
 534 ])
 535
 536 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 537 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 538                    [libc_cv_ssp_strong=yes],
 539                    [libc_cv_ssp_strong=no])
 540 ])
 541
 542 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 543 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 544                    [libc_cv_ssp_all=yes],
 545                    [libc_cv_ssp_all=no])
 546 ])
 547
 548 stack_protector=
 549 no_stack_protector=
 550 if test "$libc_cv_ssp" = yes; then
 551   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 552   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 553 fi
 554
 555 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 556   stack_protector="-fstack-protector"
 557   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 558 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 559   stack_protector="-fstack-protector-all"
 560   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 561 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 562   stack_protector="-fstack-protector-strong"
 563   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 564 else
 565   stack_protector="-fno-stack-protector"
 566   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 567 fi
 568 AC_SUBST(libc_cv_ssp)
 569 AC_SUBST(stack_protector)
 570 AC_SUBST(no_stack_protector)
 571
 572 if test -n "$stack_protector"; then
 573   dnl Don't run configure tests with stack-protection on, to avoid problems with
 574   dnl bootstrapping.
 575   no_ssp=-fno-stack-protector
 576 else
 577   no_ssp=
 578
 579   if test "$enable_stack_protector" != no; then
 580     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 581   fi
 582 fi
 583
 584 # For the multi-arch option we need support in the assembler & linker.
 585 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 586                libc_cv_ld_gnu_indirect_function, [dnl
 587 cat > conftest.S <<EOF
 588 .type foo,%gnu_indirect_function
 589 foo:
 590 .globl _start
 591 _start:
 592 .globl __start
 593 __start:
 594 .data
 595 #ifdef _LP64
 596 .quad foo
 597 #else
 598 .long foo
 599 #endif
 600 EOF
 601 libc_cv_ld_gnu_indirect_function=no
 602 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 603             -nostartfiles -nostdlib $no_ssp \
 604             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 605   # Do a link to see if the backend supports IFUNC relocs.
 606   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 607   LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
 608     libc_cv_ld_gnu_indirect_function=yes
 609   }
 610 fi
 611 rm -f conftest*])
 612
 613 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 614 AC_CACHE_CHECK([for gcc attribute ifunc support],
 615                libc_cv_gcc_indirect_function, [dnl
 616 cat > conftest.c <<EOF
 617 extern int func (int);
 618 int used_func (int a)
 619 {
 620   return a;
 621 }
 622 static void *resolver ()
 623 {
 624   return &used_func;
 625 }
 626 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 627 EOF
 628 libc_cv_gcc_indirect_function=no
 629 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 630    2>&AS_MESSAGE_LOG_FD ; then
 631   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 632     libc_cv_gcc_indirect_function=yes
 633   fi
 634 fi
 635 rm -f conftest*])
 636
 637 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 638   if test x"$multi_arch" = xyes; then
 639     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 640   else
 641     multi_arch=no
 642   fi
 643 fi
 644 if test x"$libc_cv_gcc_indirect_function" != xyes &&
 645    test x"$multi_arch" = xyes; then
 646   AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 647 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 648 fi
 649 multi_arch_d=
 650 if test x"$multi_arch" != xno; then
 651   multi_arch_d=/multiarch
 652 fi
 653
 654 # Compute the list of sysdep directories for this configuration.
 655 # This can take a while to compute.
 656 sysdep_dir=$srcdir/sysdeps
 657 AC_MSG_CHECKING(sysdep dirs)
 658 dnl We need to use [ and ] for other purposes for a while now.
 659 changequote(,)dnl
 660 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 661 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 662
 663 test "x$base_os" != x || case "$os" in
 664 gnu*)
 665   base_os=mach/hurd ;;
 666 linux*)
 667   base_os=unix/sysv ;;
 668 esac
 669
 670 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 671 tail=$os
 672 ostry=$os
 673 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 674   ostry="$ostry /$o"
 675   tail=$o
 676 done
 677 o=`echo $tail | sed 's/[0-9]*$//'`
 678 if test $o != $tail; then
 679   ostry="$ostry /$o"
 680 fi
 681 # For linux-gnu, try linux-gnu, then linux.
 682 o=`echo $tail | sed 's/-.*$//'`
 683 if test $o != $tail; then
 684   ostry="$ostry /$o"
 685 fi
 686
 687 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 688 base=
 689 tail=$base_os
 690 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 691   set $b
 692   base="$base /$1"
 693   tail="$2"
 694 done
 695
 696 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 697 mach=
 698 tail=$machine${submachine:+/$submachine}
 699 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 700   set $m
 701   # Prepend the machine's FPU directory unless --without-fp.
 702   if test "$with_fp" = yes; then
 703     maybe_fpu=/fpu
 704   else
 705     maybe_fpu=/nofpu
 706   fi
 707   # For each machine term, try it with and then without /multiarch.
 708   for try_fpu in $maybe_fpu ''; do
 709     for try_multi in $multi_arch_d ''; do
 710       mach="$mach /$1$try_fpu$try_multi"
 711     done
 712   done
 713   tail="$2"
 714 done
 715
 716 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 717 changequote([,])dnl
 718
 719 # Find what sysdep directories exist.
 720 sysnames=
 721 for b in $base ''; do
 722   for m0 in $mach ''; do
 723     for v in /$vendor ''; do
 724       test "$v" = / && continue
 725       for o in /$ostry ''; do
 726         test "$o" = / && continue
 727         for m in $mach ''; do
 728           try_suffix="$m0$b$v$o$m"
 729           if test -n "$try_suffix"; then
 730             try_srcdir="${srcdir}/"
 731             try="sysdeps$try_suffix"
 732             test -n "$enable_debug_configure" &&
 733             echo "$0 [DEBUG]: try $try" >&2
 734             if test -d "$try_srcdir$try"; then
 735               sysnames="$sysnames $try"
 736               { test -n "$o" || test -n "$b"; } && os_used=t
 737               { test -n "$m" || test -n "$m0"; } && machine_used=t
 738               case x${m0:-$m} in
 739               x*/$submachine) submachine_used=t ;;
 740               esac
 741             fi
 742           fi
 743         done
 744       done
 745     done
 746   done
 747 done
 748
 749 # If the assembler supports gnu_indirect_function symbol type and the
 750 # architecture supports multi-arch, we enable multi-arch by default.
 751 case $sysnames in
 752 *"$multi_arch_d"*)
 753   ;;
 754 *)
 755   test x"$multi_arch" = xdefault && multi_arch=no
 756   ;;
 757 esac
 758 if test x"$multi_arch" != xno; then
 759   AC_DEFINE(USE_MULTIARCH)
 760 fi
 761 AC_SUBST(multi_arch)
 762
 763 if test -z "$os_used" && test "$os" != none; then
 764   AC_MSG_ERROR(Operating system $os is not supported.)
 765 fi
 766 if test -z "$machine_used" && test "$machine" != none; then
 767   AC_MSG_ERROR(The $machine is not supported.)
 768 fi
 769 if test -z "$submachine_used" && test -n "$submachine"; then
 770   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 771 fi
 772 AC_SUBST(submachine)
 773
 774 # We have now validated the configuration.
 775
 776 # Expand the list of system names into a full list of directories
 777 # from each element's parent name and Implies file (if present).
 778 set $sysnames
 779 names=
 780 while test $# -gt 0; do
 781   name=$1
 782   shift
 783
 784   case " $names " in *" $name "*)
 785     # Already in the list.
 786     continue
 787   esac
 788
 789   # Report each name as we discover it, so there is no long pause in output.
 790   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 791
 792   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 793
 794   case $name in
 795     /*) xsrcdir= ;;
 796     *)  xsrcdir=$srcdir/ ;;
 797   esac
 798   test -n "$enable_debug_configure" &&
 799   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 800
 801   for implies_file in Implies Implies-before Implies-after; do
 802     implies_type=`echo $implies_file | sed s/-/_/`
 803     eval ${implies_type}=
 804     if test -f $xsrcdir$name/$implies_file; then
 805       # Collect more names from the `Implies' file (removing comments).
 806       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 807       for x in $implied_candidate; do
 808         found=no
 809         if test -d $xsrcdir$name_base/$x; then
 810           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 811           found=yes
 812         fi
 813         try="sysdeps/$x"
 814         try_srcdir=$srcdir/
 815         test -n "$enable_debug_configure" &&
 816          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 817         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 818         then
 819           eval "${implies_type}=\"\$${implies_type} \$try\""
 820           found=yes
 821         fi
 822         if test $found = no; then
 823           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 824         fi
 825       done
 826     fi
 827   done
 828
 829   # Add NAME to the list of names.
 830   names="$names $name"
 831
 832   # Find the parent of NAME, using the empty string if it has none.
 833 changequote(,)dnl
 834   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 835 changequote([,])dnl
 836
 837   test -n "$enable_debug_configure" &&
 838     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 839 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 840
 841   # Add the names implied by NAME, and NAME's parent (if it has one), to
 842   # the list of names to be processed (the argument list).  We prepend the
 843   # implied names to the list and append the parent.  We want implied
 844   # directories to come before further directories inferred from the
 845   # configuration components; this ensures that for sysv4, unix/common
 846   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 847   # after sysv4).
 848   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 849   test -n "$sysnames" && set $sysnames
 850 done
 851
 852 # Add the default directories.
 853 default_sysnames="sysdeps/generic"
 854 sysnames="$names $default_sysnames"
 855 AC_SUBST(sysnames)
 856 # The other names were emitted during the scan.
 857 AC_MSG_RESULT($default_sysnames)
 858
 859
 860 ### Locate tools.
 861
 862 AC_PROG_INSTALL
 863 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 864   # The makefiles need to use a different form to find it in $srcdir.
 865   INSTALL='\$(..)./scripts/install-sh -c'
 866 fi
 867 AC_PROG_LN_S
 868
 869 LIBC_PROG_BINUTILS
 870
 871 # Accept binutils 2.25 or newer.
 872 AC_CHECK_PROG_VER(AS, $AS, --version,
 873                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 874                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 875                   AS=: critic_missing="$critic_missing as")
 876
 877 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 878   # Accept gold 1.14 or higher
 879   AC_CHECK_PROG_VER(LD, $LD, --version,
 880                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 881                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 882                     LD=: critic_missing="$critic_missing GNU gold")
 883 else
 884   AC_CHECK_PROG_VER(LD, $LD, --version,
 885                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 886                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 887                     LD=: critic_missing="$critic_missing GNU ld")
 888 fi
 889
 890 # These programs are version sensitive.
 891 AC_CHECK_TOOL_PREFIX
 892 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 893   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 894   [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 895
 896 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 897   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 898   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 899   MSGFMT=: aux_missing="$aux_missing msgfmt")
 900 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 901   [GNU texinfo.* \([0-9][0-9.]*\)],
 902   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
 903   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 904 AC_CHECK_PROG_VER(SED, sed, --version,
 905   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
 906   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 907   SED=: aux_missing="$aux_missing sed")
 908 AC_CHECK_PROG_VER(AWK, gawk, --version,
 909   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
 910   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
 911
 912 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
 913 AC_TRY_COMPILE([], [
 914 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 9)
 915 #error insufficient compiler
 916 #endif],
 917                [libc_cv_compiler_ok=yes],
 918                [libc_cv_compiler_ok=no])])
 919 AS_IF([test $libc_cv_compiler_ok != yes],
 920       [critic_missing="$critic_missing compiler"])
 921
 922 AC_CHECK_TOOL(NM, nm, false)
 923
 924 if test "x$maintainer" = "xyes"; then
 925   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 926   case "x$AUTOCONF" in
 927   xno|x|x:) AUTOCONF=no ;;
 928   *)
 929     AC_CACHE_CHECK(dnl
 930   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 931     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
 932       libc_cv_autoconf_works=yes
 933     else
 934       libc_cv_autoconf_works=no
 935     fi])
 936     test $libc_cv_autoconf_works = yes || AUTOCONF=no
 937     ;;
 938   esac
 939   if test "x$AUTOCONF" = xno; then
 940     aux_missing="$aux_missing autoconf"
 941   fi
 942 else
 943   AUTOCONF=no
 944 fi
 945
 946 # Check for python3 if available, or else python.
 947 AC_CHECK_PROGS(PYTHON_PROG, python3 python,no)
 948 case "x$PYTHON_PROG" in
 949 xno|x|x:) PYTHON_PROG=no ;;
 950 *) ;;
 951 esac
 952
 953 if test "x$PYTHON_PROG" = xno; then
 954   aux_missing="$aux_missing python"
 955 else
 956   PYTHON="$PYTHON_PROG -B"
 957   AC_SUBST(PYTHON)
 958 fi
 959
 960 test -n "$critic_missing" && AC_MSG_ERROR([
 961 *** These critical programs are missing or too old:$critic_missing
 962 *** Check the INSTALL file for required versions.])
 963
 964 test -n "$aux_missing" && AC_MSG_WARN([
 965 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 966 *** some features or tests will be disabled.
 967 *** Check the INSTALL file for required versions.])
 968
 969 # if using special system headers, find out the compiler's sekrit
 970 # header directory and add that to the list.  NOTE: Only does the right
 971 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 972 if test -n "$sysheaders"; then
 973   SYSINCLUDES=-nostdinc
 974   for d in include include-fixed; do
 975     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
 976     SYSINCLUDES="$SYSINCLUDES -isystem $i"
 977   done
 978   SYSINCLUDES="$SYSINCLUDES \
 979 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
 980   if test -n "$CXX"; then
 981     CXX_SYSINCLUDES=
 982     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
 983     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
 984       test "x$cxxheaders" != x &&
 985       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
 986     done
 987   fi
 988 fi
 989 AC_SUBST(SYSINCLUDES)
 990 AC_SUBST(CXX_SYSINCLUDES)
 991
 992 # Obtain some C++ header file paths.  This is used to make a local
 993 # copy of those headers in Makerules.
 994 if test -n "$CXX"; then
 995   find_cxx_header () {
 996     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
 997          | sed -n "\,$1:,{s/:\$//;p}"
 998   }
 999   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1000   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1001   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1002 fi
1003 AC_SUBST(CXX_CSTDLIB_HEADER)
1004 AC_SUBST(CXX_CMATH_HEADER)
1005 AC_SUBST(CXX_BITS_STD_ABS_H)
1006
1007 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1008 # since this would lead to problems installing/building glibc.
1009 # LD_LIBRARY_PATH contains the current directory if one of the following
1010 # is true:
1011 # - one of the terminals (":" and ";") is the first or last sign
1012 # - two terminals occur directly after each other
1013 # - the path contains an element with a dot in it
1014 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1015 changequote(,)dnl
1016 case ${LD_LIBRARY_PATH} in
1017   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1018     ld_library_path_setting="contains current directory"
1019     ;;
1020   *)
1021     ld_library_path_setting="ok"
1022     ;;
1023 esac
1024 changequote([,])dnl
1025 AC_MSG_RESULT($ld_library_path_setting)
1026 if test "$ld_library_path_setting" != "ok"; then
1027 AC_MSG_ERROR([
1028 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1029 *** building glibc. Please change the environment variable
1030 *** and run configure again.])
1031 fi
1032
1033 AC_PATH_PROG(BASH_SHELL, bash, no)
1034
1035 AC_PATH_PROG(PERL, perl, no)
1036 if test "$PERL" != no &&
1037    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1038   PERL=no
1039 fi
1040 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1041              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1042 AC_CHECK_PROG_VER(BISON, bison, --version,
1043                   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1044                   [2.7*|[3-9].*|[1-9][0-9]*],
1045                   BISON=no)
1046
1047 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1048 cat > conftest.s <<EOF
1049 .text
1050 foo:
1051 .set glibc_conftest_frobozz,foo
1052 .globl glibc_conftest_frobozz
1053 EOF
1054 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1055 # (but it doesn't work), so we must do a linking check to be sure.
1056 cat > conftest1.c <<\EOF
1057 extern int glibc_conftest_frobozz;
1058 void _start() { glibc_conftest_frobozz = 1; }
1059 EOF
1060 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1061             -nostartfiles -nostdlib $no_ssp \
1062             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1063   libc_cv_asm_set_directive=yes
1064 else
1065   libc_cv_asm_set_directive=no
1066 fi
1067 rm -f conftest*])
1068 if test $libc_cv_asm_set_directive = yes; then
1069   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1070 fi
1071
1072 AC_CACHE_CHECK(linker support for protected data symbol,
1073                libc_cv_protected_data,
1074                [cat > conftest.c <<EOF
1075                 int bar __attribute__ ((visibility ("protected"))) = 1;
1076 EOF
1077                 libc_cv_protected_data=no
1078                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1079                   cat > conftest.c <<EOF
1080                   extern int bar;
1081                   int main (void) { return bar; }
1082 EOF
1083                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1084                     libc_cv_protected_data=yes
1085                   fi
1086                 fi
1087                 rm -f conftest.*
1088                ])
1089 AC_SUBST(libc_cv_protected_data)
1090
1091 AC_CACHE_CHECK(linker support for INSERT in linker script,
1092                libc_cv_insert,
1093                [cat > conftest.c <<EOF
1094                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1095                 int test (void) { return bar; }
1096 EOF
1097                 cat > conftest.t <<EOF
1098                 SECTIONS
1099                 {
1100                   .bar : { *(.bar) }
1101                 }
1102                 INSERT AFTER .rela.dyn;
1103 EOF
1104                 libc_cv_insert=no
1105                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1106                   libc_cv_insert=yes
1107                 fi
1108                 rm -f conftest.*
1109                ])
1110 AC_SUBST(libc_cv_insert)
1111
1112 AC_CACHE_CHECK(for broken __attribute__((alias())),
1113                libc_cv_broken_alias_attribute,
1114                [cat > conftest.c <<EOF
1115                extern int foo (int x) __asm ("xyzzy");
1116                int bar (int x) { return x; }
1117                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1118                extern int dfoo;
1119                extern __typeof (dfoo) dfoo __asm ("abccb");
1120                int dfoo = 1;
1121 EOF
1122                libc_cv_broken_alias_attribute=yes
1123                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1124                  if grep 'xyzzy' conftest.s >/dev/null &&
1125                     grep 'abccb' conftest.s >/dev/null; then
1126                    libc_cv_broken_alias_attribute=no
1127                  fi
1128                fi
1129                rm -f conftest.c conftest.s
1130                ])
1131 if test $libc_cv_broken_alias_attribute = yes; then
1132   AC_MSG_ERROR(working alias attribute support required)
1133 fi
1134
1135 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1136                libc_cv_have_sdata_section,
1137                [echo "int i;" > conftest.c
1138                 libc_cv_have_sdata_section=no
1139                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1140                    | grep '\.sdata' >/dev/null; then
1141                   libc_cv_have_sdata_section=yes
1142                 fi
1143                 rm -f conftest.c conftest.so
1144                ])
1145 if test $libc_cv_have_sdata_section = yes; then
1146   AC_DEFINE(HAVE_SDATA_SECTION)
1147 fi
1148
1149 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1150                libc_cv_ctors_header, [dnl
1151   libc_cv_ctors_header=yes
1152   LIBC_TRY_LINK_STATIC([
1153 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1154 __attribute__ ((destructor))  void dtor (void) { asm (""); }
1155 ],
1156               [dnl
1157       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1158         { gsub(/\@<:@ */, "@<:@") }
1159         $2 == ".ctors" || $2 == ".dtors" {
1160           size = strtonum("0x" $6)
1161           align = strtonum("0x" $NF)
1162           seen@<:@$2@:>@ = 1
1163           stub@<:@$2@:>@ = size == align * 2
1164         }
1165         END {
1166           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1167           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1168           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1169         }
1170       '], [libc_cv_ctors_header=no])
1171     ], [dnl
1172       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1173     ])
1174 ])
1175 if test $libc_cv_ctors_header = no; then
1176   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1177 fi
1178
1179 AC_CACHE_CHECK(for libunwind-support in compiler,
1180                libc_cv_cc_with_libunwind, [
1181   cat > conftest.c <<EOF
1182 int main (void) { return 0; }
1183 EOF
1184   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1185      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1186     libc_cv_cc_with_libunwind=yes
1187   else
1188     libc_cv_cc_with_libunwind=no
1189   fi
1190   rm -f conftest*])
1191 AC_SUBST(libc_cv_cc_with_libunwind)
1192 if test $libc_cv_cc_with_libunwind = yes; then
1193   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1194 fi
1195
1196 ASFLAGS_config=
1197 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1198                libc_cv_as_noexecstack, [dnl
1199 cat > conftest.c <<EOF
1200 void foo (void) { }
1201 EOF
1202 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1203                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1204    && grep .note.GNU-stack conftest.s >/dev/null \
1205    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1206                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1207 then
1208   libc_cv_as_noexecstack=yes
1209 else
1210   libc_cv_as_noexecstack=no
1211 fi
1212 rm -f conftest*])
1213 if test $libc_cv_as_noexecstack = yes; then
1214   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1215 fi
1216 AC_SUBST(ASFLAGS_config)
1217
1218 AC_CACHE_CHECK(for -z combreloc,
1219                libc_cv_z_combreloc, [dnl
1220 cat > conftest.c <<EOF
1221 extern int bar (int);
1222 extern int mumble;
1223 int foo (void) { return bar (mumble); }
1224 EOF
1225 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1226                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1227                         -nostdlib -nostartfiles
1228                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1229 then
1230 dnl The following test is a bit weak.  We must use a tool which can test
1231 dnl cross-platform since the gcc used can be a cross compiler.  Without
1232 dnl introducing new options this is not easily doable.  Instead use a tool
1233 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1234 dnl look for a section named .rel.dyn or .rela.dyn.
1235   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1236     libc_cv_z_combreloc=yes
1237   else
1238     libc_cv_z_combreloc=no
1239   fi
1240 else
1241   libc_cv_z_combreloc=no
1242 fi
1243 rm -f conftest*])
1244 if test "$libc_cv_z_combreloc" = yes; then
1245   AC_DEFINE(HAVE_Z_COMBRELOC)
1246 fi
1247 AC_SUBST(libc_cv_z_combreloc)
1248
1249 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1250                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1251 AC_SUBST(libc_cv_z_execstack)
1252
1253 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1254 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1255 ])
1256
1257 AC_SUBST(libc_cv_fpie)
1258
1259 AC_CACHE_CHECK(for --hash-style option,
1260                libc_cv_hashstyle, [dnl
1261 cat > conftest.c <<EOF
1262 int _start (void) { return 42; }
1263 EOF
1264 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1265                             -fPIC -shared -o conftest.so conftest.c
1266                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1267 then
1268   libc_cv_hashstyle=yes
1269 else
1270   libc_cv_hashstyle=no
1271 fi
1272 rm -f conftest*])
1273 AC_SUBST(libc_cv_hashstyle)
1274
1275 # The linker's default -shared behavior is good enough if it
1276 # does these things that our custom linker scripts ensure that
1277 # all allocated NOTE sections come first.
1278 if test "$use_default_link" = default; then
1279   AC_CACHE_CHECK([for sufficient default -shared layout],
1280                   libc_cv_use_default_link, [dnl
1281   libc_cv_use_default_link=no
1282   cat > conftest.s <<\EOF
1283           .section .note.a,"a",%note
1284           .balign 4
1285           .long 4,4,9
1286           .string "GNU"
1287           .string "foo"
1288           .section .note.b,"a",%note
1289           .balign 4
1290           .long 4,4,9
1291           .string "GNU"
1292           .string "bar"
1293 EOF
1294   if AC_TRY_COMMAND([dnl
1295   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1296        ac_try=`$READELF -S conftest.so | sed -n \
1297          ['${x;p;}
1298           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1299           t a
1300           b
1301           : a
1302           H']`
1303   then
1304     libc_seen_a=no libc_seen_b=no
1305     set -- $ac_try
1306     while test $# -ge 2 -a "$1" = NOTE; do
1307       case "$2" in
1308       .note.a) libc_seen_a=yes ;;
1309       .note.b) libc_seen_b=yes ;;
1310       esac
1311       shift 2
1312     done
1313     case "$libc_seen_a$libc_seen_b" in
1314     yesyes)
1315       libc_cv_use_default_link=yes
1316       ;;
1317     *)
1318       echo >&AS_MESSAGE_LOG_FD "\
1319 $libc_seen_a$libc_seen_b from:
1320 $ac_try"
1321       ;;
1322     esac
1323   fi
1324   rm -f conftest*])
1325   use_default_link=$libc_cv_use_default_link
1326 fi
1327
1328 AC_CACHE_CHECK(for GLOB_DAT reloc,
1329                libc_cv_has_glob_dat, [dnl
1330 cat > conftest.c <<EOF
1331 extern int mumble;
1332 int foo (void) { return mumble; }
1333 EOF
1334 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1335                         -fPIC -shared -o conftest.so conftest.c
1336                         -nostdlib -nostartfiles $no_ssp
1337                         1>&AS_MESSAGE_LOG_FD])
1338 then
1339 dnl look for GLOB_DAT relocation.
1340   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1341     libc_cv_has_glob_dat=yes
1342   else
1343     libc_cv_has_glob_dat=no
1344   fi
1345 else
1346   libc_cv_has_glob_dat=no
1347 fi
1348 rm -f conftest*])
1349 AC_SUBST(libc_cv_has_glob_dat)
1350
1351 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1352 if libc_cv_output_format=`
1353 ${CC-cc} -nostartfiles -nostdlib $no_ssp -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1354 then
1355   :
1356 else
1357   libc_cv_output_format=
1358 fi
1359 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1360 AC_SUBST(libc_cv_output_format)
1361
1362 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1363 cat > conftest.c <<EOF
1364 int foo;
1365 EOF
1366 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1367                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1368 then
1369   libc_cv_fno_toplevel_reorder=yes
1370 else
1371   libc_cv_fno_toplevel_reorder=no
1372 fi
1373 rm -f conftest*])
1374 if test $libc_cv_fno_toplevel_reorder = yes; then
1375   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1376 else
1377   fno_unit_at_a_time=-fno-unit-at-a-time
1378 fi
1379 AC_SUBST(fno_unit_at_a_time)
1380
1381 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1382 [dnl
1383 cat > conftest.c <<EOF
1384 __thread int i;
1385 void foo (void)
1386 {
1387   i = 10;
1388 }
1389 EOF
1390 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1391                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1392 then
1393   libc_cv_mtls_dialect_gnu2=yes
1394 else
1395   libc_cv_mtls_dialect_gnu2=no
1396 fi
1397 rm -f conftest*])
1398 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1399 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1400
1401 AC_CACHE_CHECK(whether cc puts quotes around section names,
1402                libc_cv_have_section_quotes,
1403                [cat > conftest.c <<EOF
1404                 static const int foo
1405                 __attribute__ ((section ("bar"))) = 1;
1406 EOF
1407                 if ${CC-cc} -S conftest.c -o conftest.s; then
1408                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1409                     libc_cv_have_section_quotes=yes
1410                   else
1411                     libc_cv_have_section_quotes=no
1412                   fi
1413                 else
1414                   libc_cv_have_section_quotes=unknown
1415                 fi
1416                 rm -f conftest.{c,s}
1417                 ])
1418 if test $libc_cv_have_section_quotes = yes; then
1419   AC_DEFINE(HAVE_SECTION_QUOTES)
1420 fi
1421
1422 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1423 cat > conftest.c <<\EOF
1424 void zero (void *x)
1425 {
1426   __builtin_memset (x, 0, 1000);
1427 }
1428 EOF
1429 dnl
1430 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1431 then
1432   libc_cv_gcc_builtin_memset=no
1433 else
1434   libc_cv_gcc_builtin_memset=yes
1435 fi
1436 rm -f conftest* ])
1437 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1438   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1439 fi
1440
1441 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1442 cat > conftest.c <<\EOF
1443 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1444 char *foo (const char *a, const char *b)
1445 {
1446   return __builtin_strstr (a, b);
1447 }
1448 EOF
1449 dnl
1450 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1451 then
1452   libc_cv_gcc_builtin_redirection=yes
1453 else
1454   libc_cv_gcc_builtin_redirection=no
1455 fi
1456 rm -f conftest* ])
1457 if test "$libc_cv_gcc_builtin_redirection" = no; then
1458   AC_MSG_ERROR([support for the symbol redirection needed])
1459 fi
1460
1461 dnl Determine how to disable generation of FMA instructions.
1462 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1463                libc_cv_cc_nofma, [dnl
1464 libc_cv_cc_nofma=
1465 for opt in -ffp-contract=off -mno-fused-madd; do
1466   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1467 done])
1468 AC_SUBST(libc_cv_cc_nofma)
1469
1470 if test -n "$submachine"; then
1471   AC_CACHE_CHECK([for compiler option for CPU variant],
1472                  libc_cv_cc_submachine, [dnl
1473   libc_cv_cc_submachine=no
1474   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1475     LIBC_TRY_CC_OPTION([$opt], [
1476       libc_cv_cc_submachine="$opt"
1477       break], [])
1478   done])
1479   if test "x$libc_cv_cc_submachine" = xno; then
1480     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1481   fi
1482 fi
1483 AC_SUBST(libc_cv_cc_submachine)
1484
1485 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1486 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1487 cat > conftest.c <<EOF
1488 void
1489 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1490 foo (void) {}
1491 EOF
1492 libc_cv_cc_loop_to_function=no
1493 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1494 then
1495   libc_cv_cc_loop_to_function=yes
1496 fi
1497 rm -f conftest*])
1498 if test $libc_cv_cc_loop_to_function = yes; then
1499   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1500 fi
1501 AC_SUBST(libc_cv_cc_loop_to_function)
1502
1503 dnl Check whether we have the gd library available.
1504 AC_MSG_CHECKING(for libgd)
1505 if test "$with_gd" != "no"; then
1506   old_CFLAGS="$CFLAGS"
1507   CFLAGS="$CFLAGS $libgd_include"
1508   old_LDFLAGS="$LDFLAGS"
1509   LDFLAGS="$LDFLAGS $libgd_ldflags"
1510   old_LIBS="$LIBS"
1511   LIBS="$LIBS -lgd -lpng -lz -lm"
1512   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1513   CFLAGS="$old_CFLAGS"
1514   LDFLAGS="$old_LDFLAGS"
1515   LIBS="$old_LIBS"
1516 else
1517   LIBGD=no
1518 fi
1519 AC_MSG_RESULT($LIBGD)
1520 AC_SUBST(LIBGD)
1521
1522 # SELinux detection
1523 if test x$with_selinux = xno ; then
1524   have_selinux=no;
1525 else
1526   # See if we have the SELinux library
1527   AC_CHECK_LIB(selinux, is_selinux_enabled,
1528                have_selinux=yes, have_selinux=no)
1529   if test x$with_selinux = xyes ; then
1530     if test x$have_selinux = xno ; then
1531       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1532     fi
1533   fi
1534 fi
1535 # Check if we're building with SELinux support.
1536 if test "x$have_selinux" = xyes; then
1537   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1538
1539   # See if we have the libaudit library
1540   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1541                have_libaudit=yes, have_libaudit=no)
1542   if test "x$have_libaudit" = xyes; then
1543     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1544   fi
1545   AC_SUBST(have_libaudit)
1546
1547   # See if we have the libcap library
1548   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1549   if test "x$have_libcap" = xyes; then
1550     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1551   fi
1552   AC_SUBST(have_libcap)
1553 fi
1554 AC_SUBST(have_selinux)
1555
1556 CPPUNDEFS=
1557 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1558 dnl Since we are building the implementations of the fortified functions here,
1559 dnl having the macro defined interacts very badly.
1560 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1561 [AC_TRY_COMPILE([], [
1562 #ifdef _FORTIFY_SOURCE
1563 # error bogon
1564 #endif],
1565                 [libc_cv_predef_fortify_source=no],
1566                 [libc_cv_predef_fortify_source=yes])])
1567 if test $libc_cv_predef_fortify_source = yes; then
1568   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1569 fi
1570 AC_SUBST(CPPUNDEFS)
1571
1572 # Some linkers on some architectures support __ehdr_start but with
1573 # bugs.  Make sure usage of it does not create relocations in the
1574 # output (as the linker should resolve them all for us).
1575 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1576                libc_cv_ehdr_start, [
1577 old_CFLAGS="$CFLAGS"
1578 old_LDFLAGS="$LDFLAGS"
1579 old_LIBS="$LIBS"
1580 CFLAGS="$CFLAGS -fPIC"
1581 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1582 LIBS=
1583 AC_LINK_IFELSE([AC_LANG_SOURCE([
1584 typedef struct {
1585   char foo;
1586   long val;
1587 } Ehdr;
1588 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1589 long ehdr (void) { return __ehdr_start.val; }
1590 ])],
1591                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1592                   libc_cv_ehdr_start=broken
1593                 else
1594                   libc_cv_ehdr_start=yes
1595                 fi], [libc_cv_ehdr_start=no])
1596 CFLAGS="$old_CFLAGS"
1597 LDFLAGS="$old_LDFLAGS"
1598 LIBS="$old_LIBS"
1599 ])
1600 if test "$libc_cv_ehdr_start" = yes; then
1601   AC_DEFINE([HAVE_EHDR_START])
1602 elif test "$libc_cv_ehdr_start" = broken; then
1603   AC_MSG_WARN([linker is broken -- you should upgrade])
1604 fi
1605
1606 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1607                libc_cv_builtin_trap, [dnl
1608 libc_cv_builtin_trap=no
1609 AC_TRY_COMPILE([], [__builtin_trap ()], [
1610 libc_undefs=`$NM -u conftest.o |
1611   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1612     2>&AS_MESSAGE_LOG_FD` || {
1613   AC_MSG_ERROR([confusing output from $NM -u])
1614 }
1615 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1616 if test -z "$libc_undefs"; then
1617   libc_cv_builtin_trap=yes
1618 fi])])
1619 if test $libc_cv_builtin_trap = yes; then
1620   AC_DEFINE([HAVE_BUILTIN_TRAP])
1621 fi
1622
1623 dnl C++ feature tests.
1624 AC_LANG_PUSH([C++])
1625
1626 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1627                libc_cv_cxx_thread_local, [
1628 old_CXXFLAGS="$CXXFLAGS"
1629 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1630 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1631 #include <thread>
1632
1633 // Compiler support.
1634 struct S
1635 {
1636   S ();
1637   ~S ();
1638 };
1639 thread_local S s;
1640 S * get () { return &s; }
1641
1642 // libstdc++ support.
1643 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1644 #error __cxa_thread_atexit_impl not supported
1645 #endif
1646 ])],
1647                [libc_cv_cxx_thread_local=yes],
1648                [libc_cv_cxx_thread_local=no])
1649 CXXFLAGS="$old_CXXFLAGS"
1650 ])
1651 AC_SUBST(libc_cv_cxx_thread_local)
1652
1653 AC_LANG_POP([C++])
1654 dnl End of C++ feature tests.
1655
1656 ### End of automated tests.
1657 ### Now run sysdeps configure fragments.
1658
1659 # They also can set these variables.
1660 use_ldconfig=no
1661 ldd_rewrite_script=no
1662 libc_cv_sysconfdir=$sysconfdir
1663 libc_cv_localstatedir=$localstatedir
1664 libc_cv_gcc_unwind_find_fde=no
1665 libc_cv_idn=no
1666
1667 # Iterate over all the sysdep directories we will use, running their
1668 # configure fragments.
1669 for dir in $sysnames; do
1670   case $dir in
1671     /*) dest=$dir ;;
1672     *)  dest=$srcdir/$dir ;;
1673   esac
1674   if test -r $dest/configure; then
1675     AC_MSG_RESULT(running configure fragment for $dir)
1676     . $dest/configure
1677   fi
1678 done
1679
1680 if test x"$build_mathvec" = xnotset; then
1681   build_mathvec=no
1682 fi
1683 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1684
1685 AC_SUBST(libc_extra_cflags)
1686 AC_SUBST(libc_extra_cppflags)
1687
1688 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1689   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1690 fi
1691 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1692
1693 # A sysdeps configure fragment can reset this if IFUNC is not actually
1694 # usable even though the assembler knows how to generate the symbol type.
1695 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1696   AC_DEFINE(HAVE_IFUNC)
1697 fi
1698
1699 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1700   AC_DEFINE(HAVE_GCC_IFUNC)
1701 fi
1702
1703 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1704 # configure fragment can override the value to prevent this AC_DEFINE.
1705 AC_SUBST(use_nscd)
1706 if test "x$use_nscd" != xno; then
1707   AC_DEFINE([USE_NSCD])
1708 fi
1709 if test "x$build_nscd" = xdefault; then
1710   build_nscd=$use_nscd
1711 fi
1712
1713 AC_SUBST(libc_cv_slibdir)
1714 AC_SUBST(libc_cv_rtlddir)
1715 AC_SUBST(libc_cv_complocaledir)
1716 AC_SUBST(libc_cv_sysconfdir)
1717 AC_SUBST(libc_cv_localstatedir)
1718 AC_SUBST(libc_cv_rootsbindir)
1719
1720 if test x$use_ldconfig = xyes; then
1721   AC_DEFINE(USE_LDCONFIG)
1722 fi
1723 AC_SUBST(use_ldconfig)
1724 AC_SUBST(ldd_rewrite_script)
1725
1726 AC_SUBST(static)
1727 AC_SUBST(shared)
1728
1729 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1730 [libc_cv_pic_default=yes
1731 cat > conftest.c <<EOF
1732 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1733 # error PIC is default.
1734 #endif
1735 EOF
1736 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1737   libc_cv_pic_default=no
1738 fi
1739 rm -f conftest.*])
1740 AC_SUBST(libc_cv_pic_default)
1741
1742 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_pie_default,
1743 [libc_cv_pie_default=yes
1744 cat > conftest.c <<EOF
1745 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1746 # error PIE is default.
1747 #endif
1748 EOF
1749 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1750   libc_cv_pie_default=no
1751 fi
1752 rm -f conftest.*])
1753 AC_SUBST(libc_cv_pie_default)
1754
1755 AC_SUBST(profile)
1756 AC_SUBST(static_nss)
1757
1758 AC_SUBST(DEFINES)
1759
1760 dnl See sysdeps/mach/configure.ac for this variable.
1761 AC_SUBST(mach_interface_list)
1762
1763 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1764 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1765 AC_SUBST(VERSION)
1766 AC_SUBST(RELEASE)
1767
1768 AC_CONFIG_FILES([config.make Makefile])
1769 AC_CONFIG_COMMANDS([default],[[
1770 case $CONFIG_FILES in *config.make*)
1771 echo "$config_vars" >> config.make;;
1772 esac
1773 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1774 AC_OUTPUT