| blob | 335c796c2be34ace239e6b7e7332428a04f119bf |
1 dnl Process this file with autoconf to produce a configure script.
2 AC_PREREQ(2.53)dnl dnl Minimum Autoconf version required.
3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
4 AC_CONFIG_SRCDIR([include/features.h])
5 AC_CONFIG_HEADERS([config.h])
6 AC_CONFIG_AUX_DIR([scripts])
8 dnl This is here so we can set $subdirs directly based on configure fragments.
9 AC_CONFIG_SUBDIRS()
11 AC_CANONICAL_HOST
13 AC_PROG_CC
14 if test $host != $build; then
15 AC_CHECK_PROGS(BUILD_CC, gcc cc)
16 fi
17 AC_SUBST(cross_compiling)
18 AC_PROG_CPP
19 # We need the C++ compiler only for testing.
20 AC_PROG_CXX
22 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
23 AC_MSG_ERROR([you must configure in a separate build directory])
24 fi
26 # This will get text that should go into config.make.
27 config_vars=
29 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
30 AC_ARG_WITH([gd],
31 AC_HELP_STRING([--with-gd=DIR],
32 [find libgd include dir and library with prefix DIR]),
33 [dnl
34 case "$with_gd" in
35 yes|''|no) ;;
36 *) libgd_include="-I$withval/include"
37 libgd_ldflags="-L$withval/lib" ;;
38 esac
39 ])
40 AC_ARG_WITH([gd-include],
41 AC_HELP_STRING([--with-gd-include=DIR],
42 [find libgd include files in DIR]),
43 [dnl
44 case "$with_gd_include" in
45 ''|no) ;;
46 *) libgd_include="-I$withval" ;;
47 esac
48 ])
49 AC_ARG_WITH([gd-lib],
50 AC_HELP_STRING([--with-gd-lib=DIR],
51 [find libgd library files in DIR]),
52 [dnl
53 case "$with_gd_lib" in
54 ''|no) ;;
55 *) libgd_ldflags="-L$withval" ;;
56 esac
57 ])
59 if test -n "$libgd_include"; then
60 config_vars="$config_vars
61 CFLAGS-memusagestat.c = $libgd_include"
62 fi
63 if test -n "$libgd_ldflags"; then
64 config_vars="$config_vars
65 libgd-LDFLAGS = $libgd_ldflags"
66 fi
68 dnl Arguments to specify presence of other packages/features.
69 AC_ARG_WITH([fp],
70 AC_HELP_STRING([--with-fp],
71 [if using floating-point hardware @<:@default=yes@:>@]),
72 [with_fp=$withval],
73 [with_fp=yes])
74 AC_SUBST(with_fp)
75 AC_ARG_WITH([binutils],
76 AC_HELP_STRING([--with-binutils=PATH],
77 [specify location of binutils (as and ld)]),
78 [path_binutils=$withval],
79 [path_binutils=''])
80 AC_ARG_WITH([selinux],
81 AC_HELP_STRING([--with-selinux],
82 [if building with SELinux support]),
83 [with_selinux=$withval],
84 [with_selinux=auto])
86 AC_ARG_WITH([headers],
87 AC_HELP_STRING([--with-headers=PATH],
88 [location of system headers to use
89 (for example /usr/src/linux/include)
90 @<:@default=compiler default@:>@]),
91 [sysheaders=$withval],
92 [sysheaders=''])
94 AC_SUBST(use_default_link)
95 AC_ARG_WITH([default-link],
96 AC_HELP_STRING([--with-default-link],
97 [do not use explicit linker scripts]),
98 [use_default_link=$withval],
99 [use_default_link=default])
101 AC_ARG_ENABLE([sanity-checks],
102 AC_HELP_STRING([--disable-sanity-checks],
103 [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
104 [enable_sanity=$enableval],
105 [enable_sanity=yes])
107 AC_SUBST(enable_check_abi)
108 AC_ARG_ENABLE([check-abi],
109 AC_HELP_STRING([--enable-check-abi],
110 [do "make check-abi" in "make check" (no/warn/yes)
111 @<:@default=no@:>@]),
112 [enable_check_abi=$enableval],
113 [enable_check_abi=no])
115 AC_ARG_ENABLE([shared],
116 AC_HELP_STRING([--enable-shared],
117 [build shared library @<:@default=yes if GNU ld@:>@]),
118 [shared=$enableval],
119 [shared=yes])
120 AC_ARG_ENABLE([profile],
121 AC_HELP_STRING([--enable-profile],
122 [build profiled library @<:@default=no@:>@]),
123 [profile=$enableval],
124 [profile=no])
125 AC_ARG_ENABLE([versioning],
126 AC_HELP_STRING([--disable-versioning],
127 [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
128 [enable_versioning=$enableval],
129 [enable_versioning=yes])
131 AC_ARG_ENABLE([oldest-abi],
132 AC_HELP_STRING([--enable-oldest-abi=ABI],
133 [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
134 [oldest_abi=$enableval],
135 [oldest_abi=no])
136 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
137 oldest_abi=default
138 else
139 AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
140 fi
141 AC_SUBST(oldest_abi)
143 AC_ARG_ENABLE([stackguard-randomization],
144 AC_HELP_STRING([--enable-stackguard-randomization],
145 [initialize __stack_chk_guard canary with a random number at program start]),
146 [enable_stackguard_randomize=$enableval],
147 [enable_stackguard_randomize=no])
148 if test "$enable_stackguard_randomize" = yes; then
149 AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
150 fi
152 dnl Generic infrastructure for drop-in additions to libc.
153 AC_ARG_ENABLE([add-ons],
154 AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
155 [configure and build add-ons in DIR1,DIR2,...
156 search for add-ons if no parameter given]),
157 , [enable_add_ons=yes])
159 AC_ARG_ENABLE([hidden-plt],
160 AC_HELP_STRING([--disable-hidden-plt],
161 [do not hide internal function calls to avoid PLT]),
162 [hidden=$enableval],
163 [hidden=yes])
164 if test "x$hidden" = xno; then
165 AC_DEFINE(NO_HIDDEN)
166 fi
168 AC_ARG_ENABLE([bind-now],
169 AC_HELP_STRING([--enable-bind-now],
170 [disable lazy relocations in DSOs]),
171 [bindnow=$enableval],
172 [bindnow=no])
173 AC_SUBST(bindnow)
175 dnl On some platforms we cannot use dynamic loading. We must provide
176 dnl static NSS modules.
177 AC_ARG_ENABLE([static-nss],
178 AC_HELP_STRING([--enable-static-nss],
179 [build static NSS modules @<:@default=no@:>@]),
180 [static_nss=$enableval],
181 [static_nss=no])
182 dnl Enable static NSS also if we build no shared objects.
183 if test x"$static_nss" = xyes || test x"$shared" = xno; then
184 static_nss=yes
185 AC_DEFINE(DO_STATIC_NSS)
186 fi
188 AC_ARG_ENABLE([force-install],
189 AC_HELP_STRING([--disable-force-install],
190 [don't force installation of files from this package, even if they are older than the installed files]),
191 [force_install=$enableval],
192 [force_install=yes])
193 AC_SUBST(force_install)
195 dnl On some platforms we allow dropping compatibility with all kernel
196 dnl versions.
197 AC_ARG_ENABLE([kernel],
198 AC_HELP_STRING([--enable-kernel=VERSION],
199 [compile for compatibility with kernel not older than VERSION]),
200 [minimum_kernel=$enableval],
201 [])
202 dnl Prevent unreasonable values.
203 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
204 # Better nothing than this.
205 minimum_kernel=""
206 else
207 if test "$minimum_kernel" = current; then
208 minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
209 fi
210 fi
212 dnl For the development we sometimes want gcc to issue even more warnings.
213 dnl This is not the default since many of the extra warnings are not
214 dnl appropriate.
215 AC_ARG_ENABLE([all-warnings],
216 AC_HELP_STRING([--enable-all-warnings],
217 [enable all useful warnings gcc can issue]),
218 [all_warnings=$enableval],
219 [])
220 AC_SUBST(all_warnings)
222 AC_ARG_ENABLE([multi-arch],
223 AC_HELP_STRING([--enable-multi-arch],
224 [enable single DSO with optimizations for multiple architectures]),
225 [multi_arch=$enableval],
226 [multi_arch=default])
228 AC_ARG_ENABLE([nss-crypt],
229 AC_HELP_STRING([--enable-nss-crypt],
230 [enable libcrypt to use nss]),
231 [nss_crypt=$enableval],
232 [nss_crypt=no])
233 if test x$nss_crypt = xyes; then
234 nss_includes=-I$(nss-config --includedir 2>/dev/null)
235 if test $? -ne 0; then
236 AC_MSG_ERROR([cannot find include directory with nss-config])
237 fi
238 old_CFLAGS="$CFLAGS"
239 CFLAGS="$CFLAGS $nss_includes"
240 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
241 #include <hasht.h>
242 #include <nsslowhash.h>
243 void f (void) { NSSLOW_Init (); }])],
244 libc_cv_nss_crypt=yes,
245 AC_MSG_ERROR([
246 cannot find NSS headers with lowlevel hash function interfaces]))
247 old_LIBS="$LIBS"
248 LIBS="$LIBS -lfreebl3"
249 AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
250 #include <hasht.h>
251 #include <nsslowhash.h>],
252 [NSSLOW_Init();])],
253 libc_cv_nss_crypt=yes,
254 AC_MSG_ERROR([
255 cannot link program using lowlevel NSS hash functions]))
256 CFLAGS="$old_CFLAGS"
257 LIBS="$old_LIBS"
258 else
259 libc_cv_nss_crypt=no
260 fi
261 AC_SUBST(libc_cv_nss_crypt)
263 # The way shlib-versions is used to generate soversions.mk uses a
264 # fairly simplistic model for name recognition that can't distinguish
265 # i486-pc-linux-gnu fully from i486-pc-gnu. So we mutate a $host_os
266 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
267 # tell. This doesn't get used much beyond that, so it's fairly safe.
268 case "$host_os" in
269 linux*)
270 ;;
271 gnu*)
272 host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
273 ;;
274 esac
276 # We keep the original values in `$config_*' and never modify them, so we
277 # can write them unchanged into config.make. Everything else uses
278 # $machine, $vendor, and $os, and changes them whenever convenient.
279 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
281 # Don't allow vendor == "unknown"
282 test "$config_vendor" = unknown && config_vendor=
283 config_os="`echo $config_os | sed 's/^unknown-//'`"
285 # Some configurations imply other options.
286 elf=yes
288 # The configure fragment of an add-on port can modify these to supplement
289 # or override the table in the case statement below. No fragment should
290 # ever change the config_* variables, however.
291 machine=$config_machine
292 vendor=$config_vendor
293 os=$config_os
294 base_os=''
296 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
297 # Unify this here.
298 if test "$machine" = rs6000; then
299 machine="powerpc"
300 fi
302 # Braindead PowerPC box with absolutely no FPU.
303 case "$machine-$host_os" in
304 powerpc*-*soft)
305 with_fp=no
306 ;;
307 esac
309 submachine=
310 AC_ARG_WITH([cpu],
311 AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
312 [dnl
313 case "$withval" in
314 yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
315 no) ;;
316 *) submachine="$withval" ;;
317 esac
318 ])
320 # An add-on can set this when it wants to disable the sanity check below.
321 libc_config_ok=no
323 dnl Having this here, though empty, makes sure that if add-ons' fragments
324 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
325 dnl our AC_OUTPUT will actually use it.
326 AC_CONFIG_SUBDIRS()
328 case "$enable_add_ons" in
329 ''|no) add_ons= ;;
330 yes|'*')
331 add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
332 sed 's@/[[^/]]*$@@' | sort | uniq`
333 add_ons_automatic=yes
334 ;;
335 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
336 add_ons_automatic=no ;;
337 esac
339 configured_add_ons=
340 add_ons_sfx=
341 add_ons_pfx=
342 if test x"$add_ons" != x; then
343 for f in $add_ons; do
344 # Some sanity checks
345 case "$f" in
346 crypt)
347 AC_MSG_ERROR([
348 *** It seems that you're using an old \`crypt' add-on. crypt is now
349 *** part of glibc and using the old add-on will not work with this
350 *** release. Start again with fresh sources and without the old
351 *** \`crypt' add-on.])
352 ;;
353 localedata)
354 AC_MSG_ERROR([
355 *** It seems that you're using an old \`localedata' add-on. localedata
356 *** is now part of glibc and using the old add-on will not work with
357 *** this release. Start again with fresh sources and without the old
358 *** \`localedata' add-on.])
359 ;;
360 esac
361 done
363 # Now source each add-on's configure fragment.
364 # The fragments can use $srcdir/$libc_add_on to find themselves,
365 # and test $add_ons_automatic to see if they were explicitly requested.
366 # A fragment can clear (or even change) $libc_add_on to affect
367 # whether it goes into the list to be actually used in the build.
368 use_add_ons=
369 for libc_add_on in $add_ons; do
370 # Test whether such a directory really exists.
371 # It can be absolute, or relative to $srcdir, or relative to the build dir.
372 case "$libc_add_on" in
373 /*)
374 libc_add_on_srcdir=$libc_add_on
375 ;;
376 *)
377 test -d "$srcdir/$libc_add_on" || {
378 if test -d "$libc_add_on"; then
379 libc_add_on="`pwd`/$libc_add_on"
380 else
381 AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
382 fi
383 }
384 libc_add_on_srcdir=$srcdir/$libc_add_on
385 ;;
386 esac
388 libc_add_on_frag=$libc_add_on_srcdir/configure
389 libc_add_on_canonical=
390 libc_add_on_config_subdirs=
391 if test -r "$libc_add_on_frag"; then
392 AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
393 libc_add_on_canonical=unknown
394 libc_add_on_subdirs=
395 . "$libc_add_on_frag"
396 test -z "$libc_add_on" || {
397 configured_add_ons="$configured_add_ons $libc_add_on"
398 if test "x$libc_add_on_canonical" = xunknown; then
399 AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
400 fi
401 for d in $libc_add_on_subdirs; do
402 case "$libc_add_on" in
403 /*) subdir_srcdir="$libc_add_on" ;;
404 *) subdir_srcdir="\$(..)$libc_add_on" ;;
405 esac
406 case "$d" in
407 .)
408 d="${libc_add_on_canonical:-$libc_add_on}"
409 ;;
410 /*)
411 subdir_srcdir="$d"
412 ;;
413 *)
414 subdir_srcdir="$subdir_srcdir/$d"
415 ;;
416 esac
417 d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
418 add_on_subdirs="$add_on_subdirs $d"
419 test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
420 $d-srcdir = $subdir_srcdir"
421 done
422 for d in $libc_add_on_config_subdirs; do
423 case "$d" in
424 /*) AC_MSG_ERROR(dnl
425 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
426 esac
427 if test ! -d "$libc_add_on_srcdir/$d"; then
428 AC_MSG_ERROR(fragment wants to configure missing directory $d)
429 fi
430 case "$libc_add_on" in
431 /*) AC_MSG_ERROR(dnl
432 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
433 esac
434 subdirs="$subdirs $libc_add_on/$d"
435 done
436 }
437 fi
438 if test -n "$libc_add_on"; then
439 if frags=`ls -d $libc_add_on_srcdir/sysdeps/*/preconfigure 2> /dev/null`
440 then
441 AC_MSG_CHECKING(add-on $libc_add_on for preconfigure fragments)
442 for frag in $frags; do
443 name=`echo "$frag" | sed 's@/[[^/]]*$@@;s@^.*/@@'`
444 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
445 . "$frag"
446 done
447 AC_MSG_RESULT()
448 fi
449 use_add_ons="$use_add_ons $libc_add_on"
450 add_ons_pfx="$add_ons_pfx $libc_add_on/"
451 test -z "$libc_add_on_canonical" ||
452 add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
453 fi
454 done
455 # Use echo to strip excess whitespace.
456 add_ons="`echo $use_add_ons`"
457 fi
458 AC_SUBST(add_ons)
459 AC_SUBST(add_on_subdirs)
462 ###
463 ### I put this here to prevent those annoying emails from people who cannot
464 ### read and try to compile glibc on unsupported platforms. --drepper
465 ###
466 ### By using the undocumented --enable-hacker-mode option for configure
467 ### one can skip this test to make the configuration not fail for unsupported
468 ### platforms.
469 ###
470 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
471 case "$machine-$host_os" in
472 *-linux* | *-gnu* | arm*-none*)
473 ;;
474 *)
475 echo "*** The GNU C library is currently not available for this platform."
476 echo "*** So far nobody cared to port it and if there is no volunteer it"
477 echo "*** might never happen. So, if you have interest to see glibc on"
478 echo "*** this platform visit"
479 echo "*** http://www.gnu.org/software/libc/porting.html"
480 echo "*** and join the group of porters"
481 exit 1
482 ;;
483 esac
484 fi
486 dnl We need to use [ and ] for other purposes for a while now.
487 changequote(,)dnl
488 # Expand the configuration machine name into a subdirectory by architecture
489 # type and particular chip. If an add-on configure fragment already set
490 # base_machine, we don't change it.
491 test -n "$base_machine" || case "$machine" in
492 i[34567]86) base_machine=i386 machine=i386/$machine ;;
493 powerpc) base_machine=powerpc machine=powerpc/powerpc32 ;;
494 powerpc64) base_machine=powerpc machine=powerpc/powerpc64 ;;
495 s390) base_machine=s390 machine=s390/s390-32 ;;
496 s390x) base_machine=s390 machine=s390/s390-64 ;;
497 sh3*) base_machine=sh machine=sh/sh3 ;;
498 sh4*) base_machine=sh machine=sh/sh4 ;;
499 sparc | sparcv[67])
500 base_machine=sparc machine=sparc/sparc32 ;;
501 sparcv8 | supersparc | hypersparc)
502 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
503 sparcv8plus | sparcv8plusa | sparcv9)
504 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
505 sparcv8plusb | sparcv9b)
506 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
507 sparcv9v)
508 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
509 sparcv9v2)
510 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
511 sparc64)
512 base_machine=sparc machine=sparc/sparc64 ;;
513 sparc64b)
514 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
515 sparc64v)
516 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
517 sparc64v2)
518 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
519 *) base_machine=$machine ;;
520 esac
521 changequote([,])dnl
522 AC_SUBST(base_machine)
524 if test "$base_machine" = "i386"; then
525 AC_DEFINE(USE_REGPARMS)
526 fi
528 # For the multi-arch option we need support in the assembler.
529 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
530 libc_cv_asm_gnu_indirect_function, [dnl
531 cat > conftest.s <<EOF
532 .type foo,%gnu_indirect_function
533 EOF
534 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
535 then
536 libc_cv_asm_gnu_indirect_function=yes
537 else
538 libc_cv_asm_gnu_indirect_function=no
539 fi
540 rm -f conftest*])
542 AC_MSG_CHECKING(whether .text pseudo-op must be used)
543 AC_CACHE_VAL(libc_cv_dot_text, [dnl
544 cat > conftest.s <<EOF
545 .text
546 EOF
547 libc_cv_dot_text=
548 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
549 libc_cv_dot_text=.text
550 fi
551 rm -f conftest*])
552 if test -z "$libc_cv_dot_text"; then
553 AC_MSG_RESULT(no)
554 else
555 AC_MSG_RESULT(yes)
556 fi
558 AC_CACHE_CHECK(for assembler global-symbol directive,
559 libc_cv_asm_global_directive, [dnl
560 libc_cv_asm_global_directive=UNKNOWN
561 for ac_globl in .globl .global .EXPORT; do
562 cat > conftest.s <<EOF
563 ${libc_cv_dot_text}
564 ${ac_globl} foo
565 foo:
566 EOF
567 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
568 libc_cv_asm_global_directive=${ac_globl}
569 fi
570 rm -f conftest*
571 test $libc_cv_asm_global_directive != UNKNOWN && break
572 done])
573 if test $libc_cv_asm_global_directive = UNKNOWN; then
574 AC_MSG_ERROR(cannot determine asm global directive)
575 else
576 AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
577 fi
579 AC_CACHE_CHECK(for assembler .type directive prefix,
580 libc_cv_asm_type_prefix, [dnl
581 libc_cv_asm_type_prefix=no
582 for ac_try_prefix in '@' '%' '#'; do
583 cat > conftest.s <<EOF
584 ${libc_cv_dot_text}
585 ${libc_cv_asm_global_directive} foo
586 .type foo, ${ac_try_prefix}object
587 .size foo, 1
588 foo:
589 .byte 1
590 EOF
591 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
592 libc_cv_asm_type_prefix=${ac_try_prefix}
593 fi
594 rm -f conftest*
595 test "x$libc_cv_asm_type_prefix" != xno && break
596 done])
597 if test "x$libc_cv_asm_type_prefix" != xno; then
598 AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
599 fi
601 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -o x"$libc_cv_asm_type_prefix" = xno; then
602 if test x"$multi_arch" = xyes; then
603 AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
604 else
605 multi_arch=no
606 fi
607 fi
608 if test x"$multi_arch" != xno; then
609 multi_arch_d=/multiarch
610 fi
612 # Compute the list of sysdep directories for this configuration.
613 # This can take a while to compute.
614 sysdep_dir=$srcdir/sysdeps
615 AC_MSG_CHECKING(sysdep dirs)
616 dnl We need to use [ and ] for other purposes for a while now.
617 changequote(,)dnl
618 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
619 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
621 test "x$base_os" != x || case "$os" in
622 gnu*)
623 base_os=mach/hurd ;;
624 netbsd* | 386bsd* | freebsd* | bsdi*)
625 base_os=unix/bsd/bsd4.4 ;;
626 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
627 base_os=unix/bsd ;;
628 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
629 base_os=unix/sysv ;;
630 irix6*)
631 base_os=unix/sysv/irix6/$os ;;
632 solaris[2-9]*)
633 base_os=unix/sysv/sysv4 ;;
634 none)
635 base_os=standalone ;;
636 esac
638 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
639 tail=$os
640 ostry=$os
641 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
642 ostry="$ostry /$o"
643 tail=$o
644 done
645 o=`echo $tail | sed 's/[0-9]*$//'`
646 if test $o != $tail; then
647 ostry="$ostry /$o"
648 fi
649 # For linux-gnu, try linux-gnu, then linux.
650 o=`echo $tail | sed 's/-.*$//'`
651 if test $o != $tail; then
652 ostry="$ostry /$o"
653 fi
655 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
656 base=
657 tail=$base_os
658 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
659 set $b
660 base="$base /$1"
661 tail="$2"
662 done
664 # For sparc/sparc32, try sparc/sparc32 and then sparc.
665 mach=
666 tail=$machine${submachine:+/$submachine}
667 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
668 set $m
669 # Prepend the machine's FPU directory unless --without-fp.
670 if test "$with_fp" = yes; then
671 mach="$mach /$1/fpu"
672 else
673 mach="$mach /$1/nofpu"
674 fi
675 mach="$mach /$1"
676 tail="$2"
677 done
679 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
680 changequote([,])dnl
682 # Find what sysdep directories exist.
683 sysnames_add_ons=
684 sysnames=
685 for b in $base ''; do
686 for m0 in $mach ''; do
687 for v in /$vendor ''; do
688 test "$v" = / && continue
689 for o in /$ostry ''; do
690 test "$o" = / && continue
691 for m in $multi_arch_d $mach ''; do
692 for d in $add_ons_pfx ''; do
693 for a in $add_ons_sfx ''; do
694 if test -n "$m0$m0sub$b$v$o$m$msub"; then
695 try_srcdir="${srcdir}/"
696 case "$d" in
697 /*) try_srcdir= ;;
698 esac
699 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
700 test -n "$enable_debug_configure" &&
701 echo "$0 [DEBUG]: try $try" >&2
702 if test -d "$try_srcdir$try"; then
703 sysnames="$sysnames $try"
704 { test -n "$o" || test -n "$b"; } && os_used=t
705 { test -n "$m" || test -n "$m0"; } && machine_used=t
706 case x${m0:-$m} in
707 x*/$submachine) submachine_used=t ;;
708 esac
709 if test -n "$d"; then
710 case "$sysnames_add_ons" in
711 *" $d "*) ;;
712 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
713 esac
714 fi
715 fi
716 fi
717 done
718 done
719 done
720 done
721 done
722 done
723 done
725 # If the assembler supports gnu_indirect_function symbol type and the
726 # architecture supports multi-arch, we enable multi-arch by default.
727 case $sysnames_add_ons$sysnames in
728 *"$multi_arch_d"*)
729 ;;
730 *)
731 test x"$multi_arch" = xdefault && multi_arch=no
732 ;;
733 esac
734 if test x"$multi_arch" != xno; then
735 AC_DEFINE(USE_MULTIARCH)
736 fi
737 AC_SUBST(multi_arch)
739 if test -z "$os_used" && test "$os" != none; then
740 AC_MSG_ERROR(Operating system $os is not supported.)
741 fi
742 if test -z "$machine_used" && test "$machine" != none; then
743 AC_MSG_ERROR(The $machine is not supported.)
744 fi
745 if test -z "$submachine_used" && test -n "$submachine"; then
746 AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
747 fi
748 AC_SUBST(submachine)
750 # We have now validated the configuration.
753 # Look for an `elf' subdirectory of each machine directory.
754 # We prepend these rather than inserting them whereever the machine appears
755 # because things specified by the machine's ELF ABI should override
756 # OS-specific things, and should always be the same for any OS on the
757 # machine (otherwise what's the point of an ABI?).
758 elf_dirs=
759 for d in $add_ons_pfx ''; do
760 for m in $mach; do
761 if test -d $srcdir/${d}sysdeps$m/elf; then
762 elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
763 fi
764 done
765 done
766 sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
769 # Expand the list of system names into a full list of directories
770 # from each element's parent name and Implies file (if present).
771 set $sysnames
772 names=
773 while test $# -gt 0; do
774 name=$1
775 shift
777 case " $names " in *" $name "*)
778 # Already in the list.
779 continue
780 esac
782 # Report each name as we discover it, so there is no long pause in output.
783 echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
785 name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
787 case $name in
788 /*) xsrcdir= ;;
789 *) xsrcdir=$srcdir/ ;;
790 esac
791 test -n "$enable_debug_configure" &&
792 echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
794 if test -f $xsrcdir$name/Implies; then
795 # Collect more names from the `Implies' file (removing comments).
796 implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
797 implied=
798 for x in $implied_candidate; do
799 found=no
800 if test -d $xsrcdir$name_base/$x; then
801 implied="$implied $name_base/$x";
802 found=yes
803 fi
804 for d in $add_ons_pfx ''; do
805 try="${d}sysdeps/$x"
806 case $d in
807 /*) try_srcdir= ;;
808 *) try_srcdir=$srcdir/ ;;
809 esac
810 test -n "$enable_debug_configure" &&
811 echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
812 if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
813 then
814 implied="$implied $try"
815 found=yes
816 case "$sysnames_add_ons" in
817 *" $d "*) ;;
818 *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
819 esac
820 fi
821 done
822 if test $found = no; then
823 AC_MSG_WARN($name/Implies specifies nonexistent $x)
824 fi
825 done
826 else
827 implied=
828 fi
830 # Add NAME to the list of names.
831 names="$names $name"
833 # Find the parent of NAME, using the empty string if it has none.
834 changequote(,)dnl
835 parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
836 changequote([,])dnl
838 # Add the names implied by NAME, and NAME's parent (if it has one), to
839 # the list of names to be processed (the argument list). We prepend the
840 # implied names to the list and append the parent. We want implied
841 # directories to come before further directories inferred from the
842 # configuration components; this ensures that for sysv4, unix/common
843 # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
844 # after sysv4).
845 sysnames="`echo $implied $* $parent`"
846 test -n "$sysnames" && set $sysnames
847 done
849 # Add the default directories.
850 default_sysnames="sysdeps/generic/elf sysdeps/generic"
851 sysnames="$names $default_sysnames"
852 AC_SUBST(sysnames)
853 # The other names were emitted during the scan.
854 AC_MSG_RESULT($default_sysnames)
856 # Collect the list of add-ons that supply partial sysdeps trees.
857 sysdeps_add_ons=
858 for add_on in $add_ons; do
859 case "$add_on" in
860 /*) xsrcdir= ;;
861 *) xsrcdir="$srcdir/" ;;
862 esac
864 test -d "$xsrcdir$add_on/sysdeps" || {
865 case "$configured_add_ons " in
866 *" $add_on "*) ;;
867 *|'')
868 AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
869 ;;
870 esac
871 continue
872 }
874 sysdeps_add_ons="$sysdeps_add_ons $add_on"
875 case "$sysnames_add_ons" in
876 *" $add_on/ "*) ;;
877 *|'')
878 AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
879 continue ;;
880 esac
882 found=no
883 for d in $sysnames; do
884 case "$d" in
885 $add_on/sysdeps/*) ;;
886 *) continue ;;
887 esac
888 (cd "$xsrcdir$d" && for f in *[[!~]]; do
889 case "$f" in
890 sys|bits)
891 for ff in $f/*.h; do
892 test -d "$ff" || { test -e "$ff" && exit 88; }
893 done
894 ;;
895 *)
896 test -d "$f" || { test -e "$f" && exit 88; }
897 ;;
898 esac
899 done)
900 if test $? -eq 88; then
901 found=yes
902 break
903 fi
904 done
905 if test $found = no; then
906 AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
907 fi
908 done
909 AC_SUBST(sysdeps_add_ons)
912 ### Locate tools.
914 AC_PROG_INSTALL
915 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
916 # The makefiles need to use a different form to find it in $srcdir.
917 INSTALL='\$(..)./scripts/install-sh -c'
918 fi
919 AC_PROG_LN_S
921 LIBC_PROG_BINUTILS
922 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
924 # Accept binutils 2.13 or newer.
925 AC_CHECK_PROG_VER(AS, $AS, --version,
926 [GNU assembler.* \([0-9]*\.[0-9.]*\)],
927 [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
928 AC_CHECK_PROG_VER(LD, $LD, --version,
929 [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
930 [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
932 # These programs are version sensitive.
933 AC_CHECK_TOOL_PREFIX
934 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
935 [version \([egcygnustpi-]*[0-9.]*\)], [3.4* | 4.[0-9]* ],
936 critic_missing="$critic_missing gcc")
937 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
938 [GNU Make[^0-9]*\([0-9][0-9.]*\)],
939 [3.79* | 3.[89]*], critic_missing="$critic_missing make")
941 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
942 [GNU gettext.* \([0-9]*\.[0-9.]*\)],
943 [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
944 MSGFMT=: aux_missing="$aux_missing msgfmt")
945 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
946 [GNU texinfo.* \([0-9][0-9.]*\)],
947 [4.*],
948 MAKEINFO=: aux_missing="$aux_missing makeinfo")
949 AC_CHECK_PROG_VER(SED, sed, --version,
950 [GNU sed version \([0-9]*\.[0-9.]*\)],
951 [3.0[2-9]*|3.[1-9]*|[4-9]*],
952 SED=: aux_missing="$aux_missing sed")
954 AC_CHECK_TOOL(READELF, readelf, false)
956 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
957 case "x$AUTOCONF" in
958 xno|x|x:) AUTOCONF=no ;;
959 *)
960 AC_CACHE_CHECK(dnl
961 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
962 if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
963 libc_cv_autoconf_works=yes
964 else
965 libc_cv_autoconf_works=no
966 fi])
967 test $libc_cv_autoconf_works = yes || AUTOCONF=no
968 ;;
969 esac
970 if test "x$AUTOCONF" = xno; then
971 aux_missing="$aux_missing autoconf"
972 fi
974 test -n "$critic_missing" && AC_MSG_ERROR([
975 *** These critical programs are missing or too old:$critic_missing
976 *** Check the INSTALL file for required versions.])
978 test -n "$aux_missing" && AC_MSG_WARN([
979 *** These auxiliary programs are missing or incompatible versions:$aux_missing
980 *** some features will be disabled.
981 *** Check the INSTALL file for required versions.])
983 # if using special system headers, find out the compiler's sekrit
984 # header directory and add that to the list. NOTE: Only does the right
985 # thing on a system that doesn't need fixincludes. (Not presently a problem.)
986 if test -n "$sysheaders"; then
987 SYSINCLUDES=-nostdinc
988 for d in include include-fixed; do
989 i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
990 SYSINCLUDES="$SYSINCLUDES -isystem $i"
991 done
992 SYSINCLUDES="$SYSINCLUDES \
993 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
994 if test -n "$CXX"; then
995 CXX_SYSINCLUDES=
996 cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
997 cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
998 for d in include "$cxxmachine/include"; do
999 i=../../../../$d/c++/$cxxversion
1000 cxxheaders=`$CXX -print-file-name="$i"` &&
1001 test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
1002 CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
1003 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1004 done
1005 fi
1006 fi
1007 AC_SUBST(SYSINCLUDES)
1008 AC_SUBST(CXX_SYSINCLUDES)
1010 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1011 # since this would lead to problems installing/building glibc.
1012 # LD_LIBRARY_PATH contains the current directory if one of the following
1013 # is true:
1014 # - one of the terminals (":" and ";") is the first or last sign
1015 # - two terminals occur directly after each other
1016 # - the path contains an element with a dot in it
1017 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1018 changequote(,)dnl
1019 case ${LD_LIBRARY_PATH} in
1020 [:\;]* | *[:\;] | *[:\;][:\;]* | *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1021 ld_library_path_setting="contains current directory"
1022 ;;
1023 *)
1024 ld_library_path_setting="ok"
1025 ;;
1026 esac
1027 changequote([,])dnl
1028 AC_MSG_RESULT($ld_library_path_setting)
1029 if test "$ld_library_path_setting" != "ok"; then
1030 AC_MSG_ERROR([
1031 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1032 *** building glibc. Please change the environment variable
1033 *** and run configure again.])
1034 fi
1036 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1037 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1038 libc_cv_gcc_static_libgcc=
1039 else
1040 libc_cv_gcc_static_libgcc=-static-libgcc
1041 fi])
1042 AC_SUBST(libc_cv_gcc_static_libgcc)
1044 AC_PATH_PROG(BASH_SHELL, bash, no)
1045 if test "$BASH_SHELL" != no &&
1046 $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1047 && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1048 libc_cv_have_bash2=yes
1049 else
1050 libc_cv_have_bash2=no
1051 fi
1052 AC_SUBST(libc_cv_have_bash2)
1054 dnl We need a ksh compatible shell for tzselect.
1055 if test "$BASH_SHELL" = no; then
1056 AC_PATH_PROG(KSH, ksh, no)
1057 if test "$KSH" = no; then
1058 libc_cv_have_ksh=no
1059 else
1060 libc_cv_have_ksh=yes
1061 fi
1062 else
1063 KSH="$BASH_SHELL"
1064 AC_SUBST(KSH)
1065 libc_cv_have_ksh=yes
1066 fi
1067 AC_SUBST(libc_cv_have_ksh)
1069 AC_PROG_AWK
1070 AC_PATH_PROG(PERL, perl, no)
1071 if test "$PERL" != no &&
1072 (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1073 PERL=no
1074 fi
1075 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1076 $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1077 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1079 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1080 AC_TRY_COMPILE(dnl
1081 [#define __need_size_t
1082 #define __need_wchar_t
1083 #include <stddef.h>
1084 #define __need_NULL
1085 #include <stddef.h>], [size_t size; wchar_t wchar;
1086 #ifdef offsetof
1087 #error stddef.h ignored __need_*
1088 #endif
1089 if (&size == NULL || &wchar == NULL) abort ();],
1090 libc_cv_friendly_stddef=yes,
1091 libc_cv_friendly_stddef=no)])
1092 if test $libc_cv_friendly_stddef = yes; then
1093 config_vars="$config_vars
1094 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1095 fi
1097 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1098 libc_cv_need_minus_P, [dnl
1099 cat > conftest.S <<EOF
1100 #include "confdefs.h"
1101 /* Nothing whatsoever. */
1102 EOF
1103 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1104 libc_cv_need_minus_P=no
1105 else
1106 libc_cv_need_minus_P=yes
1107 fi
1108 rm -f conftest*])
1109 if test $libc_cv_need_minus_P = yes; then
1110 config_vars="$config_vars
1111 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1112 fi
1114 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1115 cat > conftest.s <<EOF
1116 ${libc_cv_dot_text}
1117 foo:
1118 .set glibc_conftest_frobozz,foo
1119 $libc_cv_asm_global_directive glibc_conftest_frobozz
1120 EOF
1121 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1122 # (but it doesn't work), so we must do a linking check to be sure.
1123 cat > conftest1.c <<\EOF
1124 extern int glibc_conftest_frobozz;
1125 void _start() { glibc_conftest_frobozz = 1; }
1126 EOF
1127 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1128 -nostartfiles -nostdlib \
1129 -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1130 libc_cv_asm_set_directive=yes
1131 else
1132 libc_cv_asm_set_directive=no
1133 fi
1134 rm -f conftest*])
1135 if test $libc_cv_asm_set_directive = yes; then
1136 AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1137 fi
1139 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1140 libc_cv_asm_unique_object, [dnl
1141 cat > conftest.s <<EOF
1142 ${libc_cv_dot_text}
1143 _sym:
1144 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1145 EOF
1146 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1147 libc_cv_asm_unique_object=yes
1148 else
1149 libc_cv_asm_unique_object=no
1150 fi
1151 rm -f conftest*])
1152 if test $libc_cv_asm_unique_object = yes; then
1153 AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1154 fi
1156 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1157 [cat > conftest.s <<EOF
1158 ${libc_cv_dot_text}
1159 _sym:
1160 .symver _sym,sym@VERS
1161 EOF
1162 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1163 libc_cv_asm_symver_directive=yes
1164 else
1165 libc_cv_asm_symver_directive=no
1166 fi
1167 rm -f conftest*])
1168 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1169 if test $libc_cv_asm_symver_directive = yes; then
1170 cat > conftest.s <<EOF
1171 ${libc_cv_dot_text}
1172 _sym:
1173 .symver _sym,sym@VERS
1174 EOF
1175 cat > conftest.map <<EOF
1176 VERS_1 {
1177 global: sym;
1178 };
1180 VERS_2 {
1181 global: sym;
1182 } VERS_1;
1183 EOF
1184 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1185 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1186 -o conftest.so conftest.o
1187 -nostartfiles -nostdlib
1188 -Wl,--version-script,conftest.map
1189 1>&AS_MESSAGE_LOG_FD]);
1190 then
1191 libc_cv_ld_version_script_option=yes
1192 else
1193 libc_cv_ld_version_script_option=no
1194 fi
1195 else
1196 libc_cv_ld_version_script_option=no
1197 fi
1198 else
1199 libc_cv_ld_version_script_option=no
1200 fi
1201 rm -f conftest*])
1202 if test $shared != no &&
1203 test $libc_cv_asm_symver_directive = yes &&
1204 test $libc_cv_ld_version_script_option = yes &&
1205 test $enable_versioning = yes; then
1206 VERSIONING=yes
1207 AC_DEFINE(DO_VERSIONING)
1208 else
1209 VERSIONING=no
1210 fi
1211 AC_SUBST(VERSIONING)
1213 if test $shared != no && test $VERSIONING = no; then
1214 echo "\
1215 *** WARNING: You should not compile GNU libc without versioning. Not using
1216 *** versioning will introduce incompatibilities so that old binaries
1217 *** will not run anymore.
1218 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1219 fi
1220 AC_CACHE_CHECK(for .previous assembler directive,
1221 libc_cv_asm_previous_directive, [dnl
1222 cat > conftest.s <<EOF
1223 .section foo_section
1224 .previous
1225 EOF
1226 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1227 libc_cv_asm_previous_directive=yes
1228 else
1229 libc_cv_asm_previous_directive=no
1230 fi
1231 rm -f conftest*])
1232 if test $libc_cv_asm_previous_directive = yes; then
1233 AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1234 else
1235 AC_CACHE_CHECK(for .popsection assembler directive,
1236 libc_cv_asm_popsection_directive, [dnl
1237 cat > conftest.s <<EOF
1238 .pushsection foo_section
1239 .popsection
1240 EOF
1241 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1242 libc_cv_asm_popsection_directive=yes
1243 else
1244 libc_cv_asm_popsection_directive=no
1245 fi
1246 rm -f conftest*])
1247 if test $libc_cv_asm_popsection_directive = yes; then
1248 AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1249 fi
1250 fi
1251 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1252 libc_cv_asm_protected_directive, [dnl
1253 cat > conftest.s <<EOF
1254 .protected foo
1255 foo:
1256 .hidden bar
1257 bar:
1258 EOF
1259 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1260 libc_cv_asm_protected_directive=yes
1261 else
1262 AC_MSG_ERROR(assembler support for symbol visibility is required)
1263 fi
1264 rm -f conftest*])
1266 if test $libc_cv_asm_protected_directive = yes; then
1267 AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1268 libc_cv_visibility_attribute,
1269 [cat > conftest.c <<EOF
1270 int foo __attribute__ ((visibility ("hidden"))) = 1;
1271 int bar __attribute__ ((visibility ("protected"))) = 1;
1272 EOF
1273 libc_cv_visibility_attribute=no
1274 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1275 if grep '\.hidden.*foo' conftest.s >/dev/null; then
1276 if grep '\.protected.*bar' conftest.s >/dev/null; then
1277 libc_cv_visibility_attribute=yes
1278 fi
1279 fi
1280 fi
1281 rm -f conftest.{c,s}
1282 ])
1283 if test $libc_cv_visibility_attribute != yes; then
1284 AC_MSG_ERROR(compiler support for visibility attribute is required)
1285 fi
1286 fi
1288 if test $libc_cv_visibility_attribute = yes; then
1289 AC_CACHE_CHECK(for broken __attribute__((visibility())),
1290 libc_cv_broken_visibility_attribute,
1291 [cat > conftest.c <<EOF
1292 int foo (int x);
1293 int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1294 int bar (int x) { return x; }
1295 EOF
1296 libc_cv_broken_visibility_attribute=yes
1297 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1298 changequote(,)dnl
1299 if grep '\.hidden[ _]foo' conftest.s >/dev/null; then
1300 changequote([,])dnl
1301 libc_cv_broken_visibility_attribute=no
1302 fi
1303 fi
1304 rm -f conftest.c conftest.s
1305 ])
1306 if test $libc_cv_broken_visibility_attribute = yes; then
1307 AC_MSG_ERROR(working compiler support for visibility attribute is required)
1308 fi
1309 fi
1311 AC_CACHE_CHECK(for broken __attribute__((alias())),
1312 libc_cv_broken_alias_attribute,
1313 [cat > conftest.c <<EOF
1314 extern int foo (int x) __asm ("xyzzy");
1315 int bar (int x) { return x; }
1316 extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1317 extern int dfoo;
1318 extern __typeof (dfoo) dfoo __asm ("abccb");
1319 int dfoo = 1;
1320 EOF
1321 libc_cv_broken_alias_attribute=yes
1322 if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1323 if grep 'xyzzy' conftest.s >/dev/null &&
1324 grep 'abccb' conftest.s >/dev/null; then
1325 libc_cv_broken_alias_attribute=no
1326 fi
1327 fi
1328 rm -f conftest.c conftest.s
1329 ])
1330 if test $libc_cv_broken_alias_attribute = yes; then
1331 AC_MSG_ERROR(working alias attribute support required)
1332 fi
1334 if test $libc_cv_visibility_attribute = yes; then
1335 AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1336 libc_cv_have_sdata_section,
1337 [echo "int i;" > conftest.c
1338 libc_cv_have_sdata_section=no
1339 if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1340 | grep '\.sdata' >/dev/null; then
1341 libc_cv_have_sdata_section=yes
1342 fi
1343 rm -f conftest.c conftest.so
1344 ])
1345 if test $libc_cv_have_sdata_section = yes; then
1346 AC_DEFINE(HAVE_SDATA_SECTION)
1347 fi
1348 fi
1350 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1351 libc_cv_initfini_array, [dnl
1352 cat > conftest.c <<EOF
1353 int _start (void) { return 0; }
1354 int __start (void) { return 0; }
1355 int foo (void) { return 1; }
1356 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1357 EOF
1358 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -o conftest conftest.c
1359 -static -nostartfiles -nostdlib 1>&AS_MESSAGE_LOG_FD])
1360 then
1361 if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1362 libc_cv_initfini_array=yes
1363 else
1364 libc_cv_initfini_array=no
1365 fi
1366 else
1367 libc_cv_initfini_array=no
1368 fi
1369 rm -f conftest*])
1370 if test $libc_cv_initfini_array != yes; then
1371 AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1372 fi
1374 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1375 libc_cv_ctors_header, [dnl
1376 libc_cv_ctors_header=yes
1377 AC_TRY_LINK([], [
1378 __attribute__ ((constructor)) void ctor (void) { puts("ctor"); }
1379 __attribute__ ((destructor)) void dtor (void) { puts("dtor"); }
1380 ],
1381 [dnl
1382 AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1383 { gsub(/\@<:@ */, "@<:@") }
1384 $2 == ".ctors" || $2 == ".dtors" {
1385 size = strtonum("0x" $6)
1386 align = strtonum("0x" $NF)
1387 seen@<:@$2@:>@ = 1
1388 stub@<:@$2@:>@ = size == align * 2
1389 }
1390 END {
1391 ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1392 dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1393 exit ((ctors_ok && dtors_ok) ? 0 : 1)
1394 }
1395 '], [libc_cv_ctors_header=no])
1396 ], [dnl
1397 AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1398 ])
1399 ])
1400 if test $libc_cv_ctors_header = no; then
1401 AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1402 fi
1404 AC_CACHE_CHECK(for libunwind-support in compiler,
1405 libc_cv_cc_with_libunwind, [
1406 cat > conftest.c <<EOF
1407 int main (void) { return 0; }
1408 EOF
1409 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1410 conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1411 libc_cv_cc_with_libunwind=yes
1412 else
1413 libc_cv_cc_with_libunwind=no
1414 fi
1415 rm -f conftest*])
1416 AC_SUBST(libc_cv_cc_with_libunwind)
1417 if test $libc_cv_cc_with_libunwind = yes; then
1418 AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1419 fi
1421 AC_CACHE_CHECK(for -z nodelete option,
1422 libc_cv_z_nodelete, [dnl
1423 cat > conftest.c <<EOF
1424 int _start (void) { return 42; }
1425 EOF
1426 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1427 -fPIC -shared -o conftest.so conftest.c
1428 -nostartfiles -nostdlib
1429 -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1430 then
1431 libc_cv_z_nodelete=yes
1432 else
1433 AC_MSG_ERROR(linker with -z nodelete support required)
1434 fi
1435 rm -f conftest*])
1437 AC_CACHE_CHECK(for -z nodlopen option,
1438 libc_cv_z_nodlopen, [dnl
1439 cat > conftest.c <<EOF
1440 int _start (void) { return 42; }
1441 EOF
1442 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1443 -fPIC -shared -o conftest.so conftest.c
1444 -nostartfiles -nostdlib
1445 -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1446 then
1447 libc_cv_z_nodlopen=yes
1448 else
1449 AC_MSG_ERROR(linker with -z nodlopen support required)
1450 fi
1451 rm -f conftest*])
1453 AC_CACHE_CHECK(for -z initfirst option,
1454 libc_cv_z_initfirst, [dnl
1455 cat > conftest.c <<EOF
1456 int _start (void) { return 42; }
1457 EOF
1458 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1459 -fPIC -shared -o conftest.so conftest.c
1460 -nostartfiles -nostdlib
1461 -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1462 then
1463 libc_cv_z_initfirst=yes
1464 else
1465 AC_MSG_ERROR(linker with -z initfirst support required)
1466 fi
1467 rm -f conftest*])
1469 # Add-on fragments can set these for other machines.
1470 libc_commonpagesize=${libc_commonpagesize:-no}
1471 libc_relro_required=${libc_relro_required:-no}
1472 case "$base_machine" in
1473 i[[34567]]86 | x86_64 | powerpc* | s390*)
1474 libc_commonpagesize=0x1000
1475 libc_relro_required=yes
1476 ;;
1477 sparc*)
1478 libc_commonpagesize=0x2000
1479 libc_relro_required=yes
1480 ;;
1481 esac
1483 if test $libc_commonpagesize != no; then
1484 AC_CACHE_CHECK(for -z relro option,
1485 libc_cv_z_relro, [dnl
1486 libc_cv_z_relro=no
1487 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1488 int _start (void) { return 42; }
1489 extern void _exit (int);
1490 /* Since these pointers are const, they should go in rodata.
1491 Since they refer to functions that have to be resolved by
1492 dynamic linking, they should instead go in RELRO data. */
1493 const void *const relro[] = { &_start, &_exit, 0 };
1494 /* GNU ld fails to produce RELRO data when it's very small and there is no
1495 normal writable data following it, or if only uninitialized (.bss) data
1496 follows it, or only very small writable data. */
1497 int data[0x10000] = { 1, };
1498 ]])])
1499 cat > conftest.awk <<\EOF
1500 BEGIN {
1501 result = "no"
1502 commonpagesize = strtonum(commonpagesize)
1503 }
1504 { print "LINE:", $0 > "/dev/stderr" }
1505 $1 == "GNU_RELRO" {
1506 vaddr = strtonum($3)
1507 memsz = strtonum($6)
1508 end = vaddr + memsz
1509 printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1510 vaddr, memsz, end, commonpagesize > "/dev/stderr"
1511 result = (end % commonpagesize == 0) ? "yes" : "broken"
1512 }
1513 END { print result }
1514 EOF
1515 AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1516 -fPIC -shared -o conftest.so conftest.c
1517 -nostartfiles -nostdlib
1518 -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1519 AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1520 AC_TRY_COMMAND([
1521 $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1522 conftest.ph > conftest.cps
1523 ]) &&
1524 libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1525 rm -f conftest*])
1526 if { test "x$libc_relro_required" = xyes &&
1527 test "x$libc_cv_z_relro" != xyes
1528 }
1529 then
1530 AC_MSG_ERROR(linker with -z relro support required)
1531 fi
1532 else
1533 AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1534 fi
1536 AC_CACHE_CHECK(for -Bgroup option,
1537 libc_cv_Bgroup, [dnl
1538 cat > conftest.c <<EOF
1539 int _start (void) { return 42; }
1540 EOF
1541 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1542 -fPIC -shared -o conftest.so conftest.c
1543 -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1544 then
1545 libc_cv_Bgroup=yes
1546 else
1547 libc_cv_Bgroup=no
1548 fi
1549 rm -f conftest*])
1550 AC_SUBST(libc_cv_Bgroup)
1552 AC_CACHE_CHECK(for libgcc_s suffix,
1553 libc_cv_libgcc_s_suffix, [dnl
1554 cat > conftest.c <<EOF
1555 int main (void) { return 0; }
1556 EOF
1557 changequote(,)dnl
1558 libc_cv_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1559 -fPIC -shared -shared-libgcc -o conftest.so \
1560 conftest.c -v 2>&1 >/dev/null \
1561 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1562 changequote([,])dnl
1563 rm -f conftest*])
1564 AC_SUBST(libc_cv_libgcc_s_suffix)
1566 AC_CACHE_CHECK(for --as-needed option,
1567 libc_cv_as_needed, [dnl
1568 cat > conftest.c <<EOF
1569 int main (void) { return 0; }
1570 EOF
1571 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1572 -fPIC -shared -o conftest.so conftest.c
1573 -lgcc_s$libc_cv_libgcc_s_suffix -Wl,--as-needed
1574 -nostdlib 1>&AS_MESSAGE_LOG_FD])
1575 then
1576 libc_cv_as_needed=yes
1577 else
1578 libc_cv_as_needed=no
1579 fi
1580 rm -f conftest*])
1581 AC_SUBST(libc_cv_as_needed)
1583 ASFLAGS_config=
1584 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1585 libc_cv_as_noexecstack, [dnl
1586 cat > conftest.c <<EOF
1587 void foo (void) { }
1588 EOF
1589 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1590 -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1591 && grep -q .note.GNU-stack conftest.s \
1592 && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1593 -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1594 then
1595 libc_cv_as_noexecstack=yes
1596 else
1597 libc_cv_as_noexecstack=no
1598 fi
1599 rm -f conftest*])
1600 if test $libc_cv_as_noexecstack = yes; then
1601 ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1602 fi
1603 AC_SUBST(ASFLAGS_config)
1605 AC_CACHE_CHECK(for -z combreloc,
1606 libc_cv_z_combreloc, [dnl
1607 cat > conftest.c <<EOF
1608 extern int bar (int);
1609 extern int mumble;
1610 int foo (void) { return bar (mumble); }
1611 EOF
1612 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1613 -fPIC -shared -o conftest.so conftest.c
1614 -nostdlib -nostartfiles
1615 -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1616 then
1617 dnl The following test is a bit weak. We must use a tool which can test
1618 dnl cross-platform since the gcc used can be a cross compiler. Without
1619 dnl introducing new options this is not easily doable. Instead use a tool
1620 dnl which always is cross-platform: readelf. To detect whether -z combreloc
1621 dnl look for a section named .rel.dyn.
1622 if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1623 libc_cv_z_combreloc=yes
1624 else
1625 libc_cv_z_combreloc=no
1626 fi
1627 else
1628 libc_cv_z_combreloc=no
1629 fi
1630 rm -f conftest*])
1631 if test "$libc_cv_z_combreloc" = yes; then
1632 AC_DEFINE(HAVE_Z_COMBRELOC)
1633 fi
1634 AC_SUBST(libc_cv_z_combreloc)
1636 AC_CACHE_CHECK(for -z execstack,
1637 libc_cv_z_execstack, [dnl
1638 cat > conftest.c <<EOF
1639 int _start (void) { return 42; }
1640 EOF
1641 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1642 -fPIC -shared -o conftest.so conftest.c
1643 -Wl,-z,execstack -nostdlib
1644 1>&AS_MESSAGE_LOG_FD])
1645 then
1646 libc_cv_z_execstack=yes
1647 else
1648 libc_cv_z_execstack=no
1649 fi
1650 rm -f conftest*])
1651 AC_SUBST(libc_cv_z_execstack)
1653 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1654 cat > conftest.c <<EOF
1655 int foo;
1656 main () { return 0;}
1657 EOF
1658 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1659 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1660 then
1661 libc_cv_fpie=yes
1662 else
1663 libc_cv_fpie=no
1664 fi
1665 rm -f conftest*])
1667 AC_SUBST(libc_cv_fpie)
1669 AC_CACHE_CHECK(for --hash-style option,
1670 libc_cv_hashstyle, [dnl
1671 cat > conftest.c <<EOF
1672 int _start (void) { return 42; }
1673 EOF
1674 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1675 -fPIC -shared -o conftest.so conftest.c
1676 -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1677 then
1678 libc_cv_hashstyle=yes
1679 else
1680 libc_cv_hashstyle=no
1681 fi
1682 rm -f conftest*])
1683 AC_SUBST(libc_cv_hashstyle)
1685 # The linker's default -shared behavior is good enough if it
1686 # does these things that our custom linker scripts ensure that
1687 # all allocated NOTE sections come first.
1688 if test "$use_default_link" = default; then
1689 AC_CACHE_CHECK([for sufficient default -shared layout],
1690 libc_cv_use_default_link, [dnl
1691 libc_cv_use_default_link=no
1692 cat > conftest.s <<\EOF
1693 .section .note.a,"a",%note
1694 .balign 4
1695 .long 4,4,9
1696 .string "GNU"
1697 .string "foo"
1698 .section .note.b,"a",%note
1699 .balign 4
1700 .long 4,4,9
1701 .string "GNU"
1702 .string "bar"
1703 EOF
1704 if AC_TRY_COMMAND([dnl
1705 ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1706 ac_try=`$READELF -S conftest.so | sed -n \
1707 ['${x;p;}
1708 s/^ *\[ *[1-9][0-9]*\] *\([^ ][^ ]*\) *\([^ ][^ ]*\) .*$/\2 \1/
1709 t a
1710 b
1711 : a
1712 H']`
1713 then
1714 libc_seen_a=no libc_seen_b=no
1715 set -- $ac_try
1716 while test $# -ge 2 -a "$1" = NOTE; do
1717 case "$2" in
1718 .note.a) libc_seen_a=yes ;;
1719 .note.b) libc_seen_b=yes ;;
1720 esac
1721 shift 2
1722 done
1723 case "$libc_seen_a$libc_seen_b" in
1724 yesyes)
1725 libc_cv_use_default_link=yes
1726 ;;
1727 *)
1728 echo >&AS_MESSAGE_LOG_FD "\
1729 $libc_seen_a$libc_seen_b from:
1730 $ac_try"
1731 ;;
1732 esac
1733 fi
1734 rm -f conftest*])
1735 use_default_link=$libc_cv_use_default_link
1736 fi
1738 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1739 if libc_cv_output_format=`
1740 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1741 then
1742 :
1743 else
1744 libc_cv_output_format=
1745 fi
1746 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1747 AC_SUBST(libc_cv_output_format)
1749 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1750 cat > conftest.c <<EOF
1751 int foo;
1752 EOF
1753 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1754 conftest.c 1>&AS_MESSAGE_LOG_FD])
1755 then
1756 libc_cv_fno_toplevel_reorder=yes
1757 else
1758 libc_cv_fno_toplevel_reorder=no
1759 fi
1760 rm -f conftest*])
1761 if test $libc_cv_fno_toplevel_reorder = yes; then
1762 fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1763 else
1764 fno_unit_at_a_time=-fno-unit-at-a-time
1765 fi
1766 AC_SUBST(fno_unit_at_a_time)
1768 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1769 cat > conftest.c <<EOF
1770 int foo;
1771 main () { return 0;}
1772 EOF
1773 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -Werror -fstack-protector
1774 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1775 then
1776 libc_cv_ssp=yes
1777 else
1778 libc_cv_ssp=no
1779 fi
1780 rm -f conftest*])
1781 AC_SUBST(libc_cv_ssp)
1783 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1784 cat > conftest.c <<EOF
1785 int foo;
1786 #ifdef __GNUC_GNU_INLINE__
1787 main () { return 0;}
1788 #else
1789 #error
1790 #endif
1791 EOF
1792 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1793 -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1794 then
1795 libc_cv_gnu89_inline=yes
1796 else
1797 libc_cv_gnu89_inline=no
1798 fi
1799 rm -f conftest*])
1800 if test $libc_cv_gnu89_inline = yes; then
1801 gnu89_inline=-fgnu89-inline
1802 else
1803 gnu89_inline=
1804 fi
1805 AC_SUBST(gnu89_inline)
1807 AC_CACHE_CHECK(whether cc puts quotes around section names,
1808 libc_cv_have_section_quotes,
1809 [cat > conftest.c <<EOF
1810 static const int foo
1811 __attribute__ ((section ("bar"))) = 1;
1812 EOF
1813 if ${CC-cc} -S conftest.c -o conftest.s; then
1814 if grep '\.section.*"bar"' conftest.s >/dev/null; then
1815 libc_cv_have_section_quotes=yes
1816 else
1817 libc_cv_have_section_quotes=no
1818 fi
1819 else
1820 libc_cv_have_section_quotes=unknown
1821 fi
1822 rm -f conftest.{c,s}
1823 ])
1824 if test $libc_cv_have_section_quotes = yes; then
1825 AC_DEFINE(HAVE_SECTION_QUOTES)
1826 fi
1828 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1829 [dnl
1830 cat > conftest.s <<EOF
1831 ${libc_cv_dot_text}
1832 ${libc_cv_asm_global_directive} foo
1833 foo:
1834 .weak foo
1835 .weak bar; bar = foo
1836 EOF
1837 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1838 libc_cv_asm_weak_directive=yes
1839 else
1840 libc_cv_asm_weak_directive=no
1841 fi
1842 rm -f conftest*])
1844 if test $libc_cv_asm_weak_directive = no; then
1845 AC_CACHE_CHECK(for assembler .weakext directive,
1846 libc_cv_asm_weakext_directive,
1847 [dnl
1848 cat > conftest.s <<EOF
1849 ${libc_cv_dot_text}
1850 ${libc_cv_asm_global_directive} foo
1851 foo:
1852 .weakext bar foo
1853 .weakext baz
1854 ${libc_cv_asm_global_directive} baz
1855 baz:
1856 EOF
1857 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1858 libc_cv_asm_weakext_directive=yes
1859 else
1860 libc_cv_asm_weakext_directive=no
1861 fi
1862 rm -f conftest*])
1864 fi # no .weak
1866 if test $libc_cv_asm_weak_directive = yes; then
1867 AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1868 elif test $libc_cv_asm_weakext_directive = yes; then
1869 AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1870 fi
1872 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1873 case $machine in
1874 sparc/sparc64*) cfi_offset=2047;;
1875 *) cfi_offset=0;;
1876 esac
1877 cat > conftest.s <<EOF
1878 .text
1879 .type func,%function
1880 func:
1881 .cfi_startproc
1882 .cfi_remember_state
1883 .cfi_rel_offset 1, $cfi_offset
1884 .cfi_endproc
1885 EOF
1886 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1887 libc_cv_asm_cfi_directives=yes
1888 else
1889 libc_cv_asm_cfi_directives=no
1890 fi
1891 rm -f conftest*])
1892 if test $libc_cv_asm_cfi_directives = yes; then
1893 AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1894 fi
1896 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1897 cat > conftest.c <<\EOF
1898 _start () {}
1899 int __eh_pc;
1900 __throw () {}
1901 EOF
1902 dnl No \ in command here because it ends up inside ''.
1903 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1904 -nostdlib -nostartfiles -Wl,--no-whole-archive
1905 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1906 libc_cv_ld_no_whole_archive=yes
1907 else
1908 libc_cv_ld_no_whole_archive=no
1909 fi
1910 rm -f conftest*])
1911 if test $libc_cv_ld_no_whole_archive = no; then
1912 AC_MSG_ERROR([support for --no-whole-archive is needed])
1913 fi
1915 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1916 cat > conftest.c <<\EOF
1917 _start () {}
1918 int __eh_pc;
1919 __throw () {}
1920 EOF
1921 dnl No \ in command here because it ends up inside ''.
1922 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1923 -nostdlib -nostartfiles -fexceptions
1924 -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1925 libc_cv_gcc_exceptions=yes
1926 else
1927 libc_cv_gcc_exceptions=no
1928 fi
1929 rm -f conftest*])
1930 if test $libc_cv_gcc_exceptions = yes; then
1931 exceptions=-fexceptions
1932 fi
1933 AC_SUBST(exceptions)dnl
1935 if test "$host_cpu" = powerpc ; then
1936 # Check for a bug present in at least versions 2.8.x of GCC
1937 # and versions 1.0.x of EGCS.
1938 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1939 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1940 libc_cv_c_asmcr0_bug='no',
1941 libc_cv_c_asmcr0_bug='yes')])
1942 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1943 AC_DEFINE(BROKEN_PPC_ASM_CR0)
1944 fi
1945 fi
1947 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1948 cat > conftest.c <<\EOF
1949 void zero (void *x)
1950 {
1951 __builtin_memset (x, 0, 1000);
1952 }
1953 EOF
1954 dnl
1955 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1956 then
1957 libc_cv_gcc_builtin_memset=no
1958 else
1959 libc_cv_gcc_builtin_memset=yes
1960 fi
1961 rm -f conftest* ])
1962 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1963 AC_DEFINE(HAVE_BUILTIN_MEMSET)
1964 fi
1966 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1967 cat > conftest.c <<\EOF
1968 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1969 char *foo (const char *a, const char *b)
1970 {
1971 return __builtin_strstr (a, b);
1972 }
1973 EOF
1974 dnl
1975 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1976 then
1977 libc_cv_gcc_builtin_redirection=yes
1978 else
1979 libc_cv_gcc_builtin_redirection=no
1980 fi
1981 rm -f conftest* ])
1982 if test "$libc_cv_gcc_builtin_redirection" = no; then
1983 AC_MSG_ERROR([support for the symbol redirection needed])
1984 fi
1986 dnl Check whether the compiler supports the __thread keyword.
1987 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1988 [cat > conftest.c <<\EOF
1989 __thread int a = 42;
1990 EOF
1991 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
1992 libc_cv_gcc___thread=yes
1993 else
1994 libc_cv_gcc___thread=no
1995 fi
1996 rm -f conftest*])
1997 if test "$libc_cv_gcc___thread" = no; then
1998 AC_MSG_ERROR([support for the __thread keyword is required])
1999 fi
2001 dnl Check whether the compiler supports the tls_model attribute.
2002 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
2003 cat > conftest.c <<\EOF
2004 extern __thread int a __attribute__((tls_model ("initial-exec")));
2005 EOF
2006 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
2007 libc_cv_gcc_tls_model_attr=yes
2008 else
2009 libc_cv_gcc_tls_model_attr=no
2010 fi
2011 rm -f conftest*])
2012 if test "$libc_cv_gcc_tls_model_attr" = no; then
2013 AC_MSG_ERROR([support for the tls_model attribute is required])
2014 fi
2016 if test -n "$submachine"; then
2017 AC_CACHE_CHECK([for compiler option for CPU variant],
2018 libc_cv_cc_submachine, [dnl
2019 libc_cv_cc_submachine=no
2020 for opt in "-march=$submachine" "-mcpu=$submachine"; do
2021 if AC_TRY_COMMAND([${CC-cc} $opt -xc /dev/null -S -o /dev/null]); then
2022 libc_cv_cc_submachine="$opt"
2023 break
2024 fi
2025 done])
2026 if test "x$libc_cv_cc_submachine" = xno; then
2027 AC_MSG_ERROR([${CC-cc} does not support $submachine])
2028 fi
2029 fi
2030 AC_SUBST(libc_cv_cc_submachine)
2032 dnl Check whether we have the gd library available.
2033 AC_MSG_CHECKING(for libgd)
2034 if test "$with_gd" != "no"; then
2035 old_CFLAGS="$CFLAGS"
2036 CFLAGS="$CFLAGS $libgd_include"
2037 old_LDFLAGS="$LDFLAGS"
2038 LDFLAGS="$LDFLAGS $libgd_ldflags"
2039 old_LIBS="$LIBS"
2040 LIBS="$LIBS -lgd -lpng -lz -lm"
2041 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
2042 CFLAGS="$old_CFLAGS"
2043 LDFLAGS="$old_LDFLAGS"
2044 LIBS="$old_LIBS"
2045 else
2046 LIBGD=no
2047 fi
2048 AC_MSG_RESULT($LIBGD)
2049 AC_SUBST(LIBGD)
2051 # SELinux detection
2052 if test x$with_selinux = xno ; then
2053 have_selinux=no;
2054 else
2055 # See if we have the SELinux library
2056 AC_CHECK_LIB(selinux, is_selinux_enabled,
2057 have_selinux=yes, have_selinux=no)
2058 # See if we have the SELinux header with the NSCD permissions in it.
2059 if test x$have_selinux = xyes ; then
2060 AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2061 AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2062 [#ifdef NSCD__SHMEMHOST
2063 return 0;
2064 #else
2065 #error NSCD__SHMEMHOST not defined
2066 #endif],
2067 have_selinux=yes, have_selinux=no)
2068 AC_MSG_RESULT($have_selinux)
2069 fi
2071 if test x$with_selinux = xyes ; then
2072 if test x$have_selinux = xno ; then
2073 AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2074 fi
2075 fi
2076 fi
2077 # Check if we're building with SELinux support.
2078 if test "x$have_selinux" = xyes; then
2079 AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2081 # See if we have the libaudit library
2082 AC_CHECK_LIB(audit, audit_log_user_avc_message,
2083 have_libaudit=yes, have_libaudit=no)
2084 if test "x$have_libaudit" = xyes; then
2085 AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2086 fi
2087 AC_SUBST(have_libaudit)
2089 # See if we have the libcap library
2090 AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2091 if test "x$have_libcap" = xyes; then
2092 AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2093 fi
2094 AC_SUBST(have_libcap)
2095 fi
2096 AC_SUBST(have_selinux)
2098 dnl check for the size of 'long double'.
2099 AC_CHECK_SIZEOF(long double, 0)
2100 sizeof_long_double=$ac_cv_sizeof_long_double
2101 AC_SUBST(sizeof_long_double)
2103 ### End of automated tests.
2104 ### Now run sysdeps configure fragments.
2106 # They also can set these variables.
2107 use_ldconfig=no
2108 ldd_rewrite_script=no
2109 libc_cv_sysconfdir=$sysconfdir
2110 libc_cv_gcc_unwind_find_fde=no
2111 libc_cv_idn=no
2113 # Iterate over all the sysdep directories we will use, running their
2114 # configure fragments.
2115 for dir in $sysnames; do
2116 case $dir in
2117 /*) dest=$dir ;;
2118 *) dest=$srcdir/$dir ;;
2119 esac
2120 if test -r $dest/configure; then
2121 AC_MSG_RESULT(running configure fragment for $dir)
2122 . $dest/configure
2123 fi
2124 done
2126 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2127 AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2128 fi
2129 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2131 # Test for old glibc 2.0.x headers so that they can be removed properly
2132 # Search only in includedir.
2133 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2134 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2135 then
2136 old_glibc_headers=yes
2137 else
2138 old_glibc_headers=no
2139 fi
2140 AC_MSG_RESULT($old_glibc_headers)
2141 if test ${old_glibc_headers} = yes; then
2142 AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2143 AC_MSG_WARN(*** be removed.)
2144 fi
2145 AC_SUBST(old_glibc_headers)
2147 AC_SUBST(libc_cv_slibdir)
2148 AC_SUBST(libc_cv_localedir)
2149 AC_SUBST(libc_cv_sysconfdir)
2150 AC_SUBST(libc_cv_rootsbindir)
2151 AC_SUBST(libc_cv_forced_unwind)
2153 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2154 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2155 AC_SUBST(libc_cv_cc_sse4)
2156 AC_SUBST(libc_cv_cc_avx)
2157 AC_SUBST(libc_cv_cc_sse2avx)
2158 AC_SUBST(libc_cv_cc_novzeroupper)
2159 AC_SUBST(libc_cv_cc_fma4)
2160 AC_SUBST(libc_cv_as_i686)
2162 AC_SUBST(use_ldconfig)
2163 AC_SUBST(ldd_rewrite_script)
2165 AC_SUBST(static)
2166 AC_SUBST(shared)
2168 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2169 [libc_cv_pic_default=yes
2170 cat > conftest.c <<EOF
2171 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2172 # error PIC is default.
2173 #endif
2174 EOF
2175 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2176 libc_cv_pic_default=no
2177 fi
2178 rm -f conftest.*])
2179 AC_SUBST(libc_cv_pic_default)
2181 AC_SUBST(profile)
2182 AC_SUBST(static_nss)
2184 AC_SUBST(DEFINES)
2186 dnl See sysdeps/mach/configure.in for this variable.
2187 AC_SUBST(mach_interface_list)
2189 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2190 config_makefile=
2191 else
2192 config_makefile=Makefile
2193 fi
2195 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2196 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2197 AC_SUBST(VERSION)
2198 AC_SUBST(RELEASE)
2200 AC_CONFIG_FILES([config.make ${config_makefile}])
2201 AC_CONFIG_COMMANDS([default],[[
2202 case $CONFIG_FILES in *config.make*)
2203 echo "$config_vars" >> config.make;;
2204 esac
2205 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2206 AC_OUTPUT