sysdeps/alpha/strlen.S

   1 /* Copyright (C) 1996 Free Software Foundation, Inc.
   2    Contributed by David Mosberger (davidm@cs.arizona.edu).
   3
   4 This file is part of the GNU C Library.
   5
   6 The GNU C Library is free software; you can redistribute it and/or
   7 modify it under the terms of the GNU Library General Public License as
   8 published by the Free Software Foundation; either version 2 of the
   9 License, or (at your option) any later version.
  10
  11 The GNU C Library is distributed in the hope that it will be useful,
  12 but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14 Library General Public License for more details.
  15
  16 You should have received a copy of the GNU Library General Public
  17 License along with the GNU C Library; see the file COPYING.LIB.  If
  18 not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  19 Cambridge, MA 02139, USA.  */
  20
  21 /* Finds length of a 0-terminated string.  Optimized for the Alpha
  22    architecture:
  23
  24       - memory accessed as aligned quadwords only
  25       - uses cmpbge to compare 8 bytes in parallel
  26       - does binary search to find 0 byte in last quadword (HAKMEM
  27         needed 12 instructions to do this instead of the 8 instructions
  28         that the binary search needs).
  29 */
  30
  31 #include <sysdep.h>
  32
  33         .set noreorder
  34         .set noat
  35
  36 ENTRY(strlen)
  37 #ifdef PROF
  38         ldgp    gp, 0(pv)
  39         lda     AT, _mcount
  40         jsr     AT, (AT), _mcount
  41         .prologue 1
  42 #else
  43         .prologue 0
  44 #endif
  45
  46         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
  47         lda     t1, -1(zero)
  48         insqh   t1, a0, t1
  49         andnot  a0, 7, v0
  50         or      t1, t0, t0
  51         nop                     # dual issue the next two on ev5
  52         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
  53         bne     t1, $found
  54
  55 $loop:  ldq     t0, 8(v0)
  56         addq    v0, 8, v0       # addr += 8
  57         cmpbge  zero, t0, t1
  58         beq     t1, $loop
  59
  60 $found: negq    t1, t2          # clear all but least set bit
  61         and     t1, t2, t1
  62
  63         and     t1, 0xf0, t2    # binary search for that set bit
  64         and     t1, 0xcc, t3
  65         and     t1, 0xaa, t4
  66         cmovne  t2, 4, t2
  67         cmovne  t3, 2, t3
  68         cmovne  t4, 1, t4
  69         addq    t2, t3, t2
  70         addq    v0, t4, v0
  71         addq    v0, t2, v0
  72         nop                     # dual issue next two on ev4 and ev5
  73
  74         subq    v0, a0, v0
  75         ret
  76
  77         END(strlen)