sysdeps/alpha/divl.S

   1 /* Copyright (C) 2004-2014 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <http://www.gnu.org/licenses/>.  */
  17
  18 #include "div_libc.h"
  19
  20 /* 32-bit signed int divide.  This is not a normal C function.  Argument
  21    registers are t10 and t11, the result goes in t12.  Only t12 and AT may
  22    be clobbered.
  23
  24    The FPU can handle all input values except zero.  Whee!
  25
  26    The FPCR save/restore is due to the fact that the EV6 _will_ set FPCR_INE
  27    for cvttq/c even without /sui being set.  It will not, however, properly
  28    raise the exception, so we don't have to worry about FPCR_INED being clear
  29    and so dying by SIGFPE.  */
  30
  31 #ifndef EXTEND
  32 #define EXTEND(S,D)     sextl S, D
  33 #endif
  34
  35         .text
  36         .align  4
  37         .globl  __divl
  38         .type   __divl, @funcnoplt
  39         .usepv  __divl, no
  40
  41         cfi_startproc
  42         cfi_return_column (RA)
  43 __divl:
  44         lda     sp, -FRAME(sp)
  45         cfi_def_cfa_offset (FRAME)
  46         CALL_MCOUNT
  47         stt     $f0, 0(sp)
  48         excb
  49         beq     Y, DIVBYZERO
  50
  51         stt     $f1, 8(sp)
  52         stt     $f2, 16(sp)
  53         cfi_rel_offset ($f0, 0)
  54         cfi_rel_offset ($f1, 8)
  55         cfi_rel_offset ($f2, 16)
  56         mf_fpcr $f2
  57
  58         EXTEND  (X, RV)
  59         EXTEND  (Y, AT)
  60         _ITOFT2 RV, $f0, 24, AT, $f1, 32
  61         cvtqt   $f0, $f0
  62         cvtqt   $f1, $f1
  63         divt/c  $f0, $f1, $f0
  64         cvttq/c $f0, $f0
  65         excb
  66         mt_fpcr $f2
  67         _FTOIT  $f0, RV, 24
  68
  69         ldt     $f0, 0(sp)
  70         ldt     $f1, 8(sp)
  71         ldt     $f2, 16(sp)
  72         lda     sp, FRAME(sp)
  73         cfi_restore ($f0)
  74         cfi_restore ($f1)
  75         cfi_restore ($f2)
  76         cfi_def_cfa_offset (0)
  77         sextl   RV, RV
  78         ret     $31, (RA), 1
  79
  80         cfi_endproc
  81         .size   __divl, .-__divl
  82
  83         DO_DIVBYZERO