ports/sysdeps/arm/__longjmp.S

   1 /* longjmp for ARM.
   2    Copyright (C) 1997-2012 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20 #define _SETJMP_H
  21 #define _ASM
  22 #include <bits/setjmp.h>
  23 #include <rtld-global-offsets.h>
  24 #include <arm-features.h>
  25
  26 /* __longjmp(jmpbuf, val) */
  27
  28 ENTRY (__longjmp)
  29         mov     ip, r0
  30         movs    r0, r1          /* get the return value in place */
  31         moveq   r0, #1          /* can't let setjmp() return zero! */
  32
  33 #ifdef CHECK_SP
  34         ldr     r4, [ip, #32]   /* jmpbuf's sp */
  35         cfi_undefined (r4)
  36         CHECK_SP (r4)
  37 #endif
  38         LOADREGS(ia, ip!, {v1-v6, sl, fp, sp, lr})
  39         cfi_restore (v1)
  40         cfi_restore (v2)
  41         cfi_restore (v3)
  42         cfi_restore (v4)
  43         cfi_restore (v5)
  44         cfi_restore (v6)
  45         cfi_restore (sl)
  46         cfi_restore (fp)
  47         cfi_restore (sp)
  48         cfi_restore (lr)
  49
  50 #if !defined ARM_ASSUME_NO_IWMMXT || defined __SOFTFP__
  51 # define NEED_HWCAP 1
  52 #endif
  53
  54 #ifdef NEED_HWCAP
  55 # ifdef IS_IN_rtld
  56         ldr     a2, 1f
  57         ldr     a3, .Lrtld_local_ro
  58 0:      add     a2, pc, a2
  59         add     a2, a2, a3
  60         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  61 # else
  62 #  ifdef PIC
  63         ldr     a2, 1f
  64         ldr     a3, .Lrtld_global_ro
  65 0:      add     a2, pc, a2
  66         ldr     a2, [a2, a3]
  67         ldr     a2, [a2, #RTLD_GLOBAL_RO_DL_HWCAP_OFFSET]
  68 #  else
  69         ldr     a2, .Lhwcap
  70         ldr     a2, [a2, #0]
  71 #  endif
  72 # endif
  73 #endif
  74
  75 #ifdef __SOFTFP__
  76         tst     a2, #HWCAP_ARM_VFP
  77         beq     .Lno_vfp
  78 #endif
  79
  80         /* Restore the VFP registers.  */
  81         /* Following instruction is vldmia ip!, {d8-d15}.  */
  82         ldc     p11, cr8, [r12], #64
  83         /* Restore the floating-point status register.  */
  84         ldr     a3, [ip], #4
  85         /* Following instruction is fmxr fpscr, a3.  */
  86         mcr     p10, 7, a3, cr1, cr0, 0
  87 .Lno_vfp:
  88
  89 #ifndef ARM_ASSUME_NO_IWMMXT
  90         tst     a2, #HWCAP_ARM_IWMMXT
  91         beq     .Lno_iwmmxt
  92
  93         /* Restore the call-preserved iWMMXt registers.  */
  94         /* Following instructions are wldrd wr10, [ip], #8 (etc.)  */
  95         ldcl    p1, cr10, [r12], #8
  96         ldcl    p1, cr11, [r12], #8
  97         ldcl    p1, cr12, [r12], #8
  98         ldcl    p1, cr13, [r12], #8
  99         ldcl    p1, cr14, [r12], #8
 100         ldcl    p1, cr15, [r12], #8
 101 .Lno_iwmmxt:
 102 #endif
 103
 104         DO_RET(lr)
 105
 106 #ifdef NEED_HWCAP
 107 # ifdef IS_IN_rtld
 108 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
 109 .Lrtld_local_ro:
 110         .long   C_SYMBOL_NAME(_rtld_local_ro)(GOTOFF)
 111 # else
 112 #  ifdef PIC
 113 1:      .long   _GLOBAL_OFFSET_TABLE_ - 0b - 8
 114 .Lrtld_global_ro:
 115         .long   C_SYMBOL_NAME(_rtld_global_ro)(GOT)
 116 #  else
 117 .Lhwcap:
 118         .long   C_SYMBOL_NAME(_dl_hwcap)
 119 #  endif
 120 # endif
 121 #endif
 122
 123 END (__longjmp)