sysdeps/csky/preconfigure.ac

   1 GLIBC_PROVIDES[]dnl See aclocal.m4 in the top level source directory.
   2 # Local preconfigure fragment for sysdeps/csky
   3
   4 case "$machine" in
   5 csky*)
   6     abi=`$CC $CFLAGS $CPPFLAGS -E -dM -xc /dev/null |
   7       sed -n 's/^#define __CSKYABI__ \(.*\)/\1/p'`
   8     hard_float=`$CC $CFLAGS $CPPFLAGS -E -dM -xc /dev/null |
   9       sed -n 's/^#define __CSKY_HARD_FLOAT__ \(.*\)/\1/p'`
  10     hard_float_sf=`$CC $CFLAGS $CPPFLAGS -E -dM -xc /dev/null |
  11       sed -n 's/^#define __CSKY_HARD_FLOAT_FPU_SF__ \(.*\)/\1/p'`
  12     hard_float_abi=`$CC $CFLAGS $CPPFLAGS -E -dM -xc /dev/null |
  13       sed -n 's/^#define __CSKY_HARD_FLOAT_ABI__ \(.*\)/\1/p'`
  14
  15     case "$abi" in
  16     1)
  17         AC_MSG_ERROR([glibc does not support abiv1 yet], [1])
  18         ;;
  19     2)
  20         machine=abiv2
  21         ;;
  22     *)
  23         AC_MSG_ERROR([Unknown abi], [1])
  24         ;;
  25     esac
  26
  27     # __CSKY_HARD_FLOAT_ABI__ was added on gcc 11 to specify whether
  28     # -mfloat-abi=hard is set.  On older gcc, the float ABI is defined solely
  29     # with __CSKY_HARD_FLOAT__.  If __CSKY_HARD_FLOAT__ is set, it can be
  30     # either a hard-float ABI (gcc older than 11, or gcc11 -mfloat-abi=hard
  31     # (__CSKY_HARD_FLOAT_ABI__ is set) or -mfloat-abi=softfp
  32     # (__CSKY_HARD_FLOAT_ABI__ is not set). To be compatible with older gcc,
  33     # use __CSKY_HARD_FLOAT_FPU_SF__ identify if -mfloat-abi is supported,
  34     # because it is added to gcc at the same time as -mfloat-abi.
  35     if test -n "$hard_float"; then
  36         if test -z "$hard_float_sf"; then
  37             with_fp_cond=1
  38         else
  39             if test -n "$hard_float_abi"; then
  40                 with_fp_cond=1
  41             else
  42                 with_fp_cond=0
  43             fi
  44         fi
  45     else
  46         with_fp_cond=0
  47     fi
  48
  49     base_machine=csky
  50     machine=csky/$machine
  51
  52     AC_DEFINE_UNQUOTED([CSKYABI], [$abi])
  53     AC_DEFINE_UNQUOTED([CSKY_HARD_FLOAT], [$with_fp_cond])
  54     ;;
  55 esac