sysdeps/i386/i586/memset.S

   1 /* memset/bzero -- set memory area to CH/0
   2    Highly optimized version for ix86, x>=5.
   3    Copyright (C) 1996, 1997, 2000, 2003, 2005 Free Software Foundation, Inc.
   4    This file is part of the GNU C Library.
   5    Contributed by Torbjorn Granlund, <tege@matematik.su.se>
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, write to the Free
  19    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  20    02111-1307 USA.  */
  21
  22 #include <sysdep.h>
  23 #include "asm-syntax.h"
  24 #include "bp-sym.h"
  25 #include "bp-asm.h"
  26
  27 /* BEWARE: `#ifdef memset' means that memset is redefined as `bzero' */
  28 #define BZERO_P (defined memset)
  29
  30 #define PARMS   LINKAGE+4       /* space for 1 saved reg */
  31 #define RTN     PARMS
  32 #define DEST    RTN+RTN_SIZE
  33 #if BZERO_P
  34 # define LEN    DEST+PTR_SIZE
  35 #else
  36 # define CHR    DEST+PTR_SIZE
  37 # define LEN    CHR+4
  38 #endif
  39
  40         .text
  41 #if defined PIC && !defined NOT_IN_libc && !BZERO_P
  42 ENTRY (__memset_chk)
  43         movl    12(%esp), %eax
  44         cmpl    %eax, 16(%esp)
  45         jb      HIDDEN_JUMPTARGET (__chk_fail)
  46 END (__memset_chk)
  47 #endif
  48 ENTRY (BP_SYM (memset))
  49         ENTER
  50
  51         pushl   %edi
  52         cfi_adjust_cfa_offset (4)
  53
  54         movl    DEST(%esp), %edi
  55         cfi_rel_offset (edi, 0)
  56         movl    LEN(%esp), %edx
  57         CHECK_BOUNDS_BOTH_WIDE (%edi, DEST(%esp), %edx)
  58 #if BZERO_P
  59         xorl    %eax, %eax      /* we fill with 0 */
  60 #else
  61         movb    CHR(%esp), %al
  62         movb    %al, %ah
  63         movl    %eax, %ecx
  64         shll    $16, %eax
  65         movw    %cx, %ax
  66 #endif
  67         cld
  68
  69 /* If less than 36 bytes to write, skip tricky code (it wouldn't work).  */
  70         cmpl    $36, %edx
  71         movl    %edx, %ecx      /* needed when branch is taken! */
  72         jl      L(2)
  73
  74 /* First write 0-3 bytes to make the pointer 32-bit aligned.  */
  75         movl    %edi, %ecx      /* Copy ptr to ecx... */
  76         negl    %ecx            /* ...and negate that and... */
  77         andl    $3, %ecx        /* ...mask to get byte count.  */
  78         subl    %ecx, %edx      /* adjust global byte count */
  79         rep
  80         stosb
  81
  82         subl    $32, %edx       /* offset count for unrolled loop */
  83         movl    (%edi), %ecx    /* Fetch destination cache line */
  84
  85         .align  2, 0x90         /* supply 0x90 for broken assemblers */
  86 L(1):   movl    28(%edi), %ecx  /* allocate cache line for destination */
  87         subl    $32, %edx       /* decr loop count */
  88         movl    %eax, 0(%edi)   /* store words pairwise */
  89         movl    %eax, 4(%edi)
  90         movl    %eax, 8(%edi)
  91         movl    %eax, 12(%edi)
  92         movl    %eax, 16(%edi)
  93         movl    %eax, 20(%edi)
  94         movl    %eax, 24(%edi)
  95         movl    %eax, 28(%edi)
  96         leal    32(%edi), %edi  /* update destination pointer */
  97         jge     L(1)
  98
  99         leal    32(%edx), %ecx  /* reset offset count */
 100
 101 /* Write last 0-7 full 32-bit words (up to 8 words if loop was skipped).  */
 102 L(2):   shrl    $2, %ecx        /* convert byte count to longword count */
 103         rep
 104         stosl
 105
 106 /* Finally write the last 0-3 bytes.  */
 107         movl    %edx, %ecx
 108         andl    $3, %ecx
 109         rep
 110         stosb
 111
 112 #if !BZERO_P
 113         /* Load result (only if used as memset).  */
 114         movl DEST(%esp), %eax   /* start address of destination is result */
 115         RETURN_BOUNDED_POINTER (DEST(%esp))
 116 #endif
 117         popl    %edi
 118         cfi_adjust_cfa_offset (-4)
 119         cfi_restore (edi)
 120
 121         LEAVE
 122 #if BZERO_P
 123         ret
 124 #else
 125         RET_PTR
 126 #endif
 127 END (BP_SYM (memset))
 128 libc_hidden_builtin_def (memset)