sysdeps/s390/stpcpy-vx.S

   1 /* Vector optimized 32/64 bit S/390 version of stpcpy.
   2    Copyright (C) 2015-2023 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 #include <ifunc-stpcpy.h>
  20
  21 #if HAVE_STPCPY_Z13
  22
  23 # include "sysdep.h"
  24 # include "asm-syntax.h"
  25
  26         .text
  27
  28 /* char * stpcpy (const char *dest, const char *src)
  29    Copy string src to dest returning a pointer to its end.
  30
  31    Register usage:
  32    -r1=tmp
  33    -r2=dest and return value
  34    -r3=src
  35    -r4=tmp
  36    -r5=current_len
  37    -v16=part of src
  38    -v17=index of zero
  39    -v18=part of src
  40 */
  41 ENTRY(STPCPY_Z13)
  42         .machine "z13"
  43         .machinemode "zarch_nohighgprs"
  44
  45         vlbb    %v16,0(%r3),6   /* Load s until next 4k-byte boundary.  */
  46         lcbb    %r1,0(%r3),6    /* Get bytes to 4k-byte boundary or 16.  */
  47
  48         vfenezb %v17,%v16,%v16  /* Find element not equal with zero search.  */
  49         vlgvb   %r5,%v17,7      /* Load zero index or 16 if not found.  */
  50         clrjl   %r5,%r1,.Lfound_align /* If found zero within loaded bytes,
  51                                          copy bytes before and return.  */
  52
  53         /* Align s to 16 byte.  */
  54         risbgn  %r4,%r3,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15.  */
  55         lghi    %r5,15          /* current_len = 15.  */
  56         slr     %r5,%r4         /* Compute highest index to 16byte boundary.  */
  57
  58         vstl    %v16,%r5,0(%r2) /* Copy loaded characters - no zero.  */
  59         ahi     %r5,1           /* Start loop at next character.  */
  60
  61         /* Find zero in 16byte aligned loop.  */
  62 .Lloop:
  63         vl      %v16,0(%r5,%r3) /* Load s.  */
  64         vfenezbs %v17,%v16,%v16 /* Find element not equal with zero search.  */
  65         je      .Lfound_v16_0   /* Jump away if zero was found.  */
  66         vl      %v18,16(%r5,%r3) /* Load next part of s.  */
  67         vst     %v16,0(%r5,%r2) /* Store previous part without zero to dst.  */
  68         vfenezbs %v17,%v18,%v18
  69         je      .Lfound_v18_16
  70         vl      %v16,32(%r5,%r3)
  71         vst     %v18,16(%r5,%r2)
  72         vfenezbs %v17,%v16,%v16
  73         je      .Lfound_v16_32
  74         vl      %v18,48(%r5,%r3)
  75         vst     %v16,32(%r5,%r2)
  76         vfenezbs %v17,%v18,%v18
  77         je      .Lfound_v18_48
  78         vst     %v18,48(%r5,%r2)
  79
  80         aghi    %r5,64
  81         j       .Lloop          /* No zero found -> loop.  */
  82
  83 .Lfound_v16_32:
  84         aghi    %r5,32
  85 .Lfound_v16_0:
  86         la      %r3,0(%r5,%r2)
  87         vlgvb   %r1,%v17,7      /* Load byte index of zero.  */
  88         vstl    %v16,%r1,0(%r3) /* Copy characters including zero.  */
  89         la      %r2,0(%r1,%r3)  /* Return pointer to zero.  */
  90         br      %r14
  91
  92 .Lfound_v18_48:
  93         aghi    %r5,32
  94 .Lfound_v18_16:
  95         la      %r3,16(%r5,%r2)
  96         vlgvb   %r1,%v17,7      /* Load byte index of zero.  */
  97         vstl    %v18,%r1,0(%r3) /* Copy characters including zero.  */
  98         la      %r2,0(%r1,%r3)  /* Return pointer to zero.  */
  99         br      %r14
 100
 101 .Lfound_align:
 102         vstl    %v16,%r5,0(%r2) /* Copy characters including zero.  */
 103         la      %r2,0(%r5,%r2)  /* Return pointer to zero.  */
 104         br      %r14
 105 END(STPCPY_Z13)
 106
 107 # if ! HAVE_STPCPY_IFUNC
 108 strong_alias (STPCPY_Z13, __stpcpy)
 109 weak_alias (__stpcpy, stpcpy)
 110 # endif
 111
 112 # if ! HAVE_STPCPY_C && defined SHARED && IS_IN (libc)
 113 strong_alias (STPCPY_Z13, __GI_stpcpy)
 114 strong_alias (STPCPY_Z13, __GI___stpcpy)
 115 # endif
 116 #endif