sysdeps/alpha/strncat.S

   1 /* Copyright (C) 1996-2022 Free Software Foundation, Inc.
   2    This file is part of the GNU C Library.
   3
   4    The GNU C Library is free software; you can redistribute it and/or
   5    modify it under the terms of the GNU Lesser General Public
   6    License as published by the Free Software Foundation; either
   7    version 2.1 of the License, or (at your option) any later version.
   8
   9    The GNU C Library is distributed in the hope that it will be useful,
  10    but WITHOUT ANY WARRANTY; without even the implied warranty of
  11    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12    Lesser General Public License for more details.
  13
  14    You should have received a copy of the GNU Lesser General Public
  15    License along with the GNU C Library.  If not, see
  16    <https://www.gnu.org/licenses/>.  */
  17
  18 /* Append no more than COUNT characters from the null-terminated string SRC
  19    to the null-terminated string DST.  Always null-terminate the new DST.  */
  20
  21 #include <sysdep.h>
  22
  23         .text
  24
  25 ENTRY(strncat)
  26         ldgp    gp, 0(pv)
  27 #ifdef PROF
  28         .set noat
  29         lda     AT, _mcount
  30         jsr     AT, (AT), _mcount
  31         .set at
  32 #endif
  33         .prologue 1
  34
  35         mov     a0, v0          # set up return value
  36         beq     a2, $zerocount
  37
  38         /* Find the end of the string.  */
  39
  40         ldq_u   t0, 0(a0)       # load first quadword (a0 may be misaligned)
  41         lda     t1, -1(zero)
  42         insqh   t1, a0, t1
  43         andnot  a0, 7, a0
  44         or      t1, t0, t0
  45         cmpbge  zero, t0, t1    # t1 <- bitmask: bit i == 1 <==> i-th byte == 0
  46         bne     t1, $found
  47
  48 $loop:  ldq     t0, 8(a0)
  49         addq    a0, 8, a0       # addr += 8
  50         cmpbge  zero, t0, t1
  51         beq     t1, $loop
  52
  53 $found: negq    t1, t2          # clear all but least set bit
  54         and     t1, t2, t1
  55
  56         and     t1, 0xf0, t2    # binary search for that set bit
  57         and     t1, 0xcc, t3
  58         and     t1, 0xaa, t4
  59         cmovne  t2, 4, t2
  60         cmovne  t3, 2, t3
  61         cmovne  t4, 1, t4
  62         addq    t2, t3, t2
  63         addq    a0, t4, a0
  64         addq    a0, t2, a0
  65
  66         /* Now do the append.  */
  67
  68         jsr     t9, __stxncpy
  69
  70         /* Worry about the null termination.  */
  71
  72         zapnot  t0, t8, t1      # was last byte a null?
  73         bne     t1, 0f
  74         ret
  75
  76 0:      and     t10, 0x80, t1
  77         bne     t1, 1f
  78
  79         /* Here there are bytes left in the current word.  Clear one.  */
  80         addq    t10, t10, t10   # end-of-count bit <<= 1
  81         zap     t0, t10, t0
  82         stq_u   t0, 0(a0)
  83         ret
  84
  85 1:      /* Here we must read the next DST word and clear the first byte.  */
  86         ldq_u   t0, 8(a0)
  87         zap     t0, 1, t0
  88         stq_u   t0, 8(a0)
  89
  90 $zerocount:
  91         ret
  92
  93         END(strncat)