sysdeps/unix/sysv/linux/s390/s390-32/getcontext.S

   1 /* Copyright (C) 2001-2023 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library; if not, see
  16    <https://www.gnu.org/licenses/>.  */
  17
  18 #include <sysdep.h>
  19 #include <features.h>
  20
  21 #include "ucontext_i.h"
  22
  23 #include <shlib-compat.h>
  24
  25 /*  __getcontext (const ucontext_t *ucp)
  26
  27   Saves the machine context in UCP such that when it is activated,
  28   it appears as if __getcontext() returned again.
  29
  30   This implementation is intended to be used for *synchronous* context
  31   switches only.  Therefore, it does not have to save anything
  32   other than the PRESERVED state.  */
  33
  34 ENTRY(__getcontext)
  35         lr      %r0,%r2
  36
  37         /* rt_sigprocmask (SIG_BLOCK, NULL, &sc->sc_mask, sigsetsize).  */
  38         la      %r4,SC_MASK(%r2)
  39         la      %r2,SIG_BLOCK
  40         slr     %r3,%r3
  41         lhi     %r5,_NSIG8
  42         lhi     %r1,SYS_ify(rt_sigprocmask)
  43         svc     0
  44
  45         /* Store fpu context.  */
  46         lr      %r1,%r0
  47         stfpc   SC_FPC(%r1)
  48         std     %f0,SC_FPRS(%r1)
  49         std     %f1,SC_FPRS+8(%r1)
  50         std     %f2,SC_FPRS+16(%r1)
  51         std     %f3,SC_FPRS+24(%r1)
  52         std     %f4,SC_FPRS+32(%r1)
  53         std     %f5,SC_FPRS+40(%r1)
  54         std     %f6,SC_FPRS+48(%r1)
  55         std     %f7,SC_FPRS+56(%r1)
  56         std     %f8,SC_FPRS+64(%r1)
  57         std     %f9,SC_FPRS+72(%r1)
  58         std     %f10,SC_FPRS+80(%r1)
  59         std     %f11,SC_FPRS+88(%r1)
  60         std     %f12,SC_FPRS+96(%r1)
  61         std     %f13,SC_FPRS+104(%r1)
  62         std     %f14,SC_FPRS+112(%r1)
  63         std     %f15,SC_FPRS+120(%r1)
  64
  65         /* Set __getcontext return value to 0.  */
  66         slr     %r2,%r2
  67
  68         /* Store access registers.  */
  69         stam    %a0,%a15,SC_ACRS(%r1)
  70
  71         /* Store general purpose registers.  */
  72         stm     %r0,%r15,SC_GPRS(%r1)
  73
  74         /* Return.  */
  75         br      %r14
  76 END(__getcontext)
  77
  78 #if defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20)
  79 /* In glibc release 2.19 a new version of getcontext was introduced,
  80    but was reverted before 2.20. Thus both versions are the same function.  */
  81 weak_alias (__getcontext, __v1__getcontext)
  82 weak_alias (__getcontext, __v2__getcontext)
  83 versioned_symbol (libc, __v1__getcontext, getcontext, GLIBC_2_1)
  84 compat_symbol (libc, __v2__getcontext, getcontext, GLIBC_2_19)
  85
  86 #else
  87
  88 weak_alias (__getcontext, getcontext)
  89
  90 #endif /* !(defined SHARED && SHLIB_COMPAT (libc, GLIBC_2_19, GLIBC_2_20))  */