configure.in

   1 Dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.10)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(features.h)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This will get text that should go into config.make.
   8 config_vars=
   9
  10 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  11 AC_ARG_WITH(gmp, dnl
  12   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  13             [dnl
  14 case "$with_gmp" in
  15 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  16 ''|no) ;;
  17 *) config_vars="$config_vars
  18 gmp-srcdir = $withval" ;;
  19 esac
  20 ])
  21 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  22 AC_ARG_WITH(gettext, dnl
  23   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  24             [dnl
  25 case "$with_gettext" in
  26 yes)
  27   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  28 ''|no) ;;
  29 *)
  30   config_vars="$config_vars
  31 gettext-srcdir = $withval" ;;
  32 esac
  33 ])
  34
  35 dnl Arguments to specify presence of other packages/features.
  36 AC_ARG_WITH(fp, dnl
  37   --with-fp               if using floating-point hardware [default=yes],
  38             with_fp=$withval, with_fp=yes)
  39 AC_ARG_WITH(gnu-binutils, dnl
  40   --with-gnu-binutils     if using GNU binutils (as and ld),
  41             gnu_binutils=$withval, gnu_binutils=no)
  42 AC_ARG_WITH(gnu-ld, dnl
  43   --with-gnu-ld           if using GNU ld (in the binutils package),
  44             gnu_ld=$withval, gnu_ld=no)
  45 AC_ARG_WITH(gnu-as, dnl
  46   --with-gnu-as           if using GNU as (in the binutils package),
  47             gnu_as=$withval, gnu_as=no)
  48 test $gnu_binutils = yes && gnu_as=yes gnu_ld=yes
  49 AC_ARG_WITH(elf, dnl
  50   --with-elf              if using the ELF object format,
  51             elf=$withval, elf=no)
  52
  53 AC_ARG_ENABLE(libio, dnl
  54 [  --enable-libio          build in GNU libio instead of GNU stdio],
  55               [if test $enableval = yes; then
  56                  stdio=libio
  57                else
  58                  stdio=stdio
  59                fi],
  60               stdio=default)
  61
  62 dnl Arguments to enable or disable building the shared, profiled, and
  63 dnl -fomit-frame-pointer libraries.
  64 AC_ARG_ENABLE(shared, dnl
  65 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  66               shared=$enableval, shared=default)
  67 AC_ARG_ENABLE(profile, dnl
  68 [  --enable-profile        build profiled library [default=yes]],
  69               profile=$enableval, profile=yes)
  70 AC_ARG_ENABLE(omitfp, dnl
  71 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  72               omitfp=$enableval, omitfp=no)
  73
  74 dnl Generic infrastructure for drop-in additions to libc.
  75 AC_ARG_ENABLE(add-ons, dnl
  76 [  --enable-add-ons=DIR... configure and build named extra directories],
  77               add_ons=`echo "$enableval" | sed 's/,/ /g'`,
  78               add_ons=)
  79 AC_CONFIG_SUBDIRS($add_ons)
  80
  81 AC_CANONICAL_HOST
  82 # We keep the original values in `$config_*' and never modify them, so we
  83 # can write them unchanged into config.make.  Everything else uses
  84 # $machine, $vendor, and $os, and changes them whenever convenient.
  85 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
  86
  87 # Some configurations imply other options.
  88 case "$host_os" in
  89 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
  90   # These systems always use GNU tools.
  91   gnu_ld=yes gnu_as=yes ;;
  92 esac
  93 case "$host_os" in
  94 linux*ecoff*)
  95   ;;
  96 gnu* | linux* | sysv4* | solaris2*)
  97   # These systems (almost) always use the ELF format.
  98   elf=yes
  99   ;;
 100 esac
 101
 102 machine=$config_machine
 103 vendor=$config_vendor
 104 os=$config_os
 105
 106 dnl We need to use [ and ] for other purposes for a while now.
 107 changequote(,)dnl
 108 # Expand the configuration machine name into a subdirectory by architecture
 109 # type and particular chip.
 110 case "$machine" in
 111 a29k | am29000) base_machine=a29k machine=a29k ;;
 112 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 113 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 114 i[345]86)       base_machine=i386 machine=i386/$machine ;;
 115 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 116 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 117 m88???)         base_machine=m88k machine=m88k/$machine ;;
 118 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 119 mips*)          base_machine=mips machine=mips/$machine ;;
 120 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 121 sparc[6789])    base_machine=sparc machine=sparc/$machine ;;
 122 supersparc)     base_machine=sparc machine=sparc/sparc8 ;;
 123 esac
 124 changequote([,])dnl
 125 AC_SUBST(base_machine)
 126
 127 # Compute the list of sysdep directories for this configuration.
 128 # This can take a while to compute.
 129 sysdep_dir=$srcdir/sysdeps
 130 AC_MSG_CHECKING(sysdep dirs)
 131 dnl We need to use [ and ] for other purposes for a while now.
 132 changequote(,)dnl
 133 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 134 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 135
 136 case "$os" in
 137 gnu*)
 138   base_os=mach/hurd ;;
 139 netbsd* | 386bsd* | freebsd* | bsdi*)
 140   base_os=unix/bsd/bsd4.4 ;;
 141 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 142   base_os=unix/bsd ;;
 143 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 144   base_os=unix/sysv ;;
 145 solaris[2-9]*)
 146   base_os=unix/sysv/sysv4 ;;
 147 none)
 148   base_os=standalone ;;
 149 *)
 150   base_os='' ;;
 151 esac
 152
 153 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 154 tail=$os
 155 ostry=$os
 156 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 157   ostry="$ostry /$o"
 158   tail=$o
 159 done
 160 o=`echo $tail | sed 's/[0-9]*$//'`
 161 if test $o != $tail; then
 162   ostry="$ostry /$o"
 163 fi
 164
 165 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 166 base=
 167 tail=$base_os
 168 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 169   set $b
 170   base="$base /$1"
 171   tail="$2"
 172 done
 173
 174 # For sparc/sparc9, try sparc/sparc9 and then sparc.
 175 mach=
 176 tail=$machine
 177 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 178   set $m
 179   # Prepend the machine's FPU directory unless --without-fp.
 180   if test "$with_fp" = yes; then
 181     mach="$mach /$1/fpu"
 182   fi
 183   mach="$mach /$1"
 184   tail="$2"
 185 done
 186
 187 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 188 changequote([,])dnl
 189
 190 # Find what sysdep directories exist.
 191 sysnames=
 192 for b in $base ''; do
 193   for m0 in $mach ''; do
 194     for v in /$vendor ''; do
 195       for o in /$ostry ''; do
 196         for m in $mach ''; do
 197           try="$m0$b$v$o$m"
 198           test -n "$enable_debug_configure" && echo "$0 [DEBUG]: try $try" >&2
 199           if test -d $sysdep_dir$try; then
 200             sysnames="$sysnames $try"
 201             { test -n "$o" || test -n "$b"; } && os_used=t
 202             { test -n "$m" || test -n "$m0"; } && machine_used=t
 203           fi
 204         done
 205       done
 206     done
 207   done
 208 done
 209
 210 if test -z "$os_used" && test "$os" != none; then
 211   AC_MSG_ERROR(Operating system $os is not supported.)
 212 fi
 213 if test -z "$machine_used" && test "$machine" != none; then
 214   AC_MSG_ERROR(The $machine is not supported.)
 215 fi
 216
 217 # We have now validated the configuration.
 218
 219
 220 # If using ELF, look for an `elf' subdirectory of each machine directory.
 221 # We prepend these rather than inserting them whereever the machine appears
 222 # because things specified by the machine's ELF ABI should override
 223 # OS-specific things, and should always be the same for any OS on the
 224 # machine (otherwise what's the point of an ABI?).
 225 if test "$elf" = yes; then
 226   elf_dirs=
 227   for m in $mach; do
 228     if test -d $sysdep_dir$m/elf; then
 229       elf_dirs="$elf_dirs $m/elf"
 230     fi
 231   done
 232   sysnames="`echo $elf_dirs | sed -e 's,^/,,' -e 's, /,,g'` $sysnames"
 233 fi
 234
 235
 236 # Remove the leading slashes.
 237 sysnames="`echo $sysnames | sed -e 's@^/@@' -e 's@ /@ @g'`"
 238
 239
 240 # Expand the list of system names into a full list of directories
 241 # from each element's parent name and Implies file (if present).
 242 set $sysnames
 243 names=
 244 while test $# -gt 0; do
 245   name=$1
 246   shift
 247
 248   case " $names " in *" $name "*)
 249     # Already in the list.
 250     continue
 251   esac
 252
 253   # Report each name as we discover it, so there is no long pause in output.
 254   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 255
 256   if test -f $sysdep_dir/$name/Implies; then
 257     # Collect more names from the `Implies' file (removing comments).
 258     implied="`sed 's/#.*$//' < $sysdep_dir/$name/Implies`"
 259     for x in $implied; do
 260       test -d $sysdep_dir/$x || {
 261         AC_MSG_WARN(sysdeps/$name/Implies specifies nonexistent $x)
 262       }
 263     done
 264   else
 265     implied=
 266   fi
 267
 268   # Add NAME to the list of names.
 269   names="$names $name"
 270
 271   # Find the parent of NAME, using the empty string if it has none.
 272 changequote(,)dnl
 273   parent="`echo $name | sed -n -e '/\//!q' -e 's=/[^/]*$==p'`"
 274 changequote([,])dnl
 275
 276   # Add the names implied by NAME, and NAME's parent (if it has one), to
 277   # the list of names to be processed (the argument list).  We prepend the
 278   # implied names to the list and append the parent.  We want implied
 279   # directories to come before further directories inferred from the
 280   # configuration components; this ensures that for sysv4, unix/common
 281   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 282   # after sysv4).
 283   sysnames="`echo $implied $* $parent`"
 284   test -n "$sysnames" && set $sysnames
 285 done
 286
 287 # Add the default directories.
 288 sysnames="$names generic stub"
 289 AC_SUBST(sysnames)
 290 # The other names were emitted during the scan.
 291 AC_MSG_RESULT(generic stub)
 292
 293
 294 ### Locate tools.
 295
 296 AC_PROG_INSTALL
 297 if test "$INSTALL" = "${srcdir}/install-sh"; then
 298   # The makefiles need to use a different form to find it in $srcdir.
 299   INSTALL='$(..)./install-sh'
 300 fi
 301 AC_PROG_LN_S
 302 AC_CHECK_PROGS(MSGFMT, msgfmt gmsgfmt, :)
 303
 304 AC_CHECK_TOOL(CC, gcc)
 305 if test $host != $build; then
 306   AC_CHECK_PROG(BUILD_CC, gcc cc)
 307 fi
 308 AC_PROG_CPP
 309 AC_CHECK_TOOL(AR, ar)
 310 AC_CHECK_TOOL(RANLIB, ranlib, :)
 311
 312 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 313 echo '#include <stddef.h>
 314 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 315 if eval "$ac_cpp conftest.c 2>/dev/null" \
 316 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 317   libc_cv_signed_size_t=no
 318 else
 319   libc_cv_signed_size_t=yes
 320 fi
 321 rm -f conftest*])
 322 if test $libc_cv_signed_size_t = yes; then
 323   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 324   cat >> confdefs.h <<\EOF
 325 #undef __SIZE_TYPE__
 326 #define __SIZE_TYPE__ unsigned
 327 EOF
 328 fi
 329
 330 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 331 AC_TRY_COMPILE(dnl
 332 [#define __need_size_t
 333 #define __need_wchar_t
 334 #include <stddef.h>
 335 #define __need_NULL
 336 #include <stddef.h>], [size_t size; wchar_t wchar;
 337 #ifdef offsetof
 338 #error stddef.h ignored __need_*
 339 #endif
 340 if (&size == NULL || &wchar == NULL) abort ();],
 341                libc_cv_friendly_stddef=yes,
 342                libc_cv_friendly_stddef=no)])
 343 if test $libc_cv_friendly_stddef = yes; then
 344   config_vars="$config_vars
 345 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 346 fi
 347
 348 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 349                libc_cv_need_minus_P, [dnl
 350 cat > conftest.S <<EOF
 351 #include "confdefs.h"
 352 /* Nothing whatsoever.  */
 353 EOF
 354 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 355   libc_cv_need_minus_P=no
 356 else
 357   libc_cv_need_minus_P=yes
 358 fi
 359 rm -f conftest*])
 360 if test $libc_cv_need_minus_P = yes; then
 361   config_vars="$config_vars
 362 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 363 fi
 364
 365 AC_CACHE_CHECK(for assembler global-symbol directive,
 366                libc_cv_asm_global_directive, [dnl
 367 libc_cv_asm_global_directive=UNKNOWN
 368 for ac_globl in .globl .global; do
 369   cat > conftest.s <<EOF
 370 .text
 371 ${ac_globl} foo
 372 foo: .long 0
 373 EOF
 374   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 375     libc_cv_asm_global_directive=${ac_globl}
 376   fi
 377   rm -f conftest*
 378   test $libc_cv_asm_global_directive != UNKNOWN && break
 379 done])
 380 if test $libc_cv_asm_global_directive = UNKNOWN; then
 381   AC_MSG_ERROR(cannot determine asm global directive)
 382 else
 383   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 384 fi
 385
 386 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 387 cat > conftest.s <<EOF
 388 .text
 389 foo: .long 0
 390 .set glibc_conftest_frobozz,foo
 391 $libc_cv_asm_global_directive glibc_conftest_frobozz
 392 EOF
 393 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 394 # (but it doesn't work), so we must do a linking check to be sure.
 395 cat > conftest1.c <<\EOF
 396 extern int glibc_conftest_frobozz;
 397 main () { printf ("%d\n", glibc_conftest_frobozz); }
 398 EOF
 399 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 400             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 401   libc_cv_asm_set_directive=yes
 402 else
 403   libc_cv_asm_set_directive=no
 404 fi
 405 rm -f conftest*])
 406 if test $libc_cv_asm_set_directive = yes; then
 407   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 408 fi
 409
 410 if test $elf != yes; then
 411   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 412                  [AC_TRY_COMPILE(, [asm (".section .init");
 413                                     asm (".section .fini");
 414                                     asm (".text");],
 415                                  libc_cv_have_initfini=yes,
 416                                  libc_cv_have_initfini=no)])
 417   AC_SUBST(libc_cv_have_initfini)dnl
 418   if test $libc_cv_have_initfini = yes; then
 419     AC_DEFINE(HAVE_INITFINI)
 420   fi
 421 fi
 422
 423 if test $elf = yes; then
 424   libc_cv_asm_underscores=no
 425 else
 426   AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 427                  [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 428                               libc_cv_asm_underscores=yes,
 429                               libc_cv_asm_underscores=no)])
 430 fi
 431 if test $libc_cv_asm_underscores = no; then
 432   AC_DEFINE(NO_UNDERSCORES)
 433 fi
 434
 435 if test $elf = yes; then
 436   libc_cv_weak_symbols=yes
 437   libc_cv_asm_weak_directive=yes
 438   libc_cv_asm_weakext_directive=no
 439 else
 440   AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 441                  [dnl
 442 cat > conftest.s <<EOF
 443 .text
 444 ${libc_cv_asm_global_directive} foo
 445 foo: .long 0
 446 .weak foo
 447 .weak bar; bar = foo
 448 EOF
 449   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 450     libc_cv_asm_weak_directive=yes
 451   else
 452     libc_cv_asm_weak_directive=no
 453   fi
 454   rm -f conftest*])
 455
 456 if test $libc_cv_asm_weak_directive = no; then
 457   AC_CACHE_CHECK(for assembler .weakext directive,
 458                  libc_cv_asm_weakext_directive,
 459                  [dnl
 460 cat > conftest.s <<EOF
 461 .text
 462 ${libc_cv_asm_global_directive} foo
 463 foo: .long 0
 464 .weakext foo
 465 .weakext foo, bar
 466 EOF
 467   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 468     libc_cv_asm_weakext_directive=yes
 469   else
 470     libc_cv_asm_weakext_directive=no
 471   fi
 472   rm -f conftest*])
 473
 474   fi # no .weak
 475 fi # not ELF
 476
 477 if test $libc_cv_asm_weak_directive = yes; then
 478   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 479 elif test $libc_cv_asm_weakext_directive = yes; then
 480   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 481 fi
 482
 483 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 484 cat > conftest.c <<\EOF
 485 _start () {}
 486 EOF
 487 dnl No \ in command here because it ends up inside ''.
 488 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 489                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 490                             -o conftest conftest.c]); then
 491   libc_cv_ld_no_whole_archive=yes
 492 else
 493   libc_cv_ld_no_whole_archive=no
 494 fi
 495 rm -f conftest*])
 496 AC_SUBST(libc_cv_ld_no_whole_archive)dnl
 497
 498 ### End of automated tests.
 499 ### Now run sysdeps configure fragments.
 500
 501 # sysdeps configure fragments may set these with files to be linked below.
 502 libc_link_dests=
 503 libc_link_sources=
 504
 505 # Iterate over all the sysdep directories we will use, running their
 506 # configure fragments, and looking for a uname implementation.
 507 uname=
 508 for dir in $sysnames; do
 509   if test -r $sysdep_dir/$dir/configure; then
 510     AC_MSG_RESULT(running configure fragment for $dir)
 511     . $sysdep_dir/$dir/configure
 512   fi
 513 [
 514   if test -z "$uname"; then
 515     if test -r $sysdep_dir/$dir/uname.c ||
 516        test -r $sysdep_dir/$dir/uname.S ||
 517        { test -r $sysdep_dir/$dir/syscalls.list &&
 518          grep '^uname[  ]' $sysdep_dir/$dir/syscalls.list >/dev/null; }; then
 519       uname=$dir
 520     fi
 521   fi
 522 ]dnl
 523 done
 524
 525 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
 526
 527 # If we will use the generic uname implementation, we must figure out what
 528 # it will say by examining the system, and write the results in config-name.h.
 529 if test "$uname" = generic; then
 530
 531 changequote(,)dnl
 532   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
 533 changequote([,])dnl
 534   if test $uname_sysname != $config_os; then
 535     config_release=`echo $config_os | sed s/$uname_sysname//`
 536   fi
 537 dnl
 538 AC_DEFUN(LIBC_KERNEL_ID, [dnl
 539     if test -r /vmunix; then
 540       kernel_id=`strings /vmunix | grep UNIX`
 541     elif test -r /dynix; then
 542       kernel_id=`strings /dynix | grep DYNIX`
 543     else
 544       kernel_id=
 545     fi
 546 ])dnl
 547
 548   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
 549 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 550 changequote(,)dnl
 551   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
 552 changequote([,])dnl
 553   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
 554          != x$config_release; then
 555     # The configuration release is a substring of the kernel release.
 556     libc_cv_uname_release=$kernel_release
 557   elif test x$config_release != x; then
 558     libc_cv_uname_release=$config_release
 559   elif test x$kernel_release != x; then
 560     libc_cv_uname_release=$kernel_release
 561   else
 562     libc_cv_uname_release=unknown
 563   fi])
 564   uname_release="$libc_cv_uname_release"
 565
 566   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
 567 AC_REQUIRE([LIBC_KERNEL_ID])dnl
 568 changequote(,)dnl
 569   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
 570 changequote([,])dnl
 571   if test -n "$kernel_version"; then
 572     libc_cv_uname_version="$kernel_version"
 573   else
 574     libc_cv_uname_version=unknown
 575   fi])
 576   uname_version="$libc_cv_uname_version"
 577
 578 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
 579   config_uname=config-name.h:config-name.in
 580 else
 581   # For non-generic uname, we don't need to create config-name.h at all.
 582   config_uname=
 583 fi
 584
 585 AC_MSG_CHECKING(stdio selection)
 586 AC_SUBST(stdio)
 587 case $stdio in
 588 libio) AC_DEFINE(USE_IN_LIBIO) ;;
 589 default) stdio=stdio ;;
 590 esac
 591 AC_MSG_RESULT($stdio)
 592
 593 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
 594 if test $gnu_ld = yes; then
 595   AC_DEFINE(HAVE_GNU_LD)
 596 fi
 597 if test $gnu_as = yes; then
 598   AC_DEFINE(HAVE_GNU_AS)
 599 fi
 600 if test $elf = yes; then
 601   AC_DEFINE(HAVE_ELF)
 602 fi
 603
 604 AC_SUBST(shared)
 605 if test $shared = default; then
 606   if test $gnu_ld = yes; then
 607     shared=$elf
 608   fi
 609 fi
 610 AC_SUBST(profile)
 611 AC_SUBST(omitfp)
 612
 613 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
 614   config_makefile=
 615 else
 616   config_makefile=Makefile
 617 fi
 618
 619 AC_OUTPUT(config.make ${config_makefile} ${config_uname}, ,
 620           [echo '$config_vars' >> config.make])