sysdeps/i386/bsd-_setjmp.S

   1 /* BSD `_setjmp' entry point to `sigsetjmp (..., 0)'.  i386 version.
   2    Copyright (C) 1994-2023 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 0)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <pointer_guard.h>
  25 #include <jmpbuf-offsets.h>
  26 #include <jmp_buf-ssp.h>
  27 #include <stap-probe.h>
  28
  29 #define PARMS   4               /* no space for saved regs */
  30 #define JMPBUF  PARMS
  31 #define SIGMSK  JMPBUF+4
  32
  33 /* Don't save shadow stack register if shadow stack isn't enabled.  */
  34 #if !SHSTK_ENABLED
  35 # undef SHADOW_STACK_POINTER_OFFSET
  36 #endif
  37
  38 ENTRY (_setjmp)
  39
  40         xorl %eax, %eax
  41         movl JMPBUF(%esp), %edx
  42
  43         /* Save registers.  */
  44         movl %ebx, (JB_BX*4)(%edx)
  45         movl %esi, (JB_SI*4)(%edx)
  46         movl %edi, (JB_DI*4)(%edx)
  47         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  48 #ifdef PTR_MANGLE
  49         PTR_MANGLE (%ecx)
  50 #endif
  51         movl %ecx, (JB_SP*4)(%edx)
  52         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  53         LIBC_PROBE (setjmp, 3, 4@%edx, -4@$0, 4@%ecx)
  54 #ifdef PTR_MANGLE
  55         PTR_MANGLE (%ecx)
  56 #endif
  57         movl %ecx, (JB_PC*4)(%edx)
  58         movl %ebp, (JB_BP*4)(%edx) /* Save caller's frame pointer.  */
  59
  60         movl %eax, JB_SIZE(%edx) /* No signal mask set.  */
  61 #ifdef SHADOW_STACK_POINTER_OFFSET
  62 # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET
  63         /* Check if Shadow Stack is enabled.  */
  64         testl $X86_FEATURE_1_SHSTK, %gs:FEATURE_1_OFFSET
  65         jz L(skip_ssp)
  66 # else
  67         xorl %ecx, %ecx
  68 # endif
  69         /* Get the current Shadow-Stack-Pointer and save it.  */
  70         rdsspd %ecx
  71         movl %ecx, SHADOW_STACK_POINTER_OFFSET(%edx)
  72 # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET
  73 L(skip_ssp):
  74 # endif
  75 #endif
  76         ret
  77 END (_setjmp)
  78 libc_hidden_def (_setjmp)