sysdeps/alpha/ffs.S

   1 /* Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   2    Contributed by David Mosberger (davidm@cs.arizona.edu).
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 /* Finds the first bit set in an integer.  Optimized for the Alpha
  21    architecture.  */
  22
  23 #include <sysdep.h>
  24
  25         .set noreorder
  26         .set noat
  27
  28 ENTRY(__ffs)
  29 #ifdef PROF
  30         ldgp    gp, 0(pv)
  31         lda     AT, _mcount
  32         jsr     AT, (AT), _mcount
  33         .prologue 1
  34 #else
  35         .prologue 0
  36 #endif
  37
  38         ldq_u   zero, 0(sp)     # on the 21064, this helps dual-issuing
  39         addl    a0, zero, a0    # the last insn and reduces the stall
  40         negq    a0, t0          # due to the srl instruction
  41         and     a0, t0, t0
  42         clr     v0
  43         beq     a0, $done
  44
  45         # now do binary search for first non-zero bit
  46
  47         zapnot  t0, 0x03, t2
  48         addq    v0, 16, t3
  49         cmoveq  t2, t3, v0
  50
  51         zapnot  t0, 0x05, t2
  52         addq    v0, 8, t3
  53         cmoveq  t2, t3, v0
  54
  55         srl     t0, v0, t0
  56         addq    v0, 1, v0
  57
  58         and     t0, 0x0f, t2
  59         addq    v0, 4, t3
  60         cmoveq  t2, t3, v0
  61
  62         and     t0, 0x33, t2
  63         addq    v0, 2, t3
  64         cmoveq  t2, t3, v0
  65
  66         and     t0, 0x55, t2
  67         addq    v0, 1, t3
  68         cmoveq  t2, t3, v0
  69
  70 $done:  ret
  71
  72         END(__ffs)
  73 weak_alias (__ffs, ffs)