sysdeps/i386/addmul_1.S

   1 /* i80386 __mpn_addmul_1 -- Multiply a limb vector with a limb and add
   2    the result to a second limb vector.
   3    Copyright (C) 1992,1994,1997,1998,2000,2005 Free Software Foundation, Inc.
   4    This file is part of the GNU MP Library.
   5
   6    The GNU MP Library is free software; you can redistribute it and/or modify
   7    it under the terms of the GNU Lesser General Public License as published by
   8    the Free Software Foundation; either version 2.1 of the License, or (at your
   9    option) any later version.
  10
  11    The GNU MP Library is distributed in the hope that it will be useful, but
  12    WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  13    or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General Public
  14    License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public License
  17    along with the GNU MP Library; see the file COPYING.LIB.  If not,
  18    see <http://www.gnu.org/licenses/>.  */
  19
  20 #include "sysdep.h"
  21 #include "asm-syntax.h"
  22 #include "bp-sym.h"
  23 #include "bp-asm.h"
  24
  25 #define PARMS   LINKAGE+16      /* space for 4 saved regs */
  26 #define RES     PARMS
  27 #define S1      RES+PTR_SIZE
  28 #define SIZE    S1+PTR_SIZE
  29 #define S2LIMB  SIZE+4
  30
  31 #define res_ptr edi
  32 #define s1_ptr esi
  33 #define sizeP ecx
  34 #define s2_limb ebx
  35
  36         .text
  37 ENTRY (BP_SYM (__mpn_addmul_1))
  38         ENTER
  39
  40         pushl   %res_ptr
  41         cfi_adjust_cfa_offset (4)
  42         pushl   %s1_ptr
  43         cfi_adjust_cfa_offset (4)
  44         pushl   %ebp
  45         cfi_adjust_cfa_offset (4)
  46         pushl   %s2_limb
  47         cfi_adjust_cfa_offset (4)
  48
  49         movl    RES(%esp), %res_ptr
  50         cfi_rel_offset (res_ptr, 12)
  51         movl    S1(%esp), %s1_ptr
  52         cfi_rel_offset (s1_ptr, 8)
  53         movl    SIZE(%esp), %sizeP
  54         movl    S2LIMB(%esp), %s2_limb
  55         cfi_rel_offset (s2_limb, 0)
  56 #if __BOUNDED_POINTERS__
  57         shll    $2, %sizeP      /* convert limbs to bytes */
  58         CHECK_BOUNDS_BOTH_WIDE (%res_ptr, RES(%esp), %sizeP)
  59         CHECK_BOUNDS_BOTH_WIDE (%s1_ptr, S1(%esp), %sizeP)
  60         shrl    $2, %sizeP
  61 #endif
  62         leal    (%res_ptr,%sizeP,4), %res_ptr
  63         leal    (%s1_ptr,%sizeP,4), %s1_ptr
  64         negl    %sizeP
  65         xorl    %ebp, %ebp
  66         cfi_rel_offset (ebp, 4)
  67         ALIGN (3)
  68 L(oop):
  69         movl    (%s1_ptr,%sizeP,4), %eax
  70         mull    %s2_limb
  71         addl    %ebp, %eax
  72         adcl    $0, %edx
  73         addl    %eax, (%res_ptr,%sizeP,4)
  74         adcl    $0, %edx
  75         movl    %edx, %ebp
  76
  77         incl    %sizeP
  78         jnz     L(oop)
  79         movl    %ebp, %eax
  80
  81         popl    %s2_limb
  82         cfi_adjust_cfa_offset (-4)
  83         cfi_restore (s2_limb)
  84         popl    %ebp
  85         cfi_adjust_cfa_offset (-4)
  86         cfi_restore (ebp)
  87         popl    %s1_ptr
  88         cfi_adjust_cfa_offset (-4)
  89         cfi_restore (s1_ptr)
  90         popl    %res_ptr
  91         cfi_adjust_cfa_offset (-4)
  92         cfi_restore (res_ptr)
  93
  94         LEAVE
  95         ret
  96 END (BP_SYM (__mpn_addmul_1))