sysdeps/i386/bsd-setjmp.S

   1 /* BSD `setjmp' entry point to `sigsetjmp (..., 1)'.  i386 version.
   2    Copyright (C) 1994-2023 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <https://www.gnu.org/licenses/>.  */
  18
  19 /* This just does a tail-call to `__sigsetjmp (ARG, 1)'.
  20    We cannot do it in C because it must be a tail-call, so frame-unwinding
  21    in setjmp doesn't clobber the state restored by longjmp.  */
  22
  23 #include <sysdep.h>
  24 #include <pointer_guard.h>
  25 #include <jmpbuf-offsets.h>
  26 #include <jmp_buf-ssp.h>
  27 #include <stap-probe.h>
  28
  29 #define PARMS  4                /* no space for saved regs */
  30 #define JMPBUF PARMS
  31 #define SIGMSK JMPBUF+4
  32
  33 /* Don't save shadow stack register if shadow stack isn't enabled.  */
  34 #if !SHSTK_ENABLED
  35 # undef SHADOW_STACK_POINTER_OFFSET
  36 #endif
  37
  38 ENTRY (setjmp)
  39         /* Note that we have to use a non-exported symbol in the next
  40            jump since otherwise gas will emit it as a jump through the
  41            PLT which is what we cannot use here.  */
  42
  43         movl JMPBUF(%esp), %eax
  44
  45         /* Save registers.  */
  46         movl %ebx, (JB_BX*4)(%eax)
  47         movl %esi, (JB_SI*4)(%eax)
  48         movl %edi, (JB_DI*4)(%eax)
  49         leal JMPBUF(%esp), %ecx /* Save SP as it will be after we return.  */
  50 #ifdef PTR_MANGLE
  51         PTR_MANGLE (%ecx)
  52 #endif
  53         movl %ecx, (JB_SP*4)(%eax)
  54         movl 0(%esp), %ecx      /* Save PC we are returning to now.  */
  55         LIBC_PROBE (setjmp, 3, 4@%eax, -4@$1, 4@%ecx)
  56 #ifdef PTR_MANGLE
  57         PTR_MANGLE (%ecx)
  58 #endif
  59         movl %ecx, (JB_PC*4)(%eax)
  60         movl %ebp, (JB_BP*4)(%eax) /* Save caller's frame pointer.  */
  61 #ifdef SHADOW_STACK_POINTER_OFFSET
  62 # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET
  63         /* Check if Shadow Stack is enabled.  */
  64         testl $X86_FEATURE_1_SHSTK, %gs:FEATURE_1_OFFSET
  65         jz L(skip_ssp)
  66 # else
  67         xorl %ecx, %ecx
  68 # endif
  69         /* Get the current Shadow-Stack-Pointer and save it.  */
  70         rdsspd %ecx
  71         movl %ecx, SHADOW_STACK_POINTER_OFFSET(%eax)
  72 # if IS_IN (libc) && defined SHARED && defined FEATURE_1_OFFSET
  73 L(skip_ssp):
  74 # endif
  75 #endif
  76
  77         /* Call __sigjmp_save.  */
  78         pushl $1
  79         cfi_adjust_cfa_offset (4)
  80         pushl 8(%esp)
  81         cfi_adjust_cfa_offset (4)
  82         call __sigjmp_save
  83         popl %ecx
  84         cfi_adjust_cfa_offset (-4)
  85         popl %edx
  86         cfi_adjust_cfa_offset (-4)
  87         ret
  88 END (setjmp)