sysdeps/rs6000/addmul_1.s

   1 # IBM POWER __mpn_addmul_1 -- Multiply a limb vector with a limb and add
   2 # the result to a second limb vector.
   3
   4 # Copyright (C) 1992, 1994 Free Software Foundation, Inc.
   5
   6 # This file is part of the GNU MP Library.
   7
   8 # The GNU MP Library is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU Library General Public License as published by
  10 # the Free Software Foundation; either version 2 of the License, or (at your
  11 # option) any later version.
  12
  13 # The GNU MP Library is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  15 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
  16 # License for more details.
  17
  18 # You should have received a copy of the GNU Library General Public License
  19 # along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
  20 # the Free Software Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  21
  22
  23 # INPUT PARAMETERS
  24 # res_ptr       r3
  25 # s1_ptr        r4
  26 # size          r5
  27 # s2_limb       r6
  28
  29 # The RS/6000 has no unsigned 32x32->64 bit multiplication instruction.  To
  30 # obtain that operation, we have to use the 32x32->64 signed multiplication
  31 # instruction, and add the appropriate compensation to the high limb of the
  32 # result.  We add the multiplicand if the multiplier has its most significant
  33 # bit set, and we add the multiplier if the multiplicand has its most
  34 # significant bit set.  We need to preserve the carry flag between each
  35 # iteration, so we have to compute the compensation carefully (the natural,
  36 # srai+and doesn't work).  Since the POWER architecture has a branch unit
  37 # we can branch in zero cycles, so that's how we perform the additions.
  38
  39         .toc
  40         .csect .__mpn_addmul_1[PR]
  41         .align 2
  42         .globl __mpn_addmul_1
  43         .globl .__mpn_addmul_1
  44         .csect __mpn_addmul_1[DS]
  45 __mpn_addmul_1:
  46         .long .__mpn_addmul_1[PR], TOC[tc0], 0
  47         .csect .__mpn_addmul_1[PR]
  48 .__mpn_addmul_1:
  49
  50         cal     3,-4(3)
  51         l       0,0(4)
  52         cmpi    0,6,0
  53         mtctr   5
  54         mul     9,0,6
  55         srai    7,0,31
  56         and     7,7,6
  57         mfmq    8
  58         cax     9,9,7
  59         l       7,4(3)
  60         a       8,8,7           # add res_limb
  61         blt     Lneg
  62 Lpos:   bdz     Lend
  63
  64 Lploop: lu      0,4(4)
  65         stu     8,4(3)
  66         cmpi    0,0,0
  67         mul     10,0,6
  68         mfmq    0
  69         ae      8,0,9           # low limb + old_cy_limb + old cy
  70         l       7,4(3)
  71         aze     10,10           # propagate cy to new cy_limb
  72         a       8,8,7           # add res_limb
  73         bge     Lp0
  74         cax     10,10,6         # adjust high limb for negative limb from s1
  75 Lp0:    bdz     Lend0
  76         lu      0,4(4)
  77         stu     8,4(3)
  78         cmpi    0,0,0
  79         mul     9,0,6
  80         mfmq    0
  81         ae      8,0,10
  82         l       7,4(3)
  83         aze     9,9
  84         a       8,8,7
  85         bge     Lp1
  86         cax     9,9,6           # adjust high limb for negative limb from s1
  87 Lp1:    bdn     Lploop
  88
  89         b       Lend
  90
  91 Lneg:   cax     9,9,0
  92         bdz     Lend
  93 Lnloop: lu      0,4(4)
  94         stu     8,4(3)
  95         cmpi    0,0,0
  96         mul     10,0,6
  97         mfmq    7
  98         ae      8,7,9
  99         l       7,4(3)
 100         ae      10,10,0         # propagate cy to new cy_limb
 101         a       8,8,7           # add res_limb
 102         bge     Ln0
 103         cax     10,10,6         # adjust high limb for negative limb from s1
 104 Ln0:    bdz     Lend0
 105         lu      0,4(4)
 106         stu     8,4(3)
 107         cmpi    0,0,0
 108         mul     9,0,6
 109         mfmq    7
 110         ae      8,7,10
 111         l       7,4(3)
 112         ae      9,9,0           # propagate cy to new cy_limb
 113         a       8,8,7           # add res_limb
 114         bge     Ln1
 115         cax     9,9,6           # adjust high limb for negative limb from s1
 116 Ln1:    bdn     Lnloop
 117         b       Lend
 118
 119 Lend0:  cal     9,0(10)
 120 Lend:   st      8,4(3)
 121         aze     3,9
 122         br