sysdeps/powerpc/powerpc64/power7/strlen.S

   1 /* Optimized strlen implementation for PowerPC64/POWER7 using cmpb insn.
   2    Copyright (C) 2010 Free Software Foundation, Inc.
   3    Contributed by Luis Machado <luisgpm@br.ibm.com>.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, see
  18    <http://www.gnu.org/licenses/>.  */
  19
  20 #include <sysdep.h>
  21 #include <bp-sym.h>
  22 #include <bp-asm.h>
  23
  24 /* int [r3] strlen (char *s [r3])  */
  25         .machine  power7
  26 ENTRY (BP_SYM (strlen))
  27         CALL_MCOUNT 1
  28         dcbt    0,r3
  29         clrrdi  r4,r3,3       /* Align the address to doubleword boundary.  */
  30         rlwinm  r6,r3,3,26,28 /* Calculate padding.  */
  31         li      r0,0          /* Doubleword with null chars to use
  32                                  with cmpb.  */
  33         li      r5,-1         /* MASK = 0xffffffffffffffff.  */
  34         ld      r12,0(r4)     /* Load doubleword from memory.  */
  35         srd     r5,r5,r6      /* MASK = MASK >> padding.  */
  36         orc     r9,r12,r5     /* Mask bits that are not part of the string.  */
  37         cmpb    r10,r9,r0     /* Check for null bytes in DWORD1.  */
  38         cmpdi   cr7,r10,0     /* If r10 == 0, no null's have been found.  */
  39         bne     cr7,L(done)
  40
  41         mtcrf   0x01,r4
  42
  43         /* Are we now aligned to a quadword boundary?  If so, skip to
  44            the main loop.  Otherwise, go through the alignment code.  */
  45
  46         bt      28,L(loop)
  47
  48         /* Handle DWORD2 of pair.  */
  49         ldu     r12,8(r4)
  50         cmpb    r10,r12,r0
  51         cmpdi   cr7,r10,0
  52         bne     cr7,L(done)
  53         b       L(loop)       /* We branch here (rather than falling through)
  54                                  to skip the nops due to heavy alignment
  55                                  of the loop below.  */
  56
  57         /* Main loop to look for the end of the string.  Since it's a
  58            small loop (< 8 instructions), align it to 32-bytes.  */
  59         .p2align  5
  60 L(loop):
  61         /* Load two doublewords, compare and merge in a
  62            single register for speed.  This is an attempt
  63            to speed up the null-checking process for bigger strings.  */
  64
  65         ld      r12, 8(r4)
  66         ldu     r11, 16(r4)
  67         cmpb    r10,r12,r0
  68         cmpb    r9,r11,r0
  69         or      r8,r9,r10     /* Merge everything in one doubleword.  */
  70         cmpdi   cr7,r8,0
  71         beq     cr7,L(loop)
  72
  73         /* OK, one (or both) of the doublewords contains a null byte.  Check
  74            the first doubleword and decrement the address in case the first
  75            doubleword really contains a null byte.  */
  76
  77         cmpdi   cr6,r10,0
  78         addi    r4,r4,-8
  79         bne     cr6,L(done)
  80
  81         /* The null byte must be in the second doubleword.  Adjust the address
  82            again and move the result of cmpb to r10 so we can calculate the
  83            length.  */
  84
  85         mr      r10,r9
  86         addi    r4,r4,8
  87
  88         /* r10 has the output of the cmpb instruction, that is, it contains
  89            0xff in the same position as the null byte in the original
  90            doubleword from the string.  Use that to calculate the length.  */
  91 L(done):
  92         cntlzd  r0,r10        /* Count leading zeroes before the match.  */
  93         subf    r5,r3,r4
  94         srdi    r0,r0,3       /* Convert leading zeroes to bytes.  */
  95         add     r3,r5,r0      /* Compute final length.  */
  96         blr
  97 END (BP_SYM (strlen))
  98 libc_hidden_builtin_def (strlen)