sysdeps/powerpc/fpu/setjmp.S

   1 /* setjmp for PowerPC.
   2    Copyright (C) 1995, 1996, 1997, 1999, 2000 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, write to the Free
  17    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  18    02111-1307 USA.  */
  19
  20 #include <sysdep.h>
  21 #define _ASM
  22 #define _SETJMP_H
  23 #include <bits/setjmp.h>
  24 #include <bp-sym.h>
  25 #include <bp-asm.h>
  26
  27 ENTRY (BP_SYM (__sigsetjmp))
  28         CHECK_BOUNDS_BOTH_WIDE_LIT (r3, r8, r9, JB_SIZE)
  29
  30         stw  r1,(JB_GPR1*4)(3)
  31         mflr r0
  32         stw  r2,(JB_GPR2*4)(3)
  33         stw  r14,((JB_GPRS+0)*4)(3)
  34         stfd fp14,((JB_FPRS+0*2)*4)(3)
  35         stw  r0,(JB_LR*4)(3)
  36         stw  r15,((JB_GPRS+1)*4)(3)
  37         stfd fp15,((JB_FPRS+1*2)*4)(3)
  38         mfcr r0
  39         stw  r16,((JB_GPRS+2)*4)(3)
  40         stfd fp16,((JB_FPRS+2*2)*4)(3)
  41         stw  r0,(JB_CR*4)(3)
  42         stw  r17,((JB_GPRS+3)*4)(3)
  43         stfd fp17,((JB_FPRS+3*2)*4)(3)
  44         stw  r18,((JB_GPRS+4)*4)(3)
  45         stfd fp18,((JB_FPRS+4*2)*4)(3)
  46         stw  r19,((JB_GPRS+5)*4)(3)
  47         stfd fp19,((JB_FPRS+5*2)*4)(3)
  48         stw  r20,((JB_GPRS+6)*4)(3)
  49         stfd fp20,((JB_FPRS+6*2)*4)(3)
  50         stw  r21,((JB_GPRS+7)*4)(3)
  51         stfd fp21,((JB_FPRS+7*2)*4)(3)
  52         stw  r22,((JB_GPRS+8)*4)(3)
  53         stfd fp22,((JB_FPRS+8*2)*4)(3)
  54         stw  r23,((JB_GPRS+9)*4)(3)
  55         stfd fp23,((JB_FPRS+9*2)*4)(3)
  56         stw  r24,((JB_GPRS+10)*4)(3)
  57         stfd fp24,((JB_FPRS+10*2)*4)(3)
  58         stw  r25,((JB_GPRS+11)*4)(3)
  59         stfd fp25,((JB_FPRS+11*2)*4)(3)
  60         stw  r26,((JB_GPRS+12)*4)(3)
  61         stfd fp26,((JB_FPRS+12*2)*4)(3)
  62         stw  r27,((JB_GPRS+13)*4)(3)
  63         stfd fp27,((JB_FPRS+13*2)*4)(3)
  64         stw  r28,((JB_GPRS+14)*4)(3)
  65         stfd fp28,((JB_FPRS+14*2)*4)(3)
  66         stw  r29,((JB_GPRS+15)*4)(3)
  67         stfd fp29,((JB_FPRS+15*2)*4)(3)
  68         stw  r30,((JB_GPRS+16)*4)(3)
  69         stfd fp30,((JB_FPRS+16*2)*4)(3)
  70         stw  r31,((JB_GPRS+17)*4)(3)
  71         stfd fp31,((JB_FPRS+17*2)*4)(3)
  72         b JUMPTARGET (BP_SYM (__sigjmp_save))
  73 END (BP_SYM (__sigsetjmp))