sysdeps/s390/multiarch/stpcpy-vx.S

   1 /* Vector optimized 32/64 bit S/390 version of stpcpy.
   2    Copyright (C) 2015-2017 Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4
   5    The GNU C Library is free software; you can redistribute it and/or
   6    modify it under the terms of the GNU Lesser General Public
   7    License as published by the Free Software Foundation; either
   8    version 2.1 of the License, or (at your option) any later version.
   9
  10    The GNU C Library is distributed in the hope that it will be useful,
  11    but WITHOUT ANY WARRANTY; without even the implied warranty of
  12    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13    Lesser General Public License for more details.
  14
  15    You should have received a copy of the GNU Lesser General Public
  16    License along with the GNU C Library; if not, see
  17    <http://www.gnu.org/licenses/>.  */
  18
  19 #if defined HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc)
  20
  21 # include "sysdep.h"
  22 # include "asm-syntax.h"
  23
  24         .text
  25
  26 /* char * stpcpy (const char *dest, const char *src)
  27    Copy string src to dest returning a pointer to its end.
  28
  29    Register usage:
  30    -r1=tmp
  31    -r2=dest and return value
  32    -r3=src
  33    -r4=tmp
  34    -r5=current_len
  35    -v16=part of src
  36    -v17=index of zero
  37    -v18=part of src
  38 */
  39 ENTRY(__stpcpy_vx)
  40         .machine "z13"
  41         .machinemode "zarch_nohighgprs"
  42
  43         vlbb    %v16,0(%r3),6   /* Load s until next 4k-byte boundary.  */
  44         lcbb    %r1,0(%r3),6    /* Get bytes to 4k-byte boundary or 16.  */
  45
  46         vfenezb %v17,%v16,%v16  /* Find element not equal with zero search.  */
  47         vlgvb   %r5,%v17,7      /* Load zero index or 16 if not found.  */
  48         clrjl   %r5,%r1,.Lfound_align /* If found zero within loaded bytes,
  49                                          copy bytes before and return.  */
  50
  51         /* Align s to 16 byte.  */
  52         risbgn  %r4,%r3,60,128+63,0 /* %r3 = bits 60-63 of %r2 'and' 15.  */
  53         lghi    %r5,15          /* current_len = 15.  */
  54         slr     %r5,%r4         /* Compute highest index to 16byte boundary.  */
  55
  56         vstl    %v16,%r5,0(%r2) /* Copy loaded characters - no zero.  */
  57         ahi     %r5,1           /* Start loop at next character.  */
  58
  59         /* Find zero in 16byte aligned loop.  */
  60 .Lloop:
  61         vl      %v16,0(%r5,%r3) /* Load s.  */
  62         vfenezbs %v17,%v16,%v16 /* Find element not equal with zero search.  */
  63         je      .Lfound_v16_0   /* Jump away if zero was found.  */
  64         vl      %v18,16(%r5,%r3) /* Load next part of s.  */
  65         vst     %v16,0(%r5,%r2) /* Store previous part without zero to dst.  */
  66         vfenezbs %v17,%v18,%v18
  67         je      .Lfound_v18_16
  68         vl      %v16,32(%r5,%r3)
  69         vst     %v18,16(%r5,%r2)
  70         vfenezbs %v17,%v16,%v16
  71         je      .Lfound_v16_32
  72         vl      %v18,48(%r5,%r3)
  73         vst     %v16,32(%r5,%r2)
  74         vfenezbs %v17,%v18,%v18
  75         je      .Lfound_v18_48
  76         vst     %v18,48(%r5,%r2)
  77
  78         aghi    %r5,64
  79         j       .Lloop          /* No zero found -> loop.  */
  80
  81 .Lfound_v16_32:
  82         aghi    %r5,32
  83 .Lfound_v16_0:
  84         la      %r3,0(%r5,%r2)
  85         vlgvb   %r1,%v17,7      /* Load byte index of zero.  */
  86         vstl    %v16,%r1,0(%r3) /* Copy characters including zero.  */
  87         la      %r2,0(%r1,%r3)  /* Return pointer to zero.  */
  88         br      %r14
  89
  90 .Lfound_v18_48:
  91         aghi    %r5,32
  92 .Lfound_v18_16:
  93         la      %r3,16(%r5,%r2)
  94         vlgvb   %r1,%v17,7      /* Load byte index of zero.  */
  95         vstl    %v18,%r1,0(%r3) /* Copy characters including zero.  */
  96         la      %r2,0(%r1,%r3)  /* Return pointer to zero.  */
  97         br      %r14
  98
  99 .Lfound_align:
 100         vstl    %v16,%r5,0(%r2) /* Copy characters including zero.  */
 101         la      %r2,0(%r5,%r2)  /* Return pointer to zero.  */
 102         br      %r14
 103 END(__stpcpy_vx)
 104 #endif /* HAVE_S390_VX_ASM_SUPPORT && IS_IN (libc) */