configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Note we do not use AC_PREREQ here!  See aclocal.m4 for what we use instead.
   3 AC_INIT([GNU C Library], [(see version.h)], [https://sourceware.org/bugzilla/],
   4   [glibc], [https://www.gnu.org/software/glibc/])
   5 AC_CONFIG_SRCDIR([include/features.h])
   6 AC_CONFIG_HEADERS([config.h])
   7 AC_CONFIG_AUX_DIR([scripts])
   8
   9 ACX_PKGVERSION([GNU libc])
  10 ACX_BUGURL([https://www.gnu.org/software/libc/bugs.html])
  11 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
  12                    [Package description])
  13 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
  14                    [Bug reporting address])
  15
  16 # Glibc should not depend on any header files
  17 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  18   [m4_divert_text([DEFAULTS],
  19     [ac_includes_default='/* none */'])])
  20
  21 # We require GCC, and by default use its preprocessor.  Override AC_PROG_CPP
  22 # here to work around the Autoconf issue discussed in
  23 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
  24 AC_DEFUN([AC_PROG_CPP],
  25 [AC_REQUIRE([AC_PROG_CC])dnl
  26 AC_ARG_VAR([CPP],      [C preprocessor])dnl
  27 _AC_ARG_VAR_CPPFLAGS()dnl
  28 # On Suns, sometimes $CPP names a directory.
  29 if test -n "$CPP" && test -d "$CPP"; then
  30   CPP=
  31 fi
  32 if test -z "$CPP"; then
  33   CPP="$CC -E"
  34 fi
  35 AC_SUBST(CPP)dnl
  36 ])# AC_PROG_CPP
  37
  38 # We require GCC.  Override _AC_PROG_CC_C89 here to work around the Autoconf
  39 # issue discussed in
  40 # <https://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
  41 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
  42
  43 dnl This is here so we can set $subdirs directly based on configure fragments.
  44 AC_CONFIG_SUBDIRS()
  45
  46 AC_CANONICAL_HOST
  47
  48 AC_PROG_CC
  49 if test $host != $build; then
  50   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  51 fi
  52 AC_SUBST(cross_compiling)
  53 AC_PROG_CPP
  54 AC_CHECK_TOOL(READELF, readelf, false)
  55
  56 # We need the C++ compiler only for testing.
  57 AC_PROG_CXX
  58 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
  59 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
  60 AC_LANG_PUSH([C++])
  61 # Default, dynamic case.
  62 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
  63                [libc_cv_cxx_link_ok=yes],
  64                [libc_cv_cxx_link_ok=no])
  65 # Static case.
  66 old_LDFLAGS="$LDFLAGS"
  67 LDFLAGS="$LDFLAGS -static"
  68 AC_LINK_IFELSE([AC_LANG_SOURCE([
  69 #include <iostream>
  70
  71 int
  72 main()
  73 {
  74   std::cout << "Hello, world!";
  75   return 0;
  76 }
  77 ])],
  78                [],
  79                [libc_cv_cxx_link_ok=no])
  80 LDFLAGS="$old_LDFLAGS"
  81 AC_LANG_POP([C++])])
  82 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
  83
  84 if test "`cd $srcdir; pwd -P`" = "`pwd -P`"; then
  85   AC_MSG_ERROR([you must configure in a separate build directory])
  86 fi
  87
  88 # This will get text that should go into config.make.
  89 config_vars=
  90
  91 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  92 AC_ARG_WITH([gd],
  93             AS_HELP_STRING([--with-gd=DIR],
  94                            [find libgd include dir and library with prefix DIR]),
  95             [dnl
  96 case "$with_gd" in
  97 yes|''|no) ;;
  98 *) libgd_include="-I$withval/include"
  99    libgd_ldflags="-L$withval/lib" ;;
 100 esac
 101 ])
 102 AC_ARG_WITH([gd-include],
 103             AS_HELP_STRING([--with-gd-include=DIR],
 104                            [find libgd include files in DIR]),
 105             [dnl
 106 case "$with_gd_include" in
 107 ''|no) ;;
 108 *) libgd_include="-I$withval" ;;
 109 esac
 110 ])
 111 AC_ARG_WITH([gd-lib],
 112             AS_HELP_STRING([--with-gd-lib=DIR],
 113                            [find libgd library files in DIR]),
 114             [dnl
 115 case "$with_gd_lib" in
 116 ''|no) ;;
 117 *) libgd_ldflags="-L$withval" ;;
 118 esac
 119 ])
 120
 121 if test -n "$libgd_include"; then
 122   config_vars="$config_vars
 123 CFLAGS-memusagestat.c = $libgd_include"
 124 fi
 125 if test -n "$libgd_ldflags"; then
 126   config_vars="$config_vars
 127 libgd-LDFLAGS = $libgd_ldflags"
 128 fi
 129
 130 dnl Arguments to specify presence of other packages/features.
 131 AC_ARG_WITH([binutils],
 132             AS_HELP_STRING([--with-binutils=PATH],
 133                            [specify location of binutils (as and ld)]),
 134             [path_binutils=$withval],
 135             [path_binutils=''])
 136 AC_ARG_WITH([selinux],
 137             AS_HELP_STRING([--with-selinux],
 138                            [if building with SELinux support]),
 139             [with_selinux=$withval],
 140             [with_selinux=auto])
 141
 142 AC_ARG_WITH([headers],
 143             AS_HELP_STRING([--with-headers=PATH],
 144                            [location of system headers to use
 145                             (for example /usr/src/linux/include)
 146                             @<:@default=compiler default@:>@]),
 147             [sysheaders=$withval],
 148             [sysheaders=''])
 149 AC_SUBST(sysheaders)
 150
 151 AC_SUBST(use_default_link)
 152 AC_ARG_WITH([default-link],
 153             AS_HELP_STRING([--with-default-link],
 154                            [do not use explicit linker scripts]),
 155             [use_default_link=$withval],
 156             [use_default_link=default])
 157
 158 dnl Additional build flags injection.
 159 AC_ARG_WITH([nonshared-cflags],
 160             AS_HELP_STRING([--with-nonshared-cflags=CFLAGS],
 161                            [build nonshared libraries with additional CFLAGS]),
 162             [extra_nonshared_cflags=$withval],
 163             [extra_nonshared_cflags=])
 164 AC_SUBST(extra_nonshared_cflags)
 165
 166 AC_ARG_ENABLE([sanity-checks],
 167               AS_HELP_STRING([--disable-sanity-checks],
 168                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 169               [enable_sanity=$enableval],
 170               [enable_sanity=yes])
 171
 172 AC_ARG_ENABLE([shared],
 173               AS_HELP_STRING([--enable-shared],
 174                              [build shared library @<:@default=yes if GNU ld@:>@]),
 175               [shared=$enableval],
 176               [shared=yes])
 177 AC_ARG_ENABLE([profile],
 178               AS_HELP_STRING([--enable-profile],
 179                              [build profiled library @<:@default=no@:>@]),
 180               [profile=$enableval],
 181               [profile=no])
 182 AC_ARG_ENABLE([static-pie],
 183               AS_HELP_STRING([--enable-static-pie],
 184                              [enable static PIE support and use it in the testsuite @<:@default=no@:>@]),
 185               [static_pie=$enableval],
 186               [static_pie=no])
 187 AC_ARG_ENABLE([timezone-tools],
 188               AS_HELP_STRING([--disable-timezone-tools],
 189                              [do not install timezone tools @<:@default=install@:>@]),
 190               [enable_timezone_tools=$enableval],
 191               [enable_timezone_tools=yes])
 192 AC_SUBST(enable_timezone_tools)
 193
 194 AC_ARG_ENABLE([hardcoded-path-in-tests],
 195               AS_HELP_STRING([--enable-hardcoded-path-in-tests],
 196                              [hardcode newly built glibc path in tests @<:@default=no@:>@]),
 197               [hardcoded_path_in_tests=$enableval],
 198               [hardcoded_path_in_tests=no])
 199 AC_SUBST(hardcoded_path_in_tests)
 200
 201 AC_ARG_ENABLE([stackguard-randomization],
 202               AS_HELP_STRING([--enable-stackguard-randomization],
 203                              [initialize __stack_chk_guard canary with a random number at program start]),
 204               [enable_stackguard_randomize=$enableval],
 205               [enable_stackguard_randomize=no])
 206 if test "$enable_stackguard_randomize" = yes; then
 207   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 208 fi
 209
 210 AC_ARG_ENABLE([hidden-plt],
 211               AS_HELP_STRING([--disable-hidden-plt],
 212                              [do not hide internal function calls to avoid PLT]),
 213               [hidden=$enableval],
 214               [hidden=yes])
 215 if test "x$hidden" = xno; then
 216   AC_DEFINE(NO_HIDDEN)
 217 fi
 218
 219 AC_ARG_ENABLE([bind-now],
 220               AS_HELP_STRING([--enable-bind-now],
 221                              [disable lazy relocations in DSOs]),
 222               [bindnow=$enableval],
 223               [bindnow=no])
 224 AC_SUBST(bindnow)
 225 if test "x$bindnow" = xyes; then
 226   AC_DEFINE(BIND_NOW)
 227 fi
 228
 229 dnl Build glibc with -fstack-protector, -fstack-protector-all, or
 230 dnl -fstack-protector-strong.
 231 AC_ARG_ENABLE([stack-protector],
 232               AS_HELP_STRING([--enable-stack-protector=@<:@yes|no|all|strong@:>@],
 233                              [Use -fstack-protector[-all|-strong] to detect glibc buffer overflows]),
 234               [enable_stack_protector=$enableval],
 235               [enable_stack_protector=no])
 236 case "$enable_stack_protector" in
 237 all|yes|no|strong) ;;
 238 *) AC_MSG_ERROR([Not a valid argument for --enable-stack-protector: \"$enable_stack_protector\"]);;
 239 esac
 240
 241 dnl On some platforms we cannot use dynamic loading.  We must provide
 242 dnl static NSS modules.
 243 AC_ARG_ENABLE([static-nss],
 244               AS_HELP_STRING([--enable-static-nss],
 245                              [build static NSS modules @<:@default=no@:>@]),
 246               [static_nss=$enableval],
 247               [static_nss=no])
 248 dnl Enable static NSS also if we build no shared objects.
 249 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 250   static_nss=yes
 251   AC_DEFINE(DO_STATIC_NSS)
 252 fi
 253
 254 AC_ARG_ENABLE([force-install],
 255               AS_HELP_STRING([--disable-force-install],
 256                              [don't force installation of files from this package, even if they are older than the installed files]),
 257               [force_install=$enableval],
 258               [force_install=yes])
 259 AC_SUBST(force_install)
 260
 261 AC_ARG_ENABLE([maintainer-mode],
 262               AS_HELP_STRING([--enable-maintainer-mode],
 263                              [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
 264               [maintainer=$enableval],
 265               [maintainer=no])
 266
 267 dnl On some platforms we allow dropping compatibility with all kernel
 268 dnl versions.
 269 AC_ARG_ENABLE([kernel],
 270               AS_HELP_STRING([--enable-kernel=VERSION],
 271                              [compile for compatibility with kernel not older than VERSION]),
 272               [minimum_kernel=$enableval],
 273               [])
 274 dnl Prevent unreasonable values.
 275 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 276   # Better nothing than this.
 277   minimum_kernel=""
 278 else
 279   if test "$minimum_kernel" = current; then
 280     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 281   fi
 282 fi
 283
 284 dnl For the development we sometimes want gcc to issue even more warnings.
 285 dnl This is not the default since many of the extra warnings are not
 286 dnl appropriate.
 287 AC_ARG_ENABLE([all-warnings],
 288               AS_HELP_STRING([--enable-all-warnings],
 289                              [enable all useful warnings gcc can issue]),
 290               [all_warnings=$enableval],
 291               [])
 292 AC_SUBST(all_warnings)
 293
 294 AC_ARG_ENABLE([werror],
 295               AS_HELP_STRING([--disable-werror],
 296                              [do not build with -Werror]),
 297               [enable_werror=$enableval],
 298               [enable_werror=yes])
 299 AC_SUBST(enable_werror)
 300
 301 AC_ARG_ENABLE([multi-arch],
 302               AS_HELP_STRING([--enable-multi-arch],
 303                              [enable single DSO with optimizations for multiple architectures]),
 304               [multi_arch=$enableval],
 305               [multi_arch=default])
 306
 307 AC_ARG_ENABLE([experimental-malloc],
 308               AS_HELP_STRING([--disable-experimental-malloc],
 309                              [disable experimental malloc features]),
 310               [experimental_malloc=$enableval],
 311               [experimental_malloc=yes])
 312 AC_SUBST(experimental_malloc)
 313
 314 AC_ARG_ENABLE([memory-tagging],
 315               AS_HELP_STRING([--enable-memory-tagging],
 316                              [enable memory tagging if supported by the architecture @<:@default=no@:>@]),
 317               [memory_tagging=$enableval],
 318               [memory_tagging=no])
 319 if test "$memory_tagging" = yes; then
 320   # Only enable this on architectures that support it.
 321   case $host_cpu in
 322     aarch64)
 323       AC_DEFINE(USE_MTAG)
 324       ;;
 325   esac
 326 fi
 327 AC_SUBST(memory_tagging)
 328
 329 AC_ARG_ENABLE([crypt],
 330               AS_HELP_STRING([--disable-crypt],
 331                              [do not build nor install the passphrase hashing library, libcrypt]),
 332               [build_crypt=$enableval],
 333               [build_crypt=yes])
 334 AC_SUBST(build_crypt)
 335
 336 AC_ARG_ENABLE([nss-crypt],
 337               AS_HELP_STRING([--enable-nss-crypt],
 338                              [enable libcrypt to use nss]),
 339               [nss_crypt=$enableval],
 340               [nss_crypt=no])
 341 if test x$build_libcrypt = xno && test x$nss_crypt = xyes; then
 342   AC_MSG_WARN([--enable-nss-crypt has no effect when libcrypt is disabled])
 343   nss_crypt=no
 344 fi
 345 if test x$nss_crypt = xyes; then
 346   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 347   if test $? -ne 0; then
 348     AC_MSG_ERROR([cannot find include directory with nss-config])
 349   fi
 350   nspr_includes=-I$(nspr-config --includedir 2>/dev/null)
 351   if test $? -ne 0; then
 352     AC_MSG_ERROR([cannot find include directory with nspr-config])
 353   fi
 354   old_CFLAGS="$CFLAGS"
 355   CFLAGS="$CFLAGS $nss_includes $nspr_includes"
 356   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 357 #include <hasht.h>
 358 #include <nsslowhash.h>
 359 void f (void) { NSSLOW_Init (); }])],
 360              libc_cv_nss_crypt=yes,
 361              AC_MSG_ERROR([
 362 cannot find NSS headers with lowlevel hash function interfaces]))
 363   old_LIBS="$LIBS"
 364   old_LDFLAGS="$LDFLAGS"
 365   LIBS="$LIBS -lfreebl3"
 366   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 367 #include <hasht.h>
 368 #include <nsslowhash.h>],
 369                                   [NSSLOW_Init();])],
 370                  libc_cv_nss_crypt=yes,
 371                  AC_MSG_ERROR([
 372 cannot link program using lowlevel NSS hash functions]))
 373   # Check to see if there is a static NSS cryptographic library.
 374   # If there isn't then we can't link anything with libcrypt.a,
 375   # and that might mean disabling some static tests.
 376   LDFLAGS="$LDFLAGS -static"
 377   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 378 #include <hasht.h>
 379 #include <nsslowhash.h>],
 380                                   [NSSLOW_Init();])],
 381                  libc_cv_static_nss_crypt=yes,
 382                  libc_cv_static_nss_crypt=no)
 383   LDFLAGS="$old_LDFLAGS"
 384   CFLAGS="$old_CFLAGS"
 385   LIBS="$old_LIBS"
 386 else
 387   libc_cv_nss_crypt=no
 388   libc_cv_static_nss_crypt=no
 389 fi
 390 AC_SUBST(libc_cv_nss_crypt)
 391 AC_SUBST(libc_cv_static_nss_crypt)
 392
 393
 394 AC_ARG_ENABLE([systemtap],
 395               [AS_HELP_STRING([--enable-systemtap],
 396                [enable systemtap static probe points @<:@default=no@:>@])],
 397               [systemtap=$enableval],
 398               [systemtap=no])
 399 if test "x$systemtap" != xno; then
 400   AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
 401   old_CFLAGS="$CFLAGS"
 402   CFLAGS="-std=gnu11 $CFLAGS"
 403   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
 404 void foo (int i, void *p)
 405 {
 406   asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
 407        :: STAP_PROBE_ASM_OPERANDS (2, i, p));
 408 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
 409   CFLAGS="$old_CFLAGS"])
 410   if test $libc_cv_sdt = yes; then
 411     AC_DEFINE([USE_STAP_PROBE])
 412   elif test "x$systemtap" != xauto; then
 413     AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
 414   fi
 415 fi
 416
 417 AC_ARG_ENABLE([build-nscd],
 418               [AS_HELP_STRING([--disable-build-nscd],
 419                [disable building and installing the nscd daemon])],
 420               [build_nscd=$enableval],
 421               [build_nscd=default])
 422 AC_SUBST(build_nscd)
 423
 424 # Note the use of $use_nscd is near the bottom of the file.
 425 AC_ARG_ENABLE([nscd],
 426               [AS_HELP_STRING([--disable-nscd],
 427                [library functions will not contact the nscd daemon])],
 428               [use_nscd=$enableval],
 429               [use_nscd=yes])
 430
 431 AC_ARG_ENABLE([pt_chown],
 432               [AS_HELP_STRING([--enable-pt_chown],
 433                [Enable building and installing pt_chown])],
 434               [build_pt_chown=$enableval],
 435               [build_pt_chown=no])
 436 AC_SUBST(build_pt_chown)
 437 if test "$build_pt_chown" = yes; then
 438   AC_DEFINE(HAVE_PT_CHOWN)
 439 fi
 440
 441 AC_ARG_ENABLE([tunables],
 442               [AS_HELP_STRING([--enable-tunables],
 443                [Enable tunables support. Known values are 'yes', 'no' and 'valstring'])],
 444               [have_tunables=$enableval],
 445               [have_tunables=yes])
 446 AC_SUBST(have_tunables)
 447 if test "$have_tunables" = yes; then
 448   AC_DEFINE(HAVE_TUNABLES)
 449 fi
 450
 451 # The abi-tags file uses a fairly simplistic model for name recognition that
 452 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a
 453 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
 454 # This doesn't get used much beyond that, so it's fairly safe.
 455 case "$host_os" in
 456 linux*)
 457   ;;
 458 gnu*)
 459   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 460   ;;
 461 esac
 462
 463 AC_ARG_ENABLE([mathvec],
 464               [AS_HELP_STRING([--enable-mathvec],
 465               [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
 466               [build_mathvec=$enableval],
 467               [build_mathvec=notset])
 468
 469 AC_TRY_COMPILE([], [
 470 #ifndef __CET__
 471 # error no CET compiler support
 472 #endif],
 473                [libc_cv_compiler_default_cet=yes],
 474                [libc_cv_compiler_default_cet=no])
 475
 476 AC_ARG_ENABLE([cet],
 477               AS_HELP_STRING([--enable-cet],
 478                              [enable Intel Control-flow Enforcement Technology (CET), x86 only]),
 479               [enable_cet=$enableval],
 480               [enable_cet=$libc_cv_compiler_default_cet])
 481
 482 # We keep the original values in `$config_*' and never modify them, so we
 483 # can write them unchanged into config.make.  Everything else uses
 484 # $machine, $vendor, and $os, and changes them whenever convenient.
 485 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 486
 487 # Don't allow vendor == "unknown"
 488 test "$config_vendor" = unknown && config_vendor=
 489 config_os="`echo $config_os | sed 's/^unknown-//'`"
 490
 491 # Some configurations imply other options.
 492 elf=yes
 493
 494 # The configure fragment of a port can modify these to supplement
 495 # or override the table in the case statement below.  No fragment should
 496 # ever change the config_* variables, however.
 497 machine=$config_machine
 498 vendor=$config_vendor
 499 os=$config_os
 500 base_os=''
 501
 502 submachine=
 503 AC_ARG_WITH([cpu],
 504             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 505             [dnl
 506   case "$withval" in
 507   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 508   no) ;;
 509   *) submachine="$withval" ;;
 510   esac
 511 ])
 512
 513 # An preconfigure script can set this when it wants to disable the sanity
 514 # check below.
 515 libc_config_ok=no
 516
 517 # A preconfigure script for a system that may or may not use fpu
 518 # sysdeps directories sets this to a preprocessor conditional for
 519 # whether to use such directories.
 520 with_fp_cond=1
 521
 522 dnl Let sysdeps/*/preconfigure act here.
 523 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
 524
 525
 526 ###
 527 ### By using the undocumented --enable-hacker-mode option for configure
 528 ### one can skip this test to make the configuration not fail for unsupported
 529 ### platforms.
 530 ###
 531 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 532   case "$machine-$host_os" in
 533   *-linux* | *-gnu*)
 534     ;;
 535   *)
 536     AC_MSG_ERROR([
 537 *** The GNU C library is currently unavailable for this platform.
 538 *** If you are interested in seeing glibc on this platform visit
 539 *** the "How to submit a new port" in the wiki:
 540 ***   https://sourceware.org/glibc/wiki/#Development
 541 *** and join the community!])
 542     ;;
 543   esac
 544 fi
 545
 546 # Set base_machine if not set by a preconfigure fragment.
 547 test -n "$base_machine" || base_machine=$machine
 548 AC_SUBST(base_machine)
 549
 550 # Determine whether to use fpu or nofpu sysdeps directories.
 551 AC_CACHE_CHECK([for use of fpu sysdeps directories],
 552                libc_cv_with_fp, [dnl
 553 cat > conftest.c <<EOF
 554 #if $with_fp_cond
 555 int dummy;
 556 #else
 557 # error "no hardware floating point"
 558 #endif
 559 EOF
 560 libc_cv_with_fp=no
 561 if ${CC-cc} $CFLAGS $CPPFLAGS -S conftest.c -o conftest.s \
 562    1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 563   libc_cv_with_fp=yes
 564 fi
 565 rm -f conftest*])
 566 AC_SUBST(libc_cv_with_fp)
 567
 568 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
 569 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
 570                    [libc_cv_ssp=yes],
 571                    [libc_cv_ssp=no])
 572 ])
 573
 574 AC_CACHE_CHECK(for -fstack-protector-strong, libc_cv_ssp_strong, [dnl
 575 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-strong],
 576                    [libc_cv_ssp_strong=yes],
 577                    [libc_cv_ssp_strong=no])
 578 ])
 579
 580 AC_CACHE_CHECK(for -fstack-protector-all, libc_cv_ssp_all, [dnl
 581 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector-all],
 582                    [libc_cv_ssp_all=yes],
 583                    [libc_cv_ssp_all=no])
 584 ])
 585
 586 stack_protector=
 587 no_stack_protector=
 588 if test "$libc_cv_ssp" = yes; then
 589   no_stack_protector="-fno-stack-protector -DSTACK_PROTECTOR_LEVEL=0"
 590   AC_DEFINE(HAVE_CC_NO_STACK_PROTECTOR)
 591 fi
 592
 593 if test "$enable_stack_protector" = yes && test "$libc_cv_ssp" = yes; then
 594   stack_protector="-fstack-protector"
 595   AC_DEFINE(STACK_PROTECTOR_LEVEL, 1)
 596 elif test "$enable_stack_protector" = all && test "$libc_cv_ssp_all" = yes; then
 597   stack_protector="-fstack-protector-all"
 598   AC_DEFINE(STACK_PROTECTOR_LEVEL, 2)
 599 elif test "$enable_stack_protector" = strong && test "$libc_cv_ssp_strong" = yes; then
 600   stack_protector="-fstack-protector-strong"
 601   AC_DEFINE(STACK_PROTECTOR_LEVEL, 3)
 602 else
 603   stack_protector="-fno-stack-protector"
 604   AC_DEFINE(STACK_PROTECTOR_LEVEL, 0)
 605 fi
 606 AC_SUBST(libc_cv_ssp)
 607 AC_SUBST(stack_protector)
 608 AC_SUBST(no_stack_protector)
 609
 610 if test -n "$stack_protector"; then
 611   dnl Don't run configure tests with stack-protection on, to avoid problems with
 612   dnl bootstrapping.
 613   no_ssp=-fno-stack-protector
 614 else
 615   no_ssp=
 616
 617   if test "$enable_stack_protector" != no; then
 618     AC_MSG_ERROR([--enable-stack-protector=$enable_stack_protector specified, but specified level of stack protection is not supported by the compiler.])
 619   fi
 620 fi
 621
 622 # For the multi-arch option we need support in the assembler & linker.
 623 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
 624                libc_cv_ld_gnu_indirect_function, [dnl
 625 cat > conftest.S <<EOF
 626 .type foo,%gnu_indirect_function
 627 foo:
 628 .globl _start
 629 _start:
 630 .globl __start
 631 __start:
 632 .data
 633 #ifdef _LP64
 634 .quad foo
 635 #else
 636 .long foo
 637 #endif
 638 EOF
 639 libc_cv_ld_gnu_indirect_function=no
 640 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 641             -nostartfiles -nostdlib $no_ssp \
 642             -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
 643   # Do a link to see if the backend supports IFUNC relocs.
 644   $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
 645   LC_ALL=C $READELF -Wr conftest | grep -q 'IRELATIVE\|R_SPARC_JMP_IREL' && {
 646     libc_cv_ld_gnu_indirect_function=yes
 647   }
 648 fi
 649 rm -f conftest*])
 650
 651 # Check if gcc supports attribute ifunc as it is used in libc_ifunc macro.
 652 AC_CACHE_CHECK([for gcc attribute ifunc support],
 653                libc_cv_gcc_indirect_function, [dnl
 654 cat > conftest.c <<EOF
 655 extern int func (int);
 656 int used_func (int a)
 657 {
 658   return a;
 659 }
 660 static void *resolver ()
 661 {
 662   return &used_func;
 663 }
 664 extern __typeof (func) func __attribute__ ((ifunc ("resolver")));
 665 EOF
 666 libc_cv_gcc_indirect_function=no
 667 if ${CC-cc} -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD \
 668    2>&AS_MESSAGE_LOG_FD ; then
 669   if $READELF -s conftest.o | grep IFUNC >/dev/null 2>&AS_MESSAGE_LOG_FD; then
 670     libc_cv_gcc_indirect_function=yes
 671   fi
 672 fi
 673 rm -f conftest*])
 674
 675 # Check if linker supports textrel relocation with ifunc (used on elf/tests).
 676 # Note that it relies on libc_cv_ld_gnu_indirect_function test above.
 677 AC_CACHE_CHECK([whether the linker supports textrels along with ifunc],
 678                libc_cv_textrel_ifunc, [dnl
 679 cat > conftest.S <<EOF
 680 .type foo,%gnu_indirect_function
 681 foo:
 682 .globl _start
 683 _start:
 684 .globl __start
 685 __start:
 686 .data
 687 #ifdef _LP64
 688 .quad foo
 689 #else
 690 .long foo
 691 #endif
 692 .text
 693 .globl address
 694 address:
 695 #ifdef _LP64
 696 .quad address
 697 #else
 698 .long address
 699 #endif
 700 EOF
 701 libc_cv_textrel_ifunc=no
 702 if test $libc_cv_ld_gnu_indirect_function = yes; then
 703    if AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostartfiles -nostdlib $no_ssp -pie -o conftest conftest.S); then
 704      libc_cv_textrel_ifunc=yes
 705    fi
 706 fi
 707 rm -f conftest*])
 708 AC_SUBST(libc_cv_textrel_ifunc)
 709
 710 # Check if gcc warns about alias for function with incompatible types.
 711 AC_CACHE_CHECK([if compiler warns about alias for function with incompatible types],
 712                libc_cv_gcc_incompatible_alias, [dnl
 713 cat > conftest.c <<EOF
 714 int __redirect_foo (const void *s, int c);
 715
 716 __typeof (__redirect_foo) *foo_impl (void) __asm__ ("foo");
 717 __typeof (__redirect_foo) *foo_impl (void)
 718 {
 719   return 0;
 720 }
 721
 722 extern __typeof (__redirect_foo) foo_alias __attribute__ ((alias ("foo")));
 723 EOF
 724 libc_cv_gcc_incompatible_alias=yes
 725 if ${CC-cc} -Werror -c conftest.c -o conftest.o 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD ; then
 726   libc_cv_gcc_incompatible_alias=no
 727 fi
 728 rm -f conftest*])
 729
 730 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
 731   if test x"$multi_arch" = xyes; then
 732     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 733   else
 734     multi_arch=no
 735   fi
 736 fi
 737 if test x"$libc_cv_gcc_indirect_function" != xyes; then
 738   # GCC 8+ emits a warning for alias with incompatible types and it might
 739   # fail to build ifunc resolvers aliases to either weak or internal
 740   # symbols.  Disables multiarch build in this case.
 741   if test x"$libc_cv_gcc_incompatible_alias" == xyes; then
 742     AC_MSG_WARN([gcc emits a warning for alias between functions of incompatible types])
 743     if test x"$multi_arch" = xyes; then
 744       AC_MSG_ERROR([--enable-multi-arch support requires a gcc with gnu-indirect-function support])
 745     fi
 746     AC_MSG_WARN([Multi-arch is disabled.])
 747     multi_arch=no
 748   elif test x"$multi_arch" = xyes; then
 749     AC_MSG_WARN([--enable-multi-arch support recommends a gcc with gnu-indirect-function support.
 750 Please use a gcc which supports it by default or configure gcc with --enable-gnu-indirect-function])
 751   fi
 752 fi
 753 multi_arch_d=
 754 if test x"$multi_arch" != xno; then
 755   multi_arch_d=/multiarch
 756 fi
 757
 758 # Compute the list of sysdep directories for this configuration.
 759 # This can take a while to compute.
 760 sysdep_dir=$srcdir/sysdeps
 761 AC_MSG_CHECKING(sysdep dirs)
 762 dnl We need to use [ and ] for other purposes for a while now.
 763 changequote(,)dnl
 764 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 765 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 766
 767 test "x$base_os" != x || case "$os" in
 768 gnu*)
 769   base_os=mach/hurd ;;
 770 linux*)
 771   base_os=unix/sysv ;;
 772 esac
 773
 774 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 775 tail=$os
 776 ostry=$os
 777 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 778   ostry="$ostry /$o"
 779   tail=$o
 780 done
 781 o=`echo $tail | sed 's/[0-9]*$//'`
 782 if test $o != $tail; then
 783   ostry="$ostry /$o"
 784 fi
 785 # For linux-gnu, try linux-gnu, then linux.
 786 o=`echo $tail | sed 's/-.*$//'`
 787 if test $o != $tail; then
 788   ostry="$ostry /$o"
 789 fi
 790
 791 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 792 base=
 793 tail=$base_os
 794 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 795   set $b
 796   base="$base /$1"
 797   tail="$2"
 798 done
 799
 800 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 801 mach=
 802 tail=$machine${submachine:+/$submachine}
 803 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 804   set $m
 805   # Prepend the machine's FPU directory unless the architecture specific
 806   # preconfigure disables it.
 807   if test "$libc_cv_with_fp" = yes; then
 808     maybe_fpu=/fpu
 809   else
 810     maybe_fpu=/nofpu
 811   fi
 812   # For each machine term, try it with and then without /multiarch.
 813   for try_fpu in $maybe_fpu ''; do
 814     for try_multi in $multi_arch_d ''; do
 815       mach="$mach /$1$try_fpu$try_multi"
 816     done
 817   done
 818   tail="$2"
 819 done
 820
 821 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 822 changequote([,])dnl
 823
 824 # Find what sysdep directories exist.
 825 sysnames=
 826 for b in $base ''; do
 827   for m0 in $mach ''; do
 828     for v in /$vendor ''; do
 829       test "$v" = / && continue
 830       for o in /$ostry ''; do
 831         test "$o" = / && continue
 832         for m in $mach ''; do
 833           try_suffix="$m0$b$v$o$m"
 834           if test -n "$try_suffix"; then
 835             try_srcdir="${srcdir}/"
 836             try="sysdeps$try_suffix"
 837             test -n "$enable_debug_configure" &&
 838             echo "$0 [DEBUG]: try $try" >&2
 839             if test -d "$try_srcdir$try"; then
 840               sysnames="$sysnames $try"
 841               { test -n "$o" || test -n "$b"; } && os_used=t
 842               { test -n "$m" || test -n "$m0"; } && machine_used=t
 843               case x${m0:-$m} in
 844               x*/$submachine) submachine_used=t ;;
 845               esac
 846             fi
 847           fi
 848         done
 849       done
 850     done
 851   done
 852 done
 853
 854 # If the assembler supports gnu_indirect_function symbol type and the
 855 # architecture supports multi-arch, we enable multi-arch by default.
 856 case $sysnames in
 857 *"$multi_arch_d"*)
 858   ;;
 859 *)
 860   test x"$multi_arch" = xdefault && multi_arch=no
 861   ;;
 862 esac
 863 if test x"$multi_arch" != xno; then
 864   AC_DEFINE(USE_MULTIARCH)
 865 fi
 866 AC_SUBST(multi_arch)
 867
 868 if test -z "$os_used" && test "$os" != none; then
 869   AC_MSG_ERROR(Operating system $os is not supported.)
 870 fi
 871 if test -z "$machine_used" && test "$machine" != none; then
 872   AC_MSG_ERROR(The $machine is not supported.)
 873 fi
 874 if test -z "$submachine_used" && test -n "$submachine"; then
 875   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 876 fi
 877 AC_SUBST(submachine)
 878
 879 # We have now validated the configuration.
 880
 881 # Expand the list of system names into a full list of directories
 882 # from each element's parent name and Implies file (if present).
 883 set $sysnames
 884 names=
 885 while test $# -gt 0; do
 886   name=$1
 887   shift
 888
 889   case " $names " in *" $name "*)
 890     # Already in the list.
 891     continue
 892   esac
 893
 894   # Report each name as we discover it, so there is no long pause in output.
 895   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 896
 897   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 898
 899   case $name in
 900     /*) xsrcdir= ;;
 901     *)  xsrcdir=$srcdir/ ;;
 902   esac
 903   test -n "$enable_debug_configure" &&
 904   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 905
 906   for implies_file in Implies Implies-before Implies-after; do
 907     implies_type=`echo $implies_file | sed s/-/_/`
 908     eval ${implies_type}=
 909     if test -f $xsrcdir$name/$implies_file; then
 910       # Collect more names from the `Implies' file (removing comments).
 911       implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
 912       for x in $implied_candidate; do
 913         found=no
 914         if test -d $xsrcdir$name_base/$x; then
 915           eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
 916           found=yes
 917         fi
 918         try="sysdeps/$x"
 919         try_srcdir=$srcdir/
 920         test -n "$enable_debug_configure" &&
 921          echo "[DEBUG]: $name $implies_file $x try() {$try_srcdir}$try" >&2
 922         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 923         then
 924           eval "${implies_type}=\"\$${implies_type} \$try\""
 925           found=yes
 926         fi
 927         if test $found = no; then
 928           AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
 929         fi
 930       done
 931     fi
 932   done
 933
 934   # Add NAME to the list of names.
 935   names="$names $name"
 936
 937   # Find the parent of NAME, using the empty string if it has none.
 938 changequote(,)dnl
 939   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 940 changequote([,])dnl
 941
 942   test -n "$enable_debug_configure" &&
 943     echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
 944 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
 945
 946   # Add the names implied by NAME, and NAME's parent (if it has one), to
 947   # the list of names to be processed (the argument list).  We prepend the
 948   # implied names to the list and append the parent.  We want implied
 949   # directories to come before further directories inferred from the
 950   # configuration components; this ensures that for sysv4, unix/common
 951   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 952   # after sysv4).
 953   sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
 954   test -n "$sysnames" && set $sysnames
 955 done
 956
 957 # Add the default directories.
 958 default_sysnames="sysdeps/generic"
 959 sysnames="$names $default_sysnames"
 960 AC_SUBST(sysnames)
 961 # The other names were emitted during the scan.
 962 AC_MSG_RESULT($default_sysnames)
 963
 964
 965 ### Locate tools.
 966
 967 AC_PROG_INSTALL
 968 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 969   # The makefiles need to use a different form to find it in $srcdir.
 970   INSTALL='\$(..)./scripts/install-sh -c'
 971 fi
 972 AC_PROG_LN_S
 973
 974 LIBC_PROG_BINUTILS
 975
 976 # Accept binutils 2.25 or newer.
 977 AC_CHECK_PROG_VER(AS, $AS, --version,
 978                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 979                   [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 980                   AS=: critic_missing="$critic_missing as")
 981
 982 if test -n "`$LD --version | sed -n 's/^GNU \(gold\).*$/\1/p'`"; then
 983   # Accept gold 1.14 or higher
 984   AC_CHECK_PROG_VER(LD, $LD, --version,
 985                     [GNU gold.* \([0-9][0-9]*\.[0-9.]*\)],
 986                     [1.1[4-9]*|1.[2-9][0-9]*|1.1[0-9][0-9]*|[2-9].*|[1-9][0-9]*],
 987                     LD=: critic_missing="$critic_missing GNU gold")
 988 else
 989   AC_CHECK_PROG_VER(LD, $LD, --version,
 990                     [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 991                     [2.1[0-9][0-9]*|2.2[5-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
 992                     LD=: critic_missing="$critic_missing GNU ld")
 993 fi
 994
 995 # These programs are version sensitive.
 996 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 997   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 998   [[4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
 999
1000 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
1001   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
1002   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
1003   MSGFMT=: aux_missing="$aux_missing msgfmt")
1004 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
1005   [GNU texinfo.* \([0-9][0-9.]*\)],
1006   [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
1007   MAKEINFO=: aux_missing="$aux_missing makeinfo")
1008 AC_CHECK_PROG_VER(SED, sed, --version,
1009   [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
1010   [3.0[2-9]*|3.[1-9]*|[4-9]*],
1011   SED=: aux_missing="$aux_missing sed")
1012 AC_CHECK_PROG_VER(AWK, gawk, --version,
1013   [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
1014   [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
1015 AC_CHECK_PROG_VER(BISON, bison, --version,
1016   [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1017   [2.7*|[3-9].*|[1-9][0-9]*], critic_missing="$critic_missing bison")
1018
1019 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
1020 AC_TRY_COMPILE([], [
1021 #if !defined __GNUC__ || __GNUC__ < 6 || (__GNUC__ == 6 && __GNUC_MINOR__ < 2)
1022 #error insufficient compiler
1023 #endif],
1024                [libc_cv_compiler_ok=yes],
1025                [libc_cv_compiler_ok=no])])
1026 AS_IF([test $libc_cv_compiler_ok != yes],
1027       [critic_missing="$critic_missing compiler"])
1028
1029 AC_CHECK_TOOL(NM, nm, false)
1030
1031 if test "x$maintainer" = "xyes"; then
1032   AC_CHECK_PROGS(AUTOCONF, autoconf, no)
1033   case "x$AUTOCONF" in
1034   xno|x|x:) AUTOCONF=no ;;
1035   *)
1036     AC_CACHE_CHECK(dnl
1037   whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
1038     if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
1039       libc_cv_autoconf_works=yes
1040     else
1041       libc_cv_autoconf_works=no
1042     fi])
1043     test $libc_cv_autoconf_works = yes || AUTOCONF=no
1044     ;;
1045   esac
1046   if test "x$AUTOCONF" = xno; then
1047     aux_missing="$aux_missing autoconf"
1048   fi
1049 else
1050   AUTOCONF=no
1051 fi
1052
1053 # Check for python3 if available, or else python.
1054 AC_CHECK_PROG_VER(PYTHON_PROG, python3 python, --version,
1055   [Python \([0-9][0-9.]*\)],
1056   [3.[4-9]*|3.[1-9][0-9]*|[4-9].*|[1-9][0-9]*],
1057   critic_missing="$critic_missing python")
1058 PYTHON="$PYTHON_PROG -B"
1059 AC_SUBST(PYTHON)
1060
1061 test -n "$critic_missing" && AC_MSG_ERROR([
1062 *** These critical programs are missing or too old:$critic_missing
1063 *** Check the INSTALL file for required versions.])
1064
1065 test -n "$aux_missing" && AC_MSG_WARN([
1066 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1067 *** some features or tests will be disabled.
1068 *** Check the INSTALL file for required versions.])
1069
1070 # if using special system headers, find out the compiler's sekrit
1071 # header directory and add that to the list.  NOTE: Only does the right
1072 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1073 if test -n "$sysheaders"; then
1074   SYSINCLUDES=-nostdinc
1075   for d in include include-fixed; do
1076     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1077     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1078   done
1079   SYSINCLUDES="$SYSINCLUDES \
1080 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1081   if test -n "$CXX"; then
1082     CXX_SYSINCLUDES=
1083     for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1084     | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1085       test "x$cxxheaders" != x &&
1086       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1087     done
1088   fi
1089 fi
1090 AC_SUBST(SYSINCLUDES)
1091 AC_SUBST(CXX_SYSINCLUDES)
1092
1093 # Obtain some C++ header file paths.  This is used to make a local
1094 # copy of those headers in Makerules.
1095 if test -n "$CXX"; then
1096   find_cxx_header () {
1097     echo "#include <$1>" | $CXX -M -MP -x c++ - 2>/dev/null \
1098          | sed -n "\,$1:,{s/:\$//;p}"
1099   }
1100   CXX_CSTDLIB_HEADER="$(find_cxx_header cstdlib)"
1101   CXX_CMATH_HEADER="$(find_cxx_header cmath)"
1102   CXX_BITS_STD_ABS_H="$(find_cxx_header bits/std_abs.h)"
1103 fi
1104 AC_SUBST(CXX_CSTDLIB_HEADER)
1105 AC_SUBST(CXX_CMATH_HEADER)
1106 AC_SUBST(CXX_BITS_STD_ABS_H)
1107
1108 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1109 # since this would lead to problems installing/building glibc.
1110 # LD_LIBRARY_PATH contains the current directory if one of the following
1111 # is true:
1112 # - one of the terminals (":" and ";") is the first or last sign
1113 # - two terminals occur directly after each other
1114 # - the path contains an element with a dot in it
1115 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1116 changequote(,)dnl
1117 case ${LD_LIBRARY_PATH} in
1118   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1119     ld_library_path_setting="contains current directory"
1120     ;;
1121   *)
1122     ld_library_path_setting="ok"
1123     ;;
1124 esac
1125 changequote([,])dnl
1126 AC_MSG_RESULT($ld_library_path_setting)
1127 if test "$ld_library_path_setting" != "ok"; then
1128 AC_MSG_ERROR([
1129 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1130 *** building glibc. Please change the environment variable
1131 *** and run configure again.])
1132 fi
1133
1134 AC_PATH_PROG(BASH_SHELL, bash, no)
1135
1136 AC_PATH_PROG(PERL, perl, no)
1137 if test "$PERL" != no &&
1138    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1139   PERL=no
1140 fi
1141 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1142              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1143
1144 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1145 cat > conftest.s <<EOF
1146 .text
1147 foo:
1148 .set glibc_conftest_frobozz,foo
1149 .globl glibc_conftest_frobozz
1150 EOF
1151 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1152 # (but it doesn't work), so we must do a linking check to be sure.
1153 cat > conftest1.c <<\EOF
1154 extern int glibc_conftest_frobozz;
1155 void _start() { glibc_conftest_frobozz = 1; }
1156 EOF
1157 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1158             -nostartfiles -nostdlib $no_ssp \
1159             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1160   libc_cv_asm_set_directive=yes
1161 else
1162   libc_cv_asm_set_directive=no
1163 fi
1164 rm -f conftest*])
1165 if test $libc_cv_asm_set_directive = yes; then
1166   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1167 fi
1168
1169 AC_CACHE_CHECK(linker support for protected data symbol,
1170                libc_cv_protected_data,
1171                [cat > conftest.c <<EOF
1172                 int bar __attribute__ ((visibility ("protected"))) = 1;
1173 EOF
1174                 libc_cv_protected_data=no
1175                 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -o conftest.so); then
1176                   cat > conftest.c <<EOF
1177                   extern int bar;
1178                   int main (void) { return bar; }
1179 EOF
1180                   if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles $no_ssp conftest.c -o conftest conftest.so); then
1181                     libc_cv_protected_data=yes
1182                   fi
1183                 fi
1184                 rm -f conftest.*
1185                ])
1186 AC_SUBST(libc_cv_protected_data)
1187
1188 AC_CACHE_CHECK(linker support for INSERT in linker script,
1189                libc_cv_insert,
1190                [cat > conftest.c <<EOF
1191                 const int __attribute__ ((section(".bar"))) bar = 0x12345678;
1192                 int test (void) { return bar; }
1193 EOF
1194                 cat > conftest.t <<EOF
1195                 SECTIONS
1196                 {
1197                   .bar : { *(.bar) }
1198                 }
1199                 INSERT AFTER .rela.dyn;
1200 EOF
1201                 libc_cv_insert=no
1202                 if AC_TRY_COMMAND([${CC-cc} -nostdlib -nostartfiles $no_ssp -fPIC -shared conftest.c -Wl,-T,conftest.t -o conftest.so]); then
1203                   libc_cv_insert=yes
1204                 fi
1205                 rm -f conftest.*
1206                ])
1207 AC_SUBST(libc_cv_insert)
1208
1209 AC_CACHE_CHECK(for broken __attribute__((alias())),
1210                libc_cv_broken_alias_attribute,
1211                [cat > conftest.c <<EOF
1212                extern int foo (int x) __asm ("xyzzy");
1213                int bar (int x) { return x; }
1214                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1215                extern int dfoo;
1216                extern __typeof (dfoo) dfoo __asm ("abccb");
1217                int dfoo = 1;
1218 EOF
1219                libc_cv_broken_alias_attribute=yes
1220                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1221                  if grep 'xyzzy' conftest.s >/dev/null &&
1222                     grep 'abccb' conftest.s >/dev/null; then
1223                    libc_cv_broken_alias_attribute=no
1224                  fi
1225                fi
1226                rm -f conftest.c conftest.s
1227                ])
1228 if test $libc_cv_broken_alias_attribute = yes; then
1229   AC_MSG_ERROR(working alias attribute support required)
1230 fi
1231
1232 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1233                libc_cv_have_sdata_section,
1234                [echo "int i;" > conftest.c
1235                 libc_cv_have_sdata_section=no
1236                 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1237                    | grep '\.sdata' >/dev/null; then
1238                   libc_cv_have_sdata_section=yes
1239                 fi
1240                 rm -f conftest.c conftest.so
1241                ])
1242 if test $libc_cv_have_sdata_section = yes; then
1243   AC_DEFINE(HAVE_SDATA_SECTION)
1244 fi
1245
1246 AC_CACHE_CHECK(for libunwind-support in compiler,
1247                libc_cv_cc_with_libunwind, [
1248   cat > conftest.c <<EOF
1249 int main (void) { return 0; }
1250 EOF
1251   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1252      conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1253     libc_cv_cc_with_libunwind=yes
1254   else
1255     libc_cv_cc_with_libunwind=no
1256   fi
1257   rm -f conftest*])
1258 AC_SUBST(libc_cv_cc_with_libunwind)
1259 if test $libc_cv_cc_with_libunwind = yes; then
1260   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1261 fi
1262
1263 ASFLAGS_config=
1264 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1265                libc_cv_as_noexecstack, [dnl
1266 cat > conftest.c <<EOF
1267 void foo (void) { }
1268 EOF
1269 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1270                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1271    && grep .note.GNU-stack conftest.s >/dev/null \
1272    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1273                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1274 then
1275   libc_cv_as_noexecstack=yes
1276 else
1277   libc_cv_as_noexecstack=no
1278 fi
1279 rm -f conftest*])
1280 if test $libc_cv_as_noexecstack = yes; then
1281   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1282 fi
1283 AC_SUBST(ASFLAGS_config)
1284
1285 AC_CACHE_CHECK(for -z combreloc,
1286                libc_cv_z_combreloc, [dnl
1287 cat > conftest.c <<EOF
1288 extern int bar (int);
1289 extern int mumble;
1290 int foo (void) { return bar (mumble); }
1291 EOF
1292 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1293                         -fPIC -shared $no_ssp -o conftest.so conftest.c
1294                         -nostdlib -nostartfiles
1295                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1296 then
1297 dnl The following test is a bit weak.  We must use a tool which can test
1298 dnl cross-platform since the gcc used can be a cross compiler.  Without
1299 dnl introducing new options this is not easily doable.  Instead use a tool
1300 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1301 dnl look for a section named .rel.dyn or .rela.dyn.
1302   if $READELF -S conftest.so | grep -E '.rela?.dyn' > /dev/null; then
1303     libc_cv_z_combreloc=yes
1304   else
1305     libc_cv_z_combreloc=no
1306   fi
1307 else
1308   libc_cv_z_combreloc=no
1309 fi
1310 rm -f conftest*])
1311 if test "$libc_cv_z_combreloc" = yes; then
1312   AC_DEFINE(HAVE_Z_COMBRELOC)
1313 fi
1314 AC_SUBST(libc_cv_z_combreloc)
1315
1316 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1317                     [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1318 AC_SUBST(libc_cv_z_execstack)
1319
1320 LIBC_LINKER_FEATURE([--no-dynamic-linker],
1321                     [-Wl,--no-dynamic-linker],
1322                     [libc_cv_no_dynamic_linker=yes],
1323                     [libc_cv_no_dynamic_linker=no])
1324 LIBC_CONFIG_VAR([have-no-dynamic-linker], [$libc_cv_no_dynamic_linker])
1325
1326 AC_CACHE_CHECK(for -static-pie, libc_cv_static_pie, [dnl
1327 LIBC_TRY_CC_OPTION([-static-pie],
1328                    [libc_cv_static_pie=yes],
1329                    [libc_cv_static_pie=no])
1330 ])
1331 LIBC_CONFIG_VAR([have-static-pie], [$libc_cv_static_pie])
1332
1333 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1334 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1335 ])
1336
1337 AC_SUBST(libc_cv_fpie)
1338
1339 AC_CACHE_CHECK(for --hash-style option,
1340                libc_cv_hashstyle, [dnl
1341 cat > conftest.c <<EOF
1342 int _start (void) { return 42; }
1343 EOF
1344 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS $no_ssp
1345                             -fPIC -shared -o conftest.so conftest.c
1346                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1347 then
1348   libc_cv_hashstyle=yes
1349 else
1350   libc_cv_hashstyle=no
1351 fi
1352 rm -f conftest*])
1353 AC_SUBST(libc_cv_hashstyle)
1354
1355 # The linker's default -shared behavior is good enough if it
1356 # does these things that our custom linker scripts ensure that
1357 # all allocated NOTE sections come first.
1358 if test "$use_default_link" = default; then
1359   AC_CACHE_CHECK([for sufficient default -shared layout],
1360                   libc_cv_use_default_link, [dnl
1361   libc_cv_use_default_link=no
1362   cat > conftest.s <<\EOF
1363           .section .note.a,"a",%note
1364           .balign 4
1365           .long 4,4,9
1366           .string "GNU"
1367           .string "foo"
1368           .section .note.b,"a",%note
1369           .balign 4
1370           .long 4,4,9
1371           .string "GNU"
1372           .string "bar"
1373 EOF
1374   if AC_TRY_COMMAND([dnl
1375   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1376        ac_try=`$READELF -S conftest.so | sed -n \
1377          ['${x;p;}
1378           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1379           t a
1380           b
1381           : a
1382           H']`
1383   then
1384     libc_seen_a=no libc_seen_b=no
1385     set -- $ac_try
1386     while test $# -ge 2 -a "$1" = NOTE; do
1387       case "$2" in
1388       .note.a) libc_seen_a=yes ;;
1389       .note.b) libc_seen_b=yes ;;
1390       esac
1391       shift 2
1392     done
1393     case "$libc_seen_a$libc_seen_b" in
1394     yesyes)
1395       libc_cv_use_default_link=yes
1396       ;;
1397     *)
1398       echo >&AS_MESSAGE_LOG_FD "\
1399 $libc_seen_a$libc_seen_b from:
1400 $ac_try"
1401       ;;
1402     esac
1403   fi
1404   rm -f conftest*])
1405   use_default_link=$libc_cv_use_default_link
1406 fi
1407
1408 AC_CACHE_CHECK(for GLOB_DAT reloc,
1409                libc_cv_has_glob_dat, [dnl
1410 cat > conftest.c <<EOF
1411 extern int mumble;
1412 int foo (void) { return mumble; }
1413 EOF
1414 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1415                         -fPIC -shared -o conftest.so conftest.c
1416                         -nostdlib -nostartfiles $no_ssp
1417                         1>&AS_MESSAGE_LOG_FD])
1418 then
1419 dnl look for GLOB_DAT relocation.
1420   if $READELF -rW conftest.so | grep '_GLOB_DAT' > /dev/null; then
1421     libc_cv_has_glob_dat=yes
1422   else
1423     libc_cv_has_glob_dat=no
1424   fi
1425 else
1426   libc_cv_has_glob_dat=no
1427 fi
1428 rm -f conftest*])
1429 AC_SUBST(libc_cv_has_glob_dat)
1430
1431 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1432 cat > conftest.c <<EOF
1433 int foo;
1434 EOF
1435 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1436                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1437 then
1438   libc_cv_fno_toplevel_reorder=yes
1439 else
1440   libc_cv_fno_toplevel_reorder=no
1441 fi
1442 rm -f conftest*])
1443 if test $libc_cv_fno_toplevel_reorder = yes; then
1444   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1445 else
1446   fno_unit_at_a_time=-fno-unit-at-a-time
1447 fi
1448 AC_SUBST(fno_unit_at_a_time)
1449
1450 AC_CACHE_CHECK([for -mtls-dialect=gnu2], libc_cv_mtls_dialect_gnu2,
1451 [dnl
1452 cat > conftest.c <<EOF
1453 __thread int i;
1454 void foo (void)
1455 {
1456   i = 10;
1457 }
1458 EOF
1459 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fPIC -mtls-dialect=gnu2
1460                    conftest.c 1>&AS_MESSAGE_LOG_FD])
1461 then
1462   libc_cv_mtls_dialect_gnu2=yes
1463 else
1464   libc_cv_mtls_dialect_gnu2=no
1465 fi
1466 rm -f conftest*])
1467 AC_SUBST(libc_cv_mtls_dialect_gnu2)
1468 LIBC_CONFIG_VAR([have-mtls-dialect-gnu2], [$libc_cv_mtls_dialect_gnu2])
1469
1470 AC_CACHE_CHECK(whether cc puts quotes around section names,
1471                libc_cv_have_section_quotes,
1472                [cat > conftest.c <<EOF
1473                 static const int foo
1474                 __attribute__ ((section ("bar"))) = 1;
1475 EOF
1476                 if ${CC-cc} -S conftest.c -o conftest.s; then
1477                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1478                     libc_cv_have_section_quotes=yes
1479                   else
1480                     libc_cv_have_section_quotes=no
1481                   fi
1482                 else
1483                   libc_cv_have_section_quotes=unknown
1484                 fi
1485                 rm -f conftest.{c,s}
1486                 ])
1487 if test $libc_cv_have_section_quotes = yes; then
1488   AC_DEFINE(HAVE_SECTION_QUOTES)
1489 fi
1490
1491 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1492 cat > conftest.c <<\EOF
1493 void zero (void *x)
1494 {
1495   __builtin_memset (x, 0, 1000);
1496 }
1497 EOF
1498 dnl
1499 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "memset" > /dev/null]);
1500 then
1501   libc_cv_gcc_builtin_memset=no
1502 else
1503   libc_cv_gcc_builtin_memset=yes
1504 fi
1505 rm -f conftest* ])
1506 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1507   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1508 fi
1509
1510 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1511 cat > conftest.c <<\EOF
1512 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1513 char *foo (const char *a, const char *b)
1514 {
1515   return __builtin_strstr (a, b);
1516 }
1517 EOF
1518 dnl
1519 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | grep -F "my_strstr" > /dev/null]);
1520 then
1521   libc_cv_gcc_builtin_redirection=yes
1522 else
1523   libc_cv_gcc_builtin_redirection=no
1524 fi
1525 rm -f conftest* ])
1526 if test "$libc_cv_gcc_builtin_redirection" = no; then
1527   AC_MSG_ERROR([support for the symbol redirection needed])
1528 fi
1529
1530 dnl Determine how to disable generation of FMA instructions.
1531 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1532                libc_cv_cc_nofma, [dnl
1533 libc_cv_cc_nofma=
1534 for opt in -ffp-contract=off -mno-fused-madd; do
1535   LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1536 done])
1537 AC_SUBST(libc_cv_cc_nofma)
1538
1539 if test -n "$submachine"; then
1540   AC_CACHE_CHECK([for compiler option for CPU variant],
1541                  libc_cv_cc_submachine, [dnl
1542   libc_cv_cc_submachine=no
1543   for opt in "-march=$submachine" "-mcpu=$submachine"; do
1544     LIBC_TRY_CC_OPTION([$opt], [
1545       libc_cv_cc_submachine="$opt"
1546       break], [])
1547   done])
1548   if test "x$libc_cv_cc_submachine" = xno; then
1549     AC_MSG_ERROR([${CC-cc} does not support $submachine])
1550   fi
1551 fi
1552 AC_SUBST(libc_cv_cc_submachine)
1553
1554 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1555 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1556 cat > conftest.c <<EOF
1557 void
1558 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1559 foo (void) {}
1560 EOF
1561 libc_cv_cc_loop_to_function=no
1562 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1563 then
1564   libc_cv_cc_loop_to_function=yes
1565 fi
1566 rm -f conftest*])
1567 if test $libc_cv_cc_loop_to_function = yes; then
1568   AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1569 fi
1570 AC_SUBST(libc_cv_cc_loop_to_function)
1571
1572 dnl Check whether we have the gd library available.
1573 AC_MSG_CHECKING(for libgd)
1574 if test "$with_gd" != "no"; then
1575   old_CFLAGS="$CFLAGS"
1576   CFLAGS="$CFLAGS $libgd_include"
1577   old_LDFLAGS="$LDFLAGS"
1578   LDFLAGS="$LDFLAGS $libgd_ldflags"
1579   old_LIBS="$LIBS"
1580   LIBS="$LIBS -lgd -lpng -lz -lm"
1581   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gd.h>]], [[gdImagePng (0, 0)]])],
1582                  [LIBGD=yes], [LIBGD=no])
1583   CFLAGS="$old_CFLAGS"
1584   LDFLAGS="$old_LDFLAGS"
1585   LIBS="$old_LIBS"
1586 else
1587   LIBGD=no
1588 fi
1589 AC_MSG_RESULT($LIBGD)
1590 AC_SUBST(LIBGD)
1591
1592 # SELinux detection
1593 if test x$with_selinux = xno ; then
1594   have_selinux=no;
1595 else
1596   # See if we have the SELinux library
1597   AC_CHECK_LIB(selinux, is_selinux_enabled,
1598                have_selinux=yes, have_selinux=no)
1599   if test x$with_selinux = xyes ; then
1600     if test x$have_selinux = xno ; then
1601       AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1602     fi
1603   fi
1604 fi
1605 # Check if we're building with SELinux support.
1606 if test "x$have_selinux" = xyes; then
1607   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1608
1609   # See if we have the libaudit library
1610   AC_CHECK_LIB(audit, audit_log_user_avc_message,
1611                have_libaudit=yes, have_libaudit=no)
1612   if test "x$have_libaudit" = xyes; then
1613     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1614   fi
1615   AC_SUBST(have_libaudit)
1616
1617   # See if we have the libcap library
1618   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1619   if test "x$have_libcap" = xyes; then
1620     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1621   fi
1622   AC_SUBST(have_libcap)
1623 fi
1624 AC_SUBST(have_selinux)
1625
1626 CPPUNDEFS=
1627 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1628 dnl Since we are building the implementations of the fortified functions here,
1629 dnl having the macro defined interacts very badly.
1630 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1631 [AC_TRY_COMPILE([], [
1632 #ifdef _FORTIFY_SOURCE
1633 # error bogon
1634 #endif],
1635                 [libc_cv_predef_fortify_source=no],
1636                 [libc_cv_predef_fortify_source=yes])])
1637 if test $libc_cv_predef_fortify_source = yes; then
1638   CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1639 fi
1640 AC_SUBST(CPPUNDEFS)
1641
1642 # Some linkers on some architectures support __ehdr_start but with
1643 # bugs.  Make sure usage of it does not create relocations in the
1644 # output (as the linker should resolve them all for us).
1645 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1646                libc_cv_ehdr_start, [
1647 old_CFLAGS="$CFLAGS"
1648 old_LDFLAGS="$LDFLAGS"
1649 old_LIBS="$LIBS"
1650 CFLAGS="$CFLAGS -fPIC"
1651 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared $no_ssp"
1652 LIBS=
1653 AC_LINK_IFELSE([AC_LANG_SOURCE([
1654 typedef struct {
1655   char foo;
1656   long val;
1657 } Ehdr;
1658 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1659 long ehdr (void) { return __ehdr_start.val; }
1660 ])],
1661                [if $READELF -r conftest | grep -F __ehdr_start >/dev/null; then
1662                   libc_cv_ehdr_start=broken
1663                 else
1664                   libc_cv_ehdr_start=yes
1665                 fi], [libc_cv_ehdr_start=no])
1666 CFLAGS="$old_CFLAGS"
1667 LDFLAGS="$old_LDFLAGS"
1668 LIBS="$old_LIBS"
1669 ])
1670 if test "$libc_cv_ehdr_start" = yes; then
1671   AC_DEFINE([HAVE_EHDR_START])
1672 elif test "$libc_cv_ehdr_start" = broken; then
1673   AC_MSG_WARN([linker is broken -- you should upgrade])
1674 fi
1675
1676 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1677                libc_cv_builtin_trap, [dnl
1678 libc_cv_builtin_trap=no
1679 AC_TRY_COMPILE([], [__builtin_trap ()], [
1680 libc_undefs=`$NM -u conftest.o |
1681   LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1682     2>&AS_MESSAGE_LOG_FD` || {
1683   AC_MSG_ERROR([confusing output from $NM -u])
1684 }
1685 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1686 if test -z "$libc_undefs"; then
1687   libc_cv_builtin_trap=yes
1688 fi])])
1689 if test $libc_cv_builtin_trap = yes; then
1690   AC_DEFINE([HAVE_BUILTIN_TRAP])
1691 fi
1692
1693 dnl C++ feature tests.
1694 AC_LANG_PUSH([C++])
1695
1696 AC_CACHE_CHECK([whether the C++ compiler supports thread_local],
1697                libc_cv_cxx_thread_local, [
1698 old_CXXFLAGS="$CXXFLAGS"
1699 CXXFLAGS="$CXXFLAGS -std=gnu++11"
1700 AC_COMPILE_IFELSE([AC_LANG_SOURCE([
1701 #include <thread>
1702
1703 // Compiler support.
1704 struct S
1705 {
1706   S ();
1707   ~S ();
1708 };
1709 thread_local S s;
1710 S * get () { return &s; }
1711
1712 // libstdc++ support.
1713 #ifndef _GLIBCXX_HAVE___CXA_THREAD_ATEXIT_IMPL
1714 #error __cxa_thread_atexit_impl not supported
1715 #endif
1716 ])],
1717                [libc_cv_cxx_thread_local=yes],
1718                [libc_cv_cxx_thread_local=no])
1719 CXXFLAGS="$old_CXXFLAGS"
1720 ])
1721 AC_SUBST(libc_cv_cxx_thread_local)
1722
1723 AC_LANG_POP([C++])
1724 dnl End of C++ feature tests.
1725
1726 ### End of automated tests.
1727 ### Now run sysdeps configure fragments.
1728
1729 # They also can set these variables.
1730 use_ldconfig=no
1731 ldd_rewrite_script=no
1732 libc_cv_sysconfdir=$sysconfdir
1733 libc_cv_localstatedir=$localstatedir
1734 libc_cv_gcc_unwind_find_fde=no
1735 libc_cv_idn=no
1736
1737 # Iterate over all the sysdep directories we will use, running their
1738 # configure fragments.
1739 for dir in $sysnames; do
1740   case $dir in
1741     /*) dest=$dir ;;
1742     *)  dest=$srcdir/$dir ;;
1743   esac
1744   if test -r $dest/configure; then
1745     AC_MSG_RESULT(running configure fragment for $dir)
1746     . $dest/configure
1747   fi
1748 done
1749
1750 if test x"$build_mathvec" = xnotset; then
1751   build_mathvec=no
1752 fi
1753 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
1754
1755 AC_SUBST(libc_extra_cflags)
1756 AC_SUBST(libc_extra_cppflags)
1757
1758 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
1759   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
1760 fi
1761 AC_SUBST(libc_cv_gcc_unwind_find_fde)
1762
1763 # A sysdeps configure fragment can reset this if IFUNC is not actually
1764 # usable even though the assembler knows how to generate the symbol type.
1765 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
1766   AC_DEFINE(HAVE_IFUNC)
1767 fi
1768 LIBC_CONFIG_VAR([have-ifunc], [$libc_cv_ld_gnu_indirect_function])
1769
1770 if test x"$libc_cv_gcc_indirect_function" = xyes; then
1771   AC_DEFINE(HAVE_GCC_IFUNC)
1772 fi
1773
1774 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
1775 # configure fragment can override the value to prevent this AC_DEFINE.
1776 AC_SUBST(use_nscd)
1777 if test "x$use_nscd" != xno; then
1778   AC_DEFINE([USE_NSCD])
1779 fi
1780 if test "x$build_nscd" = xdefault; then
1781   build_nscd=$use_nscd
1782 fi
1783
1784 AC_SUBST(libc_cv_slibdir)
1785 AC_SUBST(libc_cv_rtlddir)
1786 AC_SUBST(libc_cv_complocaledir)
1787 AC_SUBST(libc_cv_sysconfdir)
1788 AC_SUBST(libc_cv_localstatedir)
1789 AC_SUBST(libc_cv_rootsbindir)
1790
1791 if test x$use_ldconfig = xyes; then
1792   AC_DEFINE(USE_LDCONFIG)
1793 fi
1794 AC_SUBST(use_ldconfig)
1795 AC_SUBST(ldd_rewrite_script)
1796
1797 AC_SUBST(static)
1798 AC_SUBST(shared)
1799
1800 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
1801 [libc_cv_pic_default=yes
1802 cat > conftest.c <<EOF
1803 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1804 # error PIC is default.
1805 #endif
1806 EOF
1807 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1808   libc_cv_pic_default=no
1809 fi
1810 rm -f conftest.*])
1811 AC_SUBST(libc_cv_pic_default)
1812
1813 AC_CACHE_CHECK([whether -fPIE is default], libc_cv_cc_pie_default,
1814 [libc_cv_cc_pie_default=yes
1815 cat > conftest.c <<EOF
1816 #if defined __PIE__ || defined __pie__ || defined PIE || defined pie
1817 # error PIE is default.
1818 #endif
1819 EOF
1820 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
1821   libc_cv_cc_pie_default=no
1822 fi
1823 rm -f conftest.*])
1824 libc_cv_pie_default=$libc_cv_cc_pie_default
1825 AC_SUBST(libc_cv_cc_pie_default)
1826 AC_SUBST(libc_cv_pie_default)
1827
1828 # Set the `multidir' variable by grabbing the variable from the compiler.
1829 # We do it once and save the result in a generated makefile.
1830 libc_cv_multidir=`${CC-cc} $CFLAGS $CPPFLAGS -print-multi-directory`
1831 AC_SUBST(libc_cv_multidir)
1832
1833 if test "$static_pie" = yes; then
1834   # Check target support for static PIE
1835   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#ifndef SUPPORT_STATIC_PIE
1836 # error static PIE is not supported
1837 #endif]])], , AC_MSG_ERROR([the architecture does not support static PIE]))
1838   # The linker must support --no-dynamic-linker.
1839   if test "$libc_cv_no_dynamic_linker" != yes; then
1840     AC_MSG_ERROR([linker support for --no-dynamic-linker needed])
1841   fi
1842   # Default to PIE.
1843   libc_cv_pie_default=yes
1844   AC_DEFINE(ENABLE_STATIC_PIE)
1845 fi
1846 LIBC_CONFIG_VAR([enable-static-pie], [$static_pie])
1847
1848 AC_SUBST(profile)
1849 AC_SUBST(static_nss)
1850
1851 AC_SUBST(DEFINES)
1852
1853 dnl See sysdeps/mach/configure.ac for this variable.
1854 AC_SUBST(mach_interface_list)
1855
1856 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1857 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1858 AC_SUBST(VERSION)
1859 AC_SUBST(RELEASE)
1860
1861 AC_CONFIG_FILES([config.make Makefile])
1862 AC_CONFIG_COMMANDS([default],[[
1863 case $CONFIG_FILES in *config.make*)
1864 echo "$config_vars" >> config.make;;
1865 esac
1866 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
1867 AC_OUTPUT