sysdeps/sparc/sparc64/fpu/s_nearbyintf.S

   1 /* Round float to int floating-point values without generating
   2    an inexact exception, sparc64 version.
   3
   4    Copyright (C) 2013-2023 Free Software Foundation, Inc.
   5    This file is part of the GNU C Library.
   6
   7    The GNU C Library is free software; you can redistribute it and/or
   8    modify it under the terms of the GNU Lesser General Public
   9    License as published by the Free Software Foundation; either
  10    version 2.1 of the License, or (at your option) any later version.
  11
  12    The GNU C Library is distributed in the hope that it will be useful,
  13    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15    Lesser General Public License for more details.
  16
  17    You should have received a copy of the GNU Lesser General Public
  18    License along with the GNU C Library; if not, see
  19    <https://www.gnu.org/licenses/>.  */
  20
  21 #include <sysdep.h>
  22 #include <libm-alias-float.h>
  23
  24         /* We pop constants into the FPU registers using the incoming
  25            argument stack slots, since this avoid having to use any PIC
  26            references.  We also thus avoid having to allocate a register
  27            window.
  28
  29            VIS instructions are used to facilitate the formation of
  30            easier constants, and the propagation of the sign bit.  */
  31
  32 #define TWO_TWENTYTHREE 0x4b000000              /* 2**23 */
  33
  34 #define ZERO            %f10                    /* 0.0 */
  35 #define SIGN_BIT        %f12                    /* -0.0 */
  36
  37 ENTRY (__nearbyintf)
  38         fcmps   %fcc3, %f1, %f1                 /* Check for sNaN */
  39         stx     %fsr, [%sp + STACK_BIAS + 144]
  40         sethi   %hi(0xf8003e0), %o5
  41         sethi   %hi(TWO_TWENTYTHREE), %o2
  42         ldx     [%sp + STACK_BIAS + 144], %o4
  43         or      %o5, %lo(0xf8003e0), %o5
  44         fzeros  ZERO
  45         andn    %o4, %o5, %o4
  46         fnegs   ZERO, SIGN_BIT
  47         st      %o2, [%sp + STACK_BIAS + 128]
  48         stx     %o4, [%sp + STACK_BIAS + 136]
  49         ldx     [%sp + STACK_BIAS + 136], %fsr
  50         fabss   %f1, %f14
  51         ld      [%sp + STACK_BIAS + 128], %f16
  52         fcmps   %fcc3, %f14, %f16
  53         fmovsuge %fcc3, ZERO, %f16
  54         fands   %f1, SIGN_BIT, SIGN_BIT
  55         fors    %f16, SIGN_BIT, %f16
  56         fadds   %f1, %f16, %f5
  57         fsubs   %f5, %f16, %f0
  58         fabss   %f0, %f0
  59         fors    %f0, SIGN_BIT, %f0
  60         retl
  61          ldx    [%sp + STACK_BIAS + 144], %fsr
  62 END (__nearbyintf)
  63 libm_alias_float (__nearbyint, nearbyint)