| blob | 4eb9277e8c99835f636680b4bbdb4b8ad1a49a00 |
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.53)dnl dnl Minimum Autoconf version required.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 dnl This is here so we can set $subdirs directly based on configure fragments.
9 AC_CONFIG_SUBDIRS()
11 AC_CANONICAL_HOST
13 AC_PROG_CC
14 if test $host != $build; then
15 AC_CHECK_PROGS(BUILD_CC, gcc cc)
16 fi
17 AC_SUBST(cross_compiling)
18 AC_PROG_CPP
19 # We need the C++ compiler only for testing.
20 AC_PROG_CXX
22 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
23 AC_MSG_ERROR([you must configure in a separate build directory])
24 fi
26 # This will get text that should go into config.make.
27 config_vars=
29 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
30 AC_ARG_WITH([gd],
31 AC_HELP_STRING([--with-gd=DIR],
32 [find libgd include dir and library with prefix DIR]),
33 [dnl
34 case "$with_gd" in
35 yes|''|no) ;;
36 *) libgd_include="-I$withval/include"
37 libgd_ldflags="-L$withval/lib" ;;
38 esac
39 ])
40 AC_ARG_WITH([gd-include],
41 AC_HELP_STRING([--with-gd-include=DIR],
42 [find libgd include files in DIR]),
43 [dnl
44 case "$with_gd_include" in
45 ''|no) ;;
46 *) libgd_include="-I$withval" ;;
47 esac
48 ])
49 AC_ARG_WITH([gd-lib],
50 AC_HELP_STRING([--with-gd-lib=DIR],
51 [find libgd library files in DIR]),
52 [dnl
53 case "$with_gd_lib" in
54 ''|no) ;;
55 *) libgd_ldflags="-L$withval" ;;
56 esac
57 ])
59 if test -n "$libgd_include"; then
60 config_vars="$config_vars
61 CFLAGS-memusagestat.c = $libgd_include"
62 fi
63 if test -n "$libgd_ldflags"; then
64 config_vars="$config_vars
65 libgd-LDFLAGS = $libgd_ldflags"
66 fi
68 dnl Arguments to specify presence of other packages/features.
69 AC_ARG_WITH([fp],
70 AC_HELP_STRING([--with-fp],
71 [if using floating-point hardware @<:@default=yes@:>@]),
72 [with_fp=$withval],
73 [with_fp=yes])
74 AC_SUBST(with_fp)
75 AC_ARG_WITH([binutils],
76 AC_HELP_STRING([--with-binutils=PATH],
77 [specify location of binutils (as and ld)]),
78 [path_binutils=$withval],
79 [path_binutils=''])
80 AC_ARG_WITH([selinux],
81 AC_HELP_STRING([--with-selinux],
82 [if building with SELinux support]),
83 [with_selinux=$withval],
84 [with_selinux=auto])
86 AC_ARG_WITH([headers],
87 AC_HELP_STRING([--with-headers=PATH],
88 [location of system headers to use
89 (for example /usr/src/linux/include)
90 @<:@default=compiler default@:>@]),
91 [sysheaders=$withval],
92 [sysheaders=''])
94 AC_SUBST(use_default_link)
95 AC_ARG_WITH([default-link],
96 AC_HELP_STRING([--with-default-link],
97 [do not use explicit linker scripts]),
98 [use_default_link=$withval],
99 [use_default_link=default])
101 AC_ARG_ENABLE([sanity-checks],
102 AC_HELP_STRING([--disable-sanity-checks],
103 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
104 [enable_sanity=$enableval],
105 [enable_sanity=yes])
107 AC_ARG_ENABLE([shared],
108 AC_HELP_STRING([--enable-shared],
109 [build shared library @<:@default=yes if GNU ld@:>@]),
110 [shared=$enableval],
111 [shared=yes])
112 AC_ARG_ENABLE([profile],
113 AC_HELP_STRING([--enable-profile],
114 [build profiled library @<:@default=no@:>@]),
115 [profile=$enableval],
116 [profile=no])
117 AC_ARG_ENABLE([versioning],
118 AC_HELP_STRING([--disable-versioning],
119 [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
120 [enable_versioning=$enableval],
121 [enable_versioning=yes])
123 AC_ARG_ENABLE([oldest-abi],
124 AC_HELP_STRING([--enable-oldest-abi=ABI],
125 [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
126 [oldest_abi=$enableval],
127 [oldest_abi=no])
128 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
129 oldest_abi=default
130 else
131 AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
132 fi
133 AC_SUBST(oldest_abi)
135 AC_ARG_ENABLE([stackguard-randomization],
136 AC_HELP_STRING([--enable-stackguard-randomization],
137 [initialize __stack_chk_guard canary with a random number at program start]),
138 [enable_stackguard_randomize=$enableval],
139 [enable_stackguard_randomize=no])
140 if test "$enable_stackguard_randomize" = yes; then
141 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
142 fi
144 dnl Generic infrastructure for drop-in additions to libc.
145 AC_ARG_ENABLE([add-ons],
146 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
147 [configure and build add-ons in DIR1,DIR2,...
148 search for add-ons if no parameter given]),
149 , [enable_add_ons=yes])
151 AC_ARG_ENABLE([hidden-plt],
152 AC_HELP_STRING([--disable-hidden-plt],
153 [do not hide internal function calls to avoid PLT]),
154 [hidden=$enableval],
155 [hidden=yes])
156 if test "x$hidden" = xno; then
157 AC_DEFINE(NO_HIDDEN)
158 fi
160 AC_ARG_ENABLE([bind-now],
161 AC_HELP_STRING([--enable-bind-now],
162 [disable lazy relocations in DSOs]),
163 [bindnow=$enableval],
164 [bindnow=no])
165 AC_SUBST(bindnow)
167 dnl On some platforms we cannot use dynamic loading. We must provide
168 dnl static NSS modules.
169 AC_ARG_ENABLE([static-nss],
170 AC_HELP_STRING([--enable-static-nss],
171 [build static NSS modules @<:@default=no@:>@]),
172 [static_nss=$enableval],
173 [static_nss=no])
174 dnl Enable static NSS also if we build no shared objects.
175 if test x"$static_nss" = xyes || test x"$shared" = xno; then
176 static_nss=yes
177 AC_DEFINE(DO_STATIC_NSS)
178 fi
180 AC_ARG_ENABLE([force-install],
181 AC_HELP_STRING([--disable-force-install],
182 [don't force installation of files from this package, even if they are older than the installed files]),
183 [force_install=$enableval],
184 [force_install=yes])
185 AC_SUBST(force_install)
187 dnl On some platforms we allow dropping compatibility with all kernel
188 dnl versions.
189 AC_ARG_ENABLE([kernel],
190 AC_HELP_STRING([--enable-kernel=VERSION],
191 [compile for compatibility with kernel not older than VERSION]),
192 [minimum_kernel=$enableval],
193 [])
194 dnl Prevent unreasonable values.
195 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
196 # Better nothing than this.
197 minimum_kernel=""
198 else
199 if test "$minimum_kernel" = current; then
200 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
201 fi
202 fi
204 dnl For the development we sometimes want gcc to issue even more warnings.
205 dnl This is not the default since many of the extra warnings are not
206 dnl appropriate.
207 AC_ARG_ENABLE([all-warnings],
208 AC_HELP_STRING([--enable-all-warnings],
209 [enable all useful warnings gcc can issue]),
210 [all_warnings=$enableval],
211 [])
212 AC_SUBST(all_warnings)
214 AC_ARG_ENABLE([multi-arch],
215 AC_HELP_STRING([--enable-multi-arch],
216 [enable single DSO with optimizations for multiple architectures]),
217 [multi_arch=$enableval],
218 [multi_arch=default])
220 AC_ARG_ENABLE([nss-crypt],
221 AC_HELP_STRING([--enable-nss-crypt],
222 [enable libcrypt to use nss]),
223 [nss_crypt=$enableval],
224 [nss_crypt=no])
225 if test x$nss_crypt = xyes; then
226 nss_includes=-I$(nss-config --includedir 2>/dev/null)
227 if test $? -ne 0; then
228 AC_MSG_ERROR([cannot find include directory with nss-config])
229 fi
230 old_CFLAGS="$CFLAGS"
231 CFLAGS="$CFLAGS $nss_includes"
232 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
233 #include <hasht.h>
234 #include <nsslowhash.h>
235 void f (void) { NSSLOW_Init (); }])],
236 libc_cv_nss_crypt=yes,
237 AC_MSG_ERROR([
238 cannot find NSS headers with lowlevel hash function interfaces]))
239 old_LIBS="$LIBS"
240 LIBS="$LIBS -lfreebl3"
241 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
242 #include <hasht.h>
243 #include <nsslowhash.h>],
244 [NSSLOW_Init();])],
245 libc_cv_nss_crypt=yes,
246 AC_MSG_ERROR([
247 cannot link program using lowlevel NSS hash functions]))
248 CFLAGS="$old_CFLAGS"
249 LIBS="$old_LIBS"
250 else
251 libc_cv_nss_crypt=no
252 fi
253 AC_SUBST(libc_cv_nss_crypt)
255 AC_ARG_ENABLE([obsolete-rpc],
256 AC_HELP_STRING([--enable-obsolete-rpc],
257 [build and install the obsolete RPC code for link-time usage]),
258 [link_obsolete_rpc=$enableval],
259 [link_obsolete_rpc=no])
260 AC_SUBST(link_obsolete_rpc)
262 if test "$link_obsolete_rpc" = yes; then
263 AC_DEFINE(LINK_OBSOLETE_RPC)
264 fi
266 # The way shlib-versions is used to generate soversions.mk uses a
267 # fairly simplistic model for name recognition that can't distinguish
268 # i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a $host_os
269 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
270 # tell. This doesn't get used much beyond that, so it's fairly safe.
271 case "$host_os" in
272 linux*)
273 ;;
274 gnu*)
275 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
276 ;;
277 esac
279 # We keep the original values in `$config_*' and never modify them, so we
280 # can write them unchanged into config.make. Everything else uses
281 # $machine, $vendor, and $os, and changes them whenever convenient.
282 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
284 # Don't allow vendor == "unknown"
285 test "$config_vendor" = unknown && config_vendor=
286 config_os="`echo $config_os | sed 's/^unknown-//'`"
288 # Some configurations imply other options.
289 elf=yes
291 # The configure fragment of an add-on port can modify these to supplement
292 # or override the table in the case statement below. No fragment should
293 # ever change the config_* variables, however.
294 machine=$config_machine
295 vendor=$config_vendor
296 os=$config_os
297 base_os=''
299 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
300 # Unify this here.
301 if test "$machine" = rs6000; then
302 machine="powerpc"
303 fi
305 # Braindead PowerPC box with absolutely no FPU.
306 case "$machine-$host_os" in
307 powerpc*-*soft)
308 with_fp=no
309 ;;
310 esac
312 submachine=
313 AC_ARG_WITH([cpu],
314 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
315 [dnl
316 case "$withval" in
317 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
318 no) ;;
319 *) submachine="$withval" ;;
320 esac
321 ])
323 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
324 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
326 # An add-on can set this when it wants to disable the sanity check below.
327 libc_config_ok=no
329 dnl Having this here, though empty, makes sure that if add-ons' fragments
330 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
331 dnl our AC_OUTPUT will actually use it.
332 AC_CONFIG_SUBDIRS()
334 case "$enable_add_ons" in
335 ''|no) add_ons= ;;
336 yes|'*')
337 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
338 sed 's@/[[^/]]*$@@' | sort | uniq`
339 add_ons_automatic=yes
340 ;;
341 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
342 add_ons_automatic=no ;;
343 esac
345 configured_add_ons=
346 add_ons_sfx=
347 add_ons_pfx=
348 if test x"$add_ons" != x; then
349 for f in $add_ons; do
350 # Some sanity checks
351 case "$f" in
352 crypt)
353 AC_MSG_ERROR([
354 *** It seems that you're using an old \`crypt' add-on. crypt is now
355 *** part of glibc and using the old add-on will not work with this
356 *** release. Start again with fresh sources and without the old
357 *** \`crypt' add-on.])
358 ;;
359 localedata)
360 AC_MSG_ERROR([
361 *** It seems that you're using an old \`localedata' add-on. localedata
362 *** is now part of glibc and using the old add-on will not work with
363 *** this release. Start again with fresh sources and without the old
364 *** \`localedata' add-on.])
365 ;;
366 esac
367 done
369 # Now source each add-on's configure fragment.
370 # The fragments can use $srcdir/$libc_add_on to find themselves,
371 # and test $add_ons_automatic to see if they were explicitly requested.
372 # A fragment can clear (or even change) $libc_add_on to affect
373 # whether it goes into the list to be actually used in the build.
374 use_add_ons=
375 for libc_add_on in $add_ons; do
376 # Test whether such a directory really exists.
377 # It can be absolute, or relative to $srcdir, or relative to the build dir.
378 case "$libc_add_on" in
379 /*)
380 libc_add_on_srcdir=$libc_add_on
381 ;;
382 *)
383 test -d "$srcdir/$libc_add_on" || {
384 if test -d "$libc_add_on"; then
385 libc_add_on="`pwd`/$libc_add_on"
386 else
387 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
388 fi
389 }
390 libc_add_on_srcdir=$srcdir/$libc_add_on
391 ;;
392 esac
394 libc_add_on_frag=$libc_add_on_srcdir/configure
395 libc_add_on_canonical=
396 libc_add_on_config_subdirs=
397 if test -r "$libc_add_on_frag"; then
398 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
399 libc_add_on_canonical=unknown
400 libc_add_on_subdirs=
401 . "$libc_add_on_frag"
402 test -z "$libc_add_on" || {
403 configured_add_ons="$configured_add_ons $libc_add_on"
404 if test "x$libc_add_on_canonical" = xunknown; then
405 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
406 fi
407 for d in $libc_add_on_subdirs; do
408 case "$libc_add_on" in
409 /*) subdir_srcdir="$libc_add_on" ;;
410 *) subdir_srcdir="\$(..)$libc_add_on" ;;
411 esac
412 case "$d" in
413 .)
414 d="${libc_add_on_canonical:-$libc_add_on}"
415 ;;
416 /*)
417 subdir_srcdir="$d"
418 ;;
419 *)
420 subdir_srcdir="$subdir_srcdir/$d"
421 ;;
422 esac
423 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
424 add_on_subdirs="$add_on_subdirs $d"
425 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
426 $d-srcdir = $subdir_srcdir"
427 done
428 for d in $libc_add_on_config_subdirs; do
429 case "$d" in
430 /*) AC_MSG_ERROR(dnl
431 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
432 esac
433 if test ! -d "$libc_add_on_srcdir/$d"; then
434 AC_MSG_ERROR(fragment wants to configure missing directory $d)
435 fi
436 case "$libc_add_on" in
437 /*) AC_MSG_ERROR(dnl
438 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
439 esac
440 subdirs="$subdirs $libc_add_on/$d"
441 done
442 }
443 fi
444 if test -n "$libc_add_on"; then
445 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
446 use_add_ons="$use_add_ons $libc_add_on"
447 add_ons_pfx="$add_ons_pfx $libc_add_on/"
448 test -z "$libc_add_on_canonical" ||
449 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
450 fi
451 done
452 # Use echo to strip excess whitespace.
453 add_ons="`echo $use_add_ons`"
454 fi
455 AC_SUBST(add_ons)
456 AC_SUBST(add_on_subdirs)
459 ###
460 ### I put this here to prevent those annoying emails from people who cannot
461 ### read and try to compile glibc on unsupported platforms. --drepper
462 ###
463 ### By using the undocumented --enable-hacker-mode option for configure
464 ### one can skip this test to make the configuration not fail for unsupported
465 ### platforms.
466 ###
467 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
468 case "$machine-$host_os" in
469 *-linux* | *-gnu*)
470 ;;
471 *)
472 echo "*** The GNU C library is currently not available for this platform."
473 echo "*** So far nobody cared to port it and if there is no volunteer it"
474 echo "*** might never happen. So, if you have interest to see glibc on"
475 echo "*** this platform visit"
476 echo "*** http://www.gnu.org/software/libc/porting.html"
477 echo "*** and join the group of porters"
478 exit 1
479 ;;
480 esac
481 fi
483 dnl We need to use [ and ] for other purposes for a while now.
484 changequote(,)dnl
485 # Expand the configuration machine name into a subdirectory by architecture
486 # type and particular chip. If an add-on configure fragment already set
487 # base_machine, we don't change it.
488 test -n "$base_machine" || case "$machine" in
489 i[34567]86) base_machine=i386 machine=i386/$machine ;;
490 powerpc) base_machine=powerpc machine=powerpc/powerpc32 ;;
491 powerpc64) base_machine=powerpc machine=powerpc/powerpc64 ;;
492 s390) base_machine=s390 machine=s390/s390-32 ;;
493 s390x) base_machine=s390 machine=s390/s390-64 ;;
494 sh3*) base_machine=sh machine=sh/sh3 ;;
495 sh4*) base_machine=sh machine=sh/sh4 ;;
496 sparc | sparcv[67])
497 base_machine=sparc machine=sparc/sparc32 ;;
498 sparcv8 | supersparc | hypersparc)
499 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
500 sparcv8plus | sparcv8plusa | sparcv9)
501 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
502 sparcv8plusb | sparcv9b)
503 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
504 sparcv9v)
505 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
506 sparcv9v2)
507 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
508 sparc64)
509 base_machine=sparc machine=sparc/sparc64 ;;
510 sparc64b)
511 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
512 sparc64v)
513 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
514 sparc64v2)
515 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
516 *) base_machine=$machine ;;
517 esac
518 changequote([,])dnl
519 AC_SUBST(base_machine)
521 if test "$base_machine" = "i386"; then
522 AC_DEFINE(USE_REGPARMS)
523 fi
525 # For the multi-arch option we need support in the assembler.
526 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
527 libc_cv_asm_gnu_indirect_function, [dnl
528 cat > conftest.s <<EOF
529 .type foo,%gnu_indirect_function
530 EOF
531 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
532 then
533 libc_cv_asm_gnu_indirect_function=yes
534 else
535 libc_cv_asm_gnu_indirect_function=no
536 fi
537 rm -f conftest*])
539 AC_MSG_CHECKING(whether .text pseudo-op must be used)
540 AC_CACHE_VAL(libc_cv_dot_text, [dnl
541 cat > conftest.s <<EOF
542 .text
543 EOF
544 libc_cv_dot_text=
545 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
546 libc_cv_dot_text=.text
547 fi
548 rm -f conftest*])
549 if test -z "$libc_cv_dot_text"; then
550 AC_MSG_RESULT(no)
551 else
552 AC_MSG_RESULT(yes)
553 fi
555 AC_CACHE_CHECK(for assembler global-symbol directive,
556 libc_cv_asm_global_directive, [dnl
557 libc_cv_asm_global_directive=UNKNOWN
558 for ac_globl in .globl .global .EXPORT; do
559 cat > conftest.s <<EOF
560 ${libc_cv_dot_text}
561 ${ac_globl} foo
562 foo:
563 EOF
564 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
565 libc_cv_asm_global_directive=${ac_globl}
566 fi
567 rm -f conftest*
568 test $libc_cv_asm_global_directive != UNKNOWN && break
569 done])
570 if test $libc_cv_asm_global_directive = UNKNOWN; then
571 AC_MSG_ERROR(cannot determine asm global directive)
572 else
573 AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
574 fi
576 AC_CACHE_CHECK(for assembler .type directive prefix,
577 libc_cv_asm_type_prefix, [dnl
578 libc_cv_asm_type_prefix=no
579 for ac_try_prefix in '@' '%' '#'; do
580 cat > conftest.s <<EOF
581 ${libc_cv_dot_text}
582 ${libc_cv_asm_global_directive} foo
583 .type foo, ${ac_try_prefix}object
584 .size foo, 1
585 foo:
586 .byte 1
587 EOF
588 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
589 libc_cv_asm_type_prefix=${ac_try_prefix}
590 fi
591 rm -f conftest*
592 test "x$libc_cv_asm_type_prefix" != xno && break
593 done])
594 if test "x$libc_cv_asm_type_prefix" != xno; then
595 AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
596 fi
598 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -o x"$libc_cv_asm_type_prefix" = xno; then
599 if test x"$multi_arch" = xyes; then
600 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
601 else
602 multi_arch=no
603 fi
604 fi
605 if test x"$multi_arch" != xno; then
606 multi_arch_d=/multiarch
607 fi
609 # Compute the list of sysdep directories for this configuration.
610 # This can take a while to compute.
611 sysdep_dir=$srcdir/sysdeps
612 AC_MSG_CHECKING(sysdep dirs)
613 dnl We need to use [ and ] for other purposes for a while now.
614 changequote(,)dnl
615 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
616 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
618 test "x$base_os" != x || case "$os" in
619 gnu*)
620 base_os=mach/hurd ;;
621 linux*)
622 base_os=unix/sysv ;;
623 esac
625 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
626 tail=$os
627 ostry=$os
628 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
629 ostry="$ostry /$o"
630 tail=$o
631 done
632 o=`echo $tail | sed 's/[0-9]*$//'`
633 if test $o != $tail; then
634 ostry="$ostry /$o"
635 fi
636 # For linux-gnu, try linux-gnu, then linux.
637 o=`echo $tail | sed 's/-.*$//'`
638 if test $o != $tail; then
639 ostry="$ostry /$o"
640 fi
642 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
643 base=
644 tail=$base_os
645 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
646 set $b
647 base="$base /$1"
648 tail="$2"
649 done
651 # For sparc/sparc32, try sparc/sparc32 and then sparc.
652 mach=
653 tail=$machine${submachine:+/$submachine}
654 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
655 set $m
656 # Prepend the machine's FPU directory unless --without-fp.
657 if test "$with_fp" = yes; then
658 mach="$mach /$1/fpu"
659 else
660 mach="$mach /$1/nofpu"
661 fi
662 mach="$mach /$1"
663 tail="$2"
664 done
666 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
667 changequote([,])dnl
669 # Find what sysdep directories exist.
670 sysnames_add_ons=
671 sysnames=
672 for b in $base ''; do
673 for m0 in $mach ''; do
674 for v in /$vendor ''; do
675 test "$v" = / && continue
676 for o in /$ostry ''; do
677 test "$o" = / && continue
678 for m in $multi_arch_d $mach ''; do
679 for d in $add_ons_pfx ''; do
680 for a in $add_ons_sfx ''; do
681 if test -n "$m0$m0sub$b$v$o$m$msub"; then
682 try_srcdir="${srcdir}/"
683 case "$d" in
684 /*) try_srcdir= ;;
685 esac
686 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
687 test -n "$enable_debug_configure" &&
688 echo "$0 [DEBUG]: try $try" >&2
689 if test -d "$try_srcdir$try"; then
690 sysnames="$sysnames $try"
691 { test -n "$o" || test -n "$b"; } && os_used=t
692 { test -n "$m" || test -n "$m0"; } && machine_used=t
693 case x${m0:-$m} in
694 x*/$submachine) submachine_used=t ;;
695 esac
696 if test -n "$d"; then
697 case "$sysnames_add_ons" in
698 *" $d "*) ;;
699 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
700 esac
701 fi
702 fi
703 fi
704 done
705 done
706 done
707 done
708 done
709 done
710 done
712 # If the assembler supports gnu_indirect_function symbol type and the
713 # architecture supports multi-arch, we enable multi-arch by default.
714 case $sysnames_add_ons$sysnames in
715 *"$multi_arch_d"*)
716 ;;
717 *)
718 test x"$multi_arch" = xdefault && multi_arch=no
719 ;;
720 esac
721 if test x"$multi_arch" != xno; then
722 AC_DEFINE(USE_MULTIARCH)
723 fi
724 AC_SUBST(multi_arch)
726 if test -z "$os_used" && test "$os" != none; then
727 AC_MSG_ERROR(Operating system $os is not supported.)
728 fi
729 if test -z "$machine_used" && test "$machine" != none; then
730 AC_MSG_ERROR(The $machine is not supported.)
731 fi
732 if test -z "$submachine_used" && test -n "$submachine"; then
733 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
734 fi
735 AC_SUBST(submachine)
737 # We have now validated the configuration.
739 # Expand the list of system names into a full list of directories
740 # from each element's parent name and Implies file (if present).
741 set $sysnames
742 names=
743 while test $# -gt 0; do
744 name=$1
745 shift
747 case " $names " in *" $name "*)
748 # Already in the list.
749 continue
750 esac
752 # Report each name as we discover it, so there is no long pause in output.
753 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
755 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
757 case $name in
758 /*) xsrcdir= ;;
759 *) xsrcdir=$srcdir/ ;;
760 esac
761 test -n "$enable_debug_configure" &&
762 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
764 if test -f $xsrcdir$name/Implies; then
765 # Collect more names from the `Implies' file (removing comments).
766 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
767 implied=
768 for x in $implied_candidate; do
769 found=no
770 if test -d $xsrcdir$name_base/$x; then
771 implied="$implied $name_base/$x";
772 found=yes
773 fi
774 for d in $add_ons_pfx ''; do
775 try="${d}sysdeps/$x"
776 case $d in
777 /*) try_srcdir= ;;
778 *) try_srcdir=$srcdir/ ;;
779 esac
780 test -n "$enable_debug_configure" &&
781 echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
782 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
783 then
784 implied="$implied $try"
785 found=yes
786 case "$sysnames_add_ons" in
787 *" $d "*) ;;
788 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
789 esac
790 fi
791 done
792 if test $found = no; then
793 AC_MSG_WARN($name/Implies specifies nonexistent $x)
794 fi
795 done
796 else
797 implied=
798 fi
800 # Add NAME to the list of names.
801 names="$names $name"
803 # Find the parent of NAME, using the empty string if it has none.
804 changequote(,)dnl
805 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
806 changequote([,])dnl
808 # Add the names implied by NAME, and NAME's parent (if it has one), to
809 # the list of names to be processed (the argument list). We prepend the
810 # implied names to the list and append the parent. We want implied
811 # directories to come before further directories inferred from the
812 # configuration components; this ensures that for sysv4, unix/common
813 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
814 # after sysv4).
815 sysnames="`echo $implied $* $parent`"
816 test -n "$sysnames" && set $sysnames
817 done
819 # Add the default directories.
820 default_sysnames="sysdeps/generic"
821 sysnames="$names $default_sysnames"
822 AC_SUBST(sysnames)
823 # The other names were emitted during the scan.
824 AC_MSG_RESULT($default_sysnames)
826 # Collect the list of add-ons that supply partial sysdeps trees.
827 sysdeps_add_ons=
828 for add_on in $add_ons; do
829 case "$add_on" in
830 /*) xsrcdir= ;;
831 *) xsrcdir="$srcdir/" ;;
832 esac
834 test -d "$xsrcdir$add_on/sysdeps" || {
835 case "$configured_add_ons " in
836 *" $add_on "*) ;;
837 *|'')
838 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
839 ;;
840 esac
841 continue
842 }
844 sysdeps_add_ons="$sysdeps_add_ons $add_on"
845 case "$sysnames_add_ons" in
846 *" $add_on/ "*) ;;
847 *|'')
848 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
849 continue ;;
850 esac
852 found=no
853 for d in $sysnames; do
854 case "$d" in
855 $add_on/sysdeps/*) ;;
856 *) continue ;;
857 esac
858 (cd "$xsrcdir$d" && for f in *[[!~]]; do
859 case "$f" in
860 sys|bits)
861 for ff in $f/*.h; do
862 test -d "$ff" || { test -e "$ff" && exit 88; }
863 done
864 ;;
865 *)
866 test -d "$f" || { test -e "$f" && exit 88; }
867 ;;
868 esac
869 done)
870 if test $? -eq 88; then
871 found=yes
872 break
873 fi
874 done
875 if test $found = no; then
876 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
877 fi
878 done
879 AC_SUBST(sysdeps_add_ons)
882 ### Locate tools.
884 AC_PROG_INSTALL
885 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
886 # The makefiles need to use a different form to find it in $srcdir.
887 INSTALL='\$(..)./scripts/install-sh -c'
888 fi
889 AC_PROG_LN_S
891 LIBC_PROG_BINUTILS
892 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
894 # Accept binutils 2.20 or newer.
895 AC_CHECK_PROG_VER(AS, $AS, --version,
896 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
897 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
898 AC_CHECK_PROG_VER(LD, $LD, --version,
899 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
900 [2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
902 # These programs are version sensitive.
903 AC_CHECK_TOOL_PREFIX
904 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
905 [version \([egcygnustpi-]*[0-9.]*\)], [4.[3-9].* | 4.[1-9][0-9].* | [5-9].* ],
906 critic_missing="$critic_missing gcc")
907 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
908 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
909 [3.79* | 3.[89]*], critic_missing="$critic_missing make")
911 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
912 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
913 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
914 MSGFMT=: aux_missing="$aux_missing msgfmt")
915 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
916 [GNU texinfo.* \([0-9][0-9.]*\)],
917 [4.*],
918 MAKEINFO=: aux_missing="$aux_missing makeinfo")
919 AC_CHECK_PROG_VER(SED, sed, --version,
920 [GNU sed version \([0-9]*\.[0-9.]*\)],
921 [3.0[2-9]*|3.[1-9]*|[4-9]*],
922 SED=: aux_missing="$aux_missing sed")
924 AC_CHECK_TOOL(READELF, readelf, false)
926 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
927 case "x$AUTOCONF" in
928 xno|x|x:) AUTOCONF=no ;;
929 *)
930 AC_CACHE_CHECK(dnl
931 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
932 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
933 libc_cv_autoconf_works=yes
934 else
935 libc_cv_autoconf_works=no
936 fi])
937 test $libc_cv_autoconf_works = yes || AUTOCONF=no
938 ;;
939 esac
940 if test "x$AUTOCONF" = xno; then
941 aux_missing="$aux_missing autoconf"
942 fi
944 test -n "$critic_missing" && AC_MSG_ERROR([
945 *** These critical programs are missing or too old:$critic_missing
946 *** Check the INSTALL file for required versions.])
948 test -n "$aux_missing" && AC_MSG_WARN([
949 *** These auxiliary programs are missing or incompatible versions:$aux_missing
950 *** some features will be disabled.
951 *** Check the INSTALL file for required versions.])
953 # if using special system headers, find out the compiler's sekrit
954 # header directory and add that to the list. NOTE: Only does the right
955 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
956 if test -n "$sysheaders"; then
957 SYSINCLUDES=-nostdinc
958 for d in include include-fixed; do
959 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
960 SYSINCLUDES="$SYSINCLUDES -isystem $i"
961 done
962 SYSINCLUDES="$SYSINCLUDES \
963 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
964 if test -n "$CXX"; then
965 CXX_SYSINCLUDES=
966 cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
967 cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
968 for d in include "$cxxmachine/include"; do
969 i=../../../../$d/c++/$cxxversion
970 cxxheaders=`$CXX -print-file-name="$i"` &&
971 test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
972 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
973 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
974 done
975 fi
976 fi
977 AC_SUBST(SYSINCLUDES)
978 AC_SUBST(CXX_SYSINCLUDES)
980 # Test if LD_LIBRARY_PATH contains the notation for the current directory
981 # since this would lead to problems installing/building glibc.
982 # LD_LIBRARY_PATH contains the current directory if one of the following
983 # is true:
984 # - one of the terminals (":" and ";") is the first or last sign
985 # - two terminals occur directly after each other
986 # - the path contains an element with a dot in it
987 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
988 changequote(,)dnl
989 case ${LD_LIBRARY_PATH} in
990 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
991 ld_library_path_setting="contains current directory"
992 ;;
993 *)
994 ld_library_path_setting="ok"
995 ;;
996 esac
997 changequote([,])dnl
998 AC_MSG_RESULT($ld_library_path_setting)
999 if test "$ld_library_path_setting" != "ok"; then
1000 AC_MSG_ERROR([
1001 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1002 *** building glibc. Please change the environment variable
1003 *** and run configure again.])
1004 fi
1006 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1007 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1008 libc_cv_gcc_static_libgcc=
1009 else
1010 libc_cv_gcc_static_libgcc=-static-libgcc
1011 fi])
1012 AC_SUBST(libc_cv_gcc_static_libgcc)
1014 AC_PATH_PROG(BASH_SHELL, bash, no)
1015 if test "$BASH_SHELL" != no &&
1016 $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1017 && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1018 libc_cv_have_bash2=yes
1019 else
1020 libc_cv_have_bash2=no
1021 fi
1022 AC_SUBST(libc_cv_have_bash2)
1024 dnl We need a ksh compatible shell for tzselect.
1025 if test "$BASH_SHELL" = no; then
1026 AC_PATH_PROG(KSH, ksh, no)
1027 if test "$KSH" = no; then
1028 libc_cv_have_ksh=no
1029 else
1030 libc_cv_have_ksh=yes
1031 fi
1032 else
1033 KSH="$BASH_SHELL"
1034 AC_SUBST(KSH)
1035 libc_cv_have_ksh=yes
1036 fi
1037 AC_SUBST(libc_cv_have_ksh)
1039 AC_PROG_AWK
1040 AC_PATH_PROG(PERL, perl, no)
1041 if test "$PERL" != no &&
1042 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1043 PERL=no
1044 fi
1045 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1046 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1047 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1049 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1050 AC_TRY_COMPILE(dnl
1051 [#define __need_size_t
1052 #define __need_wchar_t
1053 #include <stddef.h>
1054 #define __need_NULL
1055 #include <stddef.h>], [size_t size; wchar_t wchar;
1056 #ifdef offsetof
1057 #error stddef.h ignored __need_*
1058 #endif
1059 if (&size == NULL || &wchar == NULL) abort ();],
1060 libc_cv_friendly_stddef=yes,
1061 libc_cv_friendly_stddef=no)])
1062 if test $libc_cv_friendly_stddef = yes; then
1063 config_vars="$config_vars
1064 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1065 fi
1067 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1068 libc_cv_need_minus_P, [dnl
1069 cat > conftest.S <<EOF
1070 #include "confdefs.h"
1071 /* Nothing whatsoever. */
1072 EOF
1073 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1074 libc_cv_need_minus_P=no
1075 else
1076 libc_cv_need_minus_P=yes
1077 fi
1078 rm -f conftest*])
1079 if test $libc_cv_need_minus_P = yes; then
1080 config_vars="$config_vars
1081 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1082 fi
1084 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1085 cat > conftest.s <<EOF
1086 ${libc_cv_dot_text}
1087 foo:
1088 .set glibc_conftest_frobozz,foo
1089 $libc_cv_asm_global_directive glibc_conftest_frobozz
1090 EOF
1091 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1092 # (but it doesn't work), so we must do a linking check to be sure.
1093 cat > conftest1.c <<\EOF
1094 extern int glibc_conftest_frobozz;
1095 void _start() { glibc_conftest_frobozz = 1; }
1096 EOF
1097 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1098 -nostartfiles -nostdlib \
1099 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1100 libc_cv_asm_set_directive=yes
1101 else
1102 libc_cv_asm_set_directive=no
1103 fi
1104 rm -f conftest*])
1105 if test $libc_cv_asm_set_directive = yes; then
1106 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1107 fi
1109 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1110 libc_cv_asm_unique_object, [dnl
1111 cat > conftest.s <<EOF
1112 ${libc_cv_dot_text}
1113 _sym:
1114 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1115 EOF
1116 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1117 libc_cv_asm_unique_object=yes
1118 else
1119 libc_cv_asm_unique_object=no
1120 fi
1121 rm -f conftest*])
1122 if test $libc_cv_asm_unique_object = yes; then
1123 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1124 fi
1126 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1127 [cat > conftest.s <<EOF
1128 ${libc_cv_dot_text}
1129 _sym:
1130 .symver _sym,sym@VERS
1131 EOF
1132 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1133 libc_cv_asm_symver_directive=yes
1134 else
1135 libc_cv_asm_symver_directive=no
1136 fi
1137 rm -f conftest*])
1138 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1139 if test $libc_cv_asm_symver_directive = yes; then
1140 cat > conftest.s <<EOF
1141 ${libc_cv_dot_text}
1142 _sym:
1143 .symver _sym,sym@VERS
1144 EOF
1145 cat > conftest.map <<EOF
1146 VERS_1 {
1147 global: sym;
1148 };
1150 VERS_2 {
1151 global: sym;
1152 } VERS_1;
1153 EOF
1154 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1155 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1156 -o conftest.so conftest.o
1157 -nostartfiles -nostdlib
1158 -Wl,--version-script,conftest.map
1159 1>&AS_MESSAGE_LOG_FD]);
1160 then
1161 libc_cv_ld_version_script_option=yes
1162 else
1163 libc_cv_ld_version_script_option=no
1164 fi
1165 else
1166 libc_cv_ld_version_script_option=no
1167 fi
1168 else
1169 libc_cv_ld_version_script_option=no
1170 fi
1171 rm -f conftest*])
1172 if test $shared != no &&
1173 test $libc_cv_asm_symver_directive = yes &&
1174 test $libc_cv_ld_version_script_option = yes &&
1175 test $enable_versioning = yes; then
1176 VERSIONING=yes
1177 AC_DEFINE(DO_VERSIONING)
1178 else
1179 VERSIONING=no
1180 fi
1181 AC_SUBST(VERSIONING)
1183 if test $shared != no && test $VERSIONING = no; then
1184 echo "\
1185 *** WARNING: You should not compile GNU libc without versioning. Not using
1186 *** versioning will introduce incompatibilities so that old binaries
1187 *** will not run anymore.
1188 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1189 fi
1190 AC_CACHE_CHECK(for .previous assembler directive,
1191 libc_cv_asm_previous_directive, [dnl
1192 cat > conftest.s <<EOF
1193 .section foo_section
1194 .previous
1195 EOF
1196 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1197 libc_cv_asm_previous_directive=yes
1198 else
1199 libc_cv_asm_previous_directive=no
1200 fi
1201 rm -f conftest*])
1202 if test $libc_cv_asm_previous_directive = yes; then
1203 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1204 else
1205 AC_CACHE_CHECK(for .popsection assembler directive,
1206 libc_cv_asm_popsection_directive, [dnl
1207 cat > conftest.s <<EOF
1208 .pushsection foo_section
1209 .popsection
1210 EOF
1211 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1212 libc_cv_asm_popsection_directive=yes
1213 else
1214 libc_cv_asm_popsection_directive=no
1215 fi
1216 rm -f conftest*])
1217 if test $libc_cv_asm_popsection_directive = yes; then
1218 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1219 fi
1220 fi
1221 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1222 libc_cv_asm_protected_directive, [dnl
1223 cat > conftest.s <<EOF
1224 .protected foo
1225 foo:
1226 .hidden bar
1227 bar:
1228 EOF
1229 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1230 libc_cv_asm_protected_directive=yes
1231 else
1232 AC_MSG_ERROR(assembler support for symbol visibility is required)
1233 fi
1234 rm -f conftest*])
1236 if test $libc_cv_asm_protected_directive = yes; then
1237 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1238 libc_cv_visibility_attribute,
1239 [cat > conftest.c <<EOF
1240 int foo __attribute__ ((visibility ("hidden"))) = 1;
1241 int bar __attribute__ ((visibility ("protected"))) = 1;
1242 EOF
1243 libc_cv_visibility_attribute=no
1244 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1245 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1246 if grep '\.protected.*bar' conftest.s >/dev/null; then
1247 libc_cv_visibility_attribute=yes
1248 fi
1249 fi
1250 fi
1251 rm -f conftest.{c,s}
1252 ])
1253 if test $libc_cv_visibility_attribute != yes; then
1254 AC_MSG_ERROR(compiler support for visibility attribute is required)
1255 fi
1256 fi
1258 if test $libc_cv_visibility_attribute = yes; then
1259 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1260 libc_cv_broken_visibility_attribute,
1261 [cat > conftest.c <<EOF
1262 int foo (int x);
1263 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1264 int bar (int x) { return x; }
1265 EOF
1266 libc_cv_broken_visibility_attribute=yes
1267 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1268 changequote(,)dnl
1269 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1270 changequote([,])dnl
1271 libc_cv_broken_visibility_attribute=no
1272 fi
1273 fi
1274 rm -f conftest.c conftest.s
1275 ])
1276 if test $libc_cv_broken_visibility_attribute = yes; then
1277 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1278 fi
1279 fi
1281 AC_CACHE_CHECK(for broken __attribute__((alias())),
1282 libc_cv_broken_alias_attribute,
1283 [cat > conftest.c <<EOF
1284 extern int foo (int x) __asm ("xyzzy");
1285 int bar (int x) { return x; }
1286 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1287 extern int dfoo;
1288 extern __typeof (dfoo) dfoo __asm ("abccb");
1289 int dfoo = 1;
1290 EOF
1291 libc_cv_broken_alias_attribute=yes
1292 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1293 if grep 'xyzzy' conftest.s >/dev/null &&
1294 grep 'abccb' conftest.s >/dev/null; then
1295 libc_cv_broken_alias_attribute=no
1296 fi
1297 fi
1298 rm -f conftest.c conftest.s
1299 ])
1300 if test $libc_cv_broken_alias_attribute = yes; then
1301 AC_MSG_ERROR(working alias attribute support required)
1302 fi
1304 if test $libc_cv_visibility_attribute = yes; then
1305 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1306 libc_cv_have_sdata_section,
1307 [echo "int i;" > conftest.c
1308 libc_cv_have_sdata_section=no
1309 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1310 | grep '\.sdata' >/dev/null; then
1311 libc_cv_have_sdata_section=yes
1312 fi
1313 rm -f conftest.c conftest.so
1314 ])
1315 if test $libc_cv_have_sdata_section = yes; then
1316 AC_DEFINE(HAVE_SDATA_SECTION)
1317 fi
1318 fi
1320 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1321 libc_cv_initfini_array, [dnl
1322 LIBC_TRY_LINK_STATIC([
1323 int foo (void) { return 1; }
1324 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1325 ],
1326 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1327 libc_cv_initfini_array=yes
1328 else
1329 libc_cv_initfini_array=no
1330 fi],
1331 [libc_cv_initfini_array=no])
1332 ])
1333 if test $libc_cv_initfini_array != yes; then
1334 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1335 fi
1337 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1338 libc_cv_ctors_header, [dnl
1339 libc_cv_ctors_header=yes
1340 LIBC_TRY_LINK_STATIC([
1341 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1342 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1343 ],
1344 [dnl
1345 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1346 { gsub(/\@<:@ */, "@<:@") }
1347 $2 == ".ctors" || $2 == ".dtors" {
1348 size = strtonum("0x" $6)
1349 align = strtonum("0x" $NF)
1350 seen@<:@$2@:>@ = 1
1351 stub@<:@$2@:>@ = size == align * 2
1352 }
1353 END {
1354 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1355 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1356 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1357 }
1358 '], [libc_cv_ctors_header=no])
1359 ], [dnl
1360 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1361 ])
1362 ])
1363 if test $libc_cv_ctors_header = no; then
1364 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1365 fi
1367 AC_CACHE_CHECK(for libunwind-support in compiler,
1368 libc_cv_cc_with_libunwind, [
1369 cat > conftest.c <<EOF
1370 int main (void) { return 0; }
1371 EOF
1372 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1373 conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1374 libc_cv_cc_with_libunwind=yes
1375 else
1376 libc_cv_cc_with_libunwind=no
1377 fi
1378 rm -f conftest*])
1379 AC_SUBST(libc_cv_cc_with_libunwind)
1380 if test $libc_cv_cc_with_libunwind = yes; then
1381 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1382 fi
1384 AC_CACHE_CHECK(for -z nodelete option,
1385 libc_cv_z_nodelete, [dnl
1386 cat > conftest.c <<EOF
1387 int _start (void) { return 42; }
1388 EOF
1389 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1390 -fPIC -shared -o conftest.so conftest.c
1391 -nostartfiles -nostdlib
1392 -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1393 then
1394 libc_cv_z_nodelete=yes
1395 else
1396 AC_MSG_ERROR(linker with -z nodelete support required)
1397 fi
1398 rm -f conftest*])
1400 AC_CACHE_CHECK(for -z nodlopen option,
1401 libc_cv_z_nodlopen, [dnl
1402 cat > conftest.c <<EOF
1403 int _start (void) { return 42; }
1404 EOF
1405 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1406 -fPIC -shared -o conftest.so conftest.c
1407 -nostartfiles -nostdlib
1408 -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1409 then
1410 libc_cv_z_nodlopen=yes
1411 else
1412 AC_MSG_ERROR(linker with -z nodlopen support required)
1413 fi
1414 rm -f conftest*])
1416 AC_CACHE_CHECK(for -z initfirst option,
1417 libc_cv_z_initfirst, [dnl
1418 cat > conftest.c <<EOF
1419 int _start (void) { return 42; }
1420 EOF
1421 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1422 -fPIC -shared -o conftest.so conftest.c
1423 -nostartfiles -nostdlib
1424 -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1425 then
1426 libc_cv_z_initfirst=yes
1427 else
1428 AC_MSG_ERROR(linker with -z initfirst support required)
1429 fi
1430 rm -f conftest*])
1432 # Add-on fragments can set these for other machines.
1433 libc_commonpagesize=${libc_commonpagesize:-no}
1434 libc_relro_required=${libc_relro_required:-no}
1435 case "$base_machine" in
1436 i[[34567]]86 | x86_64 | powerpc* | s390*)
1437 libc_commonpagesize=0x1000
1438 libc_relro_required=yes
1439 ;;
1440 sparc*)
1441 libc_commonpagesize=0x2000
1442 libc_relro_required=yes
1443 ;;
1444 esac
1446 if test $libc_commonpagesize != no; then
1447 AC_CACHE_CHECK(for -z relro option,
1448 libc_cv_z_relro, [dnl
1449 libc_cv_z_relro=no
1450 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1451 int _start (void) { return 42; }
1452 extern void _exit (int);
1453 /* Since these pointers are const, they should go in rodata.
1454 Since they refer to functions that have to be resolved by
1455 dynamic linking, they should instead go in RELRO data. */
1456 const void *const relro[] = { &_start, &_exit, 0 };
1457 /* GNU ld fails to produce RELRO data when it's very small and there is no
1458 normal writable data following it, or if only uninitialized (.bss) data
1459 follows it, or only very small writable data. */
1460 int data[0x10000] = { 1, };
1461 ]])])
1462 cat > conftest.awk <<\EOF
1463 BEGIN {
1464 result = "no"
1465 commonpagesize = strtonum(commonpagesize)
1466 }
1467 { print "LINE:", $0 > "/dev/stderr" }
1468 $1 == "GNU_RELRO" {
1469 vaddr = strtonum($3)
1470 memsz = strtonum($6)
1471 end = vaddr + memsz
1472 printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1473 vaddr, memsz, end, commonpagesize > "/dev/stderr"
1474 result = (end % commonpagesize == 0) ? "yes" : "broken"
1475 }
1476 END { print result }
1477 EOF
1478 AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1479 -fPIC -shared -o conftest.so conftest.c
1480 -nostartfiles -nostdlib
1481 -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1482 AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1483 AC_TRY_COMMAND([
1484 $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1485 conftest.ph > conftest.cps
1486 ]) &&
1487 libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1488 rm -f conftest*])
1489 if { test "x$libc_relro_required" = xyes &&
1490 test "x$libc_cv_z_relro" != xyes
1491 }
1492 then
1493 AC_MSG_ERROR(linker with -z relro support required)
1494 fi
1495 else
1496 AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1497 fi
1499 AC_CACHE_CHECK(for -Bgroup option,
1500 libc_cv_Bgroup, [dnl
1501 cat > conftest.c <<EOF
1502 int _start (void) { return 42; }
1503 EOF
1504 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1505 -fPIC -shared -o conftest.so conftest.c
1506 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1507 then
1508 libc_cv_Bgroup=yes
1509 else
1510 libc_cv_Bgroup=no
1511 fi
1512 rm -f conftest*])
1513 AC_SUBST(libc_cv_Bgroup)
1515 ASFLAGS_config=
1516 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1517 libc_cv_as_noexecstack, [dnl
1518 cat > conftest.c <<EOF
1519 void foo (void) { }
1520 EOF
1521 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1522 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1523 && grep -q .note.GNU-stack conftest.s \
1524 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1525 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1526 then
1527 libc_cv_as_noexecstack=yes
1528 else
1529 libc_cv_as_noexecstack=no
1530 fi
1531 rm -f conftest*])
1532 if test $libc_cv_as_noexecstack = yes; then
1533 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1534 fi
1535 AC_SUBST(ASFLAGS_config)
1537 AC_CACHE_CHECK(for -z combreloc,
1538 libc_cv_z_combreloc, [dnl
1539 cat > conftest.c <<EOF
1540 extern int bar (int);
1541 extern int mumble;
1542 int foo (void) { return bar (mumble); }
1543 EOF
1544 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1545 -fPIC -shared -o conftest.so conftest.c
1546 -nostdlib -nostartfiles
1547 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1548 then
1549 dnl The following test is a bit weak. We must use a tool which can test
1550 dnl cross-platform since the gcc used can be a cross compiler. Without
1551 dnl introducing new options this is not easily doable. Instead use a tool
1552 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1553 dnl look for a section named .rel.dyn.
1554 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1555 libc_cv_z_combreloc=yes
1556 else
1557 libc_cv_z_combreloc=no
1558 fi
1559 else
1560 libc_cv_z_combreloc=no
1561 fi
1562 rm -f conftest*])
1563 if test "$libc_cv_z_combreloc" = yes; then
1564 AC_DEFINE(HAVE_Z_COMBRELOC)
1565 fi
1566 AC_SUBST(libc_cv_z_combreloc)
1568 AC_CACHE_CHECK(for -z execstack,
1569 libc_cv_z_execstack, [dnl
1570 cat > conftest.c <<EOF
1571 int _start (void) { return 42; }
1572 EOF
1573 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1574 -fPIC -shared -o conftest.so conftest.c
1575 -Wl,-z,execstack -nostdlib
1576 1>&AS_MESSAGE_LOG_FD])
1577 then
1578 libc_cv_z_execstack=yes
1579 else
1580 libc_cv_z_execstack=no
1581 fi
1582 rm -f conftest*])
1583 AC_SUBST(libc_cv_z_execstack)
1585 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1586 cat > conftest.c <<EOF
1587 int foo;
1588 main () { return 0;}
1589 EOF
1590 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1591 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1592 then
1593 libc_cv_fpie=yes
1594 else
1595 libc_cv_fpie=no
1596 fi
1597 rm -f conftest*])
1599 AC_SUBST(libc_cv_fpie)
1601 AC_CACHE_CHECK(for --hash-style option,
1602 libc_cv_hashstyle, [dnl
1603 cat > conftest.c <<EOF
1604 int _start (void) { return 42; }
1605 EOF
1606 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1607 -fPIC -shared -o conftest.so conftest.c
1608 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1609 then
1610 libc_cv_hashstyle=yes
1611 else
1612 libc_cv_hashstyle=no
1613 fi
1614 rm -f conftest*])
1615 AC_SUBST(libc_cv_hashstyle)
1617 # The linker's default -shared behavior is good enough if it
1618 # does these things that our custom linker scripts ensure that
1619 # all allocated NOTE sections come first.
1620 if test "$use_default_link" = default; then
1621 AC_CACHE_CHECK([for sufficient default -shared layout],
1622 libc_cv_use_default_link, [dnl
1623 libc_cv_use_default_link=no
1624 cat > conftest.s <<\EOF
1625 .section .note.a,"a",%note
1626 .balign 4
1627 .long 4,4,9
1628 .string "GNU"
1629 .string "foo"
1630 .section .note.b,"a",%note
1631 .balign 4
1632 .long 4,4,9
1633 .string "GNU"
1634 .string "bar"
1635 EOF
1636 if AC_TRY_COMMAND([dnl
1637 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1638 ac_try=`$READELF -S conftest.so | sed -n \
1639 ['${x;p;}
1640 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1641 t a
1642 b
1643 : a
1644 H']`
1645 then
1646 libc_seen_a=no libc_seen_b=no
1647 set -- $ac_try
1648 while test $# -ge 2 -a "$1" = NOTE; do
1649 case "$2" in
1650 .note.a) libc_seen_a=yes ;;
1651 .note.b) libc_seen_b=yes ;;
1652 esac
1653 shift 2
1654 done
1655 case "$libc_seen_a$libc_seen_b" in
1656 yesyes)
1657 libc_cv_use_default_link=yes
1658 ;;
1659 *)
1660 echo >&AS_MESSAGE_LOG_FD "\
1661 $libc_seen_a$libc_seen_b from:
1662 $ac_try"
1663 ;;
1664 esac
1665 fi
1666 rm -f conftest*])
1667 use_default_link=$libc_cv_use_default_link
1668 fi
1670 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1671 if libc_cv_output_format=`
1672 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1673 then
1674 :
1675 else
1676 libc_cv_output_format=
1677 fi
1678 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1679 AC_SUBST(libc_cv_output_format)
1681 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1682 cat > conftest.c <<EOF
1683 int foo;
1684 EOF
1685 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1686 conftest.c 1>&AS_MESSAGE_LOG_FD])
1687 then
1688 libc_cv_fno_toplevel_reorder=yes
1689 else
1690 libc_cv_fno_toplevel_reorder=no
1691 fi
1692 rm -f conftest*])
1693 if test $libc_cv_fno_toplevel_reorder = yes; then
1694 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1695 else
1696 fno_unit_at_a_time=-fno-unit-at-a-time
1697 fi
1698 AC_SUBST(fno_unit_at_a_time)
1700 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1701 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1702 [libc_cv_ssp=yes],
1703 [libc_cv_ssp=no])
1704 ])
1705 AC_SUBST(libc_cv_ssp)
1707 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1708 cat > conftest.c <<EOF
1709 int foo;
1710 #ifdef __GNUC_GNU_INLINE__
1711 main () { return 0;}
1712 #else
1713 #error
1714 #endif
1715 EOF
1716 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1717 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1718 then
1719 libc_cv_gnu89_inline=yes
1720 else
1721 libc_cv_gnu89_inline=no
1722 fi
1723 rm -f conftest*])
1724 if test $libc_cv_gnu89_inline = yes; then
1725 gnu89_inline=-fgnu89-inline
1726 else
1727 gnu89_inline=
1728 fi
1729 AC_SUBST(gnu89_inline)
1731 AC_CACHE_CHECK(whether cc puts quotes around section names,
1732 libc_cv_have_section_quotes,
1733 [cat > conftest.c <<EOF
1734 static const int foo
1735 __attribute__ ((section ("bar"))) = 1;
1736 EOF
1737 if ${CC-cc} -S conftest.c -o conftest.s; then
1738 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1739 libc_cv_have_section_quotes=yes
1740 else
1741 libc_cv_have_section_quotes=no
1742 fi
1743 else
1744 libc_cv_have_section_quotes=unknown
1745 fi
1746 rm -f conftest.{c,s}
1747 ])
1748 if test $libc_cv_have_section_quotes = yes; then
1749 AC_DEFINE(HAVE_SECTION_QUOTES)
1750 fi
1752 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1753 [dnl
1754 cat > conftest.s <<EOF
1755 ${libc_cv_dot_text}
1756 ${libc_cv_asm_global_directive} foo
1757 foo:
1758 .weak foo
1759 .weak bar; bar = foo
1760 EOF
1761 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1762 libc_cv_asm_weak_directive=yes
1763 else
1764 libc_cv_asm_weak_directive=no
1765 fi
1766 rm -f conftest*])
1768 if test $libc_cv_asm_weak_directive = no; then
1769 AC_CACHE_CHECK(for assembler .weakext directive,
1770 libc_cv_asm_weakext_directive,
1771 [dnl
1772 cat > conftest.s <<EOF
1773 ${libc_cv_dot_text}
1774 ${libc_cv_asm_global_directive} foo
1775 foo:
1776 .weakext bar foo
1777 .weakext baz
1778 ${libc_cv_asm_global_directive} baz
1779 baz:
1780 EOF
1781 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1782 libc_cv_asm_weakext_directive=yes
1783 else
1784 libc_cv_asm_weakext_directive=no
1785 fi
1786 rm -f conftest*])
1788 fi # no .weak
1790 if test $libc_cv_asm_weak_directive = yes; then
1791 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1792 elif test $libc_cv_asm_weakext_directive = yes; then
1793 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1794 fi
1796 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1797 case $machine in
1798 sparc/sparc64*) cfi_offset=2047;;
1799 *) cfi_offset=0;;
1800 esac
1801 cat > conftest.s <<EOF
1802 .text
1803 .type func,%function
1804 func:
1805 .cfi_startproc
1806 .cfi_remember_state
1807 .cfi_rel_offset 1, $cfi_offset
1808 .cfi_endproc
1809 EOF
1810 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1811 libc_cv_asm_cfi_directives=yes
1812 else
1813 libc_cv_asm_cfi_directives=no
1814 fi
1815 rm -f conftest*])
1816 if test $libc_cv_asm_cfi_directives = yes; then
1817 AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1818 fi
1820 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1821 cat > conftest.c <<\EOF
1822 _start () {}
1823 int __eh_pc;
1824 __throw () {}
1825 EOF
1826 dnl No \ in command here because it ends up inside ''.
1827 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1828 -nostdlib -nostartfiles -Wl,--no-whole-archive
1829 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1830 libc_cv_ld_no_whole_archive=yes
1831 else
1832 libc_cv_ld_no_whole_archive=no
1833 fi
1834 rm -f conftest*])
1835 if test $libc_cv_ld_no_whole_archive = no; then
1836 AC_MSG_ERROR([support for --no-whole-archive is needed])
1837 fi
1839 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1840 cat > conftest.c <<\EOF
1841 _start () {}
1842 int __eh_pc;
1843 __throw () {}
1844 EOF
1845 dnl No \ in command here because it ends up inside ''.
1846 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1847 -nostdlib -nostartfiles -fexceptions
1848 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1849 libc_cv_gcc_exceptions=yes
1850 else
1851 libc_cv_gcc_exceptions=no
1852 fi
1853 rm -f conftest*])
1854 if test $libc_cv_gcc_exceptions = yes; then
1855 exceptions=-fexceptions
1856 fi
1857 AC_SUBST(exceptions)dnl
1859 if test "$host_cpu" = powerpc ; then
1860 # Check for a bug present in at least versions 2.8.x of GCC
1861 # and versions 1.0.x of EGCS.
1862 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1863 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1864 libc_cv_c_asmcr0_bug='no',
1865 libc_cv_c_asmcr0_bug='yes')])
1866 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1867 AC_DEFINE(BROKEN_PPC_ASM_CR0)
1868 fi
1869 fi
1871 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1872 cat > conftest.c <<\EOF
1873 void zero (void *x)
1874 {
1875 __builtin_memset (x, 0, 1000);
1876 }
1877 EOF
1878 dnl
1879 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1880 then
1881 libc_cv_gcc_builtin_memset=no
1882 else
1883 libc_cv_gcc_builtin_memset=yes
1884 fi
1885 rm -f conftest* ])
1886 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1887 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1888 fi
1890 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1891 cat > conftest.c <<\EOF
1892 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1893 char *foo (const char *a, const char *b)
1894 {
1895 return __builtin_strstr (a, b);
1896 }
1897 EOF
1898 dnl
1899 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1900 then
1901 libc_cv_gcc_builtin_redirection=yes
1902 else
1903 libc_cv_gcc_builtin_redirection=no
1904 fi
1905 rm -f conftest* ])
1906 if test "$libc_cv_gcc_builtin_redirection" = no; then
1907 AC_MSG_ERROR([support for the symbol redirection needed])
1908 fi
1910 dnl Check whether the compiler supports the __thread keyword.
1911 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1912 [cat > conftest.c <<\EOF
1913 __thread int a = 42;
1914 EOF
1915 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1916 libc_cv_gcc___thread=yes
1917 else
1918 libc_cv_gcc___thread=no
1919 fi
1920 rm -f conftest*])
1921 if test "$libc_cv_gcc___thread" = no; then
1922 AC_MSG_ERROR([support for the __thread keyword is required])
1923 fi
1925 dnl Check whether the compiler supports the tls_model attribute.
1926 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1927 cat > conftest.c <<\EOF
1928 extern __thread int a __attribute__((tls_model ("initial-exec")));
1929 EOF
1930 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1931 libc_cv_gcc_tls_model_attr=yes
1932 else
1933 libc_cv_gcc_tls_model_attr=no
1934 fi
1935 rm -f conftest*])
1936 if test "$libc_cv_gcc_tls_model_attr" = no; then
1937 AC_MSG_ERROR([support for the tls_model attribute is required])
1938 fi
1940 dnl Determine how to disable generation of FMA instructions.
1941 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1942 libc_cv_cc_nofma, [dnl
1943 libc_cv_cc_nofma=
1944 for opt in -ffp-contract=off -mno-fused-madd; do
1945 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1946 done])
1948 if test -n "$submachine"; then
1949 AC_CACHE_CHECK([for compiler option for CPU variant],
1950 libc_cv_cc_submachine, [dnl
1951 libc_cv_cc_submachine=no
1952 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1953 LIBC_TRY_CC_OPTION([$opt], [
1954 libc_cv_cc_submachine="$opt"
1955 break], [])
1956 done])
1957 if test "x$libc_cv_cc_submachine" = xno; then
1958 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1959 fi
1960 fi
1961 AC_SUBST(libc_cv_cc_submachine)
1963 dnl Check whether we have the gd library available.
1964 AC_MSG_CHECKING(for libgd)
1965 if test "$with_gd" != "no"; then
1966 old_CFLAGS="$CFLAGS"
1967 CFLAGS="$CFLAGS $libgd_include"
1968 old_LDFLAGS="$LDFLAGS"
1969 LDFLAGS="$LDFLAGS $libgd_ldflags"
1970 old_LIBS="$LIBS"
1971 LIBS="$LIBS -lgd -lpng -lz -lm"
1972 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1973 CFLAGS="$old_CFLAGS"
1974 LDFLAGS="$old_LDFLAGS"
1975 LIBS="$old_LIBS"
1976 else
1977 LIBGD=no
1978 fi
1979 AC_MSG_RESULT($LIBGD)
1980 AC_SUBST(LIBGD)
1982 # SELinux detection
1983 if test x$with_selinux = xno ; then
1984 have_selinux=no;
1985 else
1986 # See if we have the SELinux library
1987 AC_CHECK_LIB(selinux, is_selinux_enabled,
1988 have_selinux=yes, have_selinux=no)
1989 # See if we have the SELinux header with the NSCD permissions in it.
1990 if test x$have_selinux = xyes ; then
1991 AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
1992 AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
1993 [#ifdef NSCD__SHMEMHOST
1994 return 0;
1995 #else
1996 #error NSCD__SHMEMHOST not defined
1997 #endif],
1998 have_selinux=yes, have_selinux=no)
1999 AC_MSG_RESULT($have_selinux)
2000 fi
2002 if test x$with_selinux = xyes ; then
2003 if test x$have_selinux = xno ; then
2004 AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2005 fi
2006 fi
2007 fi
2008 # Check if we're building with SELinux support.
2009 if test "x$have_selinux" = xyes; then
2010 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2012 # See if we have the libaudit library
2013 AC_CHECK_LIB(audit, audit_log_user_avc_message,
2014 have_libaudit=yes, have_libaudit=no)
2015 if test "x$have_libaudit" = xyes; then
2016 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2017 fi
2018 AC_SUBST(have_libaudit)
2020 # See if we have the libcap library
2021 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2022 if test "x$have_libcap" = xyes; then
2023 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2024 fi
2025 AC_SUBST(have_libcap)
2026 fi
2027 AC_SUBST(have_selinux)
2029 dnl check for the size of 'long double'.
2030 AC_CHECK_SIZEOF(long double, 0)
2031 sizeof_long_double=$ac_cv_sizeof_long_double
2032 AC_SUBST(sizeof_long_double)
2034 ### End of automated tests.
2035 ### Now run sysdeps configure fragments.
2037 # They also can set these variables.
2038 use_ldconfig=no
2039 ldd_rewrite_script=no
2040 libc_cv_sysconfdir=$sysconfdir
2041 libc_cv_gcc_unwind_find_fde=no
2042 libc_cv_idn=no
2044 # Iterate over all the sysdep directories we will use, running their
2045 # configure fragments.
2046 for dir in $sysnames; do
2047 case $dir in
2048 /*) dest=$dir ;;
2049 *) dest=$srcdir/$dir ;;
2050 esac
2051 if test -r $dest/configure; then
2052 AC_MSG_RESULT(running configure fragment for $dir)
2053 . $dest/configure
2054 fi
2055 done
2057 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2058 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2059 fi
2060 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2062 # Test for old glibc 2.0.x headers so that they can be removed properly
2063 # Search only in includedir.
2064 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2065 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2066 then
2067 old_glibc_headers=yes
2068 else
2069 old_glibc_headers=no
2070 fi
2071 AC_MSG_RESULT($old_glibc_headers)
2072 if test ${old_glibc_headers} = yes; then
2073 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2074 AC_MSG_WARN(*** be removed.)
2075 fi
2076 AC_SUBST(old_glibc_headers)
2078 AC_SUBST(libc_cv_slibdir)
2079 AC_SUBST(libc_cv_localedir)
2080 AC_SUBST(libc_cv_sysconfdir)
2081 AC_SUBST(libc_cv_rootsbindir)
2082 AC_SUBST(libc_cv_forced_unwind)
2084 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2085 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2086 AC_SUBST(libc_cv_cc_sse4)
2087 AC_SUBST(libc_cv_cc_avx)
2088 AC_SUBST(libc_cv_cc_sse2avx)
2089 AC_SUBST(libc_cv_cc_novzeroupper)
2090 AC_SUBST(libc_cv_cc_fma4)
2091 AC_SUBST(libc_cv_cc_nofma)
2092 AC_SUBST(libc_cv_as_i686)
2093 AC_SUBST(libc_cv_sparc_as_vis3)
2095 AC_SUBST(use_ldconfig)
2096 AC_SUBST(ldd_rewrite_script)
2098 AC_SUBST(static)
2099 AC_SUBST(shared)
2101 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2102 [libc_cv_pic_default=yes
2103 cat > conftest.c <<EOF
2104 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2105 # error PIC is default.
2106 #endif
2107 EOF
2108 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2109 libc_cv_pic_default=no
2110 fi
2111 rm -f conftest.*])
2112 AC_SUBST(libc_cv_pic_default)
2114 AC_SUBST(profile)
2115 AC_SUBST(static_nss)
2117 AC_SUBST(DEFINES)
2119 dnl See sysdeps/mach/configure.in for this variable.
2120 AC_SUBST(mach_interface_list)
2122 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2123 config_makefile=
2124 else
2125 config_makefile=Makefile
2126 fi
2128 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2129 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2130 AC_SUBST(VERSION)
2131 AC_SUBST(RELEASE)
2133 AC_CONFIG_FILES([config.make ${config_makefile}])
2134 AC_CONFIG_COMMANDS([default],[[
2135 case $CONFIG_FILES in *config.make*)
2136 echo "$config_vars" >> config.make;;
2137 esac
2138 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2139 AC_OUTPUT