| blob | ff66b875e3b43d2c1a39413c60ff0bcf9de6c693 |
1 dnl Process this file with autoconf to produce a configure script.
2 dnl Note we do not use AC_PREREQ here! See aclocal.m4 for what we use instead.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 ACX_PKGVERSION([GNU libc])
9 ACX_BUGURL([http://www.gnu.org/software/libc/bugs.html])
10 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"],
11 [Package description])
12 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"],
13 [Bug reporting address])
15 # Glibc should not depend on any header files
16 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
17 [m4_divert_text([DEFAULTS],
18 [ac_includes_default='/* none */'])])
20 # We require GCC, and by default use its preprocessor. Override AC_PROG_CPP
21 # here to work around the Autoconf issue discussed in
22 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00721.html>.
23 AC_DEFUN([AC_PROG_CPP],
24 [AC_REQUIRE([AC_PROG_CC])dnl
25 AC_ARG_VAR([CPP], [C preprocessor])dnl
26 _AC_ARG_VAR_CPPFLAGS()dnl
27 # On Suns, sometimes $CPP names a directory.
28 if test -n "$CPP" && test -d "$CPP"; then
29 CPP=
30 fi
31 if test -z "$CPP"; then
32 CPP="$CC -E"
33 fi
34 AC_SUBST(CPP)dnl
35 ])# AC_PROG_CPP
37 # We require GCC. Override _AC_PROG_CC_C89 here to work around the Autoconf
38 # issue discussed in
39 # <http://sourceware.org/ml/libc-alpha/2013-01/msg00757.html>.
40 AC_DEFUN([_AC_PROG_CC_C89], [[$1]])
42 dnl This is here so we can set $subdirs directly based on configure fragments.
43 AC_CONFIG_SUBDIRS()
45 AC_CANONICAL_HOST
47 AC_PROG_CC
48 if test $host != $build; then
49 AC_CHECK_PROGS(BUILD_CC, gcc cc)
50 fi
51 AC_SUBST(cross_compiling)
52 AC_PROG_CPP
53 AC_CHECK_TOOL(READELF, readelf, false)
55 # We need the C++ compiler only for testing.
56 AC_PROG_CXX
57 # It's useless to us if it can't link programs (e.g. missing -lstdc++).
58 AC_CACHE_CHECK([whether $CXX can link programs], libc_cv_cxx_link_ok, [dnl
59 AC_LANG_PUSH([C++])
60 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
61 [libc_cv_cxx_link_ok=yes],
62 [libc_cv_cxx_link_ok=no])
63 AC_LANG_POP([C++])])
64 AS_IF([test $libc_cv_cxx_link_ok != yes], [CXX=])
66 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
67 AC_MSG_ERROR([you must configure in a separate build directory])
68 fi
70 # This will get text that should go into config.make.
71 config_vars=
73 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
74 AC_ARG_WITH([gd],
75 AC_HELP_STRING([--with-gd=DIR],
76 [find libgd include dir and library with prefix DIR]),
77 [dnl
78 case "$with_gd" in
79 yes|''|no) ;;
80 *) libgd_include="-I$withval/include"
81 libgd_ldflags="-L$withval/lib" ;;
82 esac
83 ])
84 AC_ARG_WITH([gd-include],
85 AC_HELP_STRING([--with-gd-include=DIR],
86 [find libgd include files in DIR]),
87 [dnl
88 case "$with_gd_include" in
89 ''|no) ;;
90 *) libgd_include="-I$withval" ;;
91 esac
92 ])
93 AC_ARG_WITH([gd-lib],
94 AC_HELP_STRING([--with-gd-lib=DIR],
95 [find libgd library files in DIR]),
96 [dnl
97 case "$with_gd_lib" in
98 ''|no) ;;
99 *) libgd_ldflags="-L$withval" ;;
100 esac
101 ])
103 if test -n "$libgd_include"; then
104 config_vars="$config_vars
105 CFLAGS-memusagestat.c = $libgd_include"
106 fi
107 if test -n "$libgd_ldflags"; then
108 config_vars="$config_vars
109 libgd-LDFLAGS = $libgd_ldflags"
110 fi
112 dnl Arguments to specify presence of other packages/features.
113 AC_ARG_WITH([fp],
114 AC_HELP_STRING([--with-fp],
115 [if using floating-point hardware @<:@default=yes@:>@]),
116 [with_fp=$withval],
117 [with_fp=yes])
118 AC_SUBST(with_fp)
119 AC_ARG_WITH([binutils],
120 AC_HELP_STRING([--with-binutils=PATH],
121 [specify location of binutils (as and ld)]),
122 [path_binutils=$withval],
123 [path_binutils=''])
124 AC_ARG_WITH([selinux],
125 AC_HELP_STRING([--with-selinux],
126 [if building with SELinux support]),
127 [with_selinux=$withval],
128 [with_selinux=auto])
130 AC_ARG_WITH([headers],
131 AC_HELP_STRING([--with-headers=PATH],
132 [location of system headers to use
133 (for example /usr/src/linux/include)
134 @<:@default=compiler default@:>@]),
135 [sysheaders=$withval],
136 [sysheaders=''])
137 AC_SUBST(sysheaders)
139 AC_SUBST(use_default_link)
140 AC_ARG_WITH([default-link],
141 AC_HELP_STRING([--with-default-link],
142 [do not use explicit linker scripts]),
143 [use_default_link=$withval],
144 [use_default_link=default])
146 AC_ARG_ENABLE([sanity-checks],
147 AC_HELP_STRING([--disable-sanity-checks],
148 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
149 [enable_sanity=$enableval],
150 [enable_sanity=yes])
152 AC_ARG_ENABLE([shared],
153 AC_HELP_STRING([--enable-shared],
154 [build shared library @<:@default=yes if GNU ld@:>@]),
155 [shared=$enableval],
156 [shared=yes])
157 AC_ARG_ENABLE([profile],
158 AC_HELP_STRING([--enable-profile],
159 [build profiled library @<:@default=no@:>@]),
160 [profile=$enableval],
161 [profile=no])
163 AC_ARG_ENABLE([hardcoded-path-in-tests],
164 AC_HELP_STRING([--enable-hardcoded-path-in-tests],
165 [hardcode newly built glibc path in tests @<:@default=no@:>@]),
166 [hardcoded_path_in_tests=$enableval],
167 [hardcoded_path_in_tests=no])
168 AC_SUBST(hardcoded_path_in_tests)
170 AC_ARG_ENABLE([stackguard-randomization],
171 AC_HELP_STRING([--enable-stackguard-randomization],
172 [initialize __stack_chk_guard canary with a random number at program start]),
173 [enable_stackguard_randomize=$enableval],
174 [enable_stackguard_randomize=no])
175 if test "$enable_stackguard_randomize" = yes; then
176 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
177 fi
179 AC_ARG_ENABLE([lock-elision],
180 AC_HELP_STRING([--enable-lock-elision[=yes/no]],
181 [Enable lock elision for pthread mutexes by default]),
182 [enable_lock_elision=$enableval],
183 [enable_lock_elision=no])
184 AC_SUBST(enable_lock_elision)
185 if test "$enable_lock_elision" = yes ; then
186 AC_DEFINE(ENABLE_LOCK_ELISION)
187 fi
189 dnl Generic infrastructure for drop-in additions to libc.
190 AC_ARG_ENABLE([add-ons],
191 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
192 [configure and build add-ons in DIR1,DIR2,...
193 search for add-ons if no parameter given]),
194 , [enable_add_ons=yes])
196 AC_ARG_ENABLE([hidden-plt],
197 AC_HELP_STRING([--disable-hidden-plt],
198 [do not hide internal function calls to avoid PLT]),
199 [hidden=$enableval],
200 [hidden=yes])
201 if test "x$hidden" = xno; then
202 AC_DEFINE(NO_HIDDEN)
203 fi
205 AC_ARG_ENABLE([bind-now],
206 AC_HELP_STRING([--enable-bind-now],
207 [disable lazy relocations in DSOs]),
208 [bindnow=$enableval],
209 [bindnow=no])
210 AC_SUBST(bindnow)
212 dnl On some platforms we cannot use dynamic loading. We must provide
213 dnl static NSS modules.
214 AC_ARG_ENABLE([static-nss],
215 AC_HELP_STRING([--enable-static-nss],
216 [build static NSS modules @<:@default=no@:>@]),
217 [static_nss=$enableval],
218 [static_nss=no])
219 dnl Enable static NSS also if we build no shared objects.
220 if test x"$static_nss" = xyes || test x"$shared" = xno; then
221 static_nss=yes
222 AC_DEFINE(DO_STATIC_NSS)
223 fi
225 AC_ARG_ENABLE([force-install],
226 AC_HELP_STRING([--disable-force-install],
227 [don't force installation of files from this package, even if they are older than the installed files]),
228 [force_install=$enableval],
229 [force_install=yes])
230 AC_SUBST(force_install)
232 AC_ARG_ENABLE([maintainer-mode],
233 AC_HELP_STRING([--enable-maintainer-mode],
234 [enable make rules and dependencies not useful (and sometimes confusing) to the casual installer]),
235 [maintainer=$enableval],
236 [maintainer=no])
238 dnl On some platforms we allow dropping compatibility with all kernel
239 dnl versions.
240 AC_ARG_ENABLE([kernel],
241 AC_HELP_STRING([--enable-kernel=VERSION],
242 [compile for compatibility with kernel not older than VERSION]),
243 [minimum_kernel=$enableval],
244 [])
245 dnl Prevent unreasonable values.
246 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
247 # Better nothing than this.
248 minimum_kernel=""
249 else
250 if test "$minimum_kernel" = current; then
251 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
252 fi
253 fi
255 dnl For the development we sometimes want gcc to issue even more warnings.
256 dnl This is not the default since many of the extra warnings are not
257 dnl appropriate.
258 AC_ARG_ENABLE([all-warnings],
259 AC_HELP_STRING([--enable-all-warnings],
260 [enable all useful warnings gcc can issue]),
261 [all_warnings=$enableval],
262 [])
263 AC_SUBST(all_warnings)
265 AC_ARG_ENABLE([werror],
266 AC_HELP_STRING([--disable-werror],
267 [do not build with -Werror]),
268 [enable_werror=$enableval],
269 [enable_werror=yes])
270 AC_SUBST(enable_werror)
272 AC_ARG_ENABLE([multi-arch],
273 AC_HELP_STRING([--enable-multi-arch],
274 [enable single DSO with optimizations for multiple architectures]),
275 [multi_arch=$enableval],
276 [multi_arch=default])
278 AC_ARG_ENABLE([nss-crypt],
279 AC_HELP_STRING([--enable-nss-crypt],
280 [enable libcrypt to use nss]),
281 [nss_crypt=$enableval],
282 [nss_crypt=no])
283 if test x$nss_crypt = xyes; then
284 nss_includes=-I$(nss-config --includedir 2>/dev/null)
285 if test $? -ne 0; then
286 AC_MSG_ERROR([cannot find include directory with nss-config])
287 fi
288 old_CFLAGS="$CFLAGS"
289 CFLAGS="$CFLAGS $nss_includes"
290 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
291 #include <hasht.h>
292 #include <nsslowhash.h>
293 void f (void) { NSSLOW_Init (); }])],
294 libc_cv_nss_crypt=yes,
295 AC_MSG_ERROR([
296 cannot find NSS headers with lowlevel hash function interfaces]))
297 old_LIBS="$LIBS"
298 LIBS="$LIBS -lfreebl3"
299 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
300 #include <hasht.h>
301 #include <nsslowhash.h>],
302 [NSSLOW_Init();])],
303 libc_cv_nss_crypt=yes,
304 AC_MSG_ERROR([
305 cannot link program using lowlevel NSS hash functions]))
306 CFLAGS="$old_CFLAGS"
307 LIBS="$old_LIBS"
308 else
309 libc_cv_nss_crypt=no
310 fi
311 AC_SUBST(libc_cv_nss_crypt)
314 AC_ARG_ENABLE([obsolete-rpc],
315 AC_HELP_STRING([--enable-obsolete-rpc],
316 [build and install the obsolete RPC code for link-time usage]),
317 [link_obsolete_rpc=$enableval],
318 [link_obsolete_rpc=no])
319 AC_SUBST(link_obsolete_rpc)
321 if test "$link_obsolete_rpc" = yes; then
322 AC_DEFINE(LINK_OBSOLETE_RPC)
323 fi
325 AC_ARG_ENABLE([systemtap],
326 [AS_HELP_STRING([--enable-systemtap],
327 [enable systemtap static probe points @<:@default=no@:>@])],
328 [systemtap=$enableval],
329 [systemtap=no])
330 if test "x$systemtap" != xno; then
331 AC_CACHE_CHECK([for systemtap static probe support], libc_cv_sdt, [dnl
332 old_CFLAGS="$CFLAGS"
333 CFLAGS="-std=gnu99 $CFLAGS"
334 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#include <sys/sdt.h>
335 void foo (int i, void *p)
336 {
337 asm ("" STAP_PROBE_ASM (foo, bar, STAP_PROBE_ASM_TEMPLATE (2)) ""
338 :: STAP_PROBE_ASM_OPERANDS (2, i, p));
339 }]])], [libc_cv_sdt=yes], [libc_cv_sdt=no])
340 CFLAGS="$old_CFLAGS"])
341 if test $libc_cv_sdt = yes; then
342 AC_DEFINE([USE_STAP_PROBE])
343 elif test "x$systemtap" != xauto; then
344 AC_MSG_FAILURE([systemtap support needs sys/sdt.h with asm support])
345 fi
346 fi
348 AC_ARG_ENABLE([build-nscd],
349 [AS_HELP_STRING([--disable-build-nscd],
350 [disable building and installing the nscd daemon])],
351 [build_nscd=$enableval],
352 [build_nscd=default])
353 AC_SUBST(build_nscd)
355 # Note the use of $use_nscd is near the bottom of the file.
356 AC_ARG_ENABLE([nscd],
357 [AS_HELP_STRING([--disable-nscd],
358 [library functions will not contact the nscd daemon])],
359 [use_nscd=$enableval],
360 [use_nscd=yes])
362 AC_ARG_ENABLE([pt_chown],
363 [AS_HELP_STRING([--enable-pt_chown],
364 [Enable building and installing pt_chown])],
365 [build_pt_chown=$enableval],
366 [build_pt_chown=no])
367 AC_SUBST(build_pt_chown)
368 if test "$build_pt_chown" = yes; then
369 AC_DEFINE(HAVE_PT_CHOWN)
370 fi
372 # The abi-tags file uses a fairly simplistic model for name recognition that
373 # can't distinguish i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a
374 # $host_os of `gnu*' here to be `gnu-gnu*' just so that it can tell.
375 # This doesn't get used much beyond that, so it's fairly safe.
376 case "$host_os" in
377 linux*)
378 ;;
379 gnu*)
380 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
381 ;;
382 esac
384 AC_ARG_ENABLE([mathvec],
385 [AS_HELP_STRING([--enable-mathvec],
386 [Enable building and installing mathvec @<:@default depends on architecture@:>@])],
387 [build_mathvec=$enableval],
388 [build_mathvec=notset])
390 # We keep the original values in `$config_*' and never modify them, so we
391 # can write them unchanged into config.make. Everything else uses
392 # $machine, $vendor, and $os, and changes them whenever convenient.
393 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
395 # Don't allow vendor == "unknown"
396 test "$config_vendor" = unknown && config_vendor=
397 config_os="`echo $config_os | sed 's/^unknown-//'`"
399 # Some configurations imply other options.
400 elf=yes
402 # The configure fragment of an add-on port can modify these to supplement
403 # or override the table in the case statement below. No fragment should
404 # ever change the config_* variables, however.
405 machine=$config_machine
406 vendor=$config_vendor
407 os=$config_os
408 base_os=''
410 submachine=
411 AC_ARG_WITH([cpu],
412 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
413 [dnl
414 case "$withval" in
415 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
416 no) ;;
417 *) submachine="$withval" ;;
418 esac
419 ])
421 # An preconfigure script can set this when it wants to disable the sanity
422 # check below.
423 libc_config_ok=no
425 dnl Let sysdeps/*/preconfigure act here, like they can in add-ons.
426 LIBC_PRECONFIGURE([$srcdir], [for sysdeps])
428 dnl Having this here, though empty, makes sure that if add-ons' fragments
429 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
430 dnl our AC_OUTPUT will actually use it.
431 AC_CONFIG_SUBDIRS()
433 case "$enable_add_ons" in
434 ''|no) add_ons= ;;
435 yes|'*')
436 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
437 sed 's@/[[^/]]*$@@' | sort | uniq`
438 add_ons_automatic=yes
439 ;;
440 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
441 add_ons_automatic=no ;;
442 esac
444 configured_add_ons=
445 add_ons_sfx=
446 add_ons_pfx=
447 if test x"$add_ons" != x; then
448 for f in $add_ons; do
449 # Some sanity checks
450 case "$f" in
451 crypt)
452 AC_MSG_ERROR([
453 *** It seems that you're using an old \`crypt' add-on. crypt is now
454 *** part of glibc and using the old add-on will not work with this
455 *** release. Start again with fresh sources and without the old
456 *** \`crypt' add-on.])
457 ;;
458 localedata)
459 AC_MSG_ERROR([
460 *** It seems that you're using an old \`localedata' add-on. localedata
461 *** is now part of glibc and using the old add-on will not work with
462 *** this release. Start again with fresh sources and without the old
463 *** \`localedata' add-on.])
464 ;;
465 esac
466 done
468 # Now source each add-on's configure fragment.
469 # The fragments can use $srcdir/$libc_add_on to find themselves,
470 # and test $add_ons_automatic to see if they were explicitly requested.
471 # A fragment can clear (or even change) $libc_add_on to affect
472 # whether it goes into the list to be actually used in the build.
473 use_add_ons=
474 for libc_add_on in $add_ons; do
475 # Test whether such a directory really exists.
476 # It can be absolute, or relative to $srcdir, or relative to the build dir.
477 case "$libc_add_on" in
478 /*)
479 libc_add_on_srcdir=$libc_add_on
480 ;;
481 *)
482 test -d "$srcdir/$libc_add_on" || {
483 if test -d "$libc_add_on"; then
484 libc_add_on="`pwd`/$libc_add_on"
485 else
486 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
487 fi
488 }
489 libc_add_on_srcdir=$srcdir/$libc_add_on
490 ;;
491 esac
493 libc_add_on_frag=$libc_add_on_srcdir/configure
494 libc_add_on_canonical=
495 libc_add_on_config_subdirs=
496 if test -r "$libc_add_on_frag"; then
497 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
498 libc_add_on_canonical=unknown
499 libc_add_on_subdirs=
500 . "$libc_add_on_frag"
501 test -z "$libc_add_on" || {
502 configured_add_ons="$configured_add_ons $libc_add_on"
503 if test "x$libc_add_on_canonical" = xunknown; then
504 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
505 fi
506 for d in $libc_add_on_subdirs; do
507 case "$libc_add_on" in
508 /*) subdir_srcdir="$libc_add_on" ;;
509 *) subdir_srcdir="\$(..)$libc_add_on" ;;
510 esac
511 case "$d" in
512 .)
513 d="${libc_add_on_canonical:-$libc_add_on}"
514 ;;
515 /*)
516 subdir_srcdir="$d"
517 ;;
518 *)
519 subdir_srcdir="$subdir_srcdir/$d"
520 ;;
521 esac
522 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
523 add_on_subdirs="$add_on_subdirs $d"
524 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
525 $d-srcdir = $subdir_srcdir"
526 done
527 for d in $libc_add_on_config_subdirs; do
528 case "$d" in
529 /*) AC_MSG_ERROR(dnl
530 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
531 esac
532 if test ! -d "$libc_add_on_srcdir/$d"; then
533 AC_MSG_ERROR(fragment wants to configure missing directory $d)
534 fi
535 case "$libc_add_on" in
536 /*) AC_MSG_ERROR(dnl
537 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
538 esac
539 subdirs="$subdirs $libc_add_on/$d"
540 done
541 }
542 fi
543 if test -n "$libc_add_on"; then
544 LIBC_PRECONFIGURE([$libc_add_on_srcdir], [add-on $libc_add_on for])
545 use_add_ons="$use_add_ons $libc_add_on"
546 add_ons_pfx="$add_ons_pfx $libc_add_on/"
547 test -z "$libc_add_on_canonical" ||
548 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
549 fi
550 done
551 # Use echo to strip excess whitespace.
552 add_ons="`echo $use_add_ons`"
553 fi
554 AC_SUBST(add_ons)
555 AC_SUBST(add_on_subdirs)
558 ###
559 ### I put this here to prevent those annoying emails from people who cannot
560 ### read and try to compile glibc on unsupported platforms. --drepper
561 ###
562 ### By using the undocumented --enable-hacker-mode option for configure
563 ### one can skip this test to make the configuration not fail for unsupported
564 ### platforms.
565 ###
566 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
567 case "$machine-$host_os" in
568 *-linux* | *-gnu*)
569 ;;
570 *)
571 echo "*** The GNU C library is currently not available for this platform."
572 echo "*** So far nobody cared to port it and if there is no volunteer it"
573 echo "*** might never happen. So, if you have interest to see glibc on"
574 echo "*** this platform visit"
575 echo "*** http://www.gnu.org/software/libc/porting.html"
576 echo "*** and join the group of porters"
577 exit 1
578 ;;
579 esac
580 fi
582 # Set base_machine if not set by a preconfigure fragment.
583 test -n "$base_machine" || base_machine=$machine
584 AC_SUBST(base_machine)
586 # For the multi-arch option we need support in the assembler & linker.
587 AC_CACHE_CHECK([for assembler and linker STT_GNU_IFUNC support],
588 libc_cv_ld_gnu_indirect_function, [dnl
589 cat > conftest.S <<EOF
590 .type foo,%gnu_indirect_function
591 foo:
592 .globl _start
593 _start:
594 .globl __start
595 __start:
596 .data
597 #ifdef _LP64
598 .quad foo
599 #else
600 .long foo
601 #endif
602 EOF
603 libc_cv_ld_gnu_indirect_function=no
604 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
605 -nostartfiles -nostdlib \
606 -o conftest conftest.S 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
607 # Do a link to see if the backend supports IFUNC relocs.
608 $READELF -r conftest 1>&AS_MESSAGE_LOG_FD
609 LC_ALL=C $READELF -r conftest | grep 'no relocations' >/dev/null || {
610 libc_cv_ld_gnu_indirect_function=yes
611 }
612 fi
613 rm -f conftest*])
615 AC_MSG_CHECKING(whether .text pseudo-op must be used)
616 AC_CACHE_VAL(libc_cv_dot_text, [dnl
617 cat > conftest.s <<EOF
618 .text
619 EOF
620 libc_cv_dot_text=
621 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
622 libc_cv_dot_text=.text
623 fi
624 rm -f conftest*])
625 if test -z "$libc_cv_dot_text"; then
626 AC_MSG_RESULT(no)
627 else
628 AC_MSG_RESULT(yes)
629 fi
631 if test x"$libc_cv_ld_gnu_indirect_function" != xyes; then
632 if test x"$multi_arch" = xyes; then
633 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
634 else
635 multi_arch=no
636 fi
637 fi
638 multi_arch_d=
639 if test x"$multi_arch" != xno; then
640 multi_arch_d=/multiarch
641 fi
643 # Compute the list of sysdep directories for this configuration.
644 # This can take a while to compute.
645 sysdep_dir=$srcdir/sysdeps
646 AC_MSG_CHECKING(sysdep dirs)
647 dnl We need to use [ and ] for other purposes for a while now.
648 changequote(,)dnl
649 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
650 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
652 test "x$base_os" != x || case "$os" in
653 gnu*)
654 base_os=mach/hurd ;;
655 linux*)
656 base_os=unix/sysv ;;
657 esac
659 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
660 tail=$os
661 ostry=$os
662 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
663 ostry="$ostry /$o"
664 tail=$o
665 done
666 o=`echo $tail | sed 's/[0-9]*$//'`
667 if test $o != $tail; then
668 ostry="$ostry /$o"
669 fi
670 # For linux-gnu, try linux-gnu, then linux.
671 o=`echo $tail | sed 's/-.*$//'`
672 if test $o != $tail; then
673 ostry="$ostry /$o"
674 fi
676 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
677 base=
678 tail=$base_os
679 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
680 set $b
681 base="$base /$1"
682 tail="$2"
683 done
685 # For sparc/sparc32, try sparc/sparc32 and then sparc.
686 mach=
687 tail=$machine${submachine:+/$submachine}
688 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
689 set $m
690 # Prepend the machine's FPU directory unless --without-fp.
691 if test "$with_fp" = yes; then
692 maybe_fpu=/fpu
693 else
694 maybe_fpu=/nofpu
695 fi
696 # For each machine term, try it with and then without /multiarch.
697 for try_fpu in $maybe_fpu ''; do
698 for try_multi in $multi_arch_d ''; do
699 mach="$mach /$1$try_fpu$try_multi"
700 done
701 done
702 tail="$2"
703 done
705 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
706 changequote([,])dnl
708 # Find what sysdep directories exist.
709 sysnames_add_ons=
710 sysnames=
711 for b in $base ''; do
712 for m0 in $mach ''; do
713 for v in /$vendor ''; do
714 test "$v" = / && continue
715 for o in /$ostry ''; do
716 test "$o" = / && continue
717 for m in $mach ''; do
718 for d in $add_ons_pfx ''; do
719 for a in $add_ons_sfx ''; do
720 try_suffix="$m0$b$v$o$m"
721 if test -n "$try_suffix"; then
722 try_srcdir="${srcdir}/"
723 case "$d" in
724 /*) try_srcdir= ;;
725 esac
726 try="${d}sysdeps$try_suffix$a"
727 test -n "$enable_debug_configure" &&
728 echo "$0 [DEBUG]: try $try" >&2
729 if test -d "$try_srcdir$try"; then
730 sysnames="$sysnames $try"
731 { test -n "$o" || test -n "$b"; } && os_used=t
732 { test -n "$m" || test -n "$m0"; } && machine_used=t
733 case x${m0:-$m} in
734 x*/$submachine) submachine_used=t ;;
735 esac
736 if test -n "$d"; then
737 case "$sysnames_add_ons" in
738 *" $d "*) ;;
739 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
740 esac
741 fi
742 fi
743 fi
744 done
745 done
746 done
747 done
748 done
749 done
750 done
752 # If the assembler supports gnu_indirect_function symbol type and the
753 # architecture supports multi-arch, we enable multi-arch by default.
754 case $sysnames_add_ons$sysnames in
755 *"$multi_arch_d"*)
756 ;;
757 *)
758 test x"$multi_arch" = xdefault && multi_arch=no
759 ;;
760 esac
761 if test x"$multi_arch" != xno; then
762 AC_DEFINE(USE_MULTIARCH)
763 fi
764 AC_SUBST(multi_arch)
766 if test -z "$os_used" && test "$os" != none; then
767 AC_MSG_ERROR(Operating system $os is not supported.)
768 fi
769 if test -z "$machine_used" && test "$machine" != none; then
770 AC_MSG_ERROR(The $machine is not supported.)
771 fi
772 if test -z "$submachine_used" && test -n "$submachine"; then
773 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
774 fi
775 AC_SUBST(submachine)
777 # We have now validated the configuration.
779 # Expand the list of system names into a full list of directories
780 # from each element's parent name and Implies file (if present).
781 set $sysnames
782 names=
783 while test $# -gt 0; do
784 name=$1
785 shift
787 case " $names " in *" $name "*)
788 # Already in the list.
789 continue
790 esac
792 # Report each name as we discover it, so there is no long pause in output.
793 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
795 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
797 case $name in
798 /*) xsrcdir= ;;
799 *) xsrcdir=$srcdir/ ;;
800 esac
801 test -n "$enable_debug_configure" &&
802 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
804 for implies_file in Implies Implies-before Implies-after; do
805 implies_type=`echo $implies_file | sed s/-/_/`
806 eval ${implies_type}=
807 if test -f $xsrcdir$name/$implies_file; then
808 # Collect more names from the `Implies' file (removing comments).
809 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/$implies_file`"
810 for x in $implied_candidate; do
811 found=no
812 if test -d $xsrcdir$name_base/$x; then
813 eval "${implies_type}=\"\$${implies_type} \$name_base/\$x\""
814 found=yes
815 fi
816 for d in $add_ons_pfx ''; do
817 try="${d}sysdeps/$x"
818 case $d in
819 /*) try_srcdir= ;;
820 *) try_srcdir=$srcdir/ ;;
821 esac
822 test -n "$enable_debug_configure" &&
823 echo "[DEBUG]: $name $implies_file $x try($d) {$try_srcdir}$try" >&2
824 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
825 then
826 eval "${implies_type}=\"\$${implies_type} \$try\""
827 found=yes
828 case "$sysnames_add_ons" in
829 *" $d "*) ;;
830 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
831 esac
832 fi
833 done
834 if test $found = no; then
835 AC_MSG_WARN($name/$implies_file specifies nonexistent $x)
836 fi
837 done
838 fi
839 done
841 # Add NAME to the list of names.
842 names="$names $name"
844 # Find the parent of NAME, using the empty string if it has none.
845 changequote(,)dnl
846 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
847 changequote([,])dnl
849 test -n "$enable_debug_configure" &&
850 echo "[DEBUG]: $name Implies='$Implies' rest='$*' parent='$parent' \
851 Implies_before='$Implies_before' Implies_after='$Implies_after'" >&2
853 # Add the names implied by NAME, and NAME's parent (if it has one), to
854 # the list of names to be processed (the argument list). We prepend the
855 # implied names to the list and append the parent. We want implied
856 # directories to come before further directories inferred from the
857 # configuration components; this ensures that for sysv4, unix/common
858 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
859 # after sysv4).
860 sysnames="`echo $Implies $* $Implies_before $parent $Implies_after`"
861 test -n "$sysnames" && set $sysnames
862 done
864 # Add the default directories.
865 default_sysnames="sysdeps/generic"
866 sysnames="$names $default_sysnames"
867 AC_SUBST(sysnames)
868 # The other names were emitted during the scan.
869 AC_MSG_RESULT($default_sysnames)
871 # Collect the list of add-ons that supply partial sysdeps trees.
872 sysdeps_add_ons=
873 for add_on in $add_ons; do
874 case "$add_on" in
875 /*) xsrcdir= ;;
876 *) xsrcdir="$srcdir/" ;;
877 esac
879 test -d "$xsrcdir$add_on/sysdeps" || {
880 case "$configured_add_ons " in
881 *" $add_on "*) ;;
882 *|'')
883 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
884 ;;
885 esac
886 continue
887 }
889 sysdeps_add_ons="$sysdeps_add_ons $add_on"
890 case "$sysnames_add_ons" in
891 *" $add_on/ "*) ;;
892 *|'')
893 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
894 continue ;;
895 esac
897 found=no
898 for d in $sysnames; do
899 case "$d" in
900 $add_on/sysdeps/*) ;;
901 *) continue ;;
902 esac
903 (cd "$xsrcdir$d" && for f in *[[!~]]; do
904 case "$f" in
905 sys|bits)
906 for ff in $f/*.h; do
907 test -d "$ff" || { test -e "$ff" && exit 88; }
908 done
909 ;;
910 *)
911 test -d "$f" || { test -e "$f" && exit 88; }
912 ;;
913 esac
914 done)
915 if test $? -eq 88; then
916 found=yes
917 break
918 fi
919 done
920 if test $found = no; then
921 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
922 fi
923 done
924 AC_SUBST(sysdeps_add_ons)
927 ### Locate tools.
929 AC_PROG_INSTALL
930 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
931 # The makefiles need to use a different form to find it in $srcdir.
932 INSTALL='\$(..)./scripts/install-sh -c'
933 fi
934 AC_PROG_LN_S
936 LIBC_PROG_BINUTILS
938 # Accept binutils 2.22 or newer.
939 AC_CHECK_PROG_VER(AS, $AS, --version,
940 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
941 [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
942 AS=: critic_missing="$critic_missing as")
943 AC_CHECK_PROG_VER(LD, $LD, --version,
944 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
945 [2.1[0-9][0-9]*|2.2[2-9]*|2.[3-9][0-9]*|[3-9].*|[1-9][0-9]*],
946 LD=: critic_missing="$critic_missing ld")
948 # These programs are version sensitive.
949 AC_CHECK_TOOL_PREFIX
950 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
951 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
952 [3.79* | 3.[89]* | [4-9].* | [1-9][0-9]*], critic_missing="$critic_missing make")
954 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
955 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
956 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
957 MSGFMT=: aux_missing="$aux_missing msgfmt")
958 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
959 [GNU texinfo.* \([0-9][0-9.]*\)],
960 [4.[7-9]*|4.[1-9][0-9]*|[5-9].*],
961 MAKEINFO=: aux_missing="$aux_missing makeinfo")
962 AC_CHECK_PROG_VER(SED, sed, --version,
963 [GNU sed[^0-9]* \([0-9]*\.[0-9.]*\)],
964 [3.0[2-9]*|3.[1-9]*|[4-9]*],
965 SED=: aux_missing="$aux_missing sed")
966 AC_CHECK_PROG_VER(AWK, gawk, --version,
967 [GNU Awk[^0-9]*\([0-9][0-9.]*\)],
968 [3.1.[2-9]*|3.[2-9]*|[4-9]*], critic_missing="$critic_missing gawk")
970 AC_CACHE_CHECK([if $CC is sufficient to build libc], libc_cv_compiler_ok, [
971 AC_TRY_COMPILE([], [
972 #if !defined __GNUC__ || __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 6)
973 #error insufficient compiler
974 #endif],
975 [libc_cv_compiler_ok=yes],
976 [libc_cv_compiler_ok=no])])
977 AS_IF([test $libc_cv_compiler_ok != yes],
978 [critic_missing="$critic_missing compiler"])
980 AC_CHECK_TOOL(NM, nm, false)
982 if test "x$maintainer" = "xyes"; then
983 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
984 case "x$AUTOCONF" in
985 xno|x|x:) AUTOCONF=no ;;
986 *)
987 AC_CACHE_CHECK(dnl
988 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
989 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.ac > /dev/null 2>&1); then
990 libc_cv_autoconf_works=yes
991 else
992 libc_cv_autoconf_works=no
993 fi])
994 test $libc_cv_autoconf_works = yes || AUTOCONF=no
995 ;;
996 esac
997 if test "x$AUTOCONF" = xno; then
998 aux_missing="$aux_missing autoconf"
999 fi
1000 else
1001 AUTOCONF=no
1002 fi
1004 test -n "$critic_missing" && AC_MSG_ERROR([
1005 *** These critical programs are missing or too old:$critic_missing
1006 *** Check the INSTALL file for required versions.])
1008 test -n "$aux_missing" && AC_MSG_WARN([
1009 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1010 *** some features will be disabled.
1011 *** Check the INSTALL file for required versions.])
1013 # if using special system headers, find out the compiler's sekrit
1014 # header directory and add that to the list. NOTE: Only does the right
1015 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
1016 if test -n "$sysheaders"; then
1017 SYSINCLUDES=-nostdinc
1018 for d in include include-fixed; do
1019 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1020 SYSINCLUDES="$SYSINCLUDES -isystem $i"
1021 done
1022 SYSINCLUDES="$SYSINCLUDES \
1023 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1024 if test -n "$CXX"; then
1025 CXX_SYSINCLUDES=
1026 for cxxheaders in `$CXX -v -S -x c++ /dev/null -o /dev/null 2>&1 \
1027 | sed -n -e '1,/#include/d' -e 's/^ \(\/.*\/[cg]++\)/\1/p'`; do
1028 test "x$cxxheaders" != x &&
1029 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders"
1030 done
1031 fi
1032 fi
1033 AC_SUBST(SYSINCLUDES)
1034 AC_SUBST(CXX_SYSINCLUDES)
1036 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1037 # since this would lead to problems installing/building glibc.
1038 # LD_LIBRARY_PATH contains the current directory if one of the following
1039 # is true:
1040 # - one of the terminals (":" and ";") is the first or last sign
1041 # - two terminals occur directly after each other
1042 # - the path contains an element with a dot in it
1043 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1044 changequote(,)dnl
1045 case ${LD_LIBRARY_PATH} in
1046 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1047 ld_library_path_setting="contains current directory"
1048 ;;
1049 *)
1050 ld_library_path_setting="ok"
1051 ;;
1052 esac
1053 changequote([,])dnl
1054 AC_MSG_RESULT($ld_library_path_setting)
1055 if test "$ld_library_path_setting" != "ok"; then
1056 AC_MSG_ERROR([
1057 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1058 *** building glibc. Please change the environment variable
1059 *** and run configure again.])
1060 fi
1062 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1063 if $CC -v -static-libgcc 2>&1 | grep 'unrecognized option.*static-libgcc' >/dev/null; then
1064 libc_cv_gcc_static_libgcc=
1065 else
1066 libc_cv_gcc_static_libgcc=-static-libgcc
1067 fi])
1068 AC_SUBST(libc_cv_gcc_static_libgcc)
1070 AC_PATH_PROG(BASH_SHELL, bash, no)
1072 AC_PATH_PROG(PERL, perl, no)
1073 if test "$PERL" != no &&
1074 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1075 PERL=no
1076 fi
1077 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1078 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1079 AC_CHECK_PROG_VER(BISON, bison, --version,
1080 [bison (GNU Bison) \([0-9]*\.[0-9.]*\)],
1081 [2.7*|[3-9].*|[1-9][0-9]*],
1082 BISON=no)
1084 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1085 AC_TRY_COMPILE(dnl
1086 [#define __need_size_t
1087 #define __need_wchar_t
1088 #include <stddef.h>
1089 #define __need_NULL
1090 #include <stddef.h>], [size_t size; wchar_t wchar;
1091 #ifdef offsetof
1092 #error stddef.h ignored __need_*
1093 #endif
1094 if (&size == NULL || &wchar == NULL) abort ();],
1095 libc_cv_friendly_stddef=yes,
1096 libc_cv_friendly_stddef=no)])
1097 if test $libc_cv_friendly_stddef = yes; then
1098 config_vars="$config_vars
1099 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1100 fi
1102 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1103 libc_cv_need_minus_P, [dnl
1104 cat > conftest.S <<EOF
1105 #include "confdefs.h"
1106 /* Nothing whatsoever. */
1107 EOF
1108 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1109 libc_cv_need_minus_P=no
1110 else
1111 libc_cv_need_minus_P=yes
1112 fi
1113 rm -f conftest*])
1114 if test $libc_cv_need_minus_P = yes; then
1115 config_vars="$config_vars
1116 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1117 fi
1119 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1120 cat > conftest.s <<EOF
1121 ${libc_cv_dot_text}
1122 foo:
1123 .set glibc_conftest_frobozz,foo
1124 .globl glibc_conftest_frobozz
1125 EOF
1126 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1127 # (but it doesn't work), so we must do a linking check to be sure.
1128 cat > conftest1.c <<\EOF
1129 extern int glibc_conftest_frobozz;
1130 void _start() { glibc_conftest_frobozz = 1; }
1131 EOF
1132 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1133 -nostartfiles -nostdlib \
1134 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1135 libc_cv_asm_set_directive=yes
1136 else
1137 libc_cv_asm_set_directive=no
1138 fi
1139 rm -f conftest*])
1140 if test $libc_cv_asm_set_directive = yes; then
1141 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1142 fi
1144 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1145 libc_cv_asm_unique_object, [dnl
1146 cat > conftest.s <<EOF
1147 ${libc_cv_dot_text}
1148 _sym:
1149 .type _sym, %gnu_unique_object
1150 EOF
1151 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1152 libc_cv_asm_unique_object=yes
1153 else
1154 libc_cv_asm_unique_object=no
1155 fi
1156 rm -f conftest*])
1157 if test $libc_cv_asm_unique_object = yes; then
1158 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1159 fi
1161 AC_CACHE_CHECK(for .previous assembler directive,
1162 libc_cv_asm_previous_directive, [dnl
1163 cat > conftest.s <<EOF
1164 .section foo_section
1165 .previous
1166 EOF
1167 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1168 libc_cv_asm_previous_directive=yes
1169 else
1170 libc_cv_asm_previous_directive=no
1171 fi
1172 rm -f conftest*])
1173 if test $libc_cv_asm_previous_directive = yes; then
1174 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1175 else
1176 AC_CACHE_CHECK(for .popsection assembler directive,
1177 libc_cv_asm_popsection_directive, [dnl
1178 cat > conftest.s <<EOF
1179 .pushsection foo_section
1180 .popsection
1181 EOF
1182 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1183 libc_cv_asm_popsection_directive=yes
1184 else
1185 libc_cv_asm_popsection_directive=no
1186 fi
1187 rm -f conftest*])
1188 if test $libc_cv_asm_popsection_directive = yes; then
1189 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1190 fi
1191 fi
1192 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1193 libc_cv_asm_protected_directive, [dnl
1194 cat > conftest.s <<EOF
1195 .protected foo
1196 foo:
1197 .hidden bar
1198 bar:
1199 EOF
1200 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1201 libc_cv_asm_protected_directive=yes
1202 else
1203 AC_MSG_ERROR(assembler support for symbol visibility is required)
1204 fi
1205 rm -f conftest*])
1207 if test $libc_cv_asm_protected_directive = yes; then
1208 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1209 libc_cv_visibility_attribute,
1210 [cat > conftest.c <<EOF
1211 int foo __attribute__ ((visibility ("hidden"))) = 1;
1212 int bar __attribute__ ((visibility ("protected"))) = 1;
1213 EOF
1214 libc_cv_visibility_attribute=no
1215 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1216 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1217 if grep '\.protected.*bar' conftest.s >/dev/null; then
1218 libc_cv_visibility_attribute=yes
1219 fi
1220 fi
1221 fi
1222 rm -f conftest.{c,s}
1223 ])
1224 if test $libc_cv_visibility_attribute != yes; then
1225 AC_MSG_ERROR(compiler support for visibility attribute is required)
1226 fi
1227 fi
1229 if test $libc_cv_visibility_attribute = yes; then
1230 AC_CACHE_CHECK(linker support for protected data symbol,
1231 libc_cv_protected_data,
1232 [cat > conftest.c <<EOF
1233 int bar __attribute__ ((visibility ("protected"))) = 1;
1234 EOF
1235 libc_cv_protected_data=no
1236 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles -fPIC -shared conftest.c -o conftest.so); then
1237 cat > conftest.c <<EOF
1238 extern int bar;
1239 int main (void) { return bar; }
1240 EOF
1241 if AC_TRY_COMMAND(${CC-cc} -nostdlib -nostartfiles conftest.c -o conftest conftest.so); then
1242 libc_cv_protected_data=yes
1243 fi
1244 fi
1245 rm -f conftest.*
1246 ])
1247 else
1248 libc_cv_protected_data=no
1249 fi
1250 AC_SUBST(libc_cv_protected_data)
1252 if test $libc_cv_visibility_attribute = yes; then
1253 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1254 libc_cv_broken_visibility_attribute,
1255 [cat > conftest.c <<EOF
1256 int foo (int x);
1257 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1258 int bar (int x) { return x; }
1259 EOF
1260 libc_cv_broken_visibility_attribute=yes
1261 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1262 changequote(,)dnl
1263 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1264 changequote([,])dnl
1265 libc_cv_broken_visibility_attribute=no
1266 fi
1267 fi
1268 rm -f conftest.c conftest.s
1269 ])
1270 if test $libc_cv_broken_visibility_attribute = yes; then
1271 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1272 fi
1273 fi
1275 AC_CACHE_CHECK(for broken __attribute__((alias())),
1276 libc_cv_broken_alias_attribute,
1277 [cat > conftest.c <<EOF
1278 extern int foo (int x) __asm ("xyzzy");
1279 int bar (int x) { return x; }
1280 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1281 extern int dfoo;
1282 extern __typeof (dfoo) dfoo __asm ("abccb");
1283 int dfoo = 1;
1284 EOF
1285 libc_cv_broken_alias_attribute=yes
1286 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1287 if grep 'xyzzy' conftest.s >/dev/null &&
1288 grep 'abccb' conftest.s >/dev/null; then
1289 libc_cv_broken_alias_attribute=no
1290 fi
1291 fi
1292 rm -f conftest.c conftest.s
1293 ])
1294 if test $libc_cv_broken_alias_attribute = yes; then
1295 AC_MSG_ERROR(working alias attribute support required)
1296 fi
1298 if test $libc_cv_visibility_attribute = yes; then
1299 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1300 libc_cv_have_sdata_section,
1301 [echo "int i;" > conftest.c
1302 libc_cv_have_sdata_section=no
1303 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1304 | grep '\.sdata' >/dev/null; then
1305 libc_cv_have_sdata_section=yes
1306 fi
1307 rm -f conftest.c conftest.so
1308 ])
1309 if test $libc_cv_have_sdata_section = yes; then
1310 AC_DEFINE(HAVE_SDATA_SECTION)
1311 fi
1312 fi
1314 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1315 libc_cv_initfini_array, [dnl
1316 LIBC_TRY_LINK_STATIC([
1317 int foo (void) { return 1; }
1318 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1319 ],
1320 [if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1321 libc_cv_initfini_array=yes
1322 else
1323 libc_cv_initfini_array=no
1324 fi],
1325 [libc_cv_initfini_array=no])
1326 ])
1327 if test $libc_cv_initfini_array != yes; then
1328 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1329 fi
1331 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1332 libc_cv_ctors_header, [dnl
1333 libc_cv_ctors_header=yes
1334 LIBC_TRY_LINK_STATIC([
1335 __attribute__ ((constructor)) void ctor (void) { asm (""); }
1336 __attribute__ ((destructor)) void dtor (void) { asm (""); }
1337 ],
1338 [dnl
1339 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1340 { gsub(/\@<:@ */, "@<:@") }
1341 $2 == ".ctors" || $2 == ".dtors" {
1342 size = strtonum("0x" $6)
1343 align = strtonum("0x" $NF)
1344 seen@<:@$2@:>@ = 1
1345 stub@<:@$2@:>@ = size == align * 2
1346 }
1347 END {
1348 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1349 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1350 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1351 }
1352 '], [libc_cv_ctors_header=no])
1353 ], [dnl
1354 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1355 ])
1356 ])
1357 if test $libc_cv_ctors_header = no; then
1358 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1359 fi
1361 AC_CACHE_CHECK(for libunwind-support in compiler,
1362 libc_cv_cc_with_libunwind, [
1363 cat > conftest.c <<EOF
1364 int main (void) { return 0; }
1365 EOF
1366 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1367 conftest.c -v 2>&1 >/dev/null | grep ' -lunwind ' >/dev/null; then
1368 libc_cv_cc_with_libunwind=yes
1369 else
1370 libc_cv_cc_with_libunwind=no
1371 fi
1372 rm -f conftest*])
1373 AC_SUBST(libc_cv_cc_with_libunwind)
1374 if test $libc_cv_cc_with_libunwind = yes; then
1375 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1376 fi
1378 LIBC_LINKER_FEATURE([-z nodelete], [-Wl,--enable-new-dtags,-z,nodelete],
1379 [libc_cv_z_nodelete=yes],
1380 [AC_MSG_ERROR(linker with -z nodelete support required)])
1382 LIBC_LINKER_FEATURE([-z nodlopen], [-Wl,--enable-new-dtags,-z,nodlopen],
1383 [libc_cv_z_nodlopen=yes],
1384 [AC_MSG_ERROR(linker with -z nodlopen support required)])
1386 LIBC_LINKER_FEATURE([-z initfirst], [-Wl,--enable-new-dtags,-z,initfirst],
1387 [libc_cv_z_initfirst=yes],
1388 [AC_MSG_ERROR(linker with -z initfirst support required)])
1390 AC_CACHE_CHECK(for -Bgroup option,
1391 libc_cv_Bgroup, [dnl
1392 cat > conftest.c <<EOF
1393 int _start (void) { return 42; }
1394 EOF
1395 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1396 -fPIC -shared -o conftest.so conftest.c
1397 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1398 then
1399 libc_cv_Bgroup=yes
1400 else
1401 libc_cv_Bgroup=no
1402 fi
1403 rm -f conftest*])
1404 AC_SUBST(libc_cv_Bgroup)
1406 ASFLAGS_config=
1407 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1408 libc_cv_as_noexecstack, [dnl
1409 cat > conftest.c <<EOF
1410 void foo (void) { }
1411 EOF
1412 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1413 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1414 && grep .note.GNU-stack conftest.s >/dev/null \
1415 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1416 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1417 then
1418 libc_cv_as_noexecstack=yes
1419 else
1420 libc_cv_as_noexecstack=no
1421 fi
1422 rm -f conftest*])
1423 if test $libc_cv_as_noexecstack = yes; then
1424 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1425 fi
1426 AC_SUBST(ASFLAGS_config)
1428 AC_CACHE_CHECK(for -z combreloc,
1429 libc_cv_z_combreloc, [dnl
1430 cat > conftest.c <<EOF
1431 extern int bar (int);
1432 extern int mumble;
1433 int foo (void) { return bar (mumble); }
1434 EOF
1435 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1436 -fPIC -shared -o conftest.so conftest.c
1437 -nostdlib -nostartfiles
1438 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1439 then
1440 dnl The following test is a bit weak. We must use a tool which can test
1441 dnl cross-platform since the gcc used can be a cross compiler. Without
1442 dnl introducing new options this is not easily doable. Instead use a tool
1443 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1444 dnl look for a section named .rel.dyn.
1445 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1446 libc_cv_z_combreloc=yes
1447 else
1448 libc_cv_z_combreloc=no
1449 fi
1450 else
1451 libc_cv_z_combreloc=no
1452 fi
1453 rm -f conftest*])
1454 if test "$libc_cv_z_combreloc" = yes; then
1455 AC_DEFINE(HAVE_Z_COMBRELOC)
1456 fi
1457 AC_SUBST(libc_cv_z_combreloc)
1459 LIBC_LINKER_FEATURE([-z execstack], [-Wl,-z,execstack],
1460 [libc_cv_z_execstack=yes], [libc_cv_z_execstack=no])
1461 AC_SUBST(libc_cv_z_execstack)
1463 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1464 LIBC_TRY_CC_OPTION([-fpie], [libc_cv_fpie=yes], [libc_cv_fpie=no])
1465 ])
1467 AC_SUBST(libc_cv_fpie)
1469 AC_CACHE_CHECK(for --hash-style option,
1470 libc_cv_hashstyle, [dnl
1471 cat > conftest.c <<EOF
1472 int _start (void) { return 42; }
1473 EOF
1474 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1475 -fPIC -shared -o conftest.so conftest.c
1476 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1477 then
1478 libc_cv_hashstyle=yes
1479 else
1480 libc_cv_hashstyle=no
1481 fi
1482 rm -f conftest*])
1483 AC_SUBST(libc_cv_hashstyle)
1485 # The linker's default -shared behavior is good enough if it
1486 # does these things that our custom linker scripts ensure that
1487 # all allocated NOTE sections come first.
1488 if test "$use_default_link" = default; then
1489 AC_CACHE_CHECK([for sufficient default -shared layout],
1490 libc_cv_use_default_link, [dnl
1491 libc_cv_use_default_link=no
1492 cat > conftest.s <<\EOF
1493 .section .note.a,"a",%note
1494 .balign 4
1495 .long 4,4,9
1496 .string "GNU"
1497 .string "foo"
1498 .section .note.b,"a",%note
1499 .balign 4
1500 .long 4,4,9
1501 .string "GNU"
1502 .string "bar"
1503 EOF
1504 if AC_TRY_COMMAND([dnl
1505 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1506 ac_try=`$READELF -S conftest.so | sed -n \
1507 ['${x;p;}
1508 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1509 t a
1510 b
1511 : a
1512 H']`
1513 then
1514 libc_seen_a=no libc_seen_b=no
1515 set -- $ac_try
1516 while test $# -ge 2 -a "$1" = NOTE; do
1517 case "$2" in
1518 .note.a) libc_seen_a=yes ;;
1519 .note.b) libc_seen_b=yes ;;
1520 esac
1521 shift 2
1522 done
1523 case "$libc_seen_a$libc_seen_b" in
1524 yesyes)
1525 libc_cv_use_default_link=yes
1526 ;;
1527 *)
1528 echo >&AS_MESSAGE_LOG_FD "\
1529 $libc_seen_a$libc_seen_b from:
1530 $ac_try"
1531 ;;
1532 esac
1533 fi
1534 rm -f conftest*])
1535 use_default_link=$libc_cv_use_default_link
1536 fi
1538 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1539 if libc_cv_output_format=`
1540 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1541 then
1542 :
1543 else
1544 libc_cv_output_format=
1545 fi
1546 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1547 AC_SUBST(libc_cv_output_format)
1549 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1550 cat > conftest.c <<EOF
1551 int foo;
1552 EOF
1553 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1554 conftest.c 1>&AS_MESSAGE_LOG_FD])
1555 then
1556 libc_cv_fno_toplevel_reorder=yes
1557 else
1558 libc_cv_fno_toplevel_reorder=no
1559 fi
1560 rm -f conftest*])
1561 if test $libc_cv_fno_toplevel_reorder = yes; then
1562 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1563 else
1564 fno_unit_at_a_time=-fno-unit-at-a-time
1565 fi
1566 AC_SUBST(fno_unit_at_a_time)
1568 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1569 LIBC_TRY_CC_OPTION([$CFLAGS $CPPFLAGS -Werror -fstack-protector],
1570 [libc_cv_ssp=yes],
1571 [libc_cv_ssp=no])
1572 ])
1573 AC_SUBST(libc_cv_ssp)
1575 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1576 cat > conftest.c <<EOF
1577 int foo;
1578 #ifdef __GNUC_GNU_INLINE__
1579 main () { return 0;}
1580 #else
1581 #error
1582 #endif
1583 EOF
1584 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1585 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1586 then
1587 libc_cv_gnu89_inline=yes
1588 else
1589 libc_cv_gnu89_inline=no
1590 fi
1591 rm -f conftest*])
1592 if test $libc_cv_gnu89_inline = yes; then
1593 gnu89_inline=-fgnu89-inline
1594 else
1595 gnu89_inline=
1596 fi
1597 AC_SUBST(gnu89_inline)
1599 AC_CACHE_CHECK(whether cc puts quotes around section names,
1600 libc_cv_have_section_quotes,
1601 [cat > conftest.c <<EOF
1602 static const int foo
1603 __attribute__ ((section ("bar"))) = 1;
1604 EOF
1605 if ${CC-cc} -S conftest.c -o conftest.s; then
1606 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1607 libc_cv_have_section_quotes=yes
1608 else
1609 libc_cv_have_section_quotes=no
1610 fi
1611 else
1612 libc_cv_have_section_quotes=unknown
1613 fi
1614 rm -f conftest.{c,s}
1615 ])
1616 if test $libc_cv_have_section_quotes = yes; then
1617 AC_DEFINE(HAVE_SECTION_QUOTES)
1618 fi
1620 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1621 [dnl
1622 cat > conftest.s <<EOF
1623 ${libc_cv_dot_text}
1624 .globl foo
1625 foo:
1626 .weak foo
1627 .weak bar; bar = foo
1628 EOF
1629 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1630 libc_cv_asm_weak_directive=yes
1631 else
1632 libc_cv_asm_weak_directive=no
1633 fi
1634 rm -f conftest*])
1636 if test $libc_cv_asm_weak_directive = no; then
1637 AC_CACHE_CHECK(for assembler .weakext directive,
1638 libc_cv_asm_weakext_directive,
1639 [dnl
1640 cat > conftest.s <<EOF
1641 ${libc_cv_dot_text}
1642 .globl foo
1643 foo:
1644 .weakext bar foo
1645 .weakext baz
1646 .globl baz
1647 baz:
1648 EOF
1649 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1650 libc_cv_asm_weakext_directive=yes
1651 else
1652 libc_cv_asm_weakext_directive=no
1653 fi
1654 rm -f conftest*])
1656 fi # no .weak
1658 if test $libc_cv_asm_weak_directive = yes; then
1659 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1660 elif test $libc_cv_asm_weakext_directive = yes; then
1661 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1662 fi
1664 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1665 cat > conftest.c <<\EOF
1666 _start () {}
1667 int __eh_pc;
1668 __throw () {}
1669 EOF
1670 dnl No \ in command here because it ends up inside ''.
1671 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1672 -nostdlib -nostartfiles -Wl,--no-whole-archive
1673 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1674 libc_cv_ld_no_whole_archive=yes
1675 else
1676 libc_cv_ld_no_whole_archive=no
1677 fi
1678 rm -f conftest*])
1679 if test $libc_cv_ld_no_whole_archive = no; then
1680 AC_MSG_ERROR([support for --no-whole-archive is needed])
1681 fi
1683 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1684 cat > conftest.c <<\EOF
1685 _start () {}
1686 int __eh_pc;
1687 __throw () {}
1688 EOF
1689 dnl No \ in command here because it ends up inside ''.
1690 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1691 -nostdlib -nostartfiles -fexceptions
1692 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1693 libc_cv_gcc_exceptions=yes
1694 else
1695 libc_cv_gcc_exceptions=no
1696 fi
1697 rm -f conftest*])
1698 if test $libc_cv_gcc_exceptions = yes; then
1699 exceptions=-fexceptions
1700 fi
1701 AC_SUBST(exceptions)dnl
1703 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1704 cat > conftest.c <<\EOF
1705 void zero (void *x)
1706 {
1707 __builtin_memset (x, 0, 1000);
1708 }
1709 EOF
1710 dnl
1711 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1712 then
1713 libc_cv_gcc_builtin_memset=no
1714 else
1715 libc_cv_gcc_builtin_memset=yes
1716 fi
1717 rm -f conftest* ])
1718 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1719 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1720 fi
1722 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1723 cat > conftest.c <<\EOF
1724 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1725 char *foo (const char *a, const char *b)
1726 {
1727 return __builtin_strstr (a, b);
1728 }
1729 EOF
1730 dnl
1731 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1732 then
1733 libc_cv_gcc_builtin_redirection=yes
1734 else
1735 libc_cv_gcc_builtin_redirection=no
1736 fi
1737 rm -f conftest* ])
1738 if test "$libc_cv_gcc_builtin_redirection" = no; then
1739 AC_MSG_ERROR([support for the symbol redirection needed])
1740 fi
1742 dnl Check whether the compiler supports the __thread keyword.
1743 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1744 [cat > conftest.c <<\EOF
1745 __thread int a = 42;
1746 EOF
1747 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1748 libc_cv_gcc___thread=yes
1749 else
1750 libc_cv_gcc___thread=no
1751 fi
1752 rm -f conftest*])
1753 if test "$libc_cv_gcc___thread" = no; then
1754 AC_MSG_ERROR([support for the __thread keyword is required])
1755 fi
1757 dnl Check whether the compiler supports the tls_model attribute.
1758 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
1759 cat > conftest.c <<\EOF
1760 extern __thread int a __attribute__((tls_model ("initial-exec")));
1761 EOF
1762 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
1763 libc_cv_gcc_tls_model_attr=yes
1764 else
1765 libc_cv_gcc_tls_model_attr=no
1766 fi
1767 rm -f conftest*])
1768 if test "$libc_cv_gcc_tls_model_attr" = no; then
1769 AC_MSG_ERROR([support for the tls_model attribute is required])
1770 fi
1772 dnl Determine how to disable generation of FMA instructions.
1773 AC_CACHE_CHECK([for compiler option to disable generation of FMA instructions],
1774 libc_cv_cc_nofma, [dnl
1775 libc_cv_cc_nofma=
1776 for opt in -ffp-contract=off -mno-fused-madd; do
1777 LIBC_TRY_CC_OPTION([$opt], [libc_cv_cc_nofma=$opt; break])
1778 done])
1779 AC_SUBST(libc_cv_cc_nofma)
1781 if test -n "$submachine"; then
1782 AC_CACHE_CHECK([for compiler option for CPU variant],
1783 libc_cv_cc_submachine, [dnl
1784 libc_cv_cc_submachine=no
1785 for opt in "-march=$submachine" "-mcpu=$submachine"; do
1786 LIBC_TRY_CC_OPTION([$opt], [
1787 libc_cv_cc_submachine="$opt"
1788 break], [])
1789 done])
1790 if test "x$libc_cv_cc_submachine" = xno; then
1791 AC_MSG_ERROR([${CC-cc} does not support $submachine])
1792 fi
1793 fi
1794 AC_SUBST(libc_cv_cc_submachine)
1796 AC_CACHE_CHECK(if $CC accepts -fno-tree-loop-distribute-patterns with \
1797 __attribute__ ((__optimize__)), libc_cv_cc_loop_to_function, [dnl
1798 cat > conftest.c <<EOF
1799 void
1800 __attribute__ ((__optimize__ ("-fno-tree-loop-distribute-patterns")))
1801 foo (void) {}
1802 EOF
1803 libc_cv_cc_loop_to_function=no
1804 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c])
1805 then
1806 libc_cv_cc_loop_to_function=yes
1807 fi
1808 rm -f conftest*])
1809 if test $libc_cv_cc_loop_to_function = yes; then
1810 AC_DEFINE(HAVE_CC_INHIBIT_LOOP_TO_LIBCALL)
1811 fi
1812 AC_SUBST(libc_cv_cc_loop_to_function)
1814 dnl Check whether we have the gd library available.
1815 AC_MSG_CHECKING(for libgd)
1816 if test "$with_gd" != "no"; then
1817 old_CFLAGS="$CFLAGS"
1818 CFLAGS="$CFLAGS $libgd_include"
1819 old_LDFLAGS="$LDFLAGS"
1820 LDFLAGS="$LDFLAGS $libgd_ldflags"
1821 old_LIBS="$LIBS"
1822 LIBS="$LIBS -lgd -lpng -lz -lm"
1823 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1824 CFLAGS="$old_CFLAGS"
1825 LDFLAGS="$old_LDFLAGS"
1826 LIBS="$old_LIBS"
1827 else
1828 LIBGD=no
1829 fi
1830 AC_MSG_RESULT($LIBGD)
1831 AC_SUBST(LIBGD)
1833 # SELinux detection
1834 if test x$with_selinux = xno ; then
1835 have_selinux=no;
1836 else
1837 # See if we have the SELinux library
1838 AC_CHECK_LIB(selinux, is_selinux_enabled,
1839 have_selinux=yes, have_selinux=no)
1840 if test x$with_selinux = xyes ; then
1841 if test x$have_selinux = xno ; then
1842 AC_MSG_ERROR([SELinux explicitly required, but SELinux library not found])
1843 fi
1844 fi
1845 fi
1846 # Check if we're building with SELinux support.
1847 if test "x$have_selinux" = xyes; then
1848 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
1850 # See if we have the libaudit library
1851 AC_CHECK_LIB(audit, audit_log_user_avc_message,
1852 have_libaudit=yes, have_libaudit=no)
1853 if test "x$have_libaudit" = xyes; then
1854 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
1855 fi
1856 AC_SUBST(have_libaudit)
1858 # See if we have the libcap library
1859 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
1860 if test "x$have_libcap" = xyes; then
1861 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
1862 fi
1863 AC_SUBST(have_libcap)
1864 fi
1865 AC_SUBST(have_selinux)
1867 dnl check for the size of 'long double'.
1868 AC_CHECK_SIZEOF(long double, 0)
1869 sizeof_long_double=$ac_cv_sizeof_long_double
1870 AC_SUBST(sizeof_long_double)
1872 CPPUNDEFS=
1873 dnl Check for silly hacked compilers predefining _FORTIFY_SOURCE.
1874 dnl Since we are building the implementations of the fortified functions here,
1875 dnl having the macro defined interacts very badly.
1876 AC_CACHE_CHECK([for _FORTIFY_SOURCE predefine], libc_cv_predef_fortify_source,
1877 [AC_TRY_COMPILE([], [
1878 #ifdef _FORTIFY_SOURCE
1879 # error bogon
1880 #endif],
1881 [libc_cv_predef_fortify_source=no],
1882 [libc_cv_predef_fortify_source=yes])])
1883 if test $libc_cv_predef_fortify_source = yes; then
1884 CPPUNDEFS="${CPPUNDEFS:+$CPPUNDEFS }-U_FORTIFY_SOURCE"
1885 fi
1886 AC_SUBST(CPPUNDEFS)
1888 dnl Check for silly hacked compilers inserting -fstack-protector.
1889 dnl This breaks badly for the early startup code we compile, since
1890 dnl the compiled code can refer to a magic machine-dependent location
1891 dnl for the canary value before we have sufficient setup for that to
1892 dnl work. It's also questionable to build all of libc with this flag
1893 dnl even when you're doing that for most applications you build, since
1894 dnl libc's code is so heavily-used and performance-sensitive. If we
1895 dnl ever really want to make that work, it should be enabled explicitly
1896 dnl in the libc build, not inherited from implicit compiler settings.
1897 AC_CACHE_CHECK([whether $CC implicitly enables -fstack-protector],
1898 libc_cv_predef_stack_protector, [
1899 AC_TRY_COMPILE([extern void foobar (char *);],
1900 [char large_array[2048]; foobar (large_array);], [
1901 libc_undefs=`$NM -u conftest.o |
1902 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1903 2>&AS_MESSAGE_LOG_FD` || {
1904 AC_MSG_ERROR([confusing output from $NM -u])
1905 }
1906 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1907 # On some architectures, there are architecture-specific undefined
1908 # symbols (resolved by the linker), so filter out unknown symbols.
1909 # This will fail to produce the correct result if the compiler
1910 # defaults to -fstack-protector but this produces an undefined symbol
1911 # other than __stack_chk_fail. However, compilers like that have not
1912 # been encountered in practice.
1913 libc_undefs=`echo "$libc_undefs" | egrep '^(foobar|__stack_chk_fail)$'`
1914 case "$libc_undefs" in
1915 foobar) libc_cv_predef_stack_protector=no ;;
1916 '__stack_chk_fail
1917 foobar') libc_cv_predef_stack_protector=yes ;;
1918 *) AC_MSG_ERROR([unexpected symbols in test: $libc_undefs]) ;;
1919 esac],
1920 [AC_MSG_ERROR([test compilation failed])])
1921 ])
1922 libc_extra_cflags=
1923 if test $libc_cv_predef_stack_protector = yes; then
1924 libc_extra_cflags="$libc_extra_cflags -fno-stack-protector"
1925 fi
1926 libc_extra_cppflags=
1928 # Some linkers on some architectures support __ehdr_start but with
1929 # bugs. Make sure usage of it does not create relocations in the
1930 # output (as the linker should resolve them all for us).
1931 AC_CACHE_CHECK([whether the linker provides working __ehdr_start],
1932 libc_cv_ehdr_start, [
1933 old_CFLAGS="$CFLAGS"
1934 old_LDFLAGS="$LDFLAGS"
1935 old_LIBS="$LIBS"
1936 CFLAGS="$CFLAGS -fPIC"
1937 LDFLAGS="$LDFLAGS -nostdlib -nostartfiles -shared"
1938 LIBS=
1939 AC_LINK_IFELSE([AC_LANG_SOURCE([
1940 typedef struct {
1941 char foo;
1942 long val;
1943 } Ehdr;
1944 extern const Ehdr __ehdr_start __attribute__ ((visibility ("hidden")));
1945 long ehdr (void) { return __ehdr_start.val; }
1946 ])],
1947 [if $READELF -r conftest | fgrep __ehdr_start >/dev/null; then
1948 libc_cv_ehdr_start=broken
1949 else
1950 libc_cv_ehdr_start=yes
1951 fi], [libc_cv_ehdr_start=no])
1952 CFLAGS="$old_CFLAGS"
1953 LDFLAGS="$old_LDFLAGS"
1954 LIBS="$old_LIBS"
1955 ])
1956 if test "$libc_cv_ehdr_start" = yes; then
1957 AC_DEFINE([HAVE_EHDR_START])
1958 elif test "$libc_cv_ehdr_start" = broken; then
1959 AC_MSG_WARN([linker is broken -- you should upgrade])
1960 fi
1962 AC_CACHE_CHECK(for __builtin_trap with no external dependencies,
1963 libc_cv_builtin_trap, [dnl
1964 libc_cv_builtin_trap=no
1965 AC_TRY_COMPILE([], [__builtin_trap ()], [
1966 libc_undefs=`$NM -u conftest.o |
1967 LC_ALL=C $AWK '$1 == "U" { print $2 | "sort -u"; next } { exit(1) }' \
1968 2>&AS_MESSAGE_LOG_FD` || {
1969 AC_MSG_ERROR([confusing output from $NM -u])
1970 }
1971 echo >&AS_MESSAGE_LOG_FD "libc_undefs='$libc_undefs'"
1972 if test -z "$libc_undefs"; then
1973 libc_cv_builtin_trap=yes
1974 fi])])
1975 if test $libc_cv_builtin_trap = yes; then
1976 AC_DEFINE([HAVE_BUILTIN_TRAP])
1977 fi
1979 ### End of automated tests.
1980 ### Now run sysdeps configure fragments.
1982 # They also can set these variables.
1983 use_ldconfig=no
1984 ldd_rewrite_script=no
1985 libc_cv_sysconfdir=$sysconfdir
1986 libc_cv_localstatedir=$localstatedir
1987 libc_cv_gcc_unwind_find_fde=no
1988 libc_cv_idn=no
1990 # Iterate over all the sysdep directories we will use, running their
1991 # configure fragments.
1992 for dir in $sysnames; do
1993 case $dir in
1994 /*) dest=$dir ;;
1995 *) dest=$srcdir/$dir ;;
1996 esac
1997 if test -r $dest/configure; then
1998 AC_MSG_RESULT(running configure fragment for $dir)
1999 . $dest/configure
2000 fi
2001 done
2003 if test x"$build_mathvec" = xnotset; then
2004 build_mathvec=no
2005 fi
2006 LIBC_CONFIG_VAR([build-mathvec], [$build_mathvec])
2008 AC_SUBST(libc_extra_cflags)
2009 AC_SUBST(libc_extra_cppflags)
2011 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2012 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2013 fi
2014 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2016 # A sysdeps configure fragment can reset this if IFUNC is not actually
2017 # usable even though the assembler knows how to generate the symbol type.
2018 if test x"$libc_cv_ld_gnu_indirect_function" = xyes; then
2019 AC_DEFINE(HAVE_IFUNC)
2020 fi
2022 # This is far from the AC_ARG_ENABLE that sets it so that a sysdeps
2023 # configure fragment can override the value to prevent this AC_DEFINE.
2024 AC_SUBST(use_nscd)
2025 if test "x$use_nscd" != xno; then
2026 AC_DEFINE([USE_NSCD])
2027 fi
2028 if test "x$build_nscd" = xdefault; then
2029 build_nscd=$use_nscd
2030 fi
2032 # Test for old glibc 2.0.x headers so that they can be removed properly
2033 # Search only in includedir.
2034 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2035 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2036 then
2037 old_glibc_headers=yes
2038 else
2039 old_glibc_headers=no
2040 fi
2041 AC_MSG_RESULT($old_glibc_headers)
2042 if test ${old_glibc_headers} = yes; then
2043 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2044 AC_MSG_WARN(*** be removed.)
2045 fi
2046 AC_SUBST(old_glibc_headers)
2048 AC_SUBST(libc_cv_slibdir)
2049 AC_SUBST(libc_cv_rtlddir)
2050 AC_SUBST(libc_cv_localedir)
2051 AC_SUBST(libc_cv_sysconfdir)
2052 AC_SUBST(libc_cv_localstatedir)
2053 AC_SUBST(libc_cv_rootsbindir)
2054 AC_SUBST(libc_cv_forced_unwind)
2056 if test x$use_ldconfig = xyes; then
2057 AC_DEFINE(USE_LDCONFIG)
2058 fi
2059 AC_SUBST(use_ldconfig)
2060 AC_SUBST(ldd_rewrite_script)
2062 AC_SUBST(static)
2063 AC_SUBST(shared)
2065 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2066 [libc_cv_pic_default=yes
2067 cat > conftest.c <<EOF
2068 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2069 # error PIC is default.
2070 #endif
2071 EOF
2072 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2073 libc_cv_pic_default=no
2074 fi
2075 rm -f conftest.*])
2076 AC_SUBST(libc_cv_pic_default)
2078 AC_SUBST(profile)
2079 AC_SUBST(static_nss)
2081 AC_SUBST(DEFINES)
2083 dnl See sysdeps/mach/configure.ac for this variable.
2084 AC_SUBST(mach_interface_list)
2086 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2087 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2088 AC_SUBST(VERSION)
2089 AC_SUBST(RELEASE)
2091 AC_CONFIG_FILES([config.make Makefile])
2092 AC_CONFIG_COMMANDS([default],[[
2093 case $CONFIG_FILES in *config.make*)
2094 echo "$config_vars" >> config.make;;
2095 esac
2096 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2097 AC_OUTPUT