sysdeps/hppa/rshift.s

   1 ;! HP-PA  __mpn_rshift --
   2
   3 ;! Copyright (C) 1992, 1994 Free Software Foundation, Inc.
   4
   5 ;! This file is part of the GNU MP Library.
   6
   7 ;! The GNU MP Library is free software; you can redistribute it and/or modify
   8 ;! it under the terms of the GNU Lesser General Public License as published by
   9 ;! the Free Software Foundation; either version 2.1 of the License, or (at your
  10 ;! option) any later version.
  11
  12 ;! The GNU MP Library is distributed in the hope that it will be useful, but
  13 ;! WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 ;! or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  15 ;! License for more details.
  16
  17 ;! You should have received a copy of the GNU Lesser General Public License
  18 ;! along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  19 ;! the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20 ;! MA 02111-1307, USA.
  21
  22
  23 ;! INPUT PARAMETERS
  24 ;! res_ptr      gr26
  25 ;! s_ptr        gr25
  26 ;! size         gr24
  27 ;! cnt          gr23
  28
  29         .text
  30         .export         __mpn_rshift
  31 __mpn_rshift:
  32         .proc
  33         .callinfo       frame=64,no_calls
  34         .entry
  35
  36         ldws,ma         4(%r25),%r22
  37         mtsar           %r23
  38         addib,=         -1,%r24,L$0004
  39         vshd            %r22,%r0,%r28           ;! compute carry out limb
  40         ldws,ma         4(%r25),%r29
  41         addib,=         -1,%r24,L$0002
  42         vshd            %r29,%r22,%r20
  43
  44 L$loop: ldws,ma         4(%r25),%r22
  45         stws,ma         %r20,4(%r26)
  46         addib,=         -1,%r24,L$0003
  47         vshd            %r22,%r29,%r20
  48         ldws,ma         4(%r25),%r29
  49         stws,ma         %r20,4(%r26)
  50         addib,<>        -1,%r24,L$loop
  51         vshd            %r29,%r22,%r20
  52
  53 L$0002: stws,ma         %r20,4(%r26)
  54         vshd            %r0,%r29,%r20
  55         bv              0(%r2)
  56         stw             %r20,0(%r26)
  57 L$0003: stws,ma         %r20,4(%r26)
  58 L$0004: vshd            %r0,%r22,%r20
  59         bv              0(%r2)
  60         stw             %r20,0(%r26)
  61
  62         .exit
  63         .procend