sysdeps/i386/i586/submul_1.S

   1 /* Pentium __mpn_submul_1 -- Multiply a limb vector with a limb and subtract
   2    the result from a second limb vector.
   3    Copyright (C) 1992, 94, 96, 97, 98, 00, 2005 Free Software Foundation, Inc.
   4    This file is part of the GNU MP Library.
   5
   6    The GNU MP Library is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU Lesser General Public License as published by
   8    the Free Software Foundation; either version 2.1 of the License, or (at your
   9    option) any later version.
  10
  11    The GNU MP Library is distributed in the hope that it will be useful, but
  12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  14    License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public License
  17    along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  18    the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  19    MA 02111-1307, USA. */
  20
  21 #include "sysdep.h"
  22 #include "asm-syntax.h"
  23 #include "bp-sym.h"
  24 #include "bp-asm.h"
  25
  26 #define PARMS   LINKAGE+16      /* space for 4 saved regs */
  27 #define RES     PARMS
  28 #define S1      RES+PTR_SIZE
  29 #define SIZE    S1+PTR_SIZE
  30 #define S2LIMB  SIZE+4
  31
  32 #define res_ptr edi
  33 #define s1_ptr esi
  34 #define size ecx
  35 #define s2_limb ebx
  36
  37         .text
  38 ENTRY (BP_SYM (__mpn_submul_1))
  39         ENTER
  40
  41         pushl   %res_ptr
  42         cfi_adjust_cfa_offset (4)
  43         pushl   %s1_ptr
  44         cfi_adjust_cfa_offset (4)
  45         pushl   %ebp
  46         cfi_adjust_cfa_offset (4)
  47         pushl   %s2_limb
  48         cfi_adjust_cfa_offset (4)
  49
  50         movl    RES(%esp), %res_ptr
  51         cfi_rel_offset (res_ptr, 12)
  52         movl    S1(%esp), %s1_ptr
  53         cfi_rel_offset (s1_ptr, 8)
  54         movl    SIZE(%esp), %size
  55         movl    S2LIMB(%esp), %s2_limb
  56         cfi_rel_offset (s2_limb, 0)
  57 #if __BOUNDED_POINTERS__
  58         shll    $2, %sizeP      /* convert limbs to bytes */
  59         CHECK_BOUNDS_BOTH_WIDE (%res_ptr, RES(%esp), %sizeP)
  60         CHECK_BOUNDS_BOTH_WIDE (%s1_ptr, S1(%esp), %sizeP)
  61         shrl    $2, %sizeP
  62 #endif
  63         leal    (%res_ptr,%size,4), %res_ptr
  64         leal    (%s1_ptr,%size,4), %s1_ptr
  65         negl    %size
  66         xorl    %ebp, %ebp
  67         cfi_rel_offset (ebp, 4)
  68         ALIGN (3)
  69
  70 L(oop): adcl    $0, %ebp
  71         movl    (%s1_ptr,%size,4), %eax
  72
  73         mull    %s2_limb
  74
  75         addl    %ebp, %eax
  76         movl    (%res_ptr,%size,4), %ebp
  77
  78         adcl    $0, %edx
  79         subl    %eax, %ebp
  80
  81         movl    %ebp, (%res_ptr,%size,4)
  82         incl    %size
  83
  84         movl    %edx, %ebp
  85         jnz     L(oop)
  86
  87         adcl    $0, %ebp
  88         movl    %ebp, %eax
  89         popl    %s2_limb
  90         cfi_adjust_cfa_offset (-4)
  91         cfi_restore (s2_limb)
  92         popl    %ebp
  93         cfi_adjust_cfa_offset (-4)
  94         cfi_restore (ebp)
  95         popl    %s1_ptr
  96         cfi_adjust_cfa_offset (-4)
  97         cfi_restore (s1_ptr)
  98         popl    %res_ptr
  99         cfi_adjust_cfa_offset (-4)
 100         cfi_restore (res_ptr)
 101
 102         LEAVE
 103         ret
 104 #undef size
 105 END (BP_SYM (__mpn_submul_1))