sysdeps/i386/elf/start.S

   1 /* Startup code compliant to the ELF i386 ABI.
   2    Copyright (C) 1995,1996,1997,1998,2000,2001 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Library General Public License as
   7    published by the Free Software Foundation; either version 2 of the
   8    License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Library General Public License for more details.
  14
  15    You should have received a copy of the GNU Library General Public
  16    License along with the GNU C Library; see the file COPYING.LIB.  If not,
  17    write to the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  18    Boston, MA 02111-1307, USA.  */
  19
  20 /* This is the canonical entry point, usually the first thing in the text
  21    segment.  The SVR4/i386 ABI (pages 3-31, 3-32) says that when the entry
  22    point runs, most registers' values are unspecified, except for:
  23
  24    %edx         Contains a function pointer to be registered with `atexit'.
  25                 This is how the dynamic linker arranges to have DT_FINI
  26                 functions called for shared libraries that have been loaded
  27                 before this code runs.
  28
  29    %esp         The stack contains the arguments and environment:
  30                 0(%esp)                 argc
  31                 4(%esp)                 argv[0]
  32                 ...
  33                 (4*argc)(%esp)          NULL
  34                 (4*(argc+1))(%esp)      envp[0]
  35                 ...
  36                                         NULL
  37 */
  38
  39 #include "bp-sym.h"
  40
  41         .text
  42         .globl _start
  43         .type _start,@function
  44 _start:
  45         /* Clear the frame pointer.  The ABI suggests this be done, to mark
  46            the outermost frame obviously.  */
  47         xorl %ebp, %ebp
  48
  49         /* Extract the arguments as encoded on the stack and set up
  50            the arguments for `main': argc, argv.  envp will be determined
  51            later in __libc_start_main.  */
  52         popl %esi               /* Pop the argument count.  */
  53         movl %esp, %ecx         /* argv starts just at the current stack top.*/
  54
  55         /* Before pushing the arguments align the stack to a 16-byte
  56         (SSE needs 16-byte alignment) boundary to avoid penalties from
  57         misaligned accesses.  Thanks to Edward Seidl <seidl@janed.com>
  58         for pointing this out.  */
  59         andl $0xfffffff0, %esp
  60         pushl %eax              /* Push garbage because we allocate
  61                                    28 more bytes.  */
  62
  63         /* Provide the highest stack address to the user code (for stacks
  64            which grow downwards).  */
  65         pushl %esp
  66
  67         pushl %edx              /* Push address of the shared library
  68                                    termination function.  */
  69
  70         /* Push address of our own entry points to .fini and .init.  */
  71         pushl $_fini
  72         pushl $_init
  73
  74         pushl %ecx              /* Push second argument: argv.  */
  75         pushl %esi              /* Push first argument: argc.  */
  76
  77         pushl $BP_SYM (main)
  78
  79         /* Call the user's main function, and exit with its value.
  80            But let the libc call main.    */
  81         call BP_SYM (__libc_start_main)
  82
  83         hlt                     /* Crash if somehow `exit' does return.  */
  84
  85 /* To fulfill the System V/i386 ABI we need this symbol.  Yuck, it's so
  86    meaningless since we don't support machines < 80386.  */
  87         .section .rodata
  88         .globl _fp_hw
  89 _fp_hw: .long 3
  90         .size _fp_hw, 4
  91
  92 /* Define a symbol for the first piece of initialized data.  */
  93         .data
  94         .globl __data_start
  95 __data_start:
  96         .long 0
  97         .weak data_start
  98         data_start = __data_start