sysdeps/tile/dl-start.S

   1 /* Copyright (C) 2011-2018 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3    Contributed by Chris Metcalf <cmetcalf@tilera.com>, 2011.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library.  If not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #include <sysdep.h>
  20
  21         /* Get address of "sym" in "reg" assuming r51 holds ".Llink". */
  22         .macro pic_addr reg, sym
  23         moveli \reg, hw1_last(\sym - .Llink)
  24         shl16insli \reg, \reg, hw0(\sym - .Llink)
  25         ADD_PTR \reg, r51, \reg
  26         .endm
  27
  28         .text
  29 ENTRY (_start)
  30         /* Linux starts us with sp pointing at the conventional Elf layout,
  31            but we need to allow two 'caller' words for our ABI convention.  */
  32         {
  33          move r52, sp
  34          andi sp, sp, -8
  35         }
  36         cfi_def_cfa_register (r52)
  37         {
  38          /* Point sp at base of ABI area; point r4 to the caller-sp word. */
  39          ADDI_PTR sp, sp, -(2 * REGSIZE)
  40          ADDI_PTR r4, sp, -REGSIZE
  41         }
  42         {
  43          /* Save zero for caller sp in our 'caller' save area, and make
  44             sure lr has a zero value, to limit backtraces.  */
  45          move lr, zero
  46          st r4, zero
  47         }
  48         {
  49          move r0, r52
  50          jal _dl_start
  51         }
  52         /* Save returned start of user program address for later. */
  53         move r50, r0
  54
  55         /* See if we were invoked explicitly with the dynamic loader,
  56            in which case we have to adjust the argument vector.  */
  57         lnk r51; .Llink:
  58         pic_addr r4, _dl_skip_args
  59         ld4u r4, r4
  60         beqzt r4, .Lno_skip
  61
  62         /* Load the argc word at the initial sp and adjust it.
  63            We basically jump "sp" up over the first few argv entries
  64            and write "argc" a little higher up in memory, to be the
  65            base of the new kernel-initialized stack area.  */
  66         LD_PTR r0, r52
  67         {
  68          sub r0, r0, r4
  69          SHL_PTR_ADD r52, r4, r52
  70         }
  71         {
  72          ST_PTR r52, r0
  73          SHL_PTR_ADD sp, r4, sp
  74         }
  75         andi sp, sp, -8
  76
  77 .Lno_skip:
  78         /* Call_dl_init (_dl_loaded, argc, argv, envp).  See elf/start.s
  79            for the layout of memory here; r52 is pointing to "+0".  */
  80         pic_addr r0, _rtld_local
  81         {
  82          LD_PTR r1, r52  /* load argc in r1 */
  83          ADDLI_PTR r2, r52, __SIZEOF_POINTER__  /* point r2 at argv */
  84         }
  85         {
  86          LD_PTR r0, r0    /* yields _rtld_global._ns_loaded */
  87          addi r3, r1, 1
  88          move lr, zero
  89         }
  90         {
  91          SHL_PTR_ADD r3, r3, r2  /* point r3 at envp */
  92          jal _dl_init
  93         }
  94
  95         /* Call user program whose address we saved in r50.
  96            We invoke it just like a static binary, but with _dl_fini
  97            in r0 so we can distinguish.  */
  98
  99         pic_addr r0, _dl_fini
 100         move lr, zero
 101         {
 102          move sp, r52
 103          jr r50
 104         }
 105
 106         /* Tell backtracer to give up (_start has no caller). */
 107         info 2  /* INFO_OP_CANNOT_BACKTRACE */
 108
 109 END (_start)